lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use Sys::Syslog qw(syslog openlog);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38 our @TO_CLOSE_ATFORK_CHILD;
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub _store_path ($) {
  69         my ($env) = @_;
  70         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  71                 ($env->{HOME} // '/nonexistent').'/.local/share')
  72                 .'/lei/store', $env->{PWD});
  73 }
  74
  75 sub _config_path ($) {
  76         my ($env) = @_;
  77         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  78                 ($env->{HOME} // '/nonexistent').'/.config')
  79                 .'/lei/config', $env->{PWD});
  80 }
  81
  82 # TODO: generate shell completion + help using %CMD and %OPTDESC
  83 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  84 our %CMD = ( # sorted in order of importance/use:
  85 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  86         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  87         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  88         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  89
  90 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  91         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  92         pass_through('git show') ],
  93
  94 'add-external' => [ 'URL_OR_PATHNAME',
  95         'add/set priority of a publicinbox|extindex for extra matches',
  96         qw(boost=i quiet|q) ],
  97 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  98         qw(format|f=s z|0 local remote quiet|q) ],
  99 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
 100         'exclude further results from a publicinbox|extindex',
 101         qw(prune quiet|q) ],
 102
 103 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 104                 qw(name-only format|f=s z) ],
 105 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 106 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 107
 108 'plonk' => [ '--thread|--from=IDENT',
 109         'exclude mail matching From: or thread from non-Message-ID searches',
 110         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 111 'mark' => [ 'MESSAGE_FLAGS...',
 112         'set/unset flags on message(s) from stdin',
 113         qw(stdin| oid=s exact by-mid|mid:s) ],
 114 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 115         "exclude message(s) on stdin from `q' search results",
 116         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 117
 118 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 119         'remove imported messages from IMAP, Maildirs, and MH',
 120         qw(exact! all jobs:i indexed) ],
 121
 122 # code repos are used for `show' to solve blobs from patch mails
 123 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 124         qw(boost=i) ],
 125 'ls-coderepo' => [ '[FILTER_TERMS...]',
 126                 'list known code repos', qw(format|f=s z) ],
 127 'forget-coderepo' => [ 'PATHNAME',
 128         'stop using repo to solve blobs from patches',
 129         qw(prune) ],
 130
 131 'add-watch' => [ '[URL_OR_PATHNAME]',
 132                 'watch for new messages and flag changes',
 133         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 134 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 135                 qw(format|f=s z) ],
 136 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 138 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 139         qw(prune) ],
 140
 141 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 142         'one-shot import/update from URL or filesystem',
 143         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 144         ],
 145
 146 'config' => [ '[...]', sub {
 147                 'git-config(1) wrapper for '._config_path($_[0]);
 148         }, qw(config-file|system|global|file|f=s), # for conflict detection
 149         pass_through('git config') ],
 150 'init' => [ '[PATHNAME]', sub {
 151                 'initialize storage, default: '._store_path($_[0]);
 152         }, qw(quiet|q) ],
 153 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 154         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 155 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 156 'help' => [ '[SUBCOMMAND]', 'show help' ],
 157
 158 # XXX do we need this?
 159 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 160
 161 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 162         'rewrite git history in an attempt to improve compression',
 163         'gc!' ],
 164
 165 # internal commands are prefixed with '_'
 166 '_complete' => [ '[...]', 'internal shell completion helper',
 167                 pass_through('everything') ],
 168 ); # @CMD
 169
 170 # switch descriptions, try to keep consistent across commands
 171 # $spec: Getopt::Long option specification
 172 # $spec => [@ALLOWED_VALUES (default is first), $description],
 173 # $spec => $description
 174 # "$SUB_COMMAND TAB $spec" => as above
 175 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 176                 'specify message input format' ];
 177 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 178
 179 my %OPTDESC = (
 180 'help|h' => 'show this built-in help',
 181 'quiet|q' => 'be quiet',
 182 'solve!' => 'do not attempt to reconstruct blobs from emails',
 183 'save-as=s' => ['NAME', 'save a search terms by given name'],
 184
 185 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 186
 187 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 188                 'deduplication strategy'],
 189 'show   thread|t' => 'display entire thread a message belongs to',
 190 'q      thread|t' =>
 191         'return all messages in the same thread as the actual match(es)',
 192 'augment|a' => 'augment --output destination instead of clobbering',
 193
 194 'output|o=s' => [ 'DEST',
 195         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 196 'mua-cmd|mua=s' => [ 'COMMAND',
 197         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 198
 199 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 200                         'message/object output format' ],
 201 'mark   format|f=s' => $stdin_formats,
 202 'forget format|f=s' => $stdin_formats,
 203 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 204                 'specify output format, default depends on --output'],
 205 'ls-query       format|f=s' => $ls_format,
 206 'ls-external    format|f=s' => $ls_format,
 207
 208 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 209 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 210
 211 'sort|s=s' => [ 'VAL|received,relevance,docid',
 212                 "order of results `--output'-dependent"],
 213 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 214
 215 'boost=i' => 'increase/decrease priority of results (default: 0)',
 216
 217 'local' => 'limit operations to the local filesystem',
 218 'local!' => 'exclude results from the local filesystem',
 219 'remote' => 'limit operations to those requiring network access',
 220 'remote!' => 'prevent operations requiring network access',
 221
 222 'mid=s' => 'specify the Message-ID of a message',
 223 'oid=s' => 'specify the git object ID of a message',
 224
 225 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 226 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 227 'include=s' => 'include mailboxes/newsgroups based on pattern',
 228
 229 'exact' => 'operate on exact header matches only',
 230 'exact!' => 'rely on content match instead of exact header matches',
 231
 232 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 233 'jobs:i' => 'set parallelism level',
 234
 235 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 236 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 237
 238 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 239 ); # %OPTDESC
 240
 241 my %CONFIG_KEYS = (
 242         'leistore.dir' => 'top-level storage location',
 243 );
 244
 245 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 246 sub x_it ($$) {
 247         my ($self, $code) = @_;
 248         # make sure client sees stdout before exit
 249         $self->{1}->autoflush(1) if $self->{1};
 250         dump_and_clear_log();
 251         if (my $sock = $self->{sock}) {
 252                 send($sock, "x_it $code", MSG_EOR);
 253         } elsif (!($code & 127)) { # oneshot, ignore signals
 254                 # don't want to end up using $? from child processes
 255                 for my $f (qw(lxs l2m)) {
 256                         my $wq = delete $self->{$f} or next;
 257                         $wq->DESTROY;
 258                 }
 259                 $quit->($code >> 8);
 260         }
 261 }
 262
 263 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 264
 265 sub out ($;@) { print { shift->{1} } @_ }
 266
 267 sub err ($;@) {
 268         my $self = shift;
 269         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 270         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 271 }
 272
 273 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 274
 275 sub fail ($$;$) {
 276         my ($self, $buf, $exit_code) = @_;
 277         err($self, $buf);
 278         x_it($self, ($exit_code // 1) << 8);
 279         undef;
 280 }
 281
 282 sub atfork_prepare_wq {
 283         my ($self, $wq) = @_;
 284         my $tcafc = $wq->{-ipc_atfork_child_close} //= [];
 285         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 286         if (my $sock = $self->{sock}) {
 287                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 288         }
 289         if (my $pgr = $self->{pgr}) {
 290                 push @$tcafc, @$pgr[1,2];
 291         }
 292         for my $f (qw(lxs l2m)) {
 293                 my $ipc = $self->{$f} or next;
 294                 push @$tcafc, grep { defined }
 295                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 296         }
 297 }
 298
 299 # usage: my %sig = $lei->atfork_child_wq($wq);
 300 #        local @SIG{keys %sig} = values %sig;
 301 sub atfork_child_wq {
 302         my ($self, $wq) = @_;
 303         my ($sock, $l2m_wq_s1);
 304         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 305         $self->{sock} = $sock if -S $sock;
 306         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 307         %PATH2CFG = ();
 308         undef $errors_log;
 309         $quit = \&CORE::exit;
 310         @TO_CLOSE_ATFORK_CHILD = ();
 311         (__WARN__ => sub { err($self, @_) },
 312         PIPE => sub {
 313                 $self->x_it(13); # SIGPIPE = 13
 314                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 315                 for my $i (1, 2) {
 316                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 317                         close(delete $self->{$i});
 318                 }
 319                 # trigger the LeiXSearch $done OpPipe:
 320                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 321                 $SIG{PIPE} = 'DEFAULT';
 322                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 323         });
 324 }
 325
 326 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 327 sub atfork_parent_wq {
 328         my ($self, $wq) = @_;
 329         my $env = delete $self->{env}; # env is inherited at fork
 330         my $ret = bless { %$self }, ref($self);
 331         if (my $dedupe = delete $ret->{dedupe}) {
 332                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 333         }
 334         $self->{env} = $env;
 335         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 336         my @io = delete @$ret{0..2};
 337         $io[3] = delete($ret->{sock}) // $io[2];
 338         my $l2m = $ret->{l2m};
 339         if ($l2m && $l2m != $wq) { # $wq == lxs
 340                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 341                 $l2m->wq_close(1);
 342         }
 343         ($ret, @io);
 344 }
 345
 346 sub _help ($;$) {
 347         my ($self, $errmsg) = @_;
 348         my $cmd = $self->{cmd} // 'COMMAND';
 349         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 350         my @top = ($cmd, shift(@info) // ());
 351         my $cmd_desc = shift(@info);
 352         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 353         my @opt_desc;
 354         my $lpad = 2;
 355         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 356                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 357                 my $arg_vals = '';
 358                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 359
 360                 # lower-case is a keyword (e.g. `content', `oid'),
 361                 # ALL_CAPS is a string description (e.g. `PATH')
 362                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 363                         $desc .= "\ndefault: `$1'";
 364                 }
 365                 my (@vals, @s, @l);
 366                 my $x = $sw;
 367                 if ($x =~ s/!\z//) { # solve! => --no-solve
 368                         $x = "no-$x";
 369                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 370                         @vals = (' [', undef, ']');
 371                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 372                         @vals = (' ', undef);
 373                 } # else: no args $x = 'thread|t'
 374                 for (split(/\|/, $x)) { # help|h
 375                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 376                 }
 377                 if (!scalar(@vals)) { # no args 'thread|t'
 378                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 379                         $vals[1] = $1;
 380                 } else {
 381                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 382                 }
 383                 if ($arg_vals =~ /([,\|])/) {
 384                         my $sep = $1;
 385                         my @allow = split(/\Q$sep\E/, $arg_vals);
 386                         my $must = $sep eq '|' ? 'Must' : 'Can';
 387                         @allow = map { "`$_'" } @allow;
 388                         my $last = pop @allow;
 389                         $desc .= "\n$must be one of: " .
 390                                 join(', ', @allow) . " or $last";
 391                 }
 392                 my $lhs = join(', ', @s, @l) . join('', @vals);
 393                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 394                         $lhs =~ s/\A--/- , --/;
 395                 } else {
 396                         $lhs =~ s/\A--/    --/; # pad if no short options
 397                 }
 398                 $lpad = length($lhs) if length($lhs) > $lpad;
 399                 push @opt_desc, $lhs, $desc;
 400         }
 401         my $msg = $errmsg ? "E: $errmsg\n" : '';
 402         $msg .= <<EOF;
 403 usage: lei @top
 404   $cmd_desc
 405
 406 EOF
 407         $lpad += 2;
 408         local $Text::Wrap::columns = 78 - $lpad;
 409         my $padding = ' ' x ($lpad + 2);
 410         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 411                 $msg .= '  '.pack("A$lpad", $lhs);
 412                 $rhs = wrap('', '', $rhs);
 413                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 414                 $msg .= $rhs;
 415                 $msg .= "\n";
 416         }
 417         print { $self->{$errmsg ? 2 : 1} } $msg;
 418         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 419         undef;
 420 }
 421
 422 sub optparse ($$$) {
 423         my ($self, $cmd, $argv) = @_;
 424         $self->{cmd} = $cmd;
 425         $OPT = $self->{opt} = {};
 426         my $info = $CMD{$cmd} // [ '[...]' ];
 427         my ($proto, undef, @spec) = @$info;
 428         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 429         push @spec, qw(help|h);
 430         my $lone_dash;
 431         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 432                 $lone_dash = $spec[0];
 433                 $OPT->{$spec[0]} = \(my $var);
 434                 push @spec, '' => \$var;
 435         }
 436         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 437                 return _help($self, "bad arguments or options for $cmd");
 438         return _help($self) if $OPT->{help};
 439
 440         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 441
 442         # "-" aliases "stdin" or "clear"
 443         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 444
 445         my $i = 0;
 446         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 447         my ($err, $inf);
 448         my @args = split(/ /, $proto);
 449         for my $var (@args) {
 450                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 451                         $inf = defined($argv->[$i]) and last;
 452                         $var =~ s/\.\.\.\z//;
 453                         $err = "$var not supplied";
 454                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 455                         $argv->[$i++] // ($err = "$var not supplied");
 456                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 457                         $inf = 1;
 458                         last;
 459                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 460                         $i++;
 461                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 462                         my @or = split(/\|/, $var);
 463                         my $ok;
 464                         for my $o (@or) {
 465                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 466                                         $ok = defined($OPT->{$1});
 467                                         last;
 468                                 } elsif (defined($argv->[$i])) {
 469                                         $ok = 1;
 470                                         $i++;
 471                                         last;
 472                                 } # else continue looping
 473                         }
 474                         my $last = pop @or;
 475                         $err = join(', ', @or) . " or $last must be set";
 476                 } else {
 477                         warn "BUG: can't parse `$var' in $proto";
 478                 }
 479                 last if $err;
 480         }
 481         if (!$inf && scalar(@$argv) > scalar(@args)) {
 482                 $err //= 'too many arguments';
 483         }
 484         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 485 }
 486
 487 sub dispatch {
 488         my ($self, $cmd, @argv) = @_;
 489         local $current_lei = $self; # for __WARN__
 490         dump_and_clear_log("from previous run\n");
 491         return _help($self, 'no command given') unless defined($cmd);
 492         my $func = "lei_$cmd";
 493         $func =~ tr/-/_/;
 494         if (my $cb = __PACKAGE__->can($func)) {
 495                 optparse($self, $cmd, \@argv) or return;
 496                 $cb->($self, @argv);
 497         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 498                 my $opt = {};
 499                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 500                         return _help($self, 'bad arguments or options');
 501                 _help($self);
 502         } else {
 503                 fail($self, "`$cmd' is not an lei command");
 504         }
 505 }
 506
 507 sub _lei_cfg ($;$) {
 508         my ($self, $creat) = @_;
 509         my $f = _config_path($self->{env});
 510         my @st = stat($f);
 511         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 512         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 513                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 514         }
 515         if (!@st) {
 516                 unless ($creat) {
 517                         delete $self->{cfg};
 518                         return;
 519                 }
 520                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 521                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 522                 open my $fh, '>>', $f or die "open($f): $!\n";
 523                 @st = stat($fh) or die "fstat($f): $!\n";
 524                 $cur_st = pack('dd', $st[10], $st[7]);
 525                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 526         }
 527         my $cfg = PublicInbox::Config::git_config_dump($f);
 528         $cfg->{-st} = $cur_st;
 529         $cfg->{'-f'} = $f;
 530         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 531 }
 532
 533 sub _lei_store ($;$) {
 534         my ($self, $creat) = @_;
 535         my $cfg = _lei_cfg($self, $creat);
 536         $cfg->{-lei_store} //= do {
 537                 require PublicInbox::LeiStore;
 538                 my $dir = $cfg->{'leistore.dir'};
 539                 $dir //= _store_path($self->{env}) if $creat;
 540                 return unless $dir;
 541                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 542         };
 543 }
 544
 545 sub lei_show {
 546         my ($self, @argv) = @_;
 547 }
 548
 549 sub lei_mark {
 550         my ($self, @argv) = @_;
 551 }
 552
 553 sub lei_config {
 554         my ($self, @argv) = @_;
 555         $self->{opt}->{'config-file'} and return fail $self,
 556                 "config file switches not supported by `lei config'";
 557         my $env = $self->{env};
 558         delete local $env->{GIT_CONFIG};
 559         my $cfg = _lei_cfg($self, 1);
 560         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 561         my %rdr = map { $_ => $self->{$_} } (0..2);
 562         run_die($cmd, $env, \%rdr);
 563 }
 564
 565 sub lei_init {
 566         my ($self, $dir) = @_;
 567         my $cfg = _lei_cfg($self, 1);
 568         my $cur = $cfg->{'leistore.dir'};
 569         my $env = $self->{env};
 570         $dir //= _store_path($env);
 571         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 572         my @cur = stat($cur) if defined($cur);
 573         $cur = File::Spec->canonpath($cur // $dir);
 574         my @dir = stat($dir);
 575         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 576         if (@cur) {
 577                 if ($cur eq $dir) {
 578                         _lei_store($self, 1)->done;
 579                         return qerr($self, $exists);
 580                 }
 581
 582                 # some folks like symlinks and bind mounts :P
 583                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 584                         lei_config($self, 'leistore.dir', $dir);
 585                         _lei_store($self, 1)->done;
 586                         return qerr($self, "$exists (as $cur)");
 587                 }
 588                 return fail($self, <<"");
 589 E: leistore.dir=$cur already initialized and it is not $dir
 590
 591         }
 592         lei_config($self, 'leistore.dir', $dir);
 593         _lei_store($self, 1)->done;
 594         $exists //= "I: leistore.dir=$dir newly initialized";
 595         return qerr($self, $exists);
 596 }
 597
 598 sub lei_daemon_pid { puts shift, $$ }
 599
 600 sub lei_daemon_kill {
 601         my ($self) = @_;
 602         my $sig = $self->{opt}->{signal} // 'TERM';
 603         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 604 }
 605
 606 sub lei_help { _help($_[0]) }
 607
 608 # Shell completion helper.  Used by lei-completion.bash and hopefully
 609 # other shells.  Try to do as much here as possible to avoid redundancy
 610 # and improve maintainability.
 611 sub lei__complete {
 612         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 613         shift @argv; # ignore "lei", the entire command is sent
 614         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 615         my $cmd = shift @argv;
 616         my $info = $CMD{$cmd} // do { # filter matching commands
 617                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 618                 return;
 619         };
 620         my ($proto, undef, @spec) = @$info;
 621         my $cur = pop @argv;
 622         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 623         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 624                 # gross special case since the only git-config options
 625                 # Consider moving to a table if we need more special cases
 626                 # we use Getopt::Long for are the ones we reject, so these
 627                 # are the ones we don't reject:
 628                 if ($cmd eq 'config') {
 629                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 630                         @spec = qw(add z|null get get-all unset unset-all
 631                                 replace-all get-urlmatch
 632                                 remove-section rename-section
 633                                 name-only list|l edit|e
 634                                 get-color-name get-colorbool);
 635                         # fall-through
 636                 }
 637                 # TODO: arg support
 638                 puts $self, grep(/$re/, map { # generate short/long names
 639                         my $eq = '';
 640                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 641                                 $eq = '=';
 642                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 643                         } else { # negation: solve! => no-solve|solve
 644                                 s/\A(.+)!\z/no-$1|$1/;
 645                         }
 646                         map {
 647                                 length > 1 ? "--$_$eq" : "-$_"
 648                         } split(/\|/, $_, -1) # help|h
 649                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 650         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 651                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 652         }
 653         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 654         # proto parsing.
 655 }
 656
 657 sub reap_exec { # dwaitpid callback
 658         my ($self, $pid) = @_;
 659         x_it($self, $?);
 660 }
 661
 662 sub lei_git { # support passing through random git commands
 663         my ($self, @argv) = @_;
 664         my %rdr = map { $_ => $self->{$_} } (0..2);
 665         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 666         dwaitpid($pid, \&reap_exec, $self);
 667 }
 668
 669 sub exec_buf ($$) {
 670         my ($argv, $env) = @_;
 671         my $argc = scalar @$argv;
 672         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 673         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 674         $buf;
 675 }
 676
 677 sub start_mua {
 678         my ($self, $sock) = @_;
 679         my $mua = $self->{opt}->{'mua-cmd'} // return;
 680         my $mfolder = $self->{ovv}->{dst};
 681         require Text::ParseWords;
 682         my $replaced;
 683         my @cmd = Text::ParseWords::shellwords($mua);
 684         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 685         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 686         push @cmd, $mfolder unless defined($replaced);
 687         $sock //= $self->{sock};
 688         if ($sock) { # lei(1) client process runs it
 689                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 690         } else { # oneshot
 691                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 692         }
 693 }
 694
 695 # caller needs to "-t $self->{1}" to check if tty
 696 sub start_pager {
 697         my ($self) = @_;
 698         my $env = $self->{env};
 699         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 700         chomp(my $pager = <$fh> // '');
 701         close($fh) or warn "`git var PAGER' error: \$?=$?";
 702         return if $pager eq 'cat' || $pager eq '';
 703         # TODO TIOCGWINSZ
 704         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 705         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 706         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 707         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 708         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 709         if (my $sock = $self->{sock}) { # lei(1) process runs it
 710                 delete @$new_env{keys %$env}; # only set iff unset
 711                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 712                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 713         } else {
 714                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 715         }
 716         $self->{1} = $wpager;
 717         $self->{2} = $wpager if -t $self->{2};
 718         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 719         $self->{pgr} = $pgr;
 720 }
 721
 722 sub stop_pager {
 723         my ($self) = @_;
 724         my $pgr = delete($self->{pgr}) or return;
 725         $self->{2} = $pgr->[2];
 726         # do not restore original stdout, just close it so we error out
 727         close(delete($self->{1})) if $self->{1};
 728         my $pid = $pgr->[0];
 729         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 730 }
 731
 732 sub accept_dispatch { # Listener {post_accept} callback
 733         my ($sock) = @_; # ignore other
 734         $sock->autoflush(1);
 735         my $self = bless { sock => $sock }, __PACKAGE__;
 736         vec(my $rvec = '', fileno($sock), 1) = 1;
 737         select($rvec, undef, undef, 1) or
 738                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 739         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 740         if (scalar(@fds) == 4) {
 741                 my $i = 0;
 742                 for my $rdr (qw(<&= >&= >&= <&=)) {
 743                         my $fd = shift(@fds);
 744                         open($self->{$i++}, $rdr, $fd) and next;
 745                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 746                 }
 747         } else {
 748                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 749         }
 750         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 751         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 752         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 753         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 754                 return send($sock, 'request command truncated', MSG_EOR);
 755         my ($argc, @argv) = split(/\0/, $buf, -1);
 756         undef $buf;
 757         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 758         if (chdir(delete($self->{3}))) {
 759                 local %ENV = %env;
 760                 $self->{env} = \%env;
 761                 eval { dispatch($self, @argv) };
 762                 send($sock, $@, MSG_EOR) if $@;
 763         } else {
 764                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 765         }
 766 }
 767
 768 sub dclose {
 769         my ($self) = @_;
 770         for my $f (qw(lxs l2m)) {
 771                 my $wq = delete $self->{$f} or next;
 772                 if ($wq->wq_kill) {
 773                         $self->wq_close
 774                 } elsif ($wq->wq_kill_old) {
 775                         $wq->wq_wait_old;
 776                 }
 777         }
 778         close(delete $self->{1}) if $self->{1}; # may reap_compress
 779         $self->close if $self->{sock}; # PublicInbox::DS::close
 780 }
 781
 782 # for long-running results
 783 sub event_step {
 784         my ($self) = @_;
 785         local %ENV = %{$self->{env}};
 786         my $sock = $self->{sock};
 787         local $current_lei = $self;
 788         eval {
 789                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 790                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 791                                 return if $! == EAGAIN;
 792                                 next if $! == EINTR;
 793                                 last if $! == ECONNRESET;
 794                                 die "recvmsg: $!";
 795                         }
 796                         for my $fd (@fds) {
 797                                 open my $rfh, '+<&=', $fd;
 798                         }
 799                         die "unrecognized client signal: $buf";
 800                 }
 801                 dclose($self);
 802         };
 803         if (my $err = $@) {
 804                 eval { $self->fail($err) };
 805                 dclose($self);
 806         }
 807 }
 808
 809 sub event_step_init {
 810         my ($self) = @_;
 811         if (my $sock = $self->{sock}) { # using DS->EventLoop
 812                 $sock->blocking(0);
 813                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 814         }
 815 }
 816
 817 sub noop {}
 818
 819 our $oldset; sub oldset { $oldset }
 820
 821 sub dump_and_clear_log {
 822         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 823                 my @pfx = @_;
 824                 unshift(@pfx, "$errors_log ") if @pfx;
 825                 warn @pfx, do { local $/; <STDIN> };
 826                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 827         }
 828 }
 829
 830 # lei(1) calls this when it can't connect
 831 sub lazy_start {
 832         my ($path, $errno, $narg) = @_;
 833         if ($errno == ECONNREFUSED) {
 834                 unlink($path) or die "unlink($path): $!";
 835         } elsif ($errno != ENOENT) {
 836                 $! = $errno; # allow interpolation to stringify in die
 837                 die "connect($path): $!";
 838         }
 839         umask(077) // die("umask(077): $!");
 840         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 841         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 842         listen($l, 1024) or die "listen: $!";
 843         my @st = stat($path) or die "stat($path): $!";
 844         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 845         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 846         local $oldset = PublicInbox::DS::block_signals();
 847         if ($narg == 5) {
 848                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 849                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 850                         require PublicInbox::CmdIPC4;
 851                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 852                         PublicInbox::CmdIPC4->can('recv_cmd4');
 853                 };
 854         }
 855         $recv_cmd or die <<"";
 856 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 857
 858         require PublicInbox::Listener;
 859         require PublicInbox::EOFpipe;
 860         (-p STDOUT) or die "E: stdout must be a pipe\n";
 861         local $errors_log;
 862         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 863         $errors_log .= 'errors.log';
 864         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 865         STDIN->autoflush(1);
 866         dump_and_clear_log("from previous daemon process:\n");
 867         POSIX::setsid() > 0 or die "setsid: $!";
 868         my $pid = fork // die "fork: $!";
 869         return if $pid;
 870         $0 = "lei-daemon $path";
 871         local %PATH2CFG;
 872         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 873         $l->blocking(0);
 874         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 875         my $exit_code;
 876         local $quit = sub {
 877                 $exit_code //= shift;
 878                 my $listener = $l or exit($exit_code);
 879                 # closing eof_w triggers \&noop wakeup
 880                 $eof_w = $l = $path = undef;
 881                 $listener->close; # DS::close
 882                 PublicInbox::DS->SetLoopTimeout(1000);
 883         };
 884         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 885         undef $eof_r;
 886         my $sig = {
 887                 CHLD => \&PublicInbox::DS::enqueue_reap,
 888                 QUIT => $quit,
 889                 INT => $quit,
 890                 TERM => $quit,
 891                 HUP => \&noop,
 892                 USR1 => \&noop,
 893                 USR2 => \&noop,
 894         };
 895         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 896         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 897         undef $sig;
 898         local $SIG{PIPE} = 'IGNORE';
 899         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 900                 undef $sigfd;
 901                 PublicInbox::DS->SetLoopTimeout(5000);
 902         } else {
 903                 # wake up every second to accept signals if we don't
 904                 # have signalfd or IO::KQueue:
 905                 PublicInbox::DS::sig_setmask($oldset);
 906                 PublicInbox::DS->SetLoopTimeout(1000);
 907         }
 908         PublicInbox::DS->SetPostLoopCallback(sub {
 909                 my ($dmap, undef) = @_;
 910                 if (@st = defined($path) ? stat($path) : ()) {
 911                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 912                                 warn "$path dev/ino changed, quitting\n";
 913                                 $path = undef;
 914                         }
 915                 } elsif (defined($path)) {
 916                         warn "stat($path): $!, quitting ...\n";
 917                         undef $path; # don't unlink
 918                         $quit->();
 919                 }
 920                 return 1 if defined($path);
 921                 my $now = now();
 922                 my $n = 0;
 923                 for my $s (values %$dmap) {
 924                         $s->can('busy') or next;
 925                         if ($s->busy($now)) {
 926                                 ++$n;
 927                         } else {
 928                                 $s->close;
 929                         }
 930                 }
 931                 $n; # true: continue, false: stop
 932         });
 933
 934         # STDIN was redirected to /dev/null above, closing STDERR and
 935         # STDOUT will cause the calling `lei' client process to finish
 936         # reading the <$daemon> pipe.
 937         openlog($path, 'pid', 'user');
 938         local $SIG{__WARN__} = sub {
 939                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 940         };
 941         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 942                 syslog('crit', "$@") if $@;
 943         });
 944         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 945         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 946         # $daemon pipe to `lei' closed, main loop begins:
 947         PublicInbox::DS->EventLoop;
 948         @$on_destroy = (); # cancel on_destroy if we get here
 949         exit($exit_code // 0);
 950 }
 951
 952 # for users w/o Socket::Msghdr
 953 sub oneshot {
 954         my ($main_pkg) = @_;
 955         my $exit = $main_pkg->can('exit'); # caller may override exit()
 956         local $quit = $exit if $exit;
 957         local %PATH2CFG;
 958         umask(077) // die("umask(077): $!");
 959         dispatch((bless {
 960                 0 => *STDIN{GLOB},
 961                 1 => *STDOUT{GLOB},
 962                 2 => *STDERR{GLOB},
 963                 env => \%ENV
 964         }, __PACKAGE__), @ARGV);
 965 }
 966
 967 # ensures stdout hits the FS before sock disconnects so a client
 968 # can immediately reread it
 969 sub DESTROY {
 970         my ($self) = @_;
 971         $self->{1}->autoflush(1) if $self->{1};
 972         stop_pager($self);
 973         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 974                 waitpid($mua_pid, 0);
 975         }
 976 }
 977
 978 1;