lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub url_folder_cache {
 120         my ($self) = @_;
 121         require PublicInbox::SharedKV; # URI => updated_at_sec_
 122         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 123 }
 124
 125 sub ale {
 126         my ($self) = @_;
 127         $self->{ale} //= do {
 128                 require PublicInbox::LeiALE;
 129                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 130         };
 131 }
 132
 133 sub index_opt {
 134         # TODO: drop underscore variants everywhere, they're undocumented
 135         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 136         max_size|max-size=s sequential_shard|sequential-shard
 137         batch_size|batch-size=s skip-docdata)
 138 }
 139
 140 my @c_opt = qw(c=s@ C=s@ quiet|q);
 141 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 142         import-remote! no-torsocks torsocks=s),
 143         PublicInbox::LeiQuery::curl_opt());
 144
 145 # we don't support -C as an alias for --find-copies since it's already
 146 # used for chdir
 147 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 148         output-indicator-context=s indent-heuristic!
 149         minimal patience histogram anchored=s@ diff-algorithm=s
 150         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 151         word-diff:s word-diff-regex=s color-words:s no-renames
 152         rename-empty! check ws-error-highlight=s full-index binary
 153         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 154         find-copies-harder irreversible-delete|D l=i diff-filter=s
 155         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 156         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 157         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 158         inter-hunk-context=i function-context|W exit-code ext-diff
 159         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 160         line-prefix=s);
 161
 162 # we generate shell completion + help using %CMD and %OPTDESC,
 163 # see lei__complete() and PublicInbox::LeiHelp
 164 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 165 our %CMD = ( # sorted in order of importance/use:
 166 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 167         'stdin|', # /|\z/ must be first for lone dash
 168         @lxs_opt,
 169         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 170         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 171         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 172         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 173
 174 'up' => [ 'OUTPUT|--all', 'update saved search',
 175         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 176
 177 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 178         'stdin|', # /|\z/ must be first for lone dash
 179         # some of these options are ridiculous for lcat
 180         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 181         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 182         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 183         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 184
 185 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 186         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 187         @lxs_opt, @c_opt ],
 188
 189 'rediff' => [ '--stdin|LOCATION...',
 190                 'regenerate a diff with different options',
 191         'stdin|', # /|\z/ must be first for lone dash
 192         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 193         @diff_opt, @lxs_opt, @c_opt ],
 194
 195 'add-external' => [ 'LOCATION',
 196         'add/set priority of a publicinbox|extindex for extra matches',
 197         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 198         verbose|v+), @c_opt, index_opt(),
 199         PublicInbox::LeiQuery::curl_opt() ],
 200 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 201         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 202 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 203 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 204                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 205 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 206                 qw(z|0 ascii l url), @c_opt ],
 207 'forget-external' => [ 'LOCATION...|--prune',
 208         'exclude further results from a publicinbox|extindex',
 209         qw(prune), @c_opt ],
 210
 211 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 212                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 213 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 214                 qw(verbose|v+), @c_opt ],
 215 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 216                         @c_opt ],
 217 'rm' => [ '--stdin|LOCATION...',
 218         'remove a message from the index and prevent reindexing',
 219         'stdin|', # /|\z/ must be first for lone dash
 220         @c_opt ],
 221 'plonk' => [ '--threads|--from=IDENT',
 222         'exclude mail matching From: or threads from non-Message-ID searches',
 223         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 224 'tag' => [ 'KEYWORDS...',
 225         'set/unset keywords and/or labels on message(s)',
 226         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 227         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 228         pass_through('-kw:foo for delete') ],
 229
 230 'purge-mailsource' => [ 'LOCATION|--all',
 231         'remove imported messages from IMAP, Maildirs, and MH',
 232         qw(exact! all jobs:i indexed), @c_opt ],
 233
 234 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 235         qw(import! kw! interval=s recursive|r
 236         exclude=s include=s), @c_opt ],
 237 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 238                 qw(format|f=s z), @c_opt ],
 239 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 240 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 241 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 242         qw(prune), @c_opt ],
 243
 244 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 245         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 246         verbose|v+ incremental!),
 247          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 248          @c_opt ],
 249 'import' => [ 'LOCATION...|--stdin',
 250         'one-time import/update from URL or filesystem',
 251         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 252         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 253         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 254 'forget-mail-sync' => [ 'LOCATION...',
 255         'forget sync information for a mail folder', @c_opt ],
 256 'prune-mail-sync' => [ 'LOCATION...|--all',
 257         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 258 'export-kw' => [ 'LOCATION...|--all',
 259         'one-time export of keywords of sync sources',
 260         qw(all:s mode=s), @c_opt ],
 261 'convert' => [ 'LOCATION...|--stdin',
 262         'one-time conversion from URL or filesystem to another format',
 263         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 264         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 265 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 266         "use a patch to generate a query for `lei q --stdin'",
 267         qw(stdin| want|w=s@ uri debug), @c_opt ],
 268 'config' => [ '[...]', sub {
 269                 'git-config(1) wrapper for '._config_path($_[0]);
 270         }, qw(config-file|system|global|file|f=s), # for conflict detection
 271          qw(c=s@ C=s@), pass_through('git config') ],
 272 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 273         qw(pretty ascii dir=s), @c_opt ],
 274
 275 'init' => [ '[DIRNAME]', sub {
 276         "initialize storage, default: ".store_path($_[0]);
 277         }, @c_opt ],
 278 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 279         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 280         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 281 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 282 'help' => [ '[SUBCOMMAND]', 'show help' ],
 283
 284 # TODO
 285 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 286 #       'rewrite git history in an attempt to improve compression',
 287 #       qw(gc!), @c_opt ],
 288 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 289 #
 290 # internal commands are prefixed with '_'
 291 '_complete' => [ '[...]', 'internal shell completion helper',
 292                 pass_through('everything') ],
 293 ); # @CMD
 294
 295 # switch descriptions, try to keep consistent across commands
 296 # $spec: Getopt::Long option specification
 297 # $spec => [@ALLOWED_VALUES (default is first), $description],
 298 # $spec => $description
 299 # "$SUB_COMMAND TAB $spec" => as above
 300 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 301                         'specify message input format' ];
 302 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 303
 304 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 305 my %OPTDESC = (
 306 'help|h' => 'show this built-in help',
 307 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 308 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 309 'quiet|q' => 'be quiet',
 310 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 311         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 312
 313 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 314 'globoff|g' => "do not match locations using '*?' wildcards ".
 315                 "and\xa0'[]'\x{a0}ranges",
 316 'invert-match|v' => 'select non-matching lines',
 317 'color!' => 'disable color (for --format=text)',
 318 'verbose|v+' => 'be more verbose',
 319 'external!' => 'do not use externals',
 320 'mail!' => 'do not look in mail storage for OID',
 321 'cwd!' => 'do not look in git repo of current working directory',
 322 'oid-a|A=s' => 'pre-image OID',
 323 'path-a|a=s' => 'pre-image pathname associated with OID',
 324 'path-b|b=s' => 'post-image pathname associated with OID',
 325 'git-dir=s@' => 'additional git repository to scan',
 326 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 327 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 328         "proxy for (e.g. `socks5h://0:9050')" ],
 329 'torsocks=s' => ['VAL|auto|no|yes',
 330                 'whether or not to wrap git and curl commands with torsocks'],
 331 'no-torsocks' => 'alias for --torsocks=no',
 332 'save' =>  "save a search for `lei up'",
 333 'import-remote!' => 'do not memoize remote messages into local store',
 334
 335 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 336
 337 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 338                 'deduplication strategy'],
 339 'threads|t+' =>
 340         'return all messages in the same threads as the actual match(es)',
 341
 342 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 343                 'search prefixes to extract (default: dfpost7)' ],
 344
 345 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 346         'run command(s) or perform ops when done writing to output ' .
 347         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 348         'nothing otherwise)' ],
 349
 350 'augment|a' => 'augment --output destination instead of clobbering',
 351
 352 'output|mfolder|o=s' => [ 'MFOLDER',
 353         "destination (e.g.\xa0`/path/to/Maildir', ".
 354         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 355 'mua=s' => [ 'CMD',
 356         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 357 'new-only       import' => 'only import new messages from IMAP source',
 358
 359 'inbox-version=i' => [ 'NUM|1|2',
 360                 'force a public-inbox version with --mirror'],
 361 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 362
 363 # public-inbox-index options
 364 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 365 'compact' => 'run compact index after mirroring',
 366 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 367         "indexlevel with --mirror (default: full)" ],
 368 'max_size|max-size=s' => [ 'SIZE',
 369         'do not index messages larger than SIZE (default: infinity)' ],
 370 'batch_size|batch-size=s' => [ 'SIZE',
 371         'flush changes to OS after given number of bytes (default: 1m)' ],
 372 'sequential_shard|sequential-shard' =>
 373         'index Xapian shards sequentially for slow storage',
 374 'skip-docdata' =>
 375         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 376
 377 'format|f=s     q' => [
 378         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 379                 'specify output format, default depends on --output'],
 380 'exclude=s@     q' => [ 'LOCATION',
 381                 'exclude specified external(s) from search' ],
 382 'include|I=s@   q' => [ 'LOCATION',
 383                 'include specified external(s) in search' ],
 384 'only=s@        q' => [ 'LOCATION',
 385                 'only use specified external(s) for search' ],
 386 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 387                 'control number of search and writer jobs' ],
 388 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 389
 390 'in-format|F=s' => $stdin_formats,
 391 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 392                         'listing output format' ],
 393 'l      ls-search' => 'long listing format',
 394 'l      ls-mail-source' => 'long listing format',
 395 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 396 'format|f=s     ls-external' => $ls_format,
 397
 398 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 399 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 400
 401 'sort|s=s' => [ 'VAL|received|relevance|docid',
 402                 "order of results is `--output'-dependent"],
 403 'reverse|r' => 'reverse search results', # like sort(1)
 404
 405 'boost=i' => 'increase/decrease priority of results (default: 0)',
 406
 407 'local' => 'limit operations to the local filesystem',
 408 'local!' => 'exclude results from the local filesystem',
 409 'remote' => 'limit operations to those requiring network access',
 410 'remote!' => 'prevent operations requiring network access',
 411
 412 'all:s  up' => ['local', 'update all (local) saved searches' ],
 413
 414 'mid=s' => 'specify the Message-ID of a message',
 415 'oid=s' => 'specify the git object ID of a message',
 416
 417 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 418 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 419 'include=s' => 'include mailboxes/newsgroups based on pattern',
 420
 421 'exact' => 'operate on exact header matches only',
 422 'exact!' => 'rely on content match instead of exact header matches',
 423
 424 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 425
 426 'kw!' => 'disable/enable importing keywords (aka "flags")',
 427
 428 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 429 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 430
 431 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 432 ); # %OPTDESC
 433
 434 my %CONFIG_KEYS = (
 435         'leistore.dir' => 'top-level storage location',
 436 );
 437
 438 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1); # internal workers
 439
 440 sub _drop_wq {
 441         my ($self) = @_;
 442         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 443                 if ($wq->wq_kill) {
 444                         $wq->wq_close(0, undef, $self);
 445                 } elsif ($wq->wq_kill_old) {
 446                         $wq->wq_wait_old(undef, $self);
 447                 }
 448                 $wq->DESTROY;
 449         }
 450 }
 451
 452 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 453 sub x_it ($$) {
 454         my ($self, $code) = @_;
 455         # make sure client sees stdout before exit
 456         $self->{1}->autoflush(1) if $self->{1};
 457         dump_and_clear_log();
 458         stop_pager($self);
 459         if ($self->{pkt_op_p}) { # to top lei-daemon
 460                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 461         } elsif ($self->{sock}) { # to lei(1) client
 462                 send($self->{sock}, "x_it $code", MSG_EOR);
 463         } # else ignore if client disconnected
 464 }
 465
 466 sub err ($;@) {
 467         my $self = shift;
 468         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 469         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 470         print $err @_, @eor and return;
 471         my $old_err = delete $self->{2};
 472         close($old_err) if $! == EPIPE && $old_err;
 473         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 474         print $err @_, @eor or print STDERR @_, @eor;
 475 }
 476
 477 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 478
 479 sub fail_handler ($;$$) {
 480         my ($lei, $code, $io) = @_;
 481         close($io) if $io; # needed to avoid warnings on SIGPIPE
 482         _drop_wq($lei);
 483         x_it($lei, $code // (1 << 8));
 484 }
 485
 486 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 487         fail_handler($_[0], 13, delete $_[0]->{1});
 488 }
 489
 490 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 491 sub sigint_reap {
 492         my ($pgid) = @_;
 493         dwaitpid($pgid) if kill('-INT', $pgid);
 494 }
 495
 496 sub fail ($$;$) {
 497         my ($self, $buf, $exit_code) = @_;
 498         $self->{failed}++;
 499         err($self, $buf) if defined $buf;
 500         # calls fail_handler:
 501         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 502         x_it($self, ($exit_code // 1) << 8);
 503         undef;
 504 }
 505
 506 sub out ($;@) {
 507         my $self = shift;
 508         return if print { $self->{1} // return } @_; # likely
 509         return note_sigpipe($self, 1) if $! == EPIPE;
 510         my $err = "error writing to output: $!";
 511         delete $self->{1};
 512         fail($self, $err);
 513 }
 514
 515 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 516
 517 sub child_error { # passes non-fatal curl exit codes to user
 518         my ($self, $child_error, $msg) = @_; # child_error is $?
 519         $self->err($msg) if $msg;
 520         if ($self->{pkt_op_p}) { # to top lei-daemon
 521                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 522         } elsif ($self->{sock}) { # to lei(1) client
 523                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 524         } # else noop if client disconnected
 525 }
 526
 527 sub note_sigpipe { # triggers sigpipe_handler
 528         my ($self, $fd) = @_;
 529         close(delete($self->{$fd})); # explicit close silences Perl warning
 530         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 531         x_it($self, 13);
 532 }
 533
 534 sub _lei_atfork_child {
 535         my ($self, $persist) = @_;
 536         # we need to explicitly close things which are on stack
 537         if ($persist) {
 538                 chdir '/' or die "chdir(/): $!";
 539                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 540                 if (my $cfg = $self->{cfg}) {
 541                         delete $cfg->{-lei_store};
 542                 }
 543         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 544                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 545                 STDERR->autoflush(1);
 546         }
 547         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 548         if (my $op_c = delete $self->{pkt_op_c}) {
 549                 close(delete $op_c->{sock});
 550         }
 551         if (my $pgr = delete $self->{pgr}) {
 552                 close($_) for (@$pgr[1,2]);
 553         }
 554         close $listener if $listener;
 555         undef $listener;
 556         undef $dir_idle;
 557         %PATH2CFG = ();
 558         undef $errors_log;
 559         $quit = \&CORE::exit;
 560         $self->{-eml_noisy} or # only "lei import" sets this atm
 561                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 562         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 563 }
 564
 565 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 566         my ($self) = @_;
 567         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 568                 $op->close; # PublicInbox::PktOp::close
 569         }
 570         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 571         close $pkt_op_p->{op_p};
 572 }
 573
 574 sub pkt_op_pair {
 575         my ($self) = @_;
 576         require PublicInbox::OnDestroy;
 577         require PublicInbox::PktOp;
 578         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 579         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 580         $end;
 581 }
 582
 583 sub incr {
 584         my ($self, $field, $nr) = @_;
 585         $self->{counters}->{$field} += $nr;
 586 }
 587
 588 sub workers_start {
 589         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 590         $ops = {
 591                 '!' => [ \&fail_handler, $lei ],
 592                 '|' => [ \&sigpipe_handler, $lei ],
 593                 'x_it' => [ \&x_it, $lei ],
 594                 'child_error' => [ \&child_error, $lei ],
 595                 'incr' => [ \&incr, $lei ],
 596                 ($ops ? %$ops : ()),
 597         };
 598         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 599         my $end = $lei->pkt_op_pair;
 600         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 601         $flds->{lei} = $lei;
 602         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 603         delete $lei->{pkt_op_p};
 604         my $op_c = delete $lei->{pkt_op_c};
 605         @$end = ();
 606         $lei->event_step_init;
 607         ($op_c, $ops);
 608 }
 609
 610 # call this when we're ready to wait on events and yield to other clients
 611 sub wait_wq_events {
 612         my ($lei, $op_c, $ops) = @_;
 613         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 614                 $wq->wq_close(1);
 615         }
 616         $op_c->{ops} = $ops;
 617 }
 618
 619 sub _help {
 620         require PublicInbox::LeiHelp;
 621         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 622 }
 623
 624 sub optparse ($$$) {
 625         my ($self, $cmd, $argv) = @_;
 626         # allow _complete --help to complete, not show help
 627         return 1 if substr($cmd, 0, 1) eq '_';
 628         $self->{cmd} = $cmd;
 629         $OPT = $self->{opt} //= {};
 630         my $info = $CMD{$cmd} // [ '[...]' ];
 631         my ($proto, undef, @spec) = @$info;
 632         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 633         push @spec, qw(help|h);
 634         my $lone_dash;
 635         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 636                 $lone_dash = $spec[0];
 637                 $OPT->{$spec[0]} = \(my $var);
 638                 push @spec, '' => \$var;
 639         }
 640         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 641                 return _help($self, "bad arguments or options for $cmd");
 642         return _help($self) if $OPT->{help};
 643
 644         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 645
 646         # "-" aliases "stdin" or "clear"
 647         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 648
 649         my $i = 0;
 650         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 651         my ($err, $inf);
 652         my @args = split(/ /, $proto);
 653         for my $var (@args) {
 654                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 655                         $inf = defined($argv->[$i]) and last;
 656                         $var =~ s/\.\.\.\z//;
 657                         $err = "$var not supplied";
 658                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 659                         $argv->[$i++] // ($err = "$var not supplied");
 660                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 661                         $inf = 1;
 662                         last;
 663                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 664                         $i++;
 665                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 666                         $inf = 1 if index($var, '...') > 0;
 667                         my @or = split(/\|/, $var);
 668                         my $ok;
 669                         for my $o (@or) {
 670                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 671                                         my $sw = $1;
 672                                         # assume pipe/regular file on stdin
 673                                         # w/o args means stdin
 674                                         if ($sw eq 'stdin' && !@$argv &&
 675                                                         (-p $self->{0} ||
 676                                                          -f _) && -r _) {
 677                                                 $OPT->{stdin} //= 1;
 678                                         }
 679                                         $ok = defined($OPT->{$sw});
 680                                         last if $ok;
 681                                 } elsif (defined($argv->[$i])) {
 682                                         $ok = 1;
 683                                         $i++;
 684                                         last;
 685                                 } # else continue looping
 686                         }
 687                         last if $ok;
 688                         my $last = pop @or;
 689                         $err = join(', ', @or) . " or $last must be set";
 690                 } else {
 691                         warn "BUG: can't parse `$var' in $proto";
 692                 }
 693                 last if $err;
 694         }
 695         if (!$inf && scalar(@$argv) > scalar(@args)) {
 696                 $err //= 'too many arguments';
 697         }
 698         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 699 }
 700
 701 sub _tmp_cfg { # for lei -c <name>=<value> ...
 702         my ($self) = @_;
 703         my $cfg = _lei_cfg($self, 1);
 704         require File::Temp;
 705         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 706         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 707         $ft->autoflush(1);
 708         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 709 [include]
 710         path = $cfg->{-f}
 711 EOM
 712         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 713         for (@{$self->{opt}->{c}}) {
 714                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 715 `-c $_' is not of the form -c <name>=<value>'
 716 EOM
 717                 my $name = $1;
 718                 my $value = $2 // 1;
 719                 _config($self, '--add', $name, $value);
 720                 if (defined(my $v = $tmp->{$name})) {
 721                         if (ref($v) eq 'ARRAY') {
 722                                 push @$v, $value;
 723                         } else {
 724                                 $tmp->{$name} = [ $v, $value ];
 725                         }
 726                 } else {
 727                         $tmp->{$name} = $value;
 728                 }
 729         }
 730 }
 731
 732 sub lazy_cb ($$$) {
 733         my ($self, $cmd, $pfx) = @_;
 734         my $ucmd = $cmd;
 735         $ucmd =~ tr/-/_/;
 736         my $cb;
 737         $cb = $self->can($pfx.$ucmd) and return $cb;
 738         my $base = $ucmd;
 739         $base =~ s/_([a-z])/\u$1/g;
 740         my $pkg = "PublicInbox::Lei\u$base";
 741         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 742                 $pkg->can($pfx.$ucmd) : undef;
 743 }
 744
 745 sub dispatch {
 746         my ($self, $cmd, @argv) = @_;
 747         local $current_lei = $self; # for __WARN__
 748         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 749         dump_and_clear_log("from previous run\n");
 750         return _help($self, 'no command given') unless defined($cmd);
 751         # do not support Getopt bundling for this
 752         while ($cmd eq '-C' || $cmd eq '-c') {
 753                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 754                                         '-C DIRECTORY' : '-c <name>=<value>');
 755                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 756                 $cmd = shift(@argv) // return _help($self, 'no command given');
 757         }
 758         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 759                 optparse($self, $cmd, \@argv) or return;
 760                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 761                 if (my $chdir = $self->{opt}->{C}) {
 762                         for my $d (@$chdir) {
 763                                 next if $d eq ''; # same as git(1)
 764                                 chdir $d or return fail($self, "cd $d: $!");
 765                         }
 766                         open $self->{3}, '.' or return fail($self, "open . $!");
 767                 }
 768                 $cb->($self, @argv);
 769         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 770                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 771                         or return _help($self, 'bad arguments or options');
 772                 _help($self);
 773         } else {
 774                 fail($self, "`$cmd' is not an lei command");
 775         }
 776 }
 777
 778 sub _lei_cfg ($;$) {
 779         my ($self, $creat) = @_;
 780         return $self->{cfg} if $self->{cfg};
 781         my $f = _config_path($self);
 782         my @st = stat($f);
 783         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 784         my ($sto, $sto_dir);
 785         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 786                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 787                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 788         }
 789         if (!@st) {
 790                 unless ($creat) {
 791                         delete $self->{cfg};
 792                         return bless {}, 'PublicInbox::Config';
 793                 }
 794                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 795                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 796                 open my $fh, '>>', $f or die "open($f): $!\n";
 797                 @st = stat($fh) or die "fstat($f): $!\n";
 798                 $cur_st = pack('dd', $st[10], $st[7]);
 799                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 800         }
 801         my $cfg = PublicInbox::Config->git_config_dump($f);
 802         $cfg->{-st} = $cur_st;
 803         $cfg->{'-f'} = $f;
 804         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 805                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 806                                                 store_path($self))) {
 807                 $cfg->{-lei_store} = $sto;
 808         }
 809         if (scalar(keys %PATH2CFG) > 5) {
 810                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 811                 for my $k (keys %PATH2CFG) {
 812                         delete($PATH2CFG{$k}) unless -f $k
 813                 }
 814         }
 815         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 816 }
 817
 818 sub _lei_store ($;$) {
 819         my ($self, $creat) = @_;
 820         my $cfg = _lei_cfg($self, $creat);
 821         $cfg->{-lei_store} //= do {
 822                 require PublicInbox::LeiStore;
 823                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 824                 return unless $creat || -d $dir;
 825                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 826         };
 827 }
 828
 829 sub _config {
 830         my ($self, @argv) = @_;
 831         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 832         my $cfg = _lei_cfg($self, 1);
 833         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 834         my %rdr = map { $_ => $self->{$_} } (0..2);
 835         waitpid(spawn($cmd, \%env, \%rdr), 0);
 836 }
 837
 838 sub lei_config {
 839         my ($self, @argv) = @_;
 840         $self->{opt}->{'config-file'} and return fail $self,
 841                 "config file switches not supported by `lei config'";
 842         _config(@_);
 843         x_it($self, $?) if $?;
 844 }
 845
 846 sub lei_daemon_pid { puts shift, $$ }
 847
 848 sub lei_daemon_kill {
 849         my ($self) = @_;
 850         my $sig = $self->{opt}->{signal} // 'TERM';
 851         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 852 }
 853
 854 # Shell completion helper.  Used by lei-completion.bash and hopefully
 855 # other shells.  Try to do as much here as possible to avoid redundancy
 856 # and improve maintainability.
 857 sub lei__complete {
 858         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 859         shift @argv; # ignore "lei", the entire command is sent
 860         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 861         my $cmd = shift @argv;
 862         my $info = $CMD{$cmd} // do { # filter matching commands
 863                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 864                 return;
 865         };
 866         my ($proto, undef, @spec) = @$info;
 867         my $cur = pop @argv;
 868         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 869         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 870                 # gross special case since the only git-config options
 871                 # Consider moving to a table if we need more special cases
 872                 # we use Getopt::Long for are the ones we reject, so these
 873                 # are the ones we don't reject:
 874                 if ($cmd eq 'config') {
 875                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 876                         @spec = qw(add z|null get get-all unset unset-all
 877                                 replace-all get-urlmatch
 878                                 remove-section rename-section
 879                                 name-only list|l edit|e
 880                                 get-color-name get-colorbool);
 881                         # fall-through
 882                 }
 883                 # generate short/long names from Getopt::Long specs
 884                 puts $self, grep(/$re/, qw(--help -h -C), map {
 885                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 886                         } elsif (s/\+\z//) { # verbose|v+
 887                         } elsif (s/!\z//) {
 888                                 # negation: mail! => no-mail|mail
 889                                 s/([\w\-]+)/$1|no-$1/g
 890                         }
 891                         map {
 892                                 my $x = length > 1 ? "--$_" : "-$_";
 893                                 $x eq $_cur ? () : $x;
 894                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 895                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 896         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 897                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 898         }
 899
 900         # switch args (e.g. lei q -f mbox<TAB>)
 901         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 902                 my $opt = quotemeta $1;
 903                 puts $self, map {
 904                         my $v = $OPTDESC{$_};
 905                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 906                         # get rid of ALL CAPS placeholder (e.g "OUT")
 907                         # (TODO: completion for external paths)
 908                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 909                         @v;
 910                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 911         }
 912         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 913                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 914         }
 915         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 916         # proto parsing.
 917 }
 918
 919 sub exec_buf ($$) {
 920         my ($argv, $env) = @_;
 921         my $argc = scalar @$argv;
 922         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 923         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 924         $buf;
 925 }
 926
 927 sub start_mua {
 928         my ($self) = @_;
 929         my $mua = $self->{opt}->{mua} // return;
 930         my $mfolder = $self->{ovv}->{dst};
 931         my (@cmd, $replaced);
 932         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 933                 @cmd = ($mua, '-f');
 934         # TODO: help wanted: other common FOSS MUAs
 935         } else {
 936                 require Text::ParseWords;
 937                 @cmd = Text::ParseWords::shellwords($mua);
 938                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 939                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 940         }
 941         push @cmd, $mfolder unless defined($replaced);
 942         if ($self->{sock}) { # lei(1) client process runs it
 943                 # restore terminal: echo $query | lei q --stdin --mua=...
 944                 my $io = [];
 945                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 946                 send_exec_cmd($self, $io, \@cmd, {});
 947         }
 948         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 949                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 950         }
 951         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 952         $self->{opt}->{quiet} = 1;
 953         delete $self->{-progress};
 954         delete $self->{opt}->{verbose};
 955 }
 956
 957 sub send_exec_cmd { # tell script/lei to execute a command
 958         my ($self, $io, $cmd, $env) = @_;
 959         my $sock = $self->{sock} // die 'lei client gone';
 960         my $fds = [ map { fileno($_) } @$io ];
 961         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 962 }
 963
 964 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 965         my ($self) = @_;
 966         my $alerts = $self->{opt}->{alert} // return;
 967         my $sock = $self->{sock};
 968         while (my $op = shift(@$alerts)) {
 969                 if ($op eq ':WINCH') {
 970                         # hit the process group that started the MUA
 971                         send($sock, '-WINCH', MSG_EOR) if $sock;
 972                 } elsif ($op eq ':bell') {
 973                         out($self, "\a");
 974                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 975                         push @$alerts, split(/(?<!\\),/, $op);
 976                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 977                         my $cmd = $1; # run an arbitrary command
 978                         require Text::ParseWords;
 979                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 980                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 981                 } else {
 982                         err($self, "W: unsupported --alert=$op"); # non-fatal
 983                 }
 984         }
 985 }
 986
 987 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 988 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 989
 990 # this also normalizes the path
 991 sub path_to_fd {
 992         my ($self, $path) = @_;
 993         $path = rel2abs($self, $path);
 994         $path =~ tr!/!/!s;
 995         $path_to_fd{$path} // (
 996                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 997                         fail($self, "cannot open $path from daemon") : -1
 998         );
 999 }
1000
1001 # caller needs to "-t $self->{1}" to check if tty
1002 sub start_pager {
1003         my ($self) = @_;
1004         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1005         chomp(my $pager = <$fh> // '');
1006         close($fh) or warn "`git var PAGER' error: \$?=$?";
1007         return if $pager eq 'cat' || $pager eq '';
1008         my $new_env = { LESS => 'FRX', LV => '-c' };
1009         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1010         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1011         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1012         my $pgr = [ undef, @$rdr{1, 2} ];
1013         my $env = $self->{env};
1014         if ($self->{sock}) { # lei(1) process runs it
1015                 delete @$new_env{keys %$env}; # only set iff unset
1016                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1017         } else {
1018                 die 'BUG: start_pager w/o socket';
1019         }
1020         $self->{1} = $wpager;
1021         $self->{2} = $wpager if -t $self->{2};
1022         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1023         $self->{pgr} = $pgr;
1024 }
1025
1026 sub stop_pager {
1027         my ($self) = @_;
1028         my $pgr = delete($self->{pgr}) or return;
1029         $self->{2} = $pgr->[2];
1030         # do not restore original stdout, just close it so we error out
1031         close(delete($self->{1})) if $self->{1};
1032 }
1033
1034 sub accept_dispatch { # Listener {post_accept} callback
1035         my ($sock) = @_; # ignore other
1036         $sock->autoflush(1);
1037         my $self = bless { sock => $sock }, __PACKAGE__;
1038         vec(my $rvec = '', fileno($sock), 1) = 1;
1039         select($rvec, undef, undef, 60) or
1040                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1041         # (4096 * 33) >MAX_ARG_STRLEN
1042         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1043         if (!defined($fds[0])) {
1044                 warn(my $msg = "recv_cmd failed: $!");
1045                 return send($sock, $msg, MSG_EOR);
1046         } else {
1047                 my $i = 0;
1048                 for my $fd (@fds) {
1049                         open($self->{$i++}, '+<&=', $fd) and next;
1050                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1051                 }
1052                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1053         }
1054         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1055         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1056         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1057                 return send($sock, 'request command truncated', MSG_EOR);
1058         my ($argc, @argv) = split(/\0/, $buf, -1);
1059         undef $buf;
1060         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1061         if (chdir($self->{3})) {
1062                 local %ENV = %env;
1063                 $self->{env} = \%env;
1064                 eval { dispatch($self, @argv) };
1065                 send($sock, $@, MSG_EOR) if $@;
1066         } else {
1067                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1068         }
1069 }
1070
1071 sub dclose {
1072         my ($self) = @_;
1073         delete $self->{-progress};
1074         _drop_wq($self) if $self->{failed};
1075         close(delete $self->{1}) if $self->{1}; # may reap_compress
1076         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1077 }
1078
1079 # for long-running results
1080 sub event_step {
1081         my ($self) = @_;
1082         local %ENV = %{$self->{env}};
1083         my $sock = $self->{sock};
1084         local $current_lei = $self;
1085         eval {
1086                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1087                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1088                                 return if $! == EAGAIN;
1089                                 next if $! == EINTR;
1090                                 last if $! == ECONNRESET;
1091                                 die "recvmsg: $!";
1092                         }
1093                         for my $fd (@fds) {
1094                                 open my $rfh, '+<&=', $fd;
1095                         }
1096                         die "unrecognized client signal: $buf";
1097                 }
1098                 _drop_wq($self); # EOF, client disconnected
1099                 dclose($self);
1100         };
1101         if (my $err = $@) {
1102                 eval { $self->fail($err) };
1103                 dclose($self);
1104         }
1105 }
1106
1107 sub event_step_init {
1108         my ($self) = @_;
1109         my $sock = $self->{sock} or return;
1110         $self->{-event_init_done} //= do { # persist til $ops done
1111                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1112                 $sock;
1113         };
1114 }
1115
1116 sub noop {}
1117
1118 sub oldset { $oldset }
1119
1120 sub dump_and_clear_log {
1121         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1122                 my @pfx = @_;
1123                 unshift(@pfx, "$errors_log ") if @pfx;
1124                 warn @pfx, do { local $/; <STDIN> };
1125                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1126         }
1127 }
1128
1129 # lei(1) calls this when it can't connect
1130 sub lazy_start {
1131         my ($path, $errno, $narg) = @_;
1132         local ($errors_log, $listener);
1133         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1134         $errors_log = "$sock_dir/errors.log";
1135         my $addr = pack_sockaddr_un($path);
1136         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1137         $lk->lock_acquire;
1138         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1139         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1140                 return if connect($listener, $addr); # another process won
1141                 if ($errno == ECONNREFUSED && -S $path) {
1142                         unlink($path) or die "unlink($path): $!";
1143                 }
1144         } else {
1145                 $! = $errno; # allow interpolation to stringify in die
1146                 die "connect($path): $!";
1147         }
1148         umask(077) // die("umask(077): $!");
1149         bind($listener, $addr) or die "bind($path): $!";
1150         listen($listener, 1024) or die "listen: $!";
1151         $lk->lock_release;
1152         undef $lk;
1153         my @st = stat($path) or die "stat($path): $!";
1154         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1155         local $oldset = PublicInbox::DS::block_signals();
1156         if ($narg == 5) {
1157                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1158                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1159                         require PublicInbox::CmdIPC4;
1160                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1161                         PublicInbox::CmdIPC4->can('recv_cmd4');
1162                 };
1163         }
1164         $recv_cmd or die <<"";
1165 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1166
1167         require PublicInbox::Listener;
1168         require PublicInbox::PktOp;
1169         (-p STDOUT) or die "E: stdout must be a pipe\n";
1170         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1171         STDIN->autoflush(1);
1172         dump_and_clear_log("from previous daemon process:\n");
1173         POSIX::setsid() > 0 or die "setsid: $!";
1174         my $pid = fork // die "fork: $!";
1175         return if $pid;
1176         $0 = "lei-daemon $path";
1177         local %PATH2CFG;
1178         $listener->blocking(0);
1179         my $exit_code;
1180         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1181         local $quit = do {
1182                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1183                 sub {
1184                         $exit_code //= shift;
1185                         my $lis = $pil or exit($exit_code);
1186                         # closing eof_p triggers \&noop wakeup
1187                         $listener = $eof_p = $pil = $path = undef;
1188                         $lis->close; # DS::close
1189                         PublicInbox::DS->SetLoopTimeout(1000);
1190                 };
1191         };
1192         my $sig = {
1193                 CHLD => \&PublicInbox::DS::enqueue_reap,
1194                 QUIT => $quit,
1195                 INT => $quit,
1196                 TERM => $quit,
1197                 HUP => \&noop,
1198                 USR1 => \&noop,
1199                 USR2 => \&noop,
1200         };
1201         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1202         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1203         undef $sig;
1204         local $SIG{PIPE} = 'IGNORE';
1205         require PublicInbox::DirIdle;
1206         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1207                 # just rely on wakeup ot hit PostLoopCallback set below
1208                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1209         }, 1);
1210         if ($sigfd) {
1211                 undef $sigfd; # unref, already in DS::DescriptorMap
1212         } else {
1213                 # wake up every second to accept signals if we don't
1214                 # have signalfd or IO::KQueue:
1215                 PublicInbox::DS::sig_setmask($oldset);
1216                 PublicInbox::DS->SetLoopTimeout(1000);
1217         }
1218         PublicInbox::DS->SetPostLoopCallback(sub {
1219                 my ($dmap, undef) = @_;
1220                 if (@st = defined($path) ? stat($path) : ()) {
1221                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1222                                 warn "$path dev/ino changed, quitting\n";
1223                                 $path = undef;
1224                         }
1225                 } elsif (defined($path)) { # ENOENT is common
1226                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1227                         undef $path;
1228                         $quit->();
1229                 }
1230                 return 1 if defined($path);
1231                 my $now = now();
1232                 my $n = 0;
1233                 for my $s (values %$dmap) {
1234                         $s->can('busy') or next;
1235                         if ($s->busy($now)) {
1236                                 ++$n;
1237                         } else {
1238                                 $s->close;
1239                         }
1240                 }
1241                 $n; # true: continue, false: stop
1242         });
1243
1244         # STDIN was redirected to /dev/null above, closing STDERR and
1245         # STDOUT will cause the calling `lei' client process to finish
1246         # reading the <$daemon> pipe.
1247         local $SIG{__WARN__} = sub {
1248                 $current_lei ? err($current_lei, @_) : warn(
1249                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1250         };
1251         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1252         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1253         # $daemon pipe to `lei' closed, main loop begins:
1254         PublicInbox::DS->EventLoop;
1255         exit($exit_code // 0);
1256 }
1257
1258 sub busy { 1 } # prevent daemon-shutdown if client is connected
1259
1260 # ensures stdout hits the FS before sock disconnects so a client
1261 # can immediately reread it
1262 sub DESTROY {
1263         my ($self) = @_;
1264         if (my $counters = delete $self->{counters}) {
1265                 for my $k (sort keys %$counters) {
1266                         my $nr = $counters->{$k};
1267                         $self->child_error(1 << 8, "$nr $k messages");
1268                 }
1269         }
1270         $self->{1}->autoflush(1) if $self->{1};
1271         stop_pager($self);
1272         # preserve $? for ->fail or ->x_it code
1273 }
1274
1275 sub wq_done_wait { # dwaitpid callback
1276         my ($arg, $pid) = @_;
1277         my ($wq, $lei) = @$arg;
1278         my $err_type = $lei->{-err_type};
1279         $? and $lei->child_error($?,
1280                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1281         $lei->dclose;
1282 }
1283
1284 sub fchdir {
1285         my ($lei) = @_;
1286         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1287         chdir($dh) || $lei->fail("fchdir: $!");
1288 }
1289
1290 sub wq_eof { # EOF callback for main daemon
1291         my ($lei) = @_;
1292         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1293         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1294 }
1295
1296 1;