lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 222         "exclude message(s) on stdin from `q' search results",
 223         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 224
 225 'purge-mailsource' => [ 'LOCATION|--all',
 226         'remove imported messages from IMAP, Maildirs, and MH',
 227         qw(exact! all jobs:i indexed), @c_opt ],
 228
 229 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 230         qw(import! kw! interval=s recursive|r
 231         exclude=s include=s), @c_opt ],
 232 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 233                 qw(format|f=s z), @c_opt ],
 234 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 235 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 236 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 237         qw(prune), @c_opt ],
 238
 239 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 240         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 241         verbose|v+ incremental!),
 242          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 243          @c_opt ],
 244 'import' => [ 'LOCATION...|--stdin',
 245         'one-time import/update from URL or filesystem',
 246         qw(stdin| offset=i recursive|r exclude=s include|I=s
 247         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 248         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 249 'forget-mail-sync' => [ 'LOCATION...',
 250         'forget sync information for a mail folder', @c_opt ],
 251 'export-kw' => [ 'LOCATION...|--all',
 252         'one-time export of keywords of sync sources',
 253         qw(all:s mode=s), @c_opt ],
 254 'convert' => [ 'LOCATION...|--stdin',
 255         'one-time conversion from URL or filesystem to another format',
 256         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 257         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 258 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 259         "use a patch to generate a query for `lei q --stdin'",
 260         qw(stdin| want|w=s@ uri debug), @c_opt ],
 261 'config' => [ '[...]', sub {
 262                 'git-config(1) wrapper for '._config_path($_[0]);
 263         }, qw(config-file|system|global|file|f=s), # for conflict detection
 264          qw(c=s@ C=s@), pass_through('git config') ],
 265 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 266         qw(pretty ascii dir=s), @c_opt ],
 267
 268 'init' => [ '[DIRNAME]', sub {
 269         "initialize storage, default: ".store_path($_[0]);
 270         }, @c_opt ],
 271 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 272         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 273         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 274 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 275 'help' => [ '[SUBCOMMAND]', 'show help' ],
 276
 277 # TODO
 278 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 279 #       'rewrite git history in an attempt to improve compression',
 280 #       qw(gc!), @c_opt ],
 281 #
 282 # internal commands are prefixed with '_'
 283 '_complete' => [ '[...]', 'internal shell completion helper',
 284                 pass_through('everything') ],
 285 ); # @CMD
 286
 287 # switch descriptions, try to keep consistent across commands
 288 # $spec: Getopt::Long option specification
 289 # $spec => [@ALLOWED_VALUES (default is first), $description],
 290 # $spec => $description
 291 # "$SUB_COMMAND TAB $spec" => as above
 292 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 293                         'specify message input format' ];
 294 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 295
 296 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 297 my %OPTDESC = (
 298 'help|h' => 'show this built-in help',
 299 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 300 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 301 'quiet|q' => 'be quiet',
 302 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 303         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 304
 305 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 306 'globoff|g' => "do not match locations using '*?' wildcards ".
 307                 "and\xa0'[]'\x{a0}ranges",
 308 'invert-match|v' => 'select non-matching lines',
 309 'color!' => 'disable color (for --format=text)',
 310 'verbose|v+' => 'be more verbose',
 311 'external!' => 'do not use externals',
 312 'mail!' => 'do not look in mail storage for OID',
 313 'cwd!' => 'do not look in git repo of current working directory',
 314 'oid-a|A=s' => 'pre-image OID',
 315 'path-a|a=s' => 'pre-image pathname associated with OID',
 316 'path-b|b=s' => 'post-image pathname associated with OID',
 317 'git-dir=s@' => 'additional git repository to scan',
 318 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 319         "proxy for (e.g. `socks5h://0:9050')" ],
 320 'torsocks=s' => ['VAL|auto|no|yes',
 321                 'whether or not to wrap git and curl commands with torsocks'],
 322 'no-torsocks' => 'alias for --torsocks=no',
 323 'save' =>  "save a search for `lei up'",
 324 'import-remote!' => 'do not memoize remote messages into local store',
 325
 326 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 327
 328 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 329                 'deduplication strategy'],
 330 'threads|t+' =>
 331         'return all messages in the same threads as the actual match(es)',
 332
 333 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 334                 'search prefixes to extract (default: dfpost7)' ],
 335
 336 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 337         'run command(s) or perform ops when done writing to output ' .
 338         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 339         'nothing otherwise)' ],
 340
 341 'augment|a' => 'augment --output destination instead of clobbering',
 342
 343 'output|mfolder|o=s' => [ 'MFOLDER',
 344         "destination (e.g.\xa0`/path/to/Maildir', ".
 345         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 346 'mua=s' => [ 'CMD',
 347         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 348
 349 'inbox-version=i' => [ 'NUM|1|2',
 350                 'force a public-inbox version with --mirror'],
 351 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 352
 353 # public-inbox-index options
 354 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 355 'compact' => 'run compact index after mirroring',
 356 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 357         "indexlevel with --mirror (default: full)" ],
 358 'max_size|max-size=s' => [ 'SIZE',
 359         'do not index messages larger than SIZE (default: infinity)' ],
 360 'batch_size|batch-size=s' => [ 'SIZE',
 361         'flush changes to OS after given number of bytes (default: 1m)' ],
 362 'sequential_shard|sequential-shard' =>
 363         'index Xapian shards sequentially for slow storage',
 364 'skip-docdata' =>
 365         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 366
 367 'format|f=s     q' => [
 368         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 369                 'specify output format, default depends on --output'],
 370 'exclude=s@     q' => [ 'LOCATION',
 371                 'exclude specified external(s) from search' ],
 372 'include|I=s@   q' => [ 'LOCATION',
 373                 'include specified external(s) in search' ],
 374 'only=s@        q' => [ 'LOCATION',
 375                 'only use specified external(s) for search' ],
 376 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 377                 'control number of search and writer jobs' ],
 378 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 379
 380 'in-format|F=s' => $stdin_formats,
 381 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 382                         'listing output format' ],
 383 'l      ls-search' => 'long listing format',
 384 'format|f=s     ls-external' => $ls_format,
 385
 386 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 387 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 388
 389 'sort|s=s' => [ 'VAL|received|relevance|docid',
 390                 "order of results is `--output'-dependent"],
 391 'reverse|r' => 'reverse search results', # like sort(1)
 392
 393 'boost=i' => 'increase/decrease priority of results (default: 0)',
 394
 395 'local' => 'limit operations to the local filesystem',
 396 'local!' => 'exclude results from the local filesystem',
 397 'remote' => 'limit operations to those requiring network access',
 398 'remote!' => 'prevent operations requiring network access',
 399
 400 'all:s  up' => ['local', 'update all (local) saved searches' ],
 401
 402 'mid=s' => 'specify the Message-ID of a message',
 403 'oid=s' => 'specify the git object ID of a message',
 404
 405 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 406 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 407 'include=s' => 'include mailboxes/newsgroups based on pattern',
 408
 409 'exact' => 'operate on exact header matches only',
 410 'exact!' => 'rely on content match instead of exact header matches',
 411
 412 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 413
 414 'kw!' => 'disable/enable importing keywords (aka "flags")',
 415
 416 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 417 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 418
 419 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 420 ); # %OPTDESC
 421
 422 my %CONFIG_KEYS = (
 423         'leistore.dir' => 'top-level storage location',
 424 );
 425
 426 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 427
 428 sub _drop_wq {
 429         my ($self) = @_;
 430         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 431                 if ($wq->wq_kill) {
 432                         $wq->wq_close(0, undef, $self);
 433                 } elsif ($wq->wq_kill_old) {
 434                         $wq->wq_wait_old(undef, $self);
 435                 }
 436                 $wq->DESTROY;
 437         }
 438 }
 439
 440 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 441 sub x_it ($$) {
 442         my ($self, $code) = @_;
 443         # make sure client sees stdout before exit
 444         $self->{1}->autoflush(1) if $self->{1};
 445         dump_and_clear_log();
 446         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 447                 send($s, "x_it $code", MSG_EOR);
 448         } # else ignore if client disconnected
 449 }
 450
 451 sub err ($;@) {
 452         my $self = shift;
 453         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 454         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 455         print $err @_, @eor and return;
 456         my $old_err = delete $self->{2};
 457         close($old_err) if $! == EPIPE && $old_err;
 458         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         print $err @_, @eor or print STDERR @_, @eor;
 460 }
 461
 462 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 463
 464 sub fail_handler ($;$$) {
 465         my ($lei, $code, $io) = @_;
 466         close($io) if $io; # needed to avoid warnings on SIGPIPE
 467         _drop_wq($lei);
 468         x_it($lei, $code // (1 << 8));
 469 }
 470
 471 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 472         fail_handler($_[0], 13, delete $_[0]->{1});
 473 }
 474
 475 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 476 sub sigint_reap {
 477         my ($pgid) = @_;
 478         dwaitpid($pgid) if kill('-INT', $pgid);
 479 }
 480
 481 sub fail ($$;$) {
 482         my ($self, $buf, $exit_code) = @_;
 483         err($self, $buf) if defined $buf;
 484         # calls fail_handler:
 485         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 486         x_it($self, ($exit_code // 1) << 8);
 487         undef;
 488 }
 489
 490 sub out ($;@) {
 491         my $self = shift;
 492         return if print { $self->{1} // return } @_; # likely
 493         return note_sigpipe($self, 1) if $! == EPIPE;
 494         my $err = "error writing to output: $!";
 495         delete $self->{1};
 496         fail($self, $err);
 497 }
 498
 499 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 500
 501 sub child_error { # passes non-fatal curl exit codes to user
 502         my ($self, $child_error, $msg) = @_; # child_error is $?
 503         $self->err($msg) if $msg;
 504         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 505                 # send to the parent lei-daemon or to lei(1) client
 506                 send($s, "child_error $child_error", MSG_EOR);
 507         } elsif (!$PublicInbox::DS::in_loop) {
 508                 $self->{child_error} = $child_error;
 509         } # else noop if client disconnected
 510 }
 511
 512 sub note_sigpipe { # triggers sigpipe_handler
 513         my ($self, $fd) = @_;
 514         close(delete($self->{$fd})); # explicit close silences Perl warning
 515         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 516         x_it($self, 13);
 517 }
 518
 519 sub _lei_atfork_child {
 520         my ($self, $persist) = @_;
 521         # we need to explicitly close things which are on stack
 522         if ($persist) {
 523                 chdir '/' or die "chdir(/): $!";
 524                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 525                 if (my $cfg = $self->{cfg}) {
 526                         delete $cfg->{-lei_store};
 527                 }
 528         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 529                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 530                 STDERR->autoflush(1);
 531         }
 532         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 533         if (my $op_c = delete $self->{pkt_op_c}) {
 534                 close(delete $op_c->{sock});
 535         }
 536         if (my $pgr = delete $self->{pgr}) {
 537                 close($_) for (@$pgr[1,2]);
 538         }
 539         close $listener if $listener;
 540         undef $listener;
 541         undef $dir_idle;
 542         %PATH2CFG = ();
 543         undef $errors_log;
 544         $quit = \&CORE::exit;
 545         $self->{-eml_noisy} or # only "lei import" sets this atm
 546                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 547         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 548 }
 549
 550 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 551         my ($self) = @_;
 552         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 553                 $op->close; # PublicInbox::PktOp::close
 554         }
 555         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 556         close $unclosed_after_die;
 557 }
 558
 559 sub pkt_op_pair {
 560         my ($self) = @_;
 561         require PublicInbox::OnDestroy;
 562         require PublicInbox::PktOp;
 563         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 564         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 565         $end;
 566 }
 567
 568 sub workers_start {
 569         my ($lei, $wq, $jobs, $ops) = @_;
 570         $ops = {
 571                 '!' => [ \&fail_handler, $lei ],
 572                 '|' => [ \&sigpipe_handler, $lei ],
 573                 'x_it' => [ \&x_it, $lei ],
 574                 'child_error' => [ \&child_error, $lei ],
 575                 ($ops ? %$ops : ()),
 576         };
 577         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 578         my $end = $lei->pkt_op_pair;
 579         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 580         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 581         delete $lei->{pkt_op_p};
 582         my $op_c = delete $lei->{pkt_op_c};
 583         @$end = ();
 584         $lei->event_step_init;
 585         ($op_c, $ops);
 586 }
 587
 588 sub _help {
 589         require PublicInbox::LeiHelp;
 590         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 591 }
 592
 593 sub optparse ($$$) {
 594         my ($self, $cmd, $argv) = @_;
 595         # allow _complete --help to complete, not show help
 596         return 1 if substr($cmd, 0, 1) eq '_';
 597         $self->{cmd} = $cmd;
 598         $OPT = $self->{opt} //= {};
 599         my $info = $CMD{$cmd} // [ '[...]' ];
 600         my ($proto, undef, @spec) = @$info;
 601         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 602         push @spec, qw(help|h);
 603         my $lone_dash;
 604         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 605                 $lone_dash = $spec[0];
 606                 $OPT->{$spec[0]} = \(my $var);
 607                 push @spec, '' => \$var;
 608         }
 609         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 610                 return _help($self, "bad arguments or options for $cmd");
 611         return _help($self) if $OPT->{help};
 612
 613         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 614
 615         # "-" aliases "stdin" or "clear"
 616         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 617
 618         my $i = 0;
 619         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 620         my ($err, $inf);
 621         my @args = split(/ /, $proto);
 622         for my $var (@args) {
 623                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 624                         $inf = defined($argv->[$i]) and last;
 625                         $var =~ s/\.\.\.\z//;
 626                         $err = "$var not supplied";
 627                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 628                         $argv->[$i++] // ($err = "$var not supplied");
 629                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 630                         $inf = 1;
 631                         last;
 632                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 633                         $i++;
 634                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 635                         $inf = 1 if index($var, '...') > 0;
 636                         my @or = split(/\|/, $var);
 637                         my $ok;
 638                         for my $o (@or) {
 639                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 640                                         $ok = defined($OPT->{$1});
 641                                         last if $ok;
 642                                 } elsif (defined($argv->[$i])) {
 643                                         $ok = 1;
 644                                         $i++;
 645                                         last;
 646                                 } # else continue looping
 647                         }
 648                         last if $ok;
 649                         my $last = pop @or;
 650                         $err = join(', ', @or) . " or $last must be set";
 651                 } else {
 652                         warn "BUG: can't parse `$var' in $proto";
 653                 }
 654                 last if $err;
 655         }
 656         if (!$inf && scalar(@$argv) > scalar(@args)) {
 657                 $err //= 'too many arguments';
 658         }
 659         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 660 }
 661
 662 sub _tmp_cfg { # for lei -c <name>=<value> ...
 663         my ($self) = @_;
 664         my $cfg = _lei_cfg($self, 1);
 665         require File::Temp;
 666         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 667         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 668         $ft->autoflush(1);
 669         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 670 [include]
 671         path = $cfg->{-f}
 672 EOM
 673         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 674         for (@{$self->{opt}->{c}}) {
 675                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 676 `-c $_' is not of the form -c <name>=<value>'
 677 EOM
 678                 my $name = $1;
 679                 my $value = $2 // 1;
 680                 _config($self, '--add', $name, $value);
 681                 if (defined(my $v = $tmp->{$name})) {
 682                         if (ref($v) eq 'ARRAY') {
 683                                 push @$v, $value;
 684                         } else {
 685                                 $tmp->{$name} = [ $v, $value ];
 686                         }
 687                 } else {
 688                         $tmp->{$name} = $value;
 689                 }
 690         }
 691 }
 692
 693 sub lazy_cb ($$$) {
 694         my ($self, $cmd, $pfx) = @_;
 695         my $ucmd = $cmd;
 696         $ucmd =~ tr/-/_/;
 697         my $cb;
 698         $cb = $self->can($pfx.$ucmd) and return $cb;
 699         my $base = $ucmd;
 700         $base =~ s/_([a-z])/\u$1/g;
 701         my $pkg = "PublicInbox::Lei\u$base";
 702         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 703                 $pkg->can($pfx.$ucmd) : undef;
 704 }
 705
 706 sub dispatch {
 707         my ($self, $cmd, @argv) = @_;
 708         local $current_lei = $self; # for __WARN__
 709         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 710         dump_and_clear_log("from previous run\n");
 711         return _help($self, 'no command given') unless defined($cmd);
 712         # do not support Getopt bundling for this
 713         while ($cmd eq '-C' || $cmd eq '-c') {
 714                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 715                                         '-C DIRECTORY' : '-c <name>=<value>');
 716                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 717                 $cmd = shift(@argv) // return _help($self, 'no command given');
 718         }
 719         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 720                 optparse($self, $cmd, \@argv) or return;
 721                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 722                 if (my $chdir = $self->{opt}->{C}) {
 723                         for my $d (@$chdir) {
 724                                 next if $d eq ''; # same as git(1)
 725                                 chdir $d or return fail($self, "cd $d: $!");
 726                         }
 727                         if (delete $self->{3}) { # update cwd for rel2abs
 728                                 opendir my $dh, '.' or
 729                                         return fail($self, "opendir . $!");
 730                                 $self->{3} = $dh;
 731                         }
 732                 }
 733                 $cb->($self, @argv);
 734         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 735                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 736                         or return _help($self, 'bad arguments or options');
 737                 _help($self);
 738         } else {
 739                 fail($self, "`$cmd' is not an lei command");
 740         }
 741 }
 742
 743 sub _lei_cfg ($;$) {
 744         my ($self, $creat) = @_;
 745         return $self->{cfg} if $self->{cfg};
 746         my $f = _config_path($self);
 747         my @st = stat($f);
 748         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 749         my ($sto, $sto_dir);
 750         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 751                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 752                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 753         }
 754         if (!@st) {
 755                 unless ($creat) {
 756                         delete $self->{cfg};
 757                         return bless {}, 'PublicInbox::Config';
 758                 }
 759                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 760                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 761                 open my $fh, '>>', $f or die "open($f): $!\n";
 762                 @st = stat($fh) or die "fstat($f): $!\n";
 763                 $cur_st = pack('dd', $st[10], $st[7]);
 764                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 765         }
 766         my $cfg = PublicInbox::Config->git_config_dump($f);
 767         $cfg->{-st} = $cur_st;
 768         $cfg->{'-f'} = $f;
 769         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 770                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 771                                                 store_path($self))) {
 772                 $cfg->{-lei_store} = $sto;
 773         }
 774         if (scalar(keys %PATH2CFG) > 5) {
 775                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 776                 for my $k (keys %PATH2CFG) {
 777                         delete($PATH2CFG{$k}) unless -f $k
 778                 }
 779         }
 780         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 781 }
 782
 783 sub _lei_store ($;$) {
 784         my ($self, $creat) = @_;
 785         my $cfg = _lei_cfg($self, $creat);
 786         $cfg->{-lei_store} //= do {
 787                 require PublicInbox::LeiStore;
 788                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 789                 return unless $creat || -d $dir;
 790                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 791         };
 792 }
 793
 794 sub _config {
 795         my ($self, @argv) = @_;
 796         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 797         my $cfg = _lei_cfg($self, 1);
 798         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 799         my %rdr = map { $_ => $self->{$_} } (0..2);
 800         waitpid(spawn($cmd, \%env, \%rdr), 0);
 801 }
 802
 803 sub lei_config {
 804         my ($self, @argv) = @_;
 805         $self->{opt}->{'config-file'} and return fail $self,
 806                 "config file switches not supported by `lei config'";
 807         _config(@_);
 808         x_it($self, $?) if $?;
 809 }
 810
 811 sub lei_daemon_pid { puts shift, $$ }
 812
 813 sub lei_daemon_kill {
 814         my ($self) = @_;
 815         my $sig = $self->{opt}->{signal} // 'TERM';
 816         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 817 }
 818
 819 # Shell completion helper.  Used by lei-completion.bash and hopefully
 820 # other shells.  Try to do as much here as possible to avoid redundancy
 821 # and improve maintainability.
 822 sub lei__complete {
 823         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 824         shift @argv; # ignore "lei", the entire command is sent
 825         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 826         my $cmd = shift @argv;
 827         my $info = $CMD{$cmd} // do { # filter matching commands
 828                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 829                 return;
 830         };
 831         my ($proto, undef, @spec) = @$info;
 832         my $cur = pop @argv;
 833         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 834         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 835                 # gross special case since the only git-config options
 836                 # Consider moving to a table if we need more special cases
 837                 # we use Getopt::Long for are the ones we reject, so these
 838                 # are the ones we don't reject:
 839                 if ($cmd eq 'config') {
 840                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 841                         @spec = qw(add z|null get get-all unset unset-all
 842                                 replace-all get-urlmatch
 843                                 remove-section rename-section
 844                                 name-only list|l edit|e
 845                                 get-color-name get-colorbool);
 846                         # fall-through
 847                 }
 848                 # generate short/long names from Getopt::Long specs
 849                 puts $self, grep(/$re/, qw(--help -h -C), map {
 850                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 851                         } elsif (s/\+\z//) { # verbose|v+
 852                         } elsif (s/!\z//) {
 853                                 # negation: mail! => no-mail|mail
 854                                 s/([\w\-]+)/$1|no-$1/g
 855                         }
 856                         map {
 857                                 my $x = length > 1 ? "--$_" : "-$_";
 858                                 $x eq $_cur ? () : $x;
 859                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 860                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 861         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 862                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 863         }
 864
 865         # switch args (e.g. lei q -f mbox<TAB>)
 866         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 867                 my $opt = quotemeta $1;
 868                 puts $self, map {
 869                         my $v = $OPTDESC{$_};
 870                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 871                         # get rid of ALL CAPS placeholder (e.g "OUT")
 872                         # (TODO: completion for external paths)
 873                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 874                         @v;
 875                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 876         }
 877         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 878                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 879         }
 880         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 881         # proto parsing.
 882 }
 883
 884 sub exec_buf ($$) {
 885         my ($argv, $env) = @_;
 886         my $argc = scalar @$argv;
 887         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 888         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 889         $buf;
 890 }
 891
 892 sub start_mua {
 893         my ($self) = @_;
 894         my $mua = $self->{opt}->{mua} // return;
 895         my $mfolder = $self->{ovv}->{dst};
 896         my (@cmd, $replaced);
 897         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 898                 @cmd = ($mua, '-f');
 899         # TODO: help wanted: other common FOSS MUAs
 900         } else {
 901                 require Text::ParseWords;
 902                 @cmd = Text::ParseWords::shellwords($mua);
 903                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 904                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 905         }
 906         push @cmd, $mfolder unless defined($replaced);
 907         if ($self->{sock}) { # lei(1) client process runs it
 908                 # restore terminal: echo $query | lei q -stdin --mua=...
 909                 my $io = [];
 910                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 911                 send_exec_cmd($self, $io, \@cmd, {});
 912         }
 913         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 914                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 915         }
 916         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 917         $self->{opt}->{quiet} = 1;
 918         delete $self->{-progress};
 919         delete $self->{opt}->{verbose};
 920 }
 921
 922 sub send_exec_cmd { # tell script/lei to execute a command
 923         my ($self, $io, $cmd, $env) = @_;
 924         my $sock = $self->{sock} // die 'lei client gone';
 925         my $fds = [ map { fileno($_) } @$io ];
 926         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 927 }
 928
 929 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 930         my ($self) = @_;
 931         my $alerts = $self->{opt}->{alert} // return;
 932         my $sock = $self->{sock};
 933         while (my $op = shift(@$alerts)) {
 934                 if ($op eq ':WINCH') {
 935                         # hit the process group that started the MUA
 936                         send($sock, '-WINCH', MSG_EOR) if $sock;
 937                 } elsif ($op eq ':bell') {
 938                         out($self, "\a");
 939                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 940                         push @$alerts, split(/(?<!\\),/, $op);
 941                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 942                         my $cmd = $1; # run an arbitrary command
 943                         require Text::ParseWords;
 944                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 945                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 946                 } else {
 947                         err($self, "W: unsupported --alert=$op"); # non-fatal
 948                 }
 949         }
 950 }
 951
 952 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 953 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 954
 955 # this also normalizes the path
 956 sub path_to_fd {
 957         my ($self, $path) = @_;
 958         $path = rel2abs($self, $path);
 959         $path =~ tr!/!/!s;
 960         $path_to_fd{$path} // (
 961                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 962                         fail($self, "cannot open $path from daemon") : -1
 963         );
 964 }
 965
 966 # caller needs to "-t $self->{1}" to check if tty
 967 sub start_pager {
 968         my ($self) = @_;
 969         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 970         chomp(my $pager = <$fh> // '');
 971         close($fh) or warn "`git var PAGER' error: \$?=$?";
 972         return if $pager eq 'cat' || $pager eq '';
 973         my $new_env = { LESS => 'FRX', LV => '-c' };
 974         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 975         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 976         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 977         my $pgr = [ undef, @$rdr{1, 2} ];
 978         my $env = $self->{env};
 979         if ($self->{sock}) { # lei(1) process runs it
 980                 delete @$new_env{keys %$env}; # only set iff unset
 981                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 982         } else {
 983                 die 'BUG: start_pager w/o socket';
 984         }
 985         $self->{1} = $wpager;
 986         $self->{2} = $wpager if -t $self->{2};
 987         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 988         $self->{pgr} = $pgr;
 989 }
 990
 991 sub stop_pager {
 992         my ($self) = @_;
 993         my $pgr = delete($self->{pgr}) or return;
 994         $self->{2} = $pgr->[2];
 995         # do not restore original stdout, just close it so we error out
 996         close(delete($self->{1})) if $self->{1};
 997 }
 998
 999 sub accept_dispatch { # Listener {post_accept} callback
1000         my ($sock) = @_; # ignore other
1001         $sock->autoflush(1);
1002         my $self = bless { sock => $sock }, __PACKAGE__;
1003         vec(my $rvec = '', fileno($sock), 1) = 1;
1004         select($rvec, undef, undef, 60) or
1005                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1006         # (4096 * 33) >MAX_ARG_STRLEN
1007         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1008         if (!defined($fds[0])) {
1009                 warn(my $msg = "recv_cmd failed: $!");
1010                 return send($sock, $msg, MSG_EOR);
1011         } else {
1012                 my $i = 0;
1013                 for my $fd (@fds) {
1014                         open($self->{$i++}, '+<&=', $fd) and next;
1015                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1016                 }
1017                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1018         }
1019         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1020         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1021         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1022                 return send($sock, 'request command truncated', MSG_EOR);
1023         my ($argc, @argv) = split(/\0/, $buf, -1);
1024         undef $buf;
1025         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1026         if (chdir($self->{3})) {
1027                 local %ENV = %env;
1028                 $self->{env} = \%env;
1029                 eval { dispatch($self, @argv) };
1030                 send($sock, $@, MSG_EOR) if $@;
1031         } else {
1032                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1033         }
1034 }
1035
1036 sub dclose {
1037         my ($self) = @_;
1038         delete $self->{-progress};
1039         _drop_wq($self);
1040         close(delete $self->{1}) if $self->{1}; # may reap_compress
1041         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1042 }
1043
1044 # for long-running results
1045 sub event_step {
1046         my ($self) = @_;
1047         local %ENV = %{$self->{env}};
1048         my $sock = $self->{sock};
1049         local $current_lei = $self;
1050         eval {
1051                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1052                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1053                                 return if $! == EAGAIN;
1054                                 next if $! == EINTR;
1055                                 last if $! == ECONNRESET;
1056                                 die "recvmsg: $!";
1057                         }
1058                         for my $fd (@fds) {
1059                                 open my $rfh, '+<&=', $fd;
1060                         }
1061                         die "unrecognized client signal: $buf";
1062                 }
1063                 dclose($self);
1064         };
1065         if (my $err = $@) {
1066                 eval { $self->fail($err) };
1067                 dclose($self);
1068         }
1069 }
1070
1071 sub event_step_init {
1072         my ($self) = @_;
1073         return if $self->{-event_init_done}++;
1074         if (my $sock = $self->{sock}) { # using DS->EventLoop
1075                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1076         }
1077 }
1078
1079 sub noop {}
1080
1081 sub oldset { $oldset }
1082
1083 sub dump_and_clear_log {
1084         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1085                 my @pfx = @_;
1086                 unshift(@pfx, "$errors_log ") if @pfx;
1087                 warn @pfx, do { local $/; <STDIN> };
1088                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1089         }
1090 }
1091
1092 # lei(1) calls this when it can't connect
1093 sub lazy_start {
1094         my ($path, $errno, $narg) = @_;
1095         local ($errors_log, $listener);
1096         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1097         $errors_log = "$sock_dir/errors.log";
1098         my $addr = pack_sockaddr_un($path);
1099         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1100         $lk->lock_acquire;
1101         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1102         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1103                 return if connect($listener, $addr); # another process won
1104                 if ($errno == ECONNREFUSED && -S $path) {
1105                         unlink($path) or die "unlink($path): $!";
1106                 }
1107         } else {
1108                 $! = $errno; # allow interpolation to stringify in die
1109                 die "connect($path): $!";
1110         }
1111         umask(077) // die("umask(077): $!");
1112         bind($listener, $addr) or die "bind($path): $!";
1113         listen($listener, 1024) or die "listen: $!";
1114         $lk->lock_release;
1115         undef $lk;
1116         my @st = stat($path) or die "stat($path): $!";
1117         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1118         local $oldset = PublicInbox::DS::block_signals();
1119         if ($narg == 5) {
1120                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1121                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1122                         require PublicInbox::CmdIPC4;
1123                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1124                         PublicInbox::CmdIPC4->can('recv_cmd4');
1125                 };
1126         }
1127         $recv_cmd or die <<"";
1128 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1129
1130         require PublicInbox::Listener;
1131         require PublicInbox::PktOp;
1132         (-p STDOUT) or die "E: stdout must be a pipe\n";
1133         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1134         STDIN->autoflush(1);
1135         dump_and_clear_log("from previous daemon process:\n");
1136         POSIX::setsid() > 0 or die "setsid: $!";
1137         my $pid = fork // die "fork: $!";
1138         return if $pid;
1139         $0 = "lei-daemon $path";
1140         local %PATH2CFG;
1141         $listener->blocking(0);
1142         my $exit_code;
1143         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1144         local $quit = do {
1145                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1146                 sub {
1147                         $exit_code //= shift;
1148                         my $lis = $pil or exit($exit_code);
1149                         # closing eof_p triggers \&noop wakeup
1150                         $listener = $eof_p = $pil = $path = undef;
1151                         $lis->close; # DS::close
1152                         PublicInbox::DS->SetLoopTimeout(1000);
1153                 };
1154         };
1155         my $sig = {
1156                 CHLD => \&PublicInbox::DS::enqueue_reap,
1157                 QUIT => $quit,
1158                 INT => $quit,
1159                 TERM => $quit,
1160                 HUP => \&noop,
1161                 USR1 => \&noop,
1162                 USR2 => \&noop,
1163         };
1164         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1165         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1166         undef $sig;
1167         local $SIG{PIPE} = 'IGNORE';
1168         require PublicInbox::DirIdle;
1169         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1170                 # just rely on wakeup ot hit PostLoopCallback set below
1171                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1172         }, 1);
1173         if ($sigfd) {
1174                 undef $sigfd; # unref, already in DS::DescriptorMap
1175         } else {
1176                 # wake up every second to accept signals if we don't
1177                 # have signalfd or IO::KQueue:
1178                 PublicInbox::DS::sig_setmask($oldset);
1179                 PublicInbox::DS->SetLoopTimeout(1000);
1180         }
1181         PublicInbox::DS->SetPostLoopCallback(sub {
1182                 my ($dmap, undef) = @_;
1183                 if (@st = defined($path) ? stat($path) : ()) {
1184                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1185                                 warn "$path dev/ino changed, quitting\n";
1186                                 $path = undef;
1187                         }
1188                 } elsif (defined($path)) { # ENOENT is common
1189                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1190                         undef $path;
1191                         $quit->();
1192                 }
1193                 return 1 if defined($path);
1194                 my $now = now();
1195                 my $n = 0;
1196                 for my $s (values %$dmap) {
1197                         $s->can('busy') or next;
1198                         if ($s->busy($now)) {
1199                                 ++$n;
1200                         } else {
1201                                 $s->close;
1202                         }
1203                 }
1204                 $n; # true: continue, false: stop
1205         });
1206
1207         # STDIN was redirected to /dev/null above, closing STDERR and
1208         # STDOUT will cause the calling `lei' client process to finish
1209         # reading the <$daemon> pipe.
1210         local $SIG{__WARN__} = sub {
1211                 $current_lei ? err($current_lei, @_) : warn(
1212                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1213         };
1214         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1215         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1216         # $daemon pipe to `lei' closed, main loop begins:
1217         PublicInbox::DS->EventLoop;
1218         exit($exit_code // 0);
1219 }
1220
1221 sub busy { 1 } # prevent daemon-shutdown if client is connected
1222
1223 # ensures stdout hits the FS before sock disconnects so a client
1224 # can immediately reread it
1225 sub DESTROY {
1226         my ($self) = @_;
1227         $self->{1}->autoflush(1) if $self->{1};
1228         stop_pager($self);
1229         # preserve $? for ->fail or ->x_it code
1230 }
1231
1232 sub wq_done_wait { # dwaitpid callback
1233         my ($arg, $pid) = @_;
1234         my ($wq, $lei) = @$arg;
1235         my $err_type = $lei->{-err_type};
1236         $? and $lei->child_error($?,
1237                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1238         $lei->dclose;
1239 }
1240
1241 sub wq_eof { # EOF callback for main daemon
1242         my ($lei) = @_;
1243         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1244         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1245 }
1246
1247 1;