lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 200                 qw(z|0 ascii l), @c_opt ],
 201 'forget-external' => [ 'LOCATION...|--prune',
 202         'exclude further results from a publicinbox|extindex',
 203         qw(prune), @c_opt ],
 204
 205 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 206                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 207 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 208                 qw(verbose|v+), @c_opt ],
 209 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 210                         @c_opt ],
 211 'rm' => [ '--stdin|LOCATION...',
 212         'remove a message from the index and prevent reindexing',
 213         'stdin|', # /|\z/ must be first for lone dash
 214         @c_opt ],
 215 'plonk' => [ '--threads|--from=IDENT',
 216         'exclude mail matching From: or threads from non-Message-ID searches',
 217         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 218 'tag' => [ 'KEYWORDS...',
 219         'set/unset keywords and/or labels on message(s)',
 220         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 221         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 222         pass_through('-kw:foo for delete') ],
 223
 224 'purge-mailsource' => [ 'LOCATION|--all',
 225         'remove imported messages from IMAP, Maildirs, and MH',
 226         qw(exact! all jobs:i indexed), @c_opt ],
 227
 228 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 229         qw(import! kw! interval=s recursive|r
 230         exclude=s include=s), @c_opt ],
 231 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 232                 qw(format|f=s z), @c_opt ],
 233 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 234 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 235 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 236         qw(prune), @c_opt ],
 237
 238 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 239         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 240         verbose|v+ incremental!),
 241          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 242          @c_opt ],
 243 'import' => [ 'LOCATION...|--stdin',
 244         'one-time import/update from URL or filesystem',
 245         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 246         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 247         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 248 'forget-mail-sync' => [ 'LOCATION...',
 249         'forget sync information for a mail folder', @c_opt ],
 250 'prune-mail-sync' => [ 'LOCATION...|--all',
 251         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 252 'export-kw' => [ 'LOCATION...|--all',
 253         'one-time export of keywords of sync sources',
 254         qw(all:s mode=s), @c_opt ],
 255 'convert' => [ 'LOCATION...|--stdin',
 256         'one-time conversion from URL or filesystem to another format',
 257         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 258         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 259 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 260         "use a patch to generate a query for `lei q --stdin'",
 261         qw(stdin| want|w=s@ uri debug), @c_opt ],
 262 'config' => [ '[...]', sub {
 263                 'git-config(1) wrapper for '._config_path($_[0]);
 264         }, qw(config-file|system|global|file|f=s), # for conflict detection
 265          qw(c=s@ C=s@), pass_through('git config') ],
 266 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 267         qw(pretty ascii dir=s), @c_opt ],
 268
 269 'init' => [ '[DIRNAME]', sub {
 270         "initialize storage, default: ".store_path($_[0]);
 271         }, @c_opt ],
 272 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 273         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 274         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 275 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 276 'help' => [ '[SUBCOMMAND]', 'show help' ],
 277
 278 # TODO
 279 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 280 #       'rewrite git history in an attempt to improve compression',
 281 #       qw(gc!), @c_opt ],
 282 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 283 #
 284 # internal commands are prefixed with '_'
 285 '_complete' => [ '[...]', 'internal shell completion helper',
 286                 pass_through('everything') ],
 287 ); # @CMD
 288
 289 # switch descriptions, try to keep consistent across commands
 290 # $spec: Getopt::Long option specification
 291 # $spec => [@ALLOWED_VALUES (default is first), $description],
 292 # $spec => $description
 293 # "$SUB_COMMAND TAB $spec" => as above
 294 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 295                         'specify message input format' ];
 296 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 297
 298 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 299 my %OPTDESC = (
 300 'help|h' => 'show this built-in help',
 301 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 302 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 303 'quiet|q' => 'be quiet',
 304 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 305         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 306
 307 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 308 'globoff|g' => "do not match locations using '*?' wildcards ".
 309                 "and\xa0'[]'\x{a0}ranges",
 310 'invert-match|v' => 'select non-matching lines',
 311 'color!' => 'disable color (for --format=text)',
 312 'verbose|v+' => 'be more verbose',
 313 'external!' => 'do not use externals',
 314 'mail!' => 'do not look in mail storage for OID',
 315 'cwd!' => 'do not look in git repo of current working directory',
 316 'oid-a|A=s' => 'pre-image OID',
 317 'path-a|a=s' => 'pre-image pathname associated with OID',
 318 'path-b|b=s' => 'post-image pathname associated with OID',
 319 'git-dir=s@' => 'additional git repository to scan',
 320 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 321         "proxy for (e.g. `socks5h://0:9050')" ],
 322 'torsocks=s' => ['VAL|auto|no|yes',
 323                 'whether or not to wrap git and curl commands with torsocks'],
 324 'no-torsocks' => 'alias for --torsocks=no',
 325 'save' =>  "save a search for `lei up'",
 326 'import-remote!' => 'do not memoize remote messages into local store',
 327
 328 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 329
 330 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 331                 'deduplication strategy'],
 332 'threads|t+' =>
 333         'return all messages in the same threads as the actual match(es)',
 334
 335 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 336                 'search prefixes to extract (default: dfpost7)' ],
 337
 338 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 339         'run command(s) or perform ops when done writing to output ' .
 340         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 341         'nothing otherwise)' ],
 342
 343 'augment|a' => 'augment --output destination instead of clobbering',
 344
 345 'output|mfolder|o=s' => [ 'MFOLDER',
 346         "destination (e.g.\xa0`/path/to/Maildir', ".
 347         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 348 'mua=s' => [ 'CMD',
 349         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 350
 351 'inbox-version=i' => [ 'NUM|1|2',
 352                 'force a public-inbox version with --mirror'],
 353 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 354
 355 # public-inbox-index options
 356 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 357 'compact' => 'run compact index after mirroring',
 358 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 359         "indexlevel with --mirror (default: full)" ],
 360 'max_size|max-size=s' => [ 'SIZE',
 361         'do not index messages larger than SIZE (default: infinity)' ],
 362 'batch_size|batch-size=s' => [ 'SIZE',
 363         'flush changes to OS after given number of bytes (default: 1m)' ],
 364 'sequential_shard|sequential-shard' =>
 365         'index Xapian shards sequentially for slow storage',
 366 'skip-docdata' =>
 367         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 368
 369 'format|f=s     q' => [
 370         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 371                 'specify output format, default depends on --output'],
 372 'exclude=s@     q' => [ 'LOCATION',
 373                 'exclude specified external(s) from search' ],
 374 'include|I=s@   q' => [ 'LOCATION',
 375                 'include specified external(s) in search' ],
 376 'only=s@        q' => [ 'LOCATION',
 377                 'only use specified external(s) for search' ],
 378 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 379                 'control number of search and writer jobs' ],
 380 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 381
 382 'in-format|F=s' => $stdin_formats,
 383 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 384                         'listing output format' ],
 385 'l      ls-search' => 'long listing format',
 386 'l      ls-mail-source' => 'long listing format',
 387 'format|f=s     ls-external' => $ls_format,
 388
 389 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 390 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 391
 392 'sort|s=s' => [ 'VAL|received|relevance|docid',
 393                 "order of results is `--output'-dependent"],
 394 'reverse|r' => 'reverse search results', # like sort(1)
 395
 396 'boost=i' => 'increase/decrease priority of results (default: 0)',
 397
 398 'local' => 'limit operations to the local filesystem',
 399 'local!' => 'exclude results from the local filesystem',
 400 'remote' => 'limit operations to those requiring network access',
 401 'remote!' => 'prevent operations requiring network access',
 402
 403 'all:s  up' => ['local', 'update all (local) saved searches' ],
 404
 405 'mid=s' => 'specify the Message-ID of a message',
 406 'oid=s' => 'specify the git object ID of a message',
 407
 408 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 409 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 410 'include=s' => 'include mailboxes/newsgroups based on pattern',
 411
 412 'exact' => 'operate on exact header matches only',
 413 'exact!' => 'rely on content match instead of exact header matches',
 414
 415 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 416
 417 'kw!' => 'disable/enable importing keywords (aka "flags")',
 418
 419 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 420 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 421
 422 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 423 ); # %OPTDESC
 424
 425 my %CONFIG_KEYS = (
 426         'leistore.dir' => 'top-level storage location',
 427 );
 428
 429 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1); # internal workers
 430
 431 sub _drop_wq {
 432         my ($self) = @_;
 433         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 434                 if ($wq->wq_kill) {
 435                         $wq->wq_close(0, undef, $self);
 436                 } elsif ($wq->wq_kill_old) {
 437                         $wq->wq_wait_old(undef, $self);
 438                 }
 439                 $wq->DESTROY;
 440         }
 441 }
 442
 443 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 444 sub x_it ($$) {
 445         my ($self, $code) = @_;
 446         # make sure client sees stdout before exit
 447         $self->{1}->autoflush(1) if $self->{1};
 448         dump_and_clear_log();
 449         if ($self->{pkt_op_p}) { # to top lei-daemon
 450                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 451         } elsif ($self->{sock}) { # to lei(1) client
 452                 send($self->{sock}, "x_it $code", MSG_EOR);
 453         } # else ignore if client disconnected
 454 }
 455
 456 sub err ($;@) {
 457         my $self = shift;
 458         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 460         print $err @_, @eor and return;
 461         my $old_err = delete $self->{2};
 462         close($old_err) if $! == EPIPE && $old_err;
 463         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 464         print $err @_, @eor or print STDERR @_, @eor;
 465 }
 466
 467 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 468
 469 sub fail_handler ($;$$) {
 470         my ($lei, $code, $io) = @_;
 471         close($io) if $io; # needed to avoid warnings on SIGPIPE
 472         _drop_wq($lei);
 473         x_it($lei, $code // (1 << 8));
 474 }
 475
 476 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 477         fail_handler($_[0], 13, delete $_[0]->{1});
 478 }
 479
 480 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 481 sub sigint_reap {
 482         my ($pgid) = @_;
 483         dwaitpid($pgid) if kill('-INT', $pgid);
 484 }
 485
 486 sub fail ($$;$) {
 487         my ($self, $buf, $exit_code) = @_;
 488         $self->{failed}++;
 489         err($self, $buf) if defined $buf;
 490         # calls fail_handler:
 491         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 492         x_it($self, ($exit_code // 1) << 8);
 493         undef;
 494 }
 495
 496 sub out ($;@) {
 497         my $self = shift;
 498         return if print { $self->{1} // return } @_; # likely
 499         return note_sigpipe($self, 1) if $! == EPIPE;
 500         my $err = "error writing to output: $!";
 501         delete $self->{1};
 502         fail($self, $err);
 503 }
 504
 505 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 506
 507 sub child_error { # passes non-fatal curl exit codes to user
 508         my ($self, $child_error, $msg) = @_; # child_error is $?
 509         $self->err($msg) if $msg;
 510         if ($self->{pkt_op_p}) { # to top lei-daemon
 511                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 512         } elsif ($self->{sock}) { # to lei(1) client
 513                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 514         } # else noop if client disconnected
 515 }
 516
 517 sub note_sigpipe { # triggers sigpipe_handler
 518         my ($self, $fd) = @_;
 519         close(delete($self->{$fd})); # explicit close silences Perl warning
 520         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 521         x_it($self, 13);
 522 }
 523
 524 sub _lei_atfork_child {
 525         my ($self, $persist) = @_;
 526         # we need to explicitly close things which are on stack
 527         if ($persist) {
 528                 chdir '/' or die "chdir(/): $!";
 529                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 530                 if (my $cfg = $self->{cfg}) {
 531                         delete $cfg->{-lei_store};
 532                 }
 533         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 534                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 535                 STDERR->autoflush(1);
 536         }
 537         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 538         if (my $op_c = delete $self->{pkt_op_c}) {
 539                 close(delete $op_c->{sock});
 540         }
 541         if (my $pgr = delete $self->{pgr}) {
 542                 close($_) for (@$pgr[1,2]);
 543         }
 544         close $listener if $listener;
 545         undef $listener;
 546         undef $dir_idle;
 547         %PATH2CFG = ();
 548         undef $errors_log;
 549         $quit = \&CORE::exit;
 550         $self->{-eml_noisy} or # only "lei import" sets this atm
 551                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 552         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 553 }
 554
 555 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 556         my ($self) = @_;
 557         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 558                 $op->close; # PublicInbox::PktOp::close
 559         }
 560         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 561         close $pkt_op_p->{op_p};
 562 }
 563
 564 sub pkt_op_pair {
 565         my ($self) = @_;
 566         require PublicInbox::OnDestroy;
 567         require PublicInbox::PktOp;
 568         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 569         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 570         $end;
 571 }
 572
 573 sub incr {
 574         my ($self, $field, $nr) = @_;
 575         $self->{counters}->{$field} += $nr;
 576 }
 577
 578 sub workers_start {
 579         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 580         $ops = {
 581                 '!' => [ \&fail_handler, $lei ],
 582                 '|' => [ \&sigpipe_handler, $lei ],
 583                 'x_it' => [ \&x_it, $lei ],
 584                 'child_error' => [ \&child_error, $lei ],
 585                 'incr' => [ \&incr, $lei ],
 586                 ($ops ? %$ops : ()),
 587         };
 588         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 589         my $end = $lei->pkt_op_pair;
 590         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 591         $flds->{lei} = $lei;
 592         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 593         delete $lei->{pkt_op_p};
 594         my $op_c = delete $lei->{pkt_op_c};
 595         @$end = ();
 596         $lei->event_step_init;
 597         ($op_c, $ops);
 598 }
 599
 600 # call this when we're ready to wait on events and yield to other clients
 601 sub wait_wq_events {
 602         my ($lei, $op_c, $ops) = @_;
 603         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 604                 $wq->wq_close(1);
 605         }
 606         $op_c->{ops} = $ops;
 607 }
 608
 609 sub _help {
 610         require PublicInbox::LeiHelp;
 611         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 612 }
 613
 614 sub optparse ($$$) {
 615         my ($self, $cmd, $argv) = @_;
 616         # allow _complete --help to complete, not show help
 617         return 1 if substr($cmd, 0, 1) eq '_';
 618         $self->{cmd} = $cmd;
 619         $OPT = $self->{opt} //= {};
 620         my $info = $CMD{$cmd} // [ '[...]' ];
 621         my ($proto, undef, @spec) = @$info;
 622         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 623         push @spec, qw(help|h);
 624         my $lone_dash;
 625         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 626                 $lone_dash = $spec[0];
 627                 $OPT->{$spec[0]} = \(my $var);
 628                 push @spec, '' => \$var;
 629         }
 630         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 631                 return _help($self, "bad arguments or options for $cmd");
 632         return _help($self) if $OPT->{help};
 633
 634         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 635
 636         # "-" aliases "stdin" or "clear"
 637         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 638
 639         my $i = 0;
 640         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 641         my ($err, $inf);
 642         my @args = split(/ /, $proto);
 643         for my $var (@args) {
 644                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 645                         $inf = defined($argv->[$i]) and last;
 646                         $var =~ s/\.\.\.\z//;
 647                         $err = "$var not supplied";
 648                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 649                         $argv->[$i++] // ($err = "$var not supplied");
 650                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 651                         $inf = 1;
 652                         last;
 653                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 654                         $i++;
 655                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 656                         $inf = 1 if index($var, '...') > 0;
 657                         my @or = split(/\|/, $var);
 658                         my $ok;
 659                         for my $o (@or) {
 660                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 661                                         my $sw = $1;
 662                                         # assume pipe/regular file on stdin
 663                                         # w/o args means stdin
 664                                         if ($sw eq 'stdin' && !@$argv &&
 665                                                         (-p $self->{0} ||
 666                                                          -f _) && -r _) {
 667                                                 $OPT->{stdin} //= 1;
 668                                         }
 669                                         $ok = defined($OPT->{$sw});
 670                                         last if $ok;
 671                                 } elsif (defined($argv->[$i])) {
 672                                         $ok = 1;
 673                                         $i++;
 674                                         last;
 675                                 } # else continue looping
 676                         }
 677                         last if $ok;
 678                         my $last = pop @or;
 679                         $err = join(', ', @or) . " or $last must be set";
 680                 } else {
 681                         warn "BUG: can't parse `$var' in $proto";
 682                 }
 683                 last if $err;
 684         }
 685         if (!$inf && scalar(@$argv) > scalar(@args)) {
 686                 $err //= 'too many arguments';
 687         }
 688         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 689 }
 690
 691 sub _tmp_cfg { # for lei -c <name>=<value> ...
 692         my ($self) = @_;
 693         my $cfg = _lei_cfg($self, 1);
 694         require File::Temp;
 695         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 696         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 697         $ft->autoflush(1);
 698         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 699 [include]
 700         path = $cfg->{-f}
 701 EOM
 702         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 703         for (@{$self->{opt}->{c}}) {
 704                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 705 `-c $_' is not of the form -c <name>=<value>'
 706 EOM
 707                 my $name = $1;
 708                 my $value = $2 // 1;
 709                 _config($self, '--add', $name, $value);
 710                 if (defined(my $v = $tmp->{$name})) {
 711                         if (ref($v) eq 'ARRAY') {
 712                                 push @$v, $value;
 713                         } else {
 714                                 $tmp->{$name} = [ $v, $value ];
 715                         }
 716                 } else {
 717                         $tmp->{$name} = $value;
 718                 }
 719         }
 720 }
 721
 722 sub lazy_cb ($$$) {
 723         my ($self, $cmd, $pfx) = @_;
 724         my $ucmd = $cmd;
 725         $ucmd =~ tr/-/_/;
 726         my $cb;
 727         $cb = $self->can($pfx.$ucmd) and return $cb;
 728         my $base = $ucmd;
 729         $base =~ s/_([a-z])/\u$1/g;
 730         my $pkg = "PublicInbox::Lei\u$base";
 731         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 732                 $pkg->can($pfx.$ucmd) : undef;
 733 }
 734
 735 sub dispatch {
 736         my ($self, $cmd, @argv) = @_;
 737         local $current_lei = $self; # for __WARN__
 738         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 739         dump_and_clear_log("from previous run\n");
 740         return _help($self, 'no command given') unless defined($cmd);
 741         # do not support Getopt bundling for this
 742         while ($cmd eq '-C' || $cmd eq '-c') {
 743                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 744                                         '-C DIRECTORY' : '-c <name>=<value>');
 745                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 746                 $cmd = shift(@argv) // return _help($self, 'no command given');
 747         }
 748         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 749                 optparse($self, $cmd, \@argv) or return;
 750                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 751                 if (my $chdir = $self->{opt}->{C}) {
 752                         for my $d (@$chdir) {
 753                                 next if $d eq ''; # same as git(1)
 754                                 chdir $d or return fail($self, "cd $d: $!");
 755                         }
 756                         if (delete $self->{3}) { # update cwd for rel2abs
 757                                 opendir my $dh, '.' or
 758                                         return fail($self, "opendir . $!");
 759                                 $self->{3} = $dh;
 760                         }
 761                 }
 762                 $cb->($self, @argv);
 763         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 764                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 765                         or return _help($self, 'bad arguments or options');
 766                 _help($self);
 767         } else {
 768                 fail($self, "`$cmd' is not an lei command");
 769         }
 770 }
 771
 772 sub _lei_cfg ($;$) {
 773         my ($self, $creat) = @_;
 774         return $self->{cfg} if $self->{cfg};
 775         my $f = _config_path($self);
 776         my @st = stat($f);
 777         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 778         my ($sto, $sto_dir);
 779         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 780                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 781                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 782         }
 783         if (!@st) {
 784                 unless ($creat) {
 785                         delete $self->{cfg};
 786                         return bless {}, 'PublicInbox::Config';
 787                 }
 788                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 789                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 790                 open my $fh, '>>', $f or die "open($f): $!\n";
 791                 @st = stat($fh) or die "fstat($f): $!\n";
 792                 $cur_st = pack('dd', $st[10], $st[7]);
 793                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 794         }
 795         my $cfg = PublicInbox::Config->git_config_dump($f);
 796         $cfg->{-st} = $cur_st;
 797         $cfg->{'-f'} = $f;
 798         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 799                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 800                                                 store_path($self))) {
 801                 $cfg->{-lei_store} = $sto;
 802         }
 803         if (scalar(keys %PATH2CFG) > 5) {
 804                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 805                 for my $k (keys %PATH2CFG) {
 806                         delete($PATH2CFG{$k}) unless -f $k
 807                 }
 808         }
 809         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 810 }
 811
 812 sub _lei_store ($;$) {
 813         my ($self, $creat) = @_;
 814         my $cfg = _lei_cfg($self, $creat);
 815         $cfg->{-lei_store} //= do {
 816                 require PublicInbox::LeiStore;
 817                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 818                 return unless $creat || -d $dir;
 819                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 820         };
 821 }
 822
 823 sub _config {
 824         my ($self, @argv) = @_;
 825         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 826         my $cfg = _lei_cfg($self, 1);
 827         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 828         my %rdr = map { $_ => $self->{$_} } (0..2);
 829         waitpid(spawn($cmd, \%env, \%rdr), 0);
 830 }
 831
 832 sub lei_config {
 833         my ($self, @argv) = @_;
 834         $self->{opt}->{'config-file'} and return fail $self,
 835                 "config file switches not supported by `lei config'";
 836         _config(@_);
 837         x_it($self, $?) if $?;
 838 }
 839
 840 sub lei_daemon_pid { puts shift, $$ }
 841
 842 sub lei_daemon_kill {
 843         my ($self) = @_;
 844         my $sig = $self->{opt}->{signal} // 'TERM';
 845         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 846 }
 847
 848 # Shell completion helper.  Used by lei-completion.bash and hopefully
 849 # other shells.  Try to do as much here as possible to avoid redundancy
 850 # and improve maintainability.
 851 sub lei__complete {
 852         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 853         shift @argv; # ignore "lei", the entire command is sent
 854         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 855         my $cmd = shift @argv;
 856         my $info = $CMD{$cmd} // do { # filter matching commands
 857                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 858                 return;
 859         };
 860         my ($proto, undef, @spec) = @$info;
 861         my $cur = pop @argv;
 862         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 863         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 864                 # gross special case since the only git-config options
 865                 # Consider moving to a table if we need more special cases
 866                 # we use Getopt::Long for are the ones we reject, so these
 867                 # are the ones we don't reject:
 868                 if ($cmd eq 'config') {
 869                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 870                         @spec = qw(add z|null get get-all unset unset-all
 871                                 replace-all get-urlmatch
 872                                 remove-section rename-section
 873                                 name-only list|l edit|e
 874                                 get-color-name get-colorbool);
 875                         # fall-through
 876                 }
 877                 # generate short/long names from Getopt::Long specs
 878                 puts $self, grep(/$re/, qw(--help -h -C), map {
 879                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 880                         } elsif (s/\+\z//) { # verbose|v+
 881                         } elsif (s/!\z//) {
 882                                 # negation: mail! => no-mail|mail
 883                                 s/([\w\-]+)/$1|no-$1/g
 884                         }
 885                         map {
 886                                 my $x = length > 1 ? "--$_" : "-$_";
 887                                 $x eq $_cur ? () : $x;
 888                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 889                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 890         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 891                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 892         }
 893
 894         # switch args (e.g. lei q -f mbox<TAB>)
 895         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 896                 my $opt = quotemeta $1;
 897                 puts $self, map {
 898                         my $v = $OPTDESC{$_};
 899                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 900                         # get rid of ALL CAPS placeholder (e.g "OUT")
 901                         # (TODO: completion for external paths)
 902                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 903                         @v;
 904                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 905         }
 906         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 907                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 908         }
 909         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 910         # proto parsing.
 911 }
 912
 913 sub exec_buf ($$) {
 914         my ($argv, $env) = @_;
 915         my $argc = scalar @$argv;
 916         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 917         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 918         $buf;
 919 }
 920
 921 sub start_mua {
 922         my ($self) = @_;
 923         my $mua = $self->{opt}->{mua} // return;
 924         my $mfolder = $self->{ovv}->{dst};
 925         my (@cmd, $replaced);
 926         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 927                 @cmd = ($mua, '-f');
 928         # TODO: help wanted: other common FOSS MUAs
 929         } else {
 930                 require Text::ParseWords;
 931                 @cmd = Text::ParseWords::shellwords($mua);
 932                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 933                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 934         }
 935         push @cmd, $mfolder unless defined($replaced);
 936         if ($self->{sock}) { # lei(1) client process runs it
 937                 # restore terminal: echo $query | lei q --stdin --mua=...
 938                 my $io = [];
 939                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 940                 send_exec_cmd($self, $io, \@cmd, {});
 941         }
 942         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 943                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 944         }
 945         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 946         $self->{opt}->{quiet} = 1;
 947         delete $self->{-progress};
 948         delete $self->{opt}->{verbose};
 949 }
 950
 951 sub send_exec_cmd { # tell script/lei to execute a command
 952         my ($self, $io, $cmd, $env) = @_;
 953         my $sock = $self->{sock} // die 'lei client gone';
 954         my $fds = [ map { fileno($_) } @$io ];
 955         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 956 }
 957
 958 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 959         my ($self) = @_;
 960         my $alerts = $self->{opt}->{alert} // return;
 961         my $sock = $self->{sock};
 962         while (my $op = shift(@$alerts)) {
 963                 if ($op eq ':WINCH') {
 964                         # hit the process group that started the MUA
 965                         send($sock, '-WINCH', MSG_EOR) if $sock;
 966                 } elsif ($op eq ':bell') {
 967                         out($self, "\a");
 968                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 969                         push @$alerts, split(/(?<!\\),/, $op);
 970                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 971                         my $cmd = $1; # run an arbitrary command
 972                         require Text::ParseWords;
 973                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 974                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 975                 } else {
 976                         err($self, "W: unsupported --alert=$op"); # non-fatal
 977                 }
 978         }
 979 }
 980
 981 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 982 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 983
 984 # this also normalizes the path
 985 sub path_to_fd {
 986         my ($self, $path) = @_;
 987         $path = rel2abs($self, $path);
 988         $path =~ tr!/!/!s;
 989         $path_to_fd{$path} // (
 990                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 991                         fail($self, "cannot open $path from daemon") : -1
 992         );
 993 }
 994
 995 # caller needs to "-t $self->{1}" to check if tty
 996 sub start_pager {
 997         my ($self) = @_;
 998         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 999         chomp(my $pager = <$fh> // '');
1000         close($fh) or warn "`git var PAGER' error: \$?=$?";
1001         return if $pager eq 'cat' || $pager eq '';
1002         my $new_env = { LESS => 'FRX', LV => '-c' };
1003         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1004         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1005         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1006         my $pgr = [ undef, @$rdr{1, 2} ];
1007         my $env = $self->{env};
1008         if ($self->{sock}) { # lei(1) process runs it
1009                 delete @$new_env{keys %$env}; # only set iff unset
1010                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1011         } else {
1012                 die 'BUG: start_pager w/o socket';
1013         }
1014         $self->{1} = $wpager;
1015         $self->{2} = $wpager if -t $self->{2};
1016         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1017         $self->{pgr} = $pgr;
1018 }
1019
1020 sub stop_pager {
1021         my ($self) = @_;
1022         my $pgr = delete($self->{pgr}) or return;
1023         $self->{2} = $pgr->[2];
1024         # do not restore original stdout, just close it so we error out
1025         close(delete($self->{1})) if $self->{1};
1026 }
1027
1028 sub accept_dispatch { # Listener {post_accept} callback
1029         my ($sock) = @_; # ignore other
1030         $sock->autoflush(1);
1031         my $self = bless { sock => $sock }, __PACKAGE__;
1032         vec(my $rvec = '', fileno($sock), 1) = 1;
1033         select($rvec, undef, undef, 60) or
1034                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1035         # (4096 * 33) >MAX_ARG_STRLEN
1036         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1037         if (!defined($fds[0])) {
1038                 warn(my $msg = "recv_cmd failed: $!");
1039                 return send($sock, $msg, MSG_EOR);
1040         } else {
1041                 my $i = 0;
1042                 for my $fd (@fds) {
1043                         open($self->{$i++}, '+<&=', $fd) and next;
1044                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1045                 }
1046                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1047         }
1048         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1049         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1050         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1051                 return send($sock, 'request command truncated', MSG_EOR);
1052         my ($argc, @argv) = split(/\0/, $buf, -1);
1053         undef $buf;
1054         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1055         if (chdir($self->{3})) {
1056                 local %ENV = %env;
1057                 $self->{env} = \%env;
1058                 eval { dispatch($self, @argv) };
1059                 send($sock, $@, MSG_EOR) if $@;
1060         } else {
1061                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1062         }
1063 }
1064
1065 sub dclose {
1066         my ($self) = @_;
1067         delete $self->{-progress};
1068         _drop_wq($self) if $self->{failed};
1069         close(delete $self->{1}) if $self->{1}; # may reap_compress
1070         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1071 }
1072
1073 # for long-running results
1074 sub event_step {
1075         my ($self) = @_;
1076         local %ENV = %{$self->{env}};
1077         my $sock = $self->{sock};
1078         local $current_lei = $self;
1079         eval {
1080                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1081                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1082                                 return if $! == EAGAIN;
1083                                 next if $! == EINTR;
1084                                 last if $! == ECONNRESET;
1085                                 die "recvmsg: $!";
1086                         }
1087                         for my $fd (@fds) {
1088                                 open my $rfh, '+<&=', $fd;
1089                         }
1090                         die "unrecognized client signal: $buf";
1091                 }
1092                 dclose($self);
1093         };
1094         if (my $err = $@) {
1095                 eval { $self->fail($err) };
1096                 dclose($self);
1097         }
1098 }
1099
1100 sub event_step_init {
1101         my ($self) = @_;
1102         my $sock = $self->{sock} or return;
1103         $self->{-event_init_done} //= do { # persist til $ops done
1104                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1105                 $sock;
1106         };
1107 }
1108
1109 sub noop {}
1110
1111 sub oldset { $oldset }
1112
1113 sub dump_and_clear_log {
1114         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1115                 my @pfx = @_;
1116                 unshift(@pfx, "$errors_log ") if @pfx;
1117                 warn @pfx, do { local $/; <STDIN> };
1118                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1119         }
1120 }
1121
1122 # lei(1) calls this when it can't connect
1123 sub lazy_start {
1124         my ($path, $errno, $narg) = @_;
1125         local ($errors_log, $listener);
1126         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1127         $errors_log = "$sock_dir/errors.log";
1128         my $addr = pack_sockaddr_un($path);
1129         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1130         $lk->lock_acquire;
1131         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1132         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1133                 return if connect($listener, $addr); # another process won
1134                 if ($errno == ECONNREFUSED && -S $path) {
1135                         unlink($path) or die "unlink($path): $!";
1136                 }
1137         } else {
1138                 $! = $errno; # allow interpolation to stringify in die
1139                 die "connect($path): $!";
1140         }
1141         umask(077) // die("umask(077): $!");
1142         bind($listener, $addr) or die "bind($path): $!";
1143         listen($listener, 1024) or die "listen: $!";
1144         $lk->lock_release;
1145         undef $lk;
1146         my @st = stat($path) or die "stat($path): $!";
1147         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1148         local $oldset = PublicInbox::DS::block_signals();
1149         if ($narg == 5) {
1150                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1151                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1152                         require PublicInbox::CmdIPC4;
1153                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1154                         PublicInbox::CmdIPC4->can('recv_cmd4');
1155                 };
1156         }
1157         $recv_cmd or die <<"";
1158 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1159
1160         require PublicInbox::Listener;
1161         require PublicInbox::PktOp;
1162         (-p STDOUT) or die "E: stdout must be a pipe\n";
1163         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1164         STDIN->autoflush(1);
1165         dump_and_clear_log("from previous daemon process:\n");
1166         POSIX::setsid() > 0 or die "setsid: $!";
1167         my $pid = fork // die "fork: $!";
1168         return if $pid;
1169         $0 = "lei-daemon $path";
1170         local %PATH2CFG;
1171         $listener->blocking(0);
1172         my $exit_code;
1173         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1174         local $quit = do {
1175                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1176                 sub {
1177                         $exit_code //= shift;
1178                         my $lis = $pil or exit($exit_code);
1179                         # closing eof_p triggers \&noop wakeup
1180                         $listener = $eof_p = $pil = $path = undef;
1181                         $lis->close; # DS::close
1182                         PublicInbox::DS->SetLoopTimeout(1000);
1183                 };
1184         };
1185         my $sig = {
1186                 CHLD => \&PublicInbox::DS::enqueue_reap,
1187                 QUIT => $quit,
1188                 INT => $quit,
1189                 TERM => $quit,
1190                 HUP => \&noop,
1191                 USR1 => \&noop,
1192                 USR2 => \&noop,
1193         };
1194         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1195         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1196         undef $sig;
1197         local $SIG{PIPE} = 'IGNORE';
1198         require PublicInbox::DirIdle;
1199         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1200                 # just rely on wakeup ot hit PostLoopCallback set below
1201                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1202         }, 1);
1203         if ($sigfd) {
1204                 undef $sigfd; # unref, already in DS::DescriptorMap
1205         } else {
1206                 # wake up every second to accept signals if we don't
1207                 # have signalfd or IO::KQueue:
1208                 PublicInbox::DS::sig_setmask($oldset);
1209                 PublicInbox::DS->SetLoopTimeout(1000);
1210         }
1211         PublicInbox::DS->SetPostLoopCallback(sub {
1212                 my ($dmap, undef) = @_;
1213                 if (@st = defined($path) ? stat($path) : ()) {
1214                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1215                                 warn "$path dev/ino changed, quitting\n";
1216                                 $path = undef;
1217                         }
1218                 } elsif (defined($path)) { # ENOENT is common
1219                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1220                         undef $path;
1221                         $quit->();
1222                 }
1223                 return 1 if defined($path);
1224                 my $now = now();
1225                 my $n = 0;
1226                 for my $s (values %$dmap) {
1227                         $s->can('busy') or next;
1228                         if ($s->busy($now)) {
1229                                 ++$n;
1230                         } else {
1231                                 $s->close;
1232                         }
1233                 }
1234                 $n; # true: continue, false: stop
1235         });
1236
1237         # STDIN was redirected to /dev/null above, closing STDERR and
1238         # STDOUT will cause the calling `lei' client process to finish
1239         # reading the <$daemon> pipe.
1240         local $SIG{__WARN__} = sub {
1241                 $current_lei ? err($current_lei, @_) : warn(
1242                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1243         };
1244         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1245         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1246         # $daemon pipe to `lei' closed, main loop begins:
1247         PublicInbox::DS->EventLoop;
1248         exit($exit_code // 0);
1249 }
1250
1251 sub busy { 1 } # prevent daemon-shutdown if client is connected
1252
1253 # ensures stdout hits the FS before sock disconnects so a client
1254 # can immediately reread it
1255 sub DESTROY {
1256         my ($self) = @_;
1257         if (my $counters = delete $self->{counters}) {
1258                 for my $k (sort keys %$counters) {
1259                         my $nr = $counters->{$k};
1260                         $self->child_error(1 << 8, "$nr $k messages");
1261                 }
1262         }
1263         $self->{1}->autoflush(1) if $self->{1};
1264         stop_pager($self);
1265         # preserve $? for ->fail or ->x_it code
1266 }
1267
1268 sub wq_done_wait { # dwaitpid callback
1269         my ($arg, $pid) = @_;
1270         my ($wq, $lei) = @$arg;
1271         my $err_type = $lei->{-err_type};
1272         $? and $lei->child_error($?,
1273                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1274         $lei->dclose;
1275 }
1276
1277 sub fchdir {
1278         my ($lei) = @_;
1279         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1280         chdir($dh) || $lei->fail("fchdir: $!");
1281 }
1282
1283 sub wq_eof { # EOF callback for main daemon
1284         my ($lei) = @_;
1285         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1286         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1287 }
1288
1289 1;