lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209
 210 'plonk' => [ '--threads|--from=IDENT',
 211         'exclude mail matching From: or threads from non-Message-ID searches',
 212         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 213 'tag' => [ 'KEYWORDS...',
 214         'set/unset keywords and/or labels on message(s)',
 215         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 216         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 217         pass_through('-kw:foo for delete') ],
 218 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 219         "exclude message(s) on stdin from `q' search results",
 220         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246
 247 'export-kw' => [ 'LOCATION...|--all',
 248         'one-time export of keywords of sync sources',
 249         qw(all:s mode=s), @c_opt ],
 250 'convert' => [ 'LOCATION...|--stdin',
 251         'one-time conversion from URL or filesystem to another format',
 252         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 253         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 254 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 255         "use a patch to generate a query for `lei q --stdin'",
 256         qw(stdin| want|w=s@ uri debug), @c_opt ],
 257 'config' => [ '[...]', sub {
 258                 'git-config(1) wrapper for '._config_path($_[0]);
 259         }, qw(config-file|system|global|file|f=s), # for conflict detection
 260          qw(c=s@ C=s@), pass_through('git config') ],
 261 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 262         qw(pretty ascii dir=s), @c_opt ],
 263
 264 'init' => [ '[DIRNAME]', sub {
 265         "initialize storage, default: ".store_path($_[0]);
 266         }, @c_opt ],
 267 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 268         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 269         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 270 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 271 'help' => [ '[SUBCOMMAND]', 'show help' ],
 272
 273 # XXX do we need this?
 274 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 275
 276 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 277         'rewrite git history in an attempt to improve compression',
 278         qw(gc!), @c_opt ],
 279
 280 # internal commands are prefixed with '_'
 281 '_complete' => [ '[...]', 'internal shell completion helper',
 282                 pass_through('everything') ],
 283 ); # @CMD
 284
 285 # switch descriptions, try to keep consistent across commands
 286 # $spec: Getopt::Long option specification
 287 # $spec => [@ALLOWED_VALUES (default is first), $description],
 288 # $spec => $description
 289 # "$SUB_COMMAND TAB $spec" => as above
 290 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 291                         'specify message input format' ];
 292 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 293
 294 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 295 my %OPTDESC = (
 296 'help|h' => 'show this built-in help',
 297 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 298 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 299 'quiet|q' => 'be quiet',
 300 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 301         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 302
 303 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 304 'globoff|g' => "do not match locations using '*?' wildcards ".
 305                 "and\xa0'[]'\x{a0}ranges",
 306 'invert-match|v' => 'select non-matching lines',
 307 'color!' => 'disable color (for --format=text)',
 308 'verbose|v+' => 'be more verbose',
 309 'external!' => 'do not use externals',
 310 'mail!' => 'do not look in mail storage for OID',
 311 'cwd!' => 'do not look in git repo of current working directory',
 312 'oid-a|A=s' => 'pre-image OID',
 313 'path-a|a=s' => 'pre-image pathname associated with OID',
 314 'path-b|b=s' => 'post-image pathname associated with OID',
 315 'git-dir=s@' => 'additional git repository to scan',
 316 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 317         "proxy for (e.g. `socks5h://0:9050')" ],
 318 'torsocks=s' => ['VAL|auto|no|yes',
 319                 'whether or not to wrap git and curl commands with torsocks'],
 320 'no-torsocks' => 'alias for --torsocks=no',
 321 'save' =>  "save a search for `lei up'",
 322 'import-remote!' => 'do not memoize remote messages into local store',
 323
 324 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 325
 326 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 327                 'deduplication strategy'],
 328 'threads|t+' =>
 329         'return all messages in the same threads as the actual match(es)',
 330
 331 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 332                 'search prefixes to extract (default: dfpost7)' ],
 333
 334 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 335         'run command(s) or perform ops when done writing to output ' .
 336         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 337         'nothing otherwise)' ],
 338
 339 'augment|a' => 'augment --output destination instead of clobbering',
 340
 341 'output|mfolder|o=s' => [ 'MFOLDER',
 342         "destination (e.g.\xa0`/path/to/Maildir', ".
 343         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 344 'mua=s' => [ 'CMD',
 345         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 346
 347 'inbox-version=i' => [ 'NUM|1|2',
 348                 'force a public-inbox version with --mirror'],
 349 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 350
 351 # public-inbox-index options
 352 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 353 'compact' => 'run compact index after mirroring',
 354 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 355         "indexlevel with --mirror (default: full)" ],
 356 'max_size|max-size=s' => [ 'SIZE',
 357         'do not index messages larger than SIZE (default: infinity)' ],
 358 'batch_size|batch-size=s' => [ 'SIZE',
 359         'flush changes to OS after given number of bytes (default: 1m)' ],
 360 'sequential_shard|sequential-shard' =>
 361         'index Xapian shards sequentially for slow storage',
 362 'skip-docdata' =>
 363         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 364
 365 'format|f=s     q' => [
 366         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 367                 'specify output format, default depends on --output'],
 368 'exclude=s@     q' => [ 'LOCATION',
 369                 'exclude specified external(s) from search' ],
 370 'include|I=s@   q' => [ 'LOCATION',
 371                 'include specified external(s) in search' ],
 372 'only=s@        q' => [ 'LOCATION',
 373                 'only use specified external(s) for search' ],
 374 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 375                 'control number of search and writer jobs' ],
 376 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 377
 378 'in-format|F=s' => $stdin_formats,
 379 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 380                         'listing output format' ],
 381 'l      ls-search' => 'long listing format',
 382 'format|f=s     ls-external' => $ls_format,
 383
 384 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 385 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 386
 387 'sort|s=s' => [ 'VAL|received|relevance|docid',
 388                 "order of results is `--output'-dependent"],
 389 'reverse|r' => 'reverse search results', # like sort(1)
 390
 391 'boost=i' => 'increase/decrease priority of results (default: 0)',
 392
 393 'local' => 'limit operations to the local filesystem',
 394 'local!' => 'exclude results from the local filesystem',
 395 'remote' => 'limit operations to those requiring network access',
 396 'remote!' => 'prevent operations requiring network access',
 397
 398 'all:s  up' => ['local', 'update all (local) saved searches' ],
 399
 400 'mid=s' => 'specify the Message-ID of a message',
 401 'oid=s' => 'specify the git object ID of a message',
 402
 403 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 404 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 405 'include=s' => 'include mailboxes/newsgroups based on pattern',
 406
 407 'exact' => 'operate on exact header matches only',
 408 'exact!' => 'rely on content match instead of exact header matches',
 409
 410 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 411
 412 'kw!' => 'disable/enable importing keywords (aka "flags")',
 413
 414 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 415 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 416
 417 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 418 ); # %OPTDESC
 419
 420 my %CONFIG_KEYS = (
 421         'leistore.dir' => 'top-level storage location',
 422 );
 423
 424 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 425
 426 sub _drop_wq {
 427         my ($self) = @_;
 428         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 429                 if ($wq->wq_kill) {
 430                         $wq->wq_close(0, undef, $self);
 431                 } elsif ($wq->wq_kill_old) {
 432                         $wq->wq_wait_old(undef, $self);
 433                 }
 434                 $wq->DESTROY;
 435         }
 436 }
 437
 438 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 439 sub x_it ($$) {
 440         my ($self, $code) = @_;
 441         # make sure client sees stdout before exit
 442         $self->{1}->autoflush(1) if $self->{1};
 443         dump_and_clear_log();
 444         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 445                 send($s, "x_it $code", MSG_EOR);
 446         } elsif ($self->{oneshot}) {
 447                 # don't want to end up using $? from child processes
 448                 _drop_wq($self);
 449                 # cleanup anything that has tempfiles or open file handles
 450                 %PATH2CFG = ();
 451                 delete @$self{qw(ovv dedupe sto cfg)};
 452                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 453                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 454                         kill $signum, $$;
 455                         sleep(1) while 1; # wait for signal
 456                 } else {
 457                         $quit->($code >> 8);
 458                 }
 459         } # else ignore if client disconnected
 460 }
 461
 462 sub err ($;@) {
 463         my $self = shift;
 464         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 465         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 466         print $err @_, @eor and return;
 467         my $old_err = delete $self->{2};
 468         close($old_err) if $! == EPIPE && $old_err;
 469         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 470         print $err @_, @eor or print STDERR @_, @eor;
 471 }
 472
 473 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 474
 475 sub fail_handler ($;$$) {
 476         my ($lei, $code, $io) = @_;
 477         close($io) if $io; # needed to avoid warnings on SIGPIPE
 478         _drop_wq($lei);
 479         x_it($lei, $code // (1 << 8));
 480 }
 481
 482 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 483         fail_handler($_[0], 13, delete $_[0]->{1});
 484 }
 485
 486 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 487 sub sigint_reap {
 488         my ($pgid) = @_;
 489         dwaitpid($pgid) if kill('-INT', $pgid);
 490 }
 491
 492 sub fail ($$;$) {
 493         my ($self, $buf, $exit_code) = @_;
 494         err($self, $buf) if defined $buf;
 495         # calls fail_handler:
 496         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 497         x_it($self, ($exit_code // 1) << 8);
 498         undef;
 499 }
 500
 501 sub out ($;@) {
 502         my $self = shift;
 503         return if print { $self->{1} // return } @_; # likely
 504         return note_sigpipe($self, 1) if $! == EPIPE;
 505         my $err = "error writing to output: $!";
 506         delete $self->{1};
 507         fail($self, $err);
 508 }
 509
 510 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 511
 512 sub child_error { # passes non-fatal curl exit codes to user
 513         my ($self, $child_error, $msg) = @_; # child_error is $?
 514         $self->err($msg) if $msg;
 515         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 516                 # send to the parent lei-daemon or to lei(1) client
 517                 send($s, "child_error $child_error", MSG_EOR);
 518         } elsif (!$PublicInbox::DS::in_loop) {
 519                 $self->{child_error} = $child_error;
 520         } # else noop if client disconnected
 521 }
 522
 523 sub note_sigpipe { # triggers sigpipe_handler
 524         my ($self, $fd) = @_;
 525         close(delete($self->{$fd})); # explicit close silences Perl warning
 526         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 527         x_it($self, 13);
 528 }
 529
 530 sub _lei_atfork_child {
 531         my ($self, $persist) = @_;
 532         # we need to explicitly close things which are on stack
 533         if ($persist) {
 534                 chdir '/' or die "chdir(/): $!";
 535                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 536                 if (my $cfg = $self->{cfg}) {
 537                         delete $cfg->{-lei_store};
 538                 }
 539         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 540                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 541                 STDERR->autoflush(1);
 542         }
 543         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 544         if (my $op_c = delete $self->{pkt_op_c}) {
 545                 close(delete $op_c->{sock});
 546         }
 547         if (my $pgr = delete $self->{pgr}) {
 548                 close($_) for (@$pgr[1,2]);
 549         }
 550         close $listener if $listener;
 551         undef $listener;
 552         undef $dir_idle;
 553         %PATH2CFG = ();
 554         undef $errors_log;
 555         $quit = \&CORE::exit;
 556         $self->{-eml_noisy} or # only "lei import" sets this atm
 557                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 558         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 559 }
 560
 561 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 562         my ($self) = @_;
 563         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 564                 $op->close; # PublicInbox::PktOp::close
 565         }
 566         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 567         close $unclosed_after_die;
 568 }
 569
 570 sub pkt_op_pair {
 571         my ($self) = @_;
 572         require PublicInbox::OnDestroy;
 573         require PublicInbox::PktOp;
 574         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 575         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 576         $end;
 577 }
 578
 579 sub workers_start {
 580         my ($lei, $wq, $jobs, $ops) = @_;
 581         $ops = {
 582                 '!' => [ \&fail_handler, $lei ],
 583                 '|' => [ \&sigpipe_handler, $lei ],
 584                 'x_it' => [ \&x_it, $lei ],
 585                 'child_error' => [ \&child_error, $lei ],
 586                 ($ops ? %$ops : ()),
 587         };
 588         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 589         my $end = $lei->pkt_op_pair;
 590         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 591         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 592         delete $lei->{pkt_op_p};
 593         my $op_c = delete $lei->{pkt_op_c};
 594         @$end = ();
 595         $lei->event_step_init;
 596         ($op_c, $ops);
 597 }
 598
 599 sub _help {
 600         require PublicInbox::LeiHelp;
 601         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 602 }
 603
 604 sub optparse ($$$) {
 605         my ($self, $cmd, $argv) = @_;
 606         # allow _complete --help to complete, not show help
 607         return 1 if substr($cmd, 0, 1) eq '_';
 608         $self->{cmd} = $cmd;
 609         $OPT = $self->{opt} //= {};
 610         my $info = $CMD{$cmd} // [ '[...]' ];
 611         my ($proto, undef, @spec) = @$info;
 612         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 613         push @spec, qw(help|h);
 614         my $lone_dash;
 615         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 616                 $lone_dash = $spec[0];
 617                 $OPT->{$spec[0]} = \(my $var);
 618                 push @spec, '' => \$var;
 619         }
 620         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 621                 return _help($self, "bad arguments or options for $cmd");
 622         return _help($self) if $OPT->{help};
 623
 624         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 625
 626         # "-" aliases "stdin" or "clear"
 627         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 628
 629         my $i = 0;
 630         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 631         my ($err, $inf);
 632         my @args = split(/ /, $proto);
 633         for my $var (@args) {
 634                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 635                         $inf = defined($argv->[$i]) and last;
 636                         $var =~ s/\.\.\.\z//;
 637                         $err = "$var not supplied";
 638                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 639                         $argv->[$i++] // ($err = "$var not supplied");
 640                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 641                         $inf = 1;
 642                         last;
 643                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 644                         $i++;
 645                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 646                         $inf = 1 if index($var, '...') > 0;
 647                         my @or = split(/\|/, $var);
 648                         my $ok;
 649                         for my $o (@or) {
 650                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 651                                         $ok = defined($OPT->{$1});
 652                                         last if $ok;
 653                                 } elsif (defined($argv->[$i])) {
 654                                         $ok = 1;
 655                                         $i++;
 656                                         last;
 657                                 } # else continue looping
 658                         }
 659                         last if $ok;
 660                         my $last = pop @or;
 661                         $err = join(', ', @or) . " or $last must be set";
 662                 } else {
 663                         warn "BUG: can't parse `$var' in $proto";
 664                 }
 665                 last if $err;
 666         }
 667         if (!$inf && scalar(@$argv) > scalar(@args)) {
 668                 $err //= 'too many arguments';
 669         }
 670         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 671 }
 672
 673 sub _tmp_cfg { # for lei -c <name>=<value> ...
 674         my ($self) = @_;
 675         my $cfg = _lei_cfg($self, 1);
 676         require File::Temp;
 677         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 678         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 679         $ft->autoflush(1);
 680         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 681 [include]
 682         path = $cfg->{-f}
 683 EOM
 684         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 685         for (@{$self->{opt}->{c}}) {
 686                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 687 `-c $_' is not of the form -c <name>=<value>'
 688 EOM
 689                 my $name = $1;
 690                 my $value = $2 // 1;
 691                 _config($self, '--add', $name, $value);
 692                 if (defined(my $v = $tmp->{$name})) {
 693                         if (ref($v) eq 'ARRAY') {
 694                                 push @$v, $value;
 695                         } else {
 696                                 $tmp->{$name} = [ $v, $value ];
 697                         }
 698                 } else {
 699                         $tmp->{$name} = $value;
 700                 }
 701         }
 702 }
 703
 704 sub lazy_cb ($$$) {
 705         my ($self, $cmd, $pfx) = @_;
 706         my $ucmd = $cmd;
 707         $ucmd =~ tr/-/_/;
 708         my $cb;
 709         $cb = $self->can($pfx.$ucmd) and return $cb;
 710         my $base = $ucmd;
 711         $base =~ s/_([a-z])/\u$1/g;
 712         my $pkg = "PublicInbox::Lei\u$base";
 713         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 714                 $pkg->can($pfx.$ucmd) : undef;
 715 }
 716
 717 sub dispatch {
 718         my ($self, $cmd, @argv) = @_;
 719         local $current_lei = $self; # for __WARN__
 720         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 721         dump_and_clear_log("from previous run\n");
 722         return _help($self, 'no command given') unless defined($cmd);
 723         # do not support Getopt bundling for this
 724         while ($cmd eq '-C' || $cmd eq '-c') {
 725                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 726                                         '-C DIRECTORY' : '-c <name>=<value>');
 727                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 728                 $cmd = shift(@argv) // return _help($self, 'no command given');
 729         }
 730         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 731                 optparse($self, $cmd, \@argv) or return;
 732                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 733                 if (my $chdir = $self->{opt}->{C}) {
 734                         for my $d (@$chdir) {
 735                                 next if $d eq ''; # same as git(1)
 736                                 chdir $d or return fail($self, "cd $d: $!");
 737                         }
 738                         if (delete $self->{3}) { # update cwd for rel2abs
 739                                 opendir my $dh, '.' or
 740                                         return fail($self, "opendir . $!");
 741                                 $self->{3} = $dh;
 742                         }
 743                 }
 744                 $cb->($self, @argv);
 745         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 746                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 747                         or return _help($self, 'bad arguments or options');
 748                 _help($self);
 749         } else {
 750                 fail($self, "`$cmd' is not an lei command");
 751         }
 752 }
 753
 754 sub _lei_cfg ($;$) {
 755         my ($self, $creat) = @_;
 756         return $self->{cfg} if $self->{cfg};
 757         my $f = _config_path($self);
 758         my @st = stat($f);
 759         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 760         my ($sto, $sto_dir);
 761         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 762                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 763                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 764         }
 765         if (!@st) {
 766                 unless ($creat) {
 767                         delete $self->{cfg};
 768                         return bless {}, 'PublicInbox::Config';
 769                 }
 770                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 771                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 772                 open my $fh, '>>', $f or die "open($f): $!\n";
 773                 @st = stat($fh) or die "fstat($f): $!\n";
 774                 $cur_st = pack('dd', $st[10], $st[7]);
 775                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 776         }
 777         my $cfg = PublicInbox::Config->git_config_dump($f);
 778         $cfg->{-st} = $cur_st;
 779         $cfg->{'-f'} = $f;
 780         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 781                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 782                                                 store_path($self))) {
 783                 $cfg->{-lei_store} = $sto;
 784         }
 785         if (scalar(keys %PATH2CFG) > 5) {
 786                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 787                 for my $k (keys %PATH2CFG) {
 788                         delete($PATH2CFG{$k}) unless -f $k
 789                 }
 790         }
 791         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 792 }
 793
 794 sub _lei_store ($;$) {
 795         my ($self, $creat) = @_;
 796         my $cfg = _lei_cfg($self, $creat);
 797         $cfg->{-lei_store} //= do {
 798                 require PublicInbox::LeiStore;
 799                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 800                 return unless $creat || -d $dir;
 801                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 802         };
 803 }
 804
 805 sub _config {
 806         my ($self, @argv) = @_;
 807         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 808         my $cfg = _lei_cfg($self, 1);
 809         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 810         my %rdr = map { $_ => $self->{$_} } (0..2);
 811         waitpid(spawn($cmd, \%env, \%rdr), 0);
 812 }
 813
 814 sub lei_config {
 815         my ($self, @argv) = @_;
 816         $self->{opt}->{'config-file'} and return fail $self,
 817                 "config file switches not supported by `lei config'";
 818         _config(@_);
 819         x_it($self, $?) if $?;
 820 }
 821
 822 sub lei_daemon_pid { puts shift, $$ }
 823
 824 sub lei_daemon_kill {
 825         my ($self) = @_;
 826         my $sig = $self->{opt}->{signal} // 'TERM';
 827         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 828 }
 829
 830 # Shell completion helper.  Used by lei-completion.bash and hopefully
 831 # other shells.  Try to do as much here as possible to avoid redundancy
 832 # and improve maintainability.
 833 sub lei__complete {
 834         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 835         shift @argv; # ignore "lei", the entire command is sent
 836         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 837         my $cmd = shift @argv;
 838         my $info = $CMD{$cmd} // do { # filter matching commands
 839                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 840                 return;
 841         };
 842         my ($proto, undef, @spec) = @$info;
 843         my $cur = pop @argv;
 844         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 845         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 846                 # gross special case since the only git-config options
 847                 # Consider moving to a table if we need more special cases
 848                 # we use Getopt::Long for are the ones we reject, so these
 849                 # are the ones we don't reject:
 850                 if ($cmd eq 'config') {
 851                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 852                         @spec = qw(add z|null get get-all unset unset-all
 853                                 replace-all get-urlmatch
 854                                 remove-section rename-section
 855                                 name-only list|l edit|e
 856                                 get-color-name get-colorbool);
 857                         # fall-through
 858                 }
 859                 # generate short/long names from Getopt::Long specs
 860                 puts $self, grep(/$re/, qw(--help -h -C), map {
 861                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 862                         } elsif (s/\+\z//) { # verbose|v+
 863                         } elsif (s/!\z//) {
 864                                 # negation: mail! => no-mail|mail
 865                                 s/([\w\-]+)/$1|no-$1/g
 866                         }
 867                         map {
 868                                 my $x = length > 1 ? "--$_" : "-$_";
 869                                 $x eq $_cur ? () : $x;
 870                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 871                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 872         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 873                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 874         }
 875
 876         # switch args (e.g. lei q -f mbox<TAB>)
 877         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 878                 my $opt = quotemeta $1;
 879                 puts $self, map {
 880                         my $v = $OPTDESC{$_};
 881                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 882                         # get rid of ALL CAPS placeholder (e.g "OUT")
 883                         # (TODO: completion for external paths)
 884                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 885                         @v;
 886                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 887         }
 888         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 889                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 890         }
 891         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 892         # proto parsing.
 893 }
 894
 895 sub exec_buf ($$) {
 896         my ($argv, $env) = @_;
 897         my $argc = scalar @$argv;
 898         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 899         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 900         $buf;
 901 }
 902
 903 sub start_mua {
 904         my ($self) = @_;
 905         my $mua = $self->{opt}->{mua} // return;
 906         my $mfolder = $self->{ovv}->{dst};
 907         my (@cmd, $replaced);
 908         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 909                 @cmd = ($mua, '-f');
 910         # TODO: help wanted: other common FOSS MUAs
 911         } else {
 912                 require Text::ParseWords;
 913                 @cmd = Text::ParseWords::shellwords($mua);
 914                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 915                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 916         }
 917         push @cmd, $mfolder unless defined($replaced);
 918         if ($self->{sock}) { # lei(1) client process runs it
 919                 # restore terminal: echo $query | lei q -stdin --mua=...
 920                 my $io = [];
 921                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 922                 send_exec_cmd($self, $io, \@cmd, {});
 923         } elsif ($self->{oneshot}) {
 924                 my $pid = fork // die "fork: $!";
 925                 if ($pid > 0) { # original process
 926                         if ($self->{opt}->{stdin} && -t STDOUT) {
 927                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 928                         }
 929                         exec(@cmd);
 930                         warn "exec @cmd: $!\n";
 931                         POSIX::_exit(1);
 932                 }
 933                 POSIX::setsid() > 0 or die "setsid: $!";
 934         }
 935         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 936                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 937         }
 938         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 939         $self->{opt}->{quiet} = 1;
 940         delete $self->{-progress};
 941         delete $self->{opt}->{verbose};
 942 }
 943
 944 sub send_exec_cmd { # tell script/lei to execute a command
 945         my ($self, $io, $cmd, $env) = @_;
 946         my $sock = $self->{sock} // die 'lei client gone';
 947         my $fds = [ map { fileno($_) } @$io ];
 948         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 949 }
 950
 951 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 952         my ($self) = @_;
 953         my $alerts = $self->{opt}->{alert} // return;
 954         while (my $op = shift(@$alerts)) {
 955                 if ($op eq ':WINCH') {
 956                         # hit the process group that started the MUA
 957                         if ($self->{sock}) {
 958                                 send($self->{sock}, '-WINCH', MSG_EOR);
 959                         } elsif ($self->{oneshot}) {
 960                                 kill('-WINCH', $$);
 961                         }
 962                 } elsif ($op eq ':bell') {
 963                         out($self, "\a");
 964                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 965                         push @$alerts, split(/(?<!\\),/, $op);
 966                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 967                         my $cmd = $1; # run an arbitrary command
 968                         require Text::ParseWords;
 969                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 970                         if (my $s = $self->{sock}) {
 971                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 972                         } elsif ($self->{oneshot}) {
 973                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 974                         }
 975                 } else {
 976                         err($self, "W: unsupported --alert=$op"); # non-fatal
 977                 }
 978         }
 979 }
 980
 981 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 982 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 983
 984 # this also normalizes the path
 985 sub path_to_fd {
 986         my ($self, $path) = @_;
 987         $path = rel2abs($self, $path);
 988         $path =~ tr!/!/!s;
 989         $path_to_fd{$path} // (
 990                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 991                         fail($self, "cannot open $path from daemon") : -1
 992         );
 993 }
 994
 995 # caller needs to "-t $self->{1}" to check if tty
 996 sub start_pager {
 997         my ($self) = @_;
 998         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 999         chomp(my $pager = <$fh> // '');
1000         close($fh) or warn "`git var PAGER' error: \$?=$?";
1001         return if $pager eq 'cat' || $pager eq '';
1002         my $new_env = { LESS => 'FRX', LV => '-c' };
1003         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1004         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1005         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1006         my $pgr = [ undef, @$rdr{1, 2} ];
1007         my $env = $self->{env};
1008         if ($self->{sock}) { # lei(1) process runs it
1009                 delete @$new_env{keys %$env}; # only set iff unset
1010                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1011         } elsif ($self->{oneshot}) {
1012                 my $cmd = [$pager];
1013                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
1014         } else {
1015                 die 'BUG: start_pager w/o socket';
1016         }
1017         $self->{1} = $wpager;
1018         $self->{2} = $wpager if -t $self->{2};
1019         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1020         $self->{pgr} = $pgr;
1021 }
1022
1023 sub stop_pager {
1024         my ($self) = @_;
1025         my $pgr = delete($self->{pgr}) or return;
1026         $self->{2} = $pgr->[2];
1027         # do not restore original stdout, just close it so we error out
1028         close(delete($self->{1})) if $self->{1};
1029 }
1030
1031 sub accept_dispatch { # Listener {post_accept} callback
1032         my ($sock) = @_; # ignore other
1033         $sock->autoflush(1);
1034         my $self = bless { sock => $sock }, __PACKAGE__;
1035         vec(my $rvec = '', fileno($sock), 1) = 1;
1036         select($rvec, undef, undef, 60) or
1037                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1038         # (4096 * 33) >MAX_ARG_STRLEN
1039         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1040         if (!defined($fds[0])) {
1041                 warn(my $msg = "recv_cmd failed: $!");
1042                 return send($sock, $msg, MSG_EOR);
1043         } else {
1044                 my $i = 0;
1045                 for my $fd (@fds) {
1046                         open($self->{$i++}, '+<&=', $fd) and next;
1047                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1048                 }
1049                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1050         }
1051         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1052         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1053         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1054                 return send($sock, 'request command truncated', MSG_EOR);
1055         my ($argc, @argv) = split(/\0/, $buf, -1);
1056         undef $buf;
1057         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1058         if (chdir($self->{3})) {
1059                 local %ENV = %env;
1060                 $self->{env} = \%env;
1061                 eval { dispatch($self, @argv) };
1062                 send($sock, $@, MSG_EOR) if $@;
1063         } else {
1064                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1065         }
1066 }
1067
1068 sub dclose {
1069         my ($self) = @_;
1070         delete $self->{-progress};
1071         _drop_wq($self);
1072         close(delete $self->{1}) if $self->{1}; # may reap_compress
1073         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1074 }
1075
1076 # for long-running results
1077 sub event_step {
1078         my ($self) = @_;
1079         local %ENV = %{$self->{env}};
1080         my $sock = $self->{sock};
1081         local $current_lei = $self;
1082         eval {
1083                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1084                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1085                                 return if $! == EAGAIN;
1086                                 next if $! == EINTR;
1087                                 last if $! == ECONNRESET;
1088                                 die "recvmsg: $!";
1089                         }
1090                         for my $fd (@fds) {
1091                                 open my $rfh, '+<&=', $fd;
1092                         }
1093                         die "unrecognized client signal: $buf";
1094                 }
1095                 dclose($self);
1096         };
1097         if (my $err = $@) {
1098                 eval { $self->fail($err) };
1099                 dclose($self);
1100         }
1101 }
1102
1103 sub event_step_init {
1104         my ($self) = @_;
1105         return if $self->{-event_init_done}++;
1106         if (my $sock = $self->{sock}) { # using DS->EventLoop
1107                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1108         }
1109 }
1110
1111 sub noop {}
1112
1113 sub oldset { $oldset }
1114
1115 sub dump_and_clear_log {
1116         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1117                 my @pfx = @_;
1118                 unshift(@pfx, "$errors_log ") if @pfx;
1119                 warn @pfx, do { local $/; <STDIN> };
1120                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1121         }
1122 }
1123
1124 # lei(1) calls this when it can't connect
1125 sub lazy_start {
1126         my ($path, $errno, $narg) = @_;
1127         local ($errors_log, $listener);
1128         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1129         $errors_log = "$sock_dir/errors.log";
1130         my $addr = pack_sockaddr_un($path);
1131         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1132         $lk->lock_acquire;
1133         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1134         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1135                 return if connect($listener, $addr); # another process won
1136                 if ($errno == ECONNREFUSED && -S $path) {
1137                         unlink($path) or die "unlink($path): $!";
1138                 }
1139         } else {
1140                 $! = $errno; # allow interpolation to stringify in die
1141                 die "connect($path): $!";
1142         }
1143         umask(077) // die("umask(077): $!");
1144         bind($listener, $addr) or die "bind($path): $!";
1145         listen($listener, 1024) or die "listen: $!";
1146         $lk->lock_release;
1147         undef $lk;
1148         my @st = stat($path) or die "stat($path): $!";
1149         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1150         local $oldset = PublicInbox::DS::block_signals();
1151         if ($narg == 5) {
1152                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1153                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1154                         require PublicInbox::CmdIPC4;
1155                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1156                         PublicInbox::CmdIPC4->can('recv_cmd4');
1157                 };
1158         }
1159         $recv_cmd or die <<"";
1160 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1161
1162         require PublicInbox::Listener;
1163         require PublicInbox::PktOp;
1164         (-p STDOUT) or die "E: stdout must be a pipe\n";
1165         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1166         STDIN->autoflush(1);
1167         dump_and_clear_log("from previous daemon process:\n");
1168         POSIX::setsid() > 0 or die "setsid: $!";
1169         my $pid = fork // die "fork: $!";
1170         return if $pid;
1171         $0 = "lei-daemon $path";
1172         local %PATH2CFG;
1173         $listener->blocking(0);
1174         my $exit_code;
1175         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1176         local $quit = do {
1177                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1178                 sub {
1179                         $exit_code //= shift;
1180                         my $lis = $pil or exit($exit_code);
1181                         # closing eof_p triggers \&noop wakeup
1182                         $listener = $eof_p = $pil = $path = undef;
1183                         $lis->close; # DS::close
1184                         PublicInbox::DS->SetLoopTimeout(1000);
1185                 };
1186         };
1187         my $sig = {
1188                 CHLD => \&PublicInbox::DS::enqueue_reap,
1189                 QUIT => $quit,
1190                 INT => $quit,
1191                 TERM => $quit,
1192                 HUP => \&noop,
1193                 USR1 => \&noop,
1194                 USR2 => \&noop,
1195         };
1196         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1197         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1198         undef $sig;
1199         local $SIG{PIPE} = 'IGNORE';
1200         require PublicInbox::DirIdle;
1201         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1202                 # just rely on wakeup ot hit PostLoopCallback set below
1203                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1204         }, 1);
1205         if ($sigfd) {
1206                 undef $sigfd; # unref, already in DS::DescriptorMap
1207         } else {
1208                 # wake up every second to accept signals if we don't
1209                 # have signalfd or IO::KQueue:
1210                 PublicInbox::DS::sig_setmask($oldset);
1211                 PublicInbox::DS->SetLoopTimeout(1000);
1212         }
1213         PublicInbox::DS->SetPostLoopCallback(sub {
1214                 my ($dmap, undef) = @_;
1215                 if (@st = defined($path) ? stat($path) : ()) {
1216                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1217                                 warn "$path dev/ino changed, quitting\n";
1218                                 $path = undef;
1219                         }
1220                 } elsif (defined($path)) { # ENOENT is common
1221                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1222                         undef $path;
1223                         $quit->();
1224                 }
1225                 return 1 if defined($path);
1226                 my $now = now();
1227                 my $n = 0;
1228                 for my $s (values %$dmap) {
1229                         $s->can('busy') or next;
1230                         if ($s->busy($now)) {
1231                                 ++$n;
1232                         } else {
1233                                 $s->close;
1234                         }
1235                 }
1236                 $n; # true: continue, false: stop
1237         });
1238
1239         # STDIN was redirected to /dev/null above, closing STDERR and
1240         # STDOUT will cause the calling `lei' client process to finish
1241         # reading the <$daemon> pipe.
1242         local $SIG{__WARN__} = sub {
1243                 $current_lei ? err($current_lei, @_) : warn(
1244                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1245         };
1246         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1247         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1248         # $daemon pipe to `lei' closed, main loop begins:
1249         PublicInbox::DS->EventLoop;
1250         exit($exit_code // 0);
1251 }
1252
1253 sub busy { 1 } # prevent daemon-shutdown if client is connected
1254
1255 # for users w/o Socket::Msghdr installed or Inline::C enabled
1256 sub oneshot {
1257         my ($main_pkg) = @_;
1258         my $exit = $main_pkg->can('exit'); # caller may override exit()
1259         local $quit = $exit if $exit;
1260         local %PATH2CFG;
1261         umask(077) // die("umask(077): $!");
1262         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1263         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1264         dispatch($self, @ARGV);
1265         x_it($self, $self->{child_error}) if $self->{child_error};
1266 }
1267
1268 # ensures stdout hits the FS before sock disconnects so a client
1269 # can immediately reread it
1270 sub DESTROY {
1271         my ($self) = @_;
1272         $self->{1}->autoflush(1) if $self->{1};
1273         stop_pager($self);
1274         my $err = $?;
1275         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1276         waitpid($_, 0) for keys %$oneshot_pids;
1277         $? = $err if $err; # preserve ->fail or ->x_it code
1278 }
1279
1280 sub wq_done_wait { # dwaitpid callback
1281         my ($arg, $pid) = @_;
1282         my ($wq, $lei) = @$arg;
1283         my $err_type = $lei->{-err_type};
1284         $? and $lei->child_error($?,
1285                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1286         $lei->dclose;
1287 }
1288
1289 sub wq_eof { # EOF callback for main daemon
1290         my ($lei) = @_;
1291         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1292         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1293 }
1294
1295 1;