lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  15 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 my $recv_3fds;
  30 my $GLP = Getopt::Long::Parser->new;
  31 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  32 my $GLP_PASS = Getopt::Long::Parser->new;
  33 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  34
  35 our %PATH2CFG; # persistent for socket daemon
  36
  37 # TBD: this is a documentation mechanism to show a subcommand
  38 # (may) pass options through to another command:
  39 sub pass_through { $GLP_PASS }
  40
  41 my $OPT;
  42 sub opt_dash ($$) {
  43         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  44         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  45         my $cb = sub { # Getopt::Long "<>" catch-all handler
  46                 my ($arg) = @_;
  47                 if ($arg =~ /\A-($re_str)\z/) {
  48                         $OPT->{$key} = $1;
  49                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  50                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  51                 # lone (single) dash is handled elsewhere
  52                 } elsif (substr($arg, 0, 1) eq '-') {
  53                         if ($OPT->{'--'}) {
  54                                 push @{$OPT->{-argv}}, $arg;
  55                         } else {
  56                                 die "bad argument: $arg\n";
  57                         }
  58                 } else {
  59                         push @{$OPT->{-argv}}, $arg;
  60                 }
  61         };
  62         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  63 }
  64
  65 sub _store_path ($) {
  66         my ($env) = @_;
  67         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  68                 ($env->{HOME} // '/nonexistent').'/.local/share')
  69                 .'/lei/store', $env->{PWD});
  70 }
  71
  72 sub _config_path ($) {
  73         my ($env) = @_;
  74         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  75                 ($env->{HOME} // '/nonexistent').'/.config')
  76                 .'/lei/config', $env->{PWD});
  77 }
  78
  79 # TODO: generate shell completion + help using %CMD and %OPTDESC
  80 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  81 our %CMD = ( # sorted in order of importance/use:
  82 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  83         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  84         sort|s=s reverse|r offset=i remote local! external! pretty
  85         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  86
  87 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  88         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  89         pass_through('git show') ],
  90
  91 'add-external' => [ 'URL_OR_PATHNAME',
  92         'add/set priority of a publicinbox|extindex for extra matches',
  93         qw(boost=i quiet|q) ],
  94 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  95         qw(format|f=s z|0 local remote quiet|q) ],
  96 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  97         'exclude further results from a publicinbox|extindex',
  98         qw(prune quiet|q) ],
  99
 100 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 101                 qw(name-only format|f=s z) ],
 102 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 103 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 104
 105 'plonk' => [ '--thread|--from=IDENT',
 106         'exclude mail matching From: or thread from non-Message-ID searches',
 107         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 108 'mark' => [ 'MESSAGE_FLAGS...',
 109         'set/unset flags on message(s) from stdin',
 110         qw(stdin| oid=s exact by-mid|mid:s) ],
 111 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 112         "exclude message(s) on stdin from `q' search results",
 113         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 114
 115 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 116         'remove imported messages from IMAP, Maildirs, and MH',
 117         qw(exact! all jobs:i indexed) ],
 118
 119 # code repos are used for `show' to solve blobs from patch mails
 120 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 121         qw(boost=i) ],
 122 'ls-coderepo' => [ '[FILTER_TERMS...]',
 123                 'list known code repos', qw(format|f=s z) ],
 124 'forget-coderepo' => [ 'PATHNAME',
 125         'stop using repo to solve blobs from patches',
 126         qw(prune) ],
 127
 128 'add-watch' => [ '[URL_OR_PATHNAME]',
 129                 'watch for new messages and flag changes',
 130         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 131 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 132                 qw(format|f=s z) ],
 133 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 134 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 135 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 136         qw(prune) ],
 137
 138 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 139         'one-shot import/update from URL or filesystem',
 140         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 141         ],
 142
 143 'config' => [ '[...]', sub {
 144                 'git-config(1) wrapper for '._config_path($_[0]);
 145         }, qw(config-file|system|global|file|f=s), # for conflict detection
 146         pass_through('git config') ],
 147 'init' => [ '[PATHNAME]', sub {
 148                 'initialize storage, default: '._store_path($_[0]);
 149         }, qw(quiet|q) ],
 150 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 151         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 152 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 153 'help' => [ '[SUBCOMMAND]', 'show help' ],
 154
 155 # XXX do we need this?
 156 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 157
 158 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 159         'rewrite git history in an attempt to improve compression',
 160         'gc!' ],
 161
 162 # internal commands are prefixed with '_'
 163 '_complete' => [ '[...]', 'internal shell completion helper',
 164                 pass_through('everything') ],
 165 ); # @CMD
 166
 167 # switch descriptions, try to keep consistent across commands
 168 # $spec: Getopt::Long option specification
 169 # $spec => [@ALLOWED_VALUES (default is first), $description],
 170 # $spec => $description
 171 # "$SUB_COMMAND TAB $spec" => as above
 172 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 173                 'specify message input format' ];
 174 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 175
 176 my %OPTDESC = (
 177 'help|h' => 'show this built-in help',
 178 'quiet|q' => 'be quiet',
 179 'solve!' => 'do not attempt to reconstruct blobs from emails',
 180 'save-as=s' => ['NAME', 'save a search terms by given name'],
 181
 182 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 183
 184 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 185                 'deduplication strategy'],
 186 'show   thread|t' => 'display entire thread a message belongs to',
 187 'q      thread|t' =>
 188         'return all messages in the same thread as the actual match(es)',
 189 'augment|a' => 'augment --output destination instead of clobbering',
 190
 191 'output|o=s' => [ 'DEST',
 192         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 193
 194 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 195                         'message/object output format' ],
 196 'mark   format|f=s' => $stdin_formats,
 197 'forget format|f=s' => $stdin_formats,
 198 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 199                 'specify output format, default depends on --output'],
 200 'ls-query       format|f=s' => $ls_format,
 201 'ls-external    format|f=s' => $ls_format,
 202
 203 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 204 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 205
 206 'sort|s=s' => [ 'VAL|received,relevance,docid',
 207                 "order of results `--output'-dependent"],
 208 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 209
 210 'boost=i' => 'increase/decrease priority of results (default: 0)',
 211
 212 'local' => 'limit operations to the local filesystem',
 213 'local!' => 'exclude results from the local filesystem',
 214 'remote' => 'limit operations to those requiring network access',
 215 'remote!' => 'prevent operations requiring network access',
 216
 217 'mid=s' => 'specify the Message-ID of a message',
 218 'oid=s' => 'specify the git object ID of a message',
 219
 220 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 221 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 222 'include=s' => 'include mailboxes/newsgroups based on pattern',
 223
 224 'exact' => 'operate on exact header matches only',
 225 'exact!' => 'rely on content match instead of exact header matches',
 226
 227 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 228 'jobs:i' => 'set parallelism level',
 229
 230 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 231 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 232
 233 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 234 ); # %OPTDESC
 235
 236 my %CONFIG_KEYS = (
 237         'leistore.dir' => 'top-level storage location',
 238 );
 239
 240 sub x_it ($$) { # pronounced "exit"
 241         my ($self, $code) = @_;
 242         $self->{1}->autoflush(1); # make sure client sees stdout before exit
 243         if (my $sig = ($code & 127)) {
 244                 kill($sig, $self->{pid} // $$);
 245         } else {
 246                 $code >>= 8;
 247                 if (my $sock = $self->{sock}) {
 248                         say $sock "exit=$code";
 249                 } else { # for oneshot
 250                         $quit->($code);
 251                 }
 252         }
 253 }
 254
 255 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 256
 257 sub out ($;@) { print { shift->{1} } @_ }
 258
 259 sub err ($;@) {
 260         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 261 }
 262
 263 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 264
 265 sub fail ($$;$) {
 266         my ($self, $buf, $exit_code) = @_;
 267         err($self, $buf);
 268         x_it($self, ($exit_code // 1) << 8);
 269         undef;
 270 }
 271
 272 sub _help ($;$) {
 273         my ($self, $errmsg) = @_;
 274         my $cmd = $self->{cmd} // 'COMMAND';
 275         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 276         my @top = ($cmd, shift(@info) // ());
 277         my $cmd_desc = shift(@info);
 278         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 279         my @opt_desc;
 280         my $lpad = 2;
 281         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 282                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 283                 my $arg_vals = '';
 284                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 285
 286                 # lower-case is a keyword (e.g. `content', `oid'),
 287                 # ALL_CAPS is a string description (e.g. `PATH')
 288                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 289                         $desc .= "\ndefault: `$1'";
 290                 }
 291                 my (@vals, @s, @l);
 292                 my $x = $sw;
 293                 if ($x =~ s/!\z//) { # solve! => --no-solve
 294                         $x = "no-$x";
 295                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 296                         @vals = (' [', undef, ']');
 297                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 298                         @vals = (' ', undef);
 299                 } # else: no args $x = 'thread|t'
 300                 for (split(/\|/, $x)) { # help|h
 301                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 302                 }
 303                 if (!scalar(@vals)) { # no args 'thread|t'
 304                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 305                         $vals[1] = $1;
 306                 } else {
 307                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 308                 }
 309                 if ($arg_vals =~ /([,\|])/) {
 310                         my $sep = $1;
 311                         my @allow = split(/\Q$sep\E/, $arg_vals);
 312                         my $must = $sep eq '|' ? 'Must' : 'Can';
 313                         @allow = map { "`$_'" } @allow;
 314                         my $last = pop @allow;
 315                         $desc .= "\n$must be one of: " .
 316                                 join(', ', @allow) . " or $last";
 317                 }
 318                 my $lhs = join(', ', @s, @l) . join('', @vals);
 319                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 320                         $lhs =~ s/\A--/- , --/;
 321                 } else {
 322                         $lhs =~ s/\A--/    --/; # pad if no short options
 323                 }
 324                 $lpad = length($lhs) if length($lhs) > $lpad;
 325                 push @opt_desc, $lhs, $desc;
 326         }
 327         my $msg = $errmsg ? "E: $errmsg\n" : '';
 328         $msg .= <<EOF;
 329 usage: lei @top
 330   $cmd_desc
 331
 332 EOF
 333         $lpad += 2;
 334         local $Text::Wrap::columns = 78 - $lpad;
 335         my $padding = ' ' x ($lpad + 2);
 336         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 337                 $msg .= '  '.pack("A$lpad", $lhs);
 338                 $rhs = wrap('', '', $rhs);
 339                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 340                 $msg .= $rhs;
 341                 $msg .= "\n";
 342         }
 343         print { $self->{$errmsg ? 2 : 1} } $msg;
 344         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 345         undef;
 346 }
 347
 348 sub optparse ($$$) {
 349         my ($self, $cmd, $argv) = @_;
 350         $self->{cmd} = $cmd;
 351         $OPT = $self->{opt} = {};
 352         my $info = $CMD{$cmd} // [ '[...]' ];
 353         my ($proto, undef, @spec) = @$info;
 354         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 355         push @spec, qw(help|h);
 356         my $lone_dash;
 357         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 358                 $lone_dash = $spec[0];
 359                 $OPT->{$spec[0]} = \(my $var);
 360                 push @spec, '' => \$var;
 361         }
 362         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 363                 return _help($self, "bad arguments or options for $cmd");
 364         return _help($self) if $OPT->{help};
 365
 366         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 367
 368         # "-" aliases "stdin" or "clear"
 369         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 370
 371         my $i = 0;
 372         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 373         my ($err, $inf);
 374         my @args = split(/ /, $proto);
 375         for my $var (@args) {
 376                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 377                         $inf = defined($argv->[$i]) and last;
 378                         $var =~ s/\.\.\.\z//;
 379                         $err = "$var not supplied";
 380                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 381                         $argv->[$i++] // ($err = "$var not supplied");
 382                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 383                         $inf = 1;
 384                         last;
 385                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 386                         $i++;
 387                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 388                         my @or = split(/\|/, $var);
 389                         my $ok;
 390                         for my $o (@or) {
 391                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 392                                         $ok = defined($OPT->{$1});
 393                                         last;
 394                                 } elsif (defined($argv->[$i])) {
 395                                         $ok = 1;
 396                                         $i++;
 397                                         last;
 398                                 } # else continue looping
 399                         }
 400                         my $last = pop @or;
 401                         $err = join(', ', @or) . " or $last must be set";
 402                 } else {
 403                         warn "BUG: can't parse `$var' in $proto";
 404                 }
 405                 last if $err;
 406         }
 407         if (!$inf && scalar(@$argv) > scalar(@args)) {
 408                 $err //= 'too many arguments';
 409         }
 410         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 411 }
 412
 413 sub dispatch {
 414         my ($self, $cmd, @argv) = @_;
 415         local $SIG{__WARN__} = sub { err($self, @_) };
 416         return _help($self, 'no command given') unless defined($cmd);
 417         my $func = "lei_$cmd";
 418         $func =~ tr/-/_/;
 419         if (my $cb = __PACKAGE__->can($func)) {
 420                 optparse($self, $cmd, \@argv) or return;
 421                 $cb->($self, @argv);
 422         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 423                 my $opt = {};
 424                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 425                         return _help($self, 'bad arguments or options');
 426                 _help($self);
 427         } else {
 428                 fail($self, "`$cmd' is not an lei command");
 429         }
 430 }
 431
 432 sub _lei_cfg ($;$) {
 433         my ($self, $creat) = @_;
 434         my $f = _config_path($self->{env});
 435         my @st = stat($f);
 436         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 437         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 438                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 439         }
 440         if (!@st) {
 441                 unless ($creat) {
 442                         delete $self->{cfg};
 443                         return;
 444                 }
 445                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 446                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 447                 open my $fh, '>>', $f or die "open($f): $!\n";
 448                 @st = stat($fh) or die "fstat($f): $!\n";
 449                 $cur_st = pack('dd', $st[10], $st[7]);
 450                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 451         }
 452         my $cfg = PublicInbox::Config::git_config_dump($f);
 453         $cfg->{-st} = $cur_st;
 454         $cfg->{'-f'} = $f;
 455         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 456 }
 457
 458 sub _lei_store ($;$) {
 459         my ($self, $creat) = @_;
 460         my $cfg = _lei_cfg($self, $creat);
 461         $cfg->{-lei_store} //= do {
 462                 require PublicInbox::LeiStore;
 463                 my $dir = $cfg->{'leistore.dir'};
 464                 $dir //= _store_path($self->{env}) if $creat;
 465                 return unless $dir;
 466                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 467         };
 468 }
 469
 470 sub lei_show {
 471         my ($self, @argv) = @_;
 472 }
 473
 474 sub lei_mark {
 475         my ($self, @argv) = @_;
 476 }
 477
 478 sub lei_config {
 479         my ($self, @argv) = @_;
 480         $self->{opt}->{'config-file'} and return fail $self,
 481                 "config file switches not supported by `lei config'";
 482         my $env = $self->{env};
 483         delete local $env->{GIT_CONFIG};
 484         my $cfg = _lei_cfg($self, 1);
 485         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 486         my %rdr = map { $_ => $self->{$_} } (0..2);
 487         run_die($cmd, $env, \%rdr);
 488 }
 489
 490 sub lei_init {
 491         my ($self, $dir) = @_;
 492         my $cfg = _lei_cfg($self, 1);
 493         my $cur = $cfg->{'leistore.dir'};
 494         my $env = $self->{env};
 495         $dir //= _store_path($env);
 496         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 497         my @cur = stat($cur) if defined($cur);
 498         $cur = File::Spec->canonpath($cur // $dir);
 499         my @dir = stat($dir);
 500         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 501         if (@cur) {
 502                 if ($cur eq $dir) {
 503                         _lei_store($self, 1)->done;
 504                         return qerr($self, $exists);
 505                 }
 506
 507                 # some folks like symlinks and bind mounts :P
 508                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 509                         lei_config($self, 'leistore.dir', $dir);
 510                         _lei_store($self, 1)->done;
 511                         return qerr($self, "$exists (as $cur)");
 512                 }
 513                 return fail($self, <<"");
 514 E: leistore.dir=$cur already initialized and it is not $dir
 515
 516         }
 517         lei_config($self, 'leistore.dir', $dir);
 518         _lei_store($self, 1)->done;
 519         $exists //= "I: leistore.dir=$dir newly initialized";
 520         return qerr($self, $exists);
 521 }
 522
 523 sub lei_daemon_pid { puts shift, $$ }
 524
 525 sub lei_daemon_kill {
 526         my ($self) = @_;
 527         my $sig = $self->{opt}->{signal} // 'TERM';
 528         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 529 }
 530
 531 sub lei_help { _help($_[0]) }
 532
 533 # Shell completion helper.  Used by lei-completion.bash and hopefully
 534 # other shells.  Try to do as much here as possible to avoid redundancy
 535 # and improve maintainability.
 536 sub lei__complete {
 537         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 538         shift @argv; # ignore "lei", the entire command is sent
 539         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 540         my $cmd = shift @argv;
 541         my $info = $CMD{$cmd} // do { # filter matching commands
 542                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 543                 return;
 544         };
 545         my ($proto, undef, @spec) = @$info;
 546         my $cur = pop @argv;
 547         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 548         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 549                 # gross special case since the only git-config options
 550                 # Consider moving to a table if we need more special cases
 551                 # we use Getopt::Long for are the ones we reject, so these
 552                 # are the ones we don't reject:
 553                 if ($cmd eq 'config') {
 554                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 555                         @spec = qw(add z|null get get-all unset unset-all
 556                                 replace-all get-urlmatch
 557                                 remove-section rename-section
 558                                 name-only list|l edit|e
 559                                 get-color-name get-colorbool);
 560                         # fall-through
 561                 }
 562                 # TODO: arg support
 563                 puts $self, grep(/$re/, map { # generate short/long names
 564                         my $eq = '';
 565                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 566                                 $eq = '=';
 567                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 568                         } else { # negation: solve! => no-solve|solve
 569                                 s/\A(.+)!\z/no-$1|$1/;
 570                         }
 571                         map {
 572                                 length > 1 ? "--$_$eq" : "-$_"
 573                         } split(/\|/, $_, -1) # help|h
 574                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 575         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 576                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 577         }
 578         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 579         # proto parsing.
 580 }
 581
 582 sub reap_exec { # dwaitpid callback
 583         my ($self, $pid) = @_;
 584         x_it($self, $?);
 585 }
 586
 587 sub lei_git { # support passing through random git commands
 588         my ($self, @argv) = @_;
 589         my %rdr = map { $_ => $self->{$_} } (0..2);
 590         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 591         dwaitpid($pid, \&reap_exec, $self);
 592 }
 593
 594 # caller needs to "-t $self->{1}" to check if tty
 595 sub start_pager {
 596         my ($self) = @_;
 597         my $env = $self->{env};
 598         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 599         chomp(my $pager = <$fh> // '');
 600         close($fh) or warn "`git var PAGER' error: \$?=$?";
 601         return if $pager eq 'cat' || $pager eq '';
 602         $env->{LESS} //= 'FRX';
 603         $env->{LV} //= '-c';
 604         $env->{COLUMNS} //= 80; # TODO TIOCGWINSZ
 605         $env->{MORE} //= 'FRX' if $^O eq 'freebsd';
 606         pipe(my ($r, $w)) or return warn "pipe: $!";
 607         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 608         $self->{1} = $w;
 609         $self->{2} = $w if -t $self->{2};
 610         $self->{'pager.pid'} = spawn([$pager], $env, $rdr);
 611         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 612 }
 613
 614 sub accept_dispatch { # Listener {post_accept} callback
 615         my ($sock) = @_; # ignore other
 616         $sock->blocking(1);
 617         $sock->autoflush(1);
 618         my $self = bless { sock => $sock }, __PACKAGE__;
 619         vec(my $rin = '', fileno($sock), 1) = 1;
 620         # `say $sock' triggers "die" in lei(1)
 621         if (select(my $rout = $rin, undef, undef, 1)) {
 622                 my @fds = $recv_3fds->(fileno($sock));
 623                 if (scalar(@fds) == 3) {
 624                         my $i = 0;
 625                         for my $rdr (qw(<&= >&= >&=)) {
 626                                 my $fd = shift(@fds);
 627                                 if (open(my $fh, $rdr, $fd)) {
 628                                         $self->{$i++} = $fh;
 629                                 }  else {
 630                                         say $sock "open($rdr$fd) (FD=$i): $!";
 631                                         return;
 632                                 }
 633                         }
 634                 } else {
 635                         say $sock "recv_3fds failed: $!";
 636                         return;
 637                 }
 638         } else {
 639                 say $sock "timed out waiting to recv FDs";
 640                 return;
 641         }
 642         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 643         # $ARGV_STR = join("]\0[", @ARGV);
 644         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 645         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 646         my ($client_pid, $argv, $env) = do {
 647                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 648                 chomp(my $line = <$sock>);
 649                 split(/\0\0>/, $line, 3);
 650         };
 651         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 652         if (chdir($env{PWD})) {
 653                 local %ENV = %env;
 654                 $self->{env} = \%env;
 655                 $self->{pid} = $client_pid;
 656                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 657                 say $sock $@ if $@;
 658         } else {
 659                 say $sock "chdir($env{PWD}): $!"; # implicit close
 660         }
 661 }
 662
 663 # for long-running results
 664 sub event_step {
 665         my ($self) = @_;
 666         local %ENV = %{$self->{env}};
 667         eval {}; # TODO
 668         if ($@) {
 669                 say { $self->{sock} } $@;
 670                 $self->close; # PublicInbox::DS::close
 671         }
 672 }
 673
 674 sub noop {}
 675
 676 # lei(1) calls this when it can't connect
 677 sub lazy_start {
 678         my ($path, $errno, $nfd) = @_;
 679         if ($errno == ECONNREFUSED) {
 680                 unlink($path) or die "unlink($path): $!";
 681         } elsif ($errno != ENOENT) {
 682                 $! = $errno; # allow interpolation to stringify in die
 683                 die "connect($path): $!";
 684         }
 685         umask(077) // die("umask(077): $!");
 686         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 687         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 688         listen($l, 1024) or die "listen: $!";
 689         my @st = stat($path) or die "stat($path): $!";
 690         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 691         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 692         my $oldset = PublicInbox::Sigfd::block_signals();
 693         if ($nfd == 1) {
 694                 require IO::FDPass;
 695                 $recv_3fds = sub { map { IO::FDPass::recv($_[0]) } (0..2) };
 696         } elsif ($nfd == 3) {
 697                 $recv_3fds = PublicInbox::Spawn->can('recv_3fds');
 698         }
 699         $recv_3fds or die
 700                 "IO::FDPass missing or Inline::C not installed/configured\n";
 701         require PublicInbox::Listener;
 702         require PublicInbox::EOFpipe;
 703         (-p STDOUT) or die "E: stdout must be a pipe\n";
 704         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 705         POSIX::setsid() > 0 or die "setsid: $!";
 706         my $pid = fork // die "fork: $!";
 707         return if $pid;
 708         $0 = "lei-daemon $path";
 709         local %PATH2CFG;
 710         $_->blocking(0) for ($l, $eof_r, $eof_w);
 711         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 712         my $exit_code;
 713         local $quit = sub {
 714                 $exit_code //= shift;
 715                 my $listener = $l or exit($exit_code);
 716                 unlink($path) if defined($path);
 717                 # closing eof_w triggers \&noop wakeup
 718                 $eof_w = $l = $path = undef;
 719                 $listener->close; # DS::close
 720                 PublicInbox::DS->SetLoopTimeout(1000);
 721         };
 722         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 723         my $sig = {
 724                 CHLD => \&PublicInbox::DS::enqueue_reap,
 725                 QUIT => $quit,
 726                 INT => $quit,
 727                 TERM => $quit,
 728                 HUP => \&noop,
 729                 USR1 => \&noop,
 730                 USR2 => \&noop,
 731         };
 732         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 733         local %SIG = (%SIG, %$sig) if !$sigfd;
 734         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 735                 PublicInbox::DS->SetLoopTimeout(5000);
 736         } else {
 737                 # wake up every second to accept signals if we don't
 738                 # have signalfd or IO::KQueue:
 739                 PublicInbox::Sigfd::sig_setmask($oldset);
 740                 PublicInbox::DS->SetLoopTimeout(1000);
 741         }
 742         PublicInbox::DS->SetPostLoopCallback(sub {
 743                 my ($dmap, undef) = @_;
 744                 if (@st = defined($path) ? stat($path) : ()) {
 745                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 746                                 warn "$path dev/ino changed, quitting\n";
 747                                 $path = undef;
 748                         }
 749                 } elsif (defined($path)) {
 750                         warn "stat($path): $!, quitting ...\n";
 751                         undef $path; # don't unlink
 752                         $quit->();
 753                 }
 754                 return 1 if defined($path);
 755                 my $now = now();
 756                 my $n = 0;
 757                 for my $s (values %$dmap) {
 758                         $s->can('busy') or next;
 759                         if ($s->busy($now)) {
 760                                 ++$n;
 761                         } else {
 762                                 $s->close;
 763                         }
 764                 }
 765                 $n; # true: continue, false: stop
 766         });
 767
 768         # STDIN was redirected to /dev/null above, closing STDERR and
 769         # STDOUT will cause the calling `lei' client process to finish
 770         # reading the <$daemon> pipe.
 771         openlog($path, 'pid', 'user');
 772         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 773         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 774                 syslog('crit', "$@") if $@;
 775         });
 776         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 777         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 778         # $daemon pipe to `lei' closed, main loop begins:
 779         PublicInbox::DS->EventLoop;
 780         @$on_destroy = (); # cancel on_destroy if we get here
 781         exit($exit_code // 0);
 782 }
 783
 784 # for users w/o IO::FDPass
 785 sub oneshot {
 786         my ($main_pkg) = @_;
 787         my $exit = $main_pkg->can('exit'); # caller may override exit()
 788         local $quit = $exit if $exit;
 789         local %PATH2CFG;
 790         umask(077) // die("umask(077): $!");
 791         dispatch((bless {
 792                 0 => *STDIN{IO},
 793                 1 => *STDOUT{IO},
 794                 2 => *STDERR{IO},
 795                 env => \%ENV
 796         }, __PACKAGE__), @ARGV);
 797 }
 798
 799 # ensures stdout hits the FS before sock disconnects so a client
 800 # can immediately reread it
 801 sub DESTROY {
 802         my ($self) = @_;
 803         $self->{1}->autoflush(1);
 804         if (my $pid = delete $self->{'pager.pid'}) {
 805                 dwaitpid($pid, undef, $self->{sock});
 806         }
 807 }
 808
 809 1;