lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 my ($recv_cmd, $send_cmd);
  30 my $GLP = Getopt::Long::Parser->new;
  31 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  32 my $GLP_PASS = Getopt::Long::Parser->new;
  33 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  34
  35 our %PATH2CFG; # persistent for socket daemon
  36 our @TO_CLOSE_ATFORK_CHILD;
  37
  38 # TBD: this is a documentation mechanism to show a subcommand
  39 # (may) pass options through to another command:
  40 sub pass_through { $GLP_PASS }
  41
  42 my $OPT;
  43 sub opt_dash ($$) {
  44         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  45         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  46         my $cb = sub { # Getopt::Long "<>" catch-all handler
  47                 my ($arg) = @_;
  48                 if ($arg =~ /\A-($re_str)\z/) {
  49                         $OPT->{$key} = $1;
  50                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  51                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  52                 # lone (single) dash is handled elsewhere
  53                 } elsif (substr($arg, 0, 1) eq '-') {
  54                         if ($OPT->{'--'}) {
  55                                 push @{$OPT->{-argv}}, $arg;
  56                         } else {
  57                                 die "bad argument: $arg\n";
  58                         }
  59                 } else {
  60                         push @{$OPT->{-argv}}, $arg;
  61                 }
  62         };
  63         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  64 }
  65
  66 sub _store_path ($) {
  67         my ($env) = @_;
  68         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  69                 ($env->{HOME} // '/nonexistent').'/.local/share')
  70                 .'/lei/store', $env->{PWD});
  71 }
  72
  73 sub _config_path ($) {
  74         my ($env) = @_;
  75         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  76                 ($env->{HOME} // '/nonexistent').'/.config')
  77                 .'/lei/config', $env->{PWD});
  78 }
  79
  80 # TODO: generate shell completion + help using %CMD and %OPTDESC
  81 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  82 our %CMD = ( # sorted in order of importance/use:
  83 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  84         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  85         sort|s=s reverse|r offset=i remote local! external! pretty
  86         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  87
  88 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  89         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  90         pass_through('git show') ],
  91
  92 'add-external' => [ 'URL_OR_PATHNAME',
  93         'add/set priority of a publicinbox|extindex for extra matches',
  94         qw(boost=i quiet|q) ],
  95 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  96         qw(format|f=s z|0 local remote quiet|q) ],
  97 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  98         'exclude further results from a publicinbox|extindex',
  99         qw(prune quiet|q) ],
 100
 101 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 102                 qw(name-only format|f=s z) ],
 103 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 104 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 105
 106 'plonk' => [ '--thread|--from=IDENT',
 107         'exclude mail matching From: or thread from non-Message-ID searches',
 108         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 109 'mark' => [ 'MESSAGE_FLAGS...',
 110         'set/unset flags on message(s) from stdin',
 111         qw(stdin| oid=s exact by-mid|mid:s) ],
 112 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 113         "exclude message(s) on stdin from `q' search results",
 114         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 115
 116 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 117         'remove imported messages from IMAP, Maildirs, and MH',
 118         qw(exact! all jobs:i indexed) ],
 119
 120 # code repos are used for `show' to solve blobs from patch mails
 121 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 122         qw(boost=i) ],
 123 'ls-coderepo' => [ '[FILTER_TERMS...]',
 124                 'list known code repos', qw(format|f=s z) ],
 125 'forget-coderepo' => [ 'PATHNAME',
 126         'stop using repo to solve blobs from patches',
 127         qw(prune) ],
 128
 129 'add-watch' => [ '[URL_OR_PATHNAME]',
 130                 'watch for new messages and flag changes',
 131         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 132 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 133                 qw(format|f=s z) ],
 134 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 135 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 137         qw(prune) ],
 138
 139 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 140         'one-shot import/update from URL or filesystem',
 141         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 142         ],
 143
 144 'config' => [ '[...]', sub {
 145                 'git-config(1) wrapper for '._config_path($_[0]);
 146         }, qw(config-file|system|global|file|f=s), # for conflict detection
 147         pass_through('git config') ],
 148 'init' => [ '[PATHNAME]', sub {
 149                 'initialize storage, default: '._store_path($_[0]);
 150         }, qw(quiet|q) ],
 151 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 152         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 153 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 154 'help' => [ '[SUBCOMMAND]', 'show help' ],
 155
 156 # XXX do we need this?
 157 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 158
 159 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 160         'rewrite git history in an attempt to improve compression',
 161         'gc!' ],
 162
 163 # internal commands are prefixed with '_'
 164 '_complete' => [ '[...]', 'internal shell completion helper',
 165                 pass_through('everything') ],
 166 ); # @CMD
 167
 168 # switch descriptions, try to keep consistent across commands
 169 # $spec: Getopt::Long option specification
 170 # $spec => [@ALLOWED_VALUES (default is first), $description],
 171 # $spec => $description
 172 # "$SUB_COMMAND TAB $spec" => as above
 173 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 174                 'specify message input format' ];
 175 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 176
 177 my %OPTDESC = (
 178 'help|h' => 'show this built-in help',
 179 'quiet|q' => 'be quiet',
 180 'solve!' => 'do not attempt to reconstruct blobs from emails',
 181 'save-as=s' => ['NAME', 'save a search terms by given name'],
 182
 183 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 184
 185 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 186                 'deduplication strategy'],
 187 'show   thread|t' => 'display entire thread a message belongs to',
 188 'q      thread|t' =>
 189         'return all messages in the same thread as the actual match(es)',
 190 'augment|a' => 'augment --output destination instead of clobbering',
 191
 192 'output|o=s' => [ 'DEST',
 193         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 194
 195 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 196                         'message/object output format' ],
 197 'mark   format|f=s' => $stdin_formats,
 198 'forget format|f=s' => $stdin_formats,
 199 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 200                 'specify output format, default depends on --output'],
 201 'ls-query       format|f=s' => $ls_format,
 202 'ls-external    format|f=s' => $ls_format,
 203
 204 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 205 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 206
 207 'sort|s=s' => [ 'VAL|received,relevance,docid',
 208                 "order of results `--output'-dependent"],
 209 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 210
 211 'boost=i' => 'increase/decrease priority of results (default: 0)',
 212
 213 'local' => 'limit operations to the local filesystem',
 214 'local!' => 'exclude results from the local filesystem',
 215 'remote' => 'limit operations to those requiring network access',
 216 'remote!' => 'prevent operations requiring network access',
 217
 218 'mid=s' => 'specify the Message-ID of a message',
 219 'oid=s' => 'specify the git object ID of a message',
 220
 221 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 222 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 223 'include=s' => 'include mailboxes/newsgroups based on pattern',
 224
 225 'exact' => 'operate on exact header matches only',
 226 'exact!' => 'rely on content match instead of exact header matches',
 227
 228 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 229 'jobs:i' => 'set parallelism level',
 230
 231 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 232 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 233
 234 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 235 ); # %OPTDESC
 236
 237 my %CONFIG_KEYS = (
 238         'leistore.dir' => 'top-level storage location',
 239 );
 240
 241 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 242 sub x_it ($$) {
 243         my ($self, $code) = @_;
 244         # make sure client sees stdout before exit
 245         $self->{1}->autoflush(1) if $self->{1};
 246         if (my $sock = $self->{sock}) {
 247                 send($sock, "x_it $code", MSG_EOR);
 248         } elsif (!($code & 127)) { # oneshot, ignore signals
 249                 $quit->($code >> 8);
 250         }
 251 }
 252
 253 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 254
 255 sub out ($;@) { print { shift->{1} } @_ }
 256
 257 sub err ($;@) {
 258         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 259 }
 260
 261 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 262
 263 sub fail ($$;$) {
 264         my ($self, $buf, $exit_code) = @_;
 265         err($self, $buf);
 266         x_it($self, ($exit_code // 1) << 8);
 267         undef;
 268 }
 269
 270 sub atfork_prepare_wq {
 271         my ($self, $wq) = @_;
 272         push @{$wq->{-ipc_atfork_child_close}}, @TO_CLOSE_ATFORK_CHILD,
 273                                 grep { defined } @$self{qw(0 1 2 sock)}
 274 }
 275
 276 # usage: my %sig = $lei->atfork_child_wq($wq);
 277 #        local @SIG{keys %sig} = values %sig;
 278 sub atfork_child_wq {
 279         my ($self, $wq) = @_;
 280         @$self{qw(0 1 2 sock)} = delete(@$wq{0..3});
 281         %PATH2CFG = ();
 282         $quit = \&CORE::exit;
 283         @TO_CLOSE_ATFORK_CHILD = ();
 284         (__WARN__ => sub { err($self, @_) },
 285         PIPE => sub {
 286                 $self->x_it(13); # SIGPIPE = 13
 287                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 288                 close($_) for (delete @$self{1..2});
 289                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 290         });
 291 }
 292
 293 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 294 sub atfork_parent_wq {
 295         my ($self, $wq) = @_;
 296         if ($wq->wq_workers) {
 297                 my $env = delete $self->{env}; # env is inherited at fork
 298                 my $ret = bless { %$self }, ref($self);
 299                 $self->{env} = $env;
 300                 delete @$ret{qw(-lei_store cfg pgr)};
 301                 ($ret, delete @$ret{0..2}, delete($ret->{sock}) // ());
 302         } else {
 303                 ($self, @$self{0..2}, $self->{sock} // ());
 304         }
 305 }
 306
 307 sub _help ($;$) {
 308         my ($self, $errmsg) = @_;
 309         my $cmd = $self->{cmd} // 'COMMAND';
 310         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 311         my @top = ($cmd, shift(@info) // ());
 312         my $cmd_desc = shift(@info);
 313         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 314         my @opt_desc;
 315         my $lpad = 2;
 316         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 317                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 318                 my $arg_vals = '';
 319                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 320
 321                 # lower-case is a keyword (e.g. `content', `oid'),
 322                 # ALL_CAPS is a string description (e.g. `PATH')
 323                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 324                         $desc .= "\ndefault: `$1'";
 325                 }
 326                 my (@vals, @s, @l);
 327                 my $x = $sw;
 328                 if ($x =~ s/!\z//) { # solve! => --no-solve
 329                         $x = "no-$x";
 330                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 331                         @vals = (' [', undef, ']');
 332                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 333                         @vals = (' ', undef);
 334                 } # else: no args $x = 'thread|t'
 335                 for (split(/\|/, $x)) { # help|h
 336                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 337                 }
 338                 if (!scalar(@vals)) { # no args 'thread|t'
 339                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 340                         $vals[1] = $1;
 341                 } else {
 342                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 343                 }
 344                 if ($arg_vals =~ /([,\|])/) {
 345                         my $sep = $1;
 346                         my @allow = split(/\Q$sep\E/, $arg_vals);
 347                         my $must = $sep eq '|' ? 'Must' : 'Can';
 348                         @allow = map { "`$_'" } @allow;
 349                         my $last = pop @allow;
 350                         $desc .= "\n$must be one of: " .
 351                                 join(', ', @allow) . " or $last";
 352                 }
 353                 my $lhs = join(', ', @s, @l) . join('', @vals);
 354                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 355                         $lhs =~ s/\A--/- , --/;
 356                 } else {
 357                         $lhs =~ s/\A--/    --/; # pad if no short options
 358                 }
 359                 $lpad = length($lhs) if length($lhs) > $lpad;
 360                 push @opt_desc, $lhs, $desc;
 361         }
 362         my $msg = $errmsg ? "E: $errmsg\n" : '';
 363         $msg .= <<EOF;
 364 usage: lei @top
 365   $cmd_desc
 366
 367 EOF
 368         $lpad += 2;
 369         local $Text::Wrap::columns = 78 - $lpad;
 370         my $padding = ' ' x ($lpad + 2);
 371         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 372                 $msg .= '  '.pack("A$lpad", $lhs);
 373                 $rhs = wrap('', '', $rhs);
 374                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 375                 $msg .= $rhs;
 376                 $msg .= "\n";
 377         }
 378         print { $self->{$errmsg ? 2 : 1} } $msg;
 379         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 380         undef;
 381 }
 382
 383 sub optparse ($$$) {
 384         my ($self, $cmd, $argv) = @_;
 385         $self->{cmd} = $cmd;
 386         $OPT = $self->{opt} = {};
 387         my $info = $CMD{$cmd} // [ '[...]' ];
 388         my ($proto, undef, @spec) = @$info;
 389         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 390         push @spec, qw(help|h);
 391         my $lone_dash;
 392         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 393                 $lone_dash = $spec[0];
 394                 $OPT->{$spec[0]} = \(my $var);
 395                 push @spec, '' => \$var;
 396         }
 397         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 398                 return _help($self, "bad arguments or options for $cmd");
 399         return _help($self) if $OPT->{help};
 400
 401         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 402
 403         # "-" aliases "stdin" or "clear"
 404         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 405
 406         my $i = 0;
 407         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 408         my ($err, $inf);
 409         my @args = split(/ /, $proto);
 410         for my $var (@args) {
 411                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 412                         $inf = defined($argv->[$i]) and last;
 413                         $var =~ s/\.\.\.\z//;
 414                         $err = "$var not supplied";
 415                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 416                         $argv->[$i++] // ($err = "$var not supplied");
 417                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 418                         $inf = 1;
 419                         last;
 420                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 421                         $i++;
 422                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 423                         my @or = split(/\|/, $var);
 424                         my $ok;
 425                         for my $o (@or) {
 426                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 427                                         $ok = defined($OPT->{$1});
 428                                         last;
 429                                 } elsif (defined($argv->[$i])) {
 430                                         $ok = 1;
 431                                         $i++;
 432                                         last;
 433                                 } # else continue looping
 434                         }
 435                         my $last = pop @or;
 436                         $err = join(', ', @or) . " or $last must be set";
 437                 } else {
 438                         warn "BUG: can't parse `$var' in $proto";
 439                 }
 440                 last if $err;
 441         }
 442         if (!$inf && scalar(@$argv) > scalar(@args)) {
 443                 $err //= 'too many arguments';
 444         }
 445         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 446 }
 447
 448 sub dispatch {
 449         my ($self, $cmd, @argv) = @_;
 450         local $SIG{__WARN__} = sub { err($self, @_) };
 451         return _help($self, 'no command given') unless defined($cmd);
 452         my $func = "lei_$cmd";
 453         $func =~ tr/-/_/;
 454         if (my $cb = __PACKAGE__->can($func)) {
 455                 optparse($self, $cmd, \@argv) or return;
 456                 $cb->($self, @argv);
 457         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 458                 my $opt = {};
 459                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 460                         return _help($self, 'bad arguments or options');
 461                 _help($self);
 462         } else {
 463                 fail($self, "`$cmd' is not an lei command");
 464         }
 465 }
 466
 467 sub _lei_cfg ($;$) {
 468         my ($self, $creat) = @_;
 469         my $f = _config_path($self->{env});
 470         my @st = stat($f);
 471         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 472         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 473                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 474         }
 475         if (!@st) {
 476                 unless ($creat) {
 477                         delete $self->{cfg};
 478                         return;
 479                 }
 480                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 481                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 482                 open my $fh, '>>', $f or die "open($f): $!\n";
 483                 @st = stat($fh) or die "fstat($f): $!\n";
 484                 $cur_st = pack('dd', $st[10], $st[7]);
 485                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 486         }
 487         my $cfg = PublicInbox::Config::git_config_dump($f);
 488         $cfg->{-st} = $cur_st;
 489         $cfg->{'-f'} = $f;
 490         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 491 }
 492
 493 sub _lei_store ($;$) {
 494         my ($self, $creat) = @_;
 495         my $cfg = _lei_cfg($self, $creat);
 496         $cfg->{-lei_store} //= do {
 497                 require PublicInbox::LeiStore;
 498                 my $dir = $cfg->{'leistore.dir'};
 499                 $dir //= _store_path($self->{env}) if $creat;
 500                 return unless $dir;
 501                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 502         };
 503 }
 504
 505 sub lei_show {
 506         my ($self, @argv) = @_;
 507 }
 508
 509 sub lei_mark {
 510         my ($self, @argv) = @_;
 511 }
 512
 513 sub lei_config {
 514         my ($self, @argv) = @_;
 515         $self->{opt}->{'config-file'} and return fail $self,
 516                 "config file switches not supported by `lei config'";
 517         my $env = $self->{env};
 518         delete local $env->{GIT_CONFIG};
 519         my $cfg = _lei_cfg($self, 1);
 520         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 521         my %rdr = map { $_ => $self->{$_} } (0..2);
 522         run_die($cmd, $env, \%rdr);
 523 }
 524
 525 sub lei_init {
 526         my ($self, $dir) = @_;
 527         my $cfg = _lei_cfg($self, 1);
 528         my $cur = $cfg->{'leistore.dir'};
 529         my $env = $self->{env};
 530         $dir //= _store_path($env);
 531         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 532         my @cur = stat($cur) if defined($cur);
 533         $cur = File::Spec->canonpath($cur // $dir);
 534         my @dir = stat($dir);
 535         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 536         if (@cur) {
 537                 if ($cur eq $dir) {
 538                         _lei_store($self, 1)->done;
 539                         return qerr($self, $exists);
 540                 }
 541
 542                 # some folks like symlinks and bind mounts :P
 543                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 544                         lei_config($self, 'leistore.dir', $dir);
 545                         _lei_store($self, 1)->done;
 546                         return qerr($self, "$exists (as $cur)");
 547                 }
 548                 return fail($self, <<"");
 549 E: leistore.dir=$cur already initialized and it is not $dir
 550
 551         }
 552         lei_config($self, 'leistore.dir', $dir);
 553         _lei_store($self, 1)->done;
 554         $exists //= "I: leistore.dir=$dir newly initialized";
 555         return qerr($self, $exists);
 556 }
 557
 558 sub lei_daemon_pid { puts shift, $$ }
 559
 560 sub lei_daemon_kill {
 561         my ($self) = @_;
 562         my $sig = $self->{opt}->{signal} // 'TERM';
 563         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 564 }
 565
 566 sub lei_help { _help($_[0]) }
 567
 568 # Shell completion helper.  Used by lei-completion.bash and hopefully
 569 # other shells.  Try to do as much here as possible to avoid redundancy
 570 # and improve maintainability.
 571 sub lei__complete {
 572         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 573         shift @argv; # ignore "lei", the entire command is sent
 574         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 575         my $cmd = shift @argv;
 576         my $info = $CMD{$cmd} // do { # filter matching commands
 577                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 578                 return;
 579         };
 580         my ($proto, undef, @spec) = @$info;
 581         my $cur = pop @argv;
 582         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 583         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 584                 # gross special case since the only git-config options
 585                 # Consider moving to a table if we need more special cases
 586                 # we use Getopt::Long for are the ones we reject, so these
 587                 # are the ones we don't reject:
 588                 if ($cmd eq 'config') {
 589                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 590                         @spec = qw(add z|null get get-all unset unset-all
 591                                 replace-all get-urlmatch
 592                                 remove-section rename-section
 593                                 name-only list|l edit|e
 594                                 get-color-name get-colorbool);
 595                         # fall-through
 596                 }
 597                 # TODO: arg support
 598                 puts $self, grep(/$re/, map { # generate short/long names
 599                         my $eq = '';
 600                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 601                                 $eq = '=';
 602                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 603                         } else { # negation: solve! => no-solve|solve
 604                                 s/\A(.+)!\z/no-$1|$1/;
 605                         }
 606                         map {
 607                                 length > 1 ? "--$_$eq" : "-$_"
 608                         } split(/\|/, $_, -1) # help|h
 609                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 610         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 611                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 612         }
 613         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 614         # proto parsing.
 615 }
 616
 617 sub reap_exec { # dwaitpid callback
 618         my ($self, $pid) = @_;
 619         x_it($self, $?);
 620 }
 621
 622 sub lei_git { # support passing through random git commands
 623         my ($self, @argv) = @_;
 624         my %rdr = map { $_ => $self->{$_} } (0..2);
 625         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 626         dwaitpid($pid, \&reap_exec, $self);
 627 }
 628
 629 # caller needs to "-t $self->{1}" to check if tty
 630 sub start_pager {
 631         my ($self) = @_;
 632         my $env = $self->{env};
 633         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 634         chomp(my $pager = <$fh> // '');
 635         close($fh) or warn "`git var PAGER' error: \$?=$?";
 636         return if $pager eq 'cat' || $pager eq '';
 637         # TODO TIOCGWINSZ
 638         my %new_env = (LESS => 'FRX', LV => '-c', COLUMNS => 80);
 639         $new_env{MORE} = 'FRX' if $^O eq 'freebsd';
 640         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 641         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 642         my $pgr = [ undef, @$rdr{1, 2} ];
 643         if (my $sock = $self->{sock}) { # lei(1) process runs it
 644                 delete @new_env{keys %$env}; # only set iff unset
 645                 my $buf = "exec 1\0".$pager;
 646                 while (my ($k, $v) = each %new_env) { $buf .= "\0$k=$v" };
 647                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 648                 $send_cmd->($sock, $fds, $buf, MSG_EOR);
 649         } else {
 650                 $pgr->[0] = spawn([$pager], $env, $rdr);
 651         }
 652         $self->{1} = $wpager;
 653         $self->{2} = $wpager if -t $self->{2};
 654         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 655         $self->{pgr} = $pgr;
 656 }
 657
 658 sub stop_pager {
 659         my ($self) = @_;
 660         my $pgr = delete($self->{pgr}) or return;
 661         $self->{2} = $pgr->[2];
 662         # do not restore original stdout, just close it so we error out
 663         close(delete($self->{1})) if $self->{1};
 664         my $pid = $pgr->[0];
 665         dwaitpid($pid, undef, $self->{sock}) if $pid;
 666 }
 667
 668 sub accept_dispatch { # Listener {post_accept} callback
 669         my ($sock) = @_; # ignore other
 670         $sock->autoflush(1);
 671         my $self = bless { sock => $sock }, __PACKAGE__;
 672         vec(my $rvec, fileno($sock), 1) = 1;
 673         select($rvec, undef, undef, 1) or
 674                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 675         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 676         if (scalar(@fds) == 3) {
 677                 my $i = 0;
 678                 for my $rdr (qw(<&= >&= >&=)) {
 679                         my $fd = shift(@fds);
 680                         if (open(my $fh, $rdr, $fd)) {
 681                                 $self->{$i++} = $fh;
 682                                 next;
 683                         }
 684                         return send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 685                 }
 686         } else {
 687                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 688         }
 689         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 690         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 691         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 692         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 693                 return send($sock, 'request command truncated', MSG_EOR);
 694         my ($argc, @argv) = split(/\0/, $buf, -1);
 695         undef $buf;
 696         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 697         if (chdir($env{PWD})) {
 698                 local %ENV = %env;
 699                 $self->{env} = \%env;
 700                 eval { dispatch($self, @argv) };
 701                 send($sock, $@, MSG_EOR) if $@;
 702         } else {
 703                 send($sock, "chdir($env{PWD}): $!", MSG_EOR); # implicit close
 704         }
 705 }
 706
 707 sub dclose {
 708         my ($self) = @_;
 709         delete $self->{lxs}; # stops LeiXSearch queries
 710         $self->close; # PublicInbox::DS::close
 711 }
 712
 713 # for long-running results
 714 sub event_step {
 715         my ($self) = @_;
 716         local %ENV = %{$self->{env}};
 717         my $sock = $self->{sock};
 718         eval {
 719                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 720                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 721                                 return if $! == EAGAIN;
 722                                 next if $! == EINTR;
 723                                 last if $! == ECONNRESET;
 724                                 die "recvmsg: $!";
 725                         }
 726                         for my $fd (@fds) {
 727                                 open my $rfh, '+<&=', $fd;
 728                         }
 729                         die "unrecognized client signal: $buf";
 730                 }
 731                 dclose($self);
 732         };
 733         if (my $err = $@) {
 734                 eval { $self->fail($err) };
 735                 dclose($self);
 736         }
 737 }
 738
 739 sub event_step_init {
 740         my ($self) = @_;
 741         $self->{sock}->blocking(0);
 742         $self->SUPER::new($self->{sock}, EPOLLIN|EPOLLET);
 743 }
 744
 745 sub noop {}
 746
 747 our $oldset; sub oldset { $oldset }
 748
 749 # lei(1) calls this when it can't connect
 750 sub lazy_start {
 751         my ($path, $errno, $nfd) = @_;
 752         if ($errno == ECONNREFUSED) {
 753                 unlink($path) or die "unlink($path): $!";
 754         } elsif ($errno != ENOENT) {
 755                 $! = $errno; # allow interpolation to stringify in die
 756                 die "connect($path): $!";
 757         }
 758         umask(077) // die("umask(077): $!");
 759         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 760         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 761         listen($l, 1024) or die "listen: $!";
 762         my @st = stat($path) or die "stat($path): $!";
 763         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 764         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 765         local $oldset = PublicInbox::DS::block_signals();
 766         if ($nfd == 4) {
 767                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 768                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 769                         require PublicInbox::CmdIPC4;
 770                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 771                         PublicInbox::CmdIPC4->can('recv_cmd4');
 772                 };
 773         }
 774         $recv_cmd or die <<"";
 775 (Socket::MsgHdr || Inline::C) missing/unconfigured (nfd=$nfd);
 776
 777         require PublicInbox::Listener;
 778         require PublicInbox::EOFpipe;
 779         (-p STDOUT) or die "E: stdout must be a pipe\n";
 780         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 781         POSIX::setsid() > 0 or die "setsid: $!";
 782         my $pid = fork // die "fork: $!";
 783         return if $pid;
 784         $0 = "lei-daemon $path";
 785         local %PATH2CFG;
 786         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 787         $l->blocking(0);
 788         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 789         my $exit_code;
 790         local $quit = sub {
 791                 $exit_code //= shift;
 792                 my $listener = $l or exit($exit_code);
 793                 # closing eof_w triggers \&noop wakeup
 794                 $eof_w = $l = $path = undef;
 795                 $listener->close; # DS::close
 796                 PublicInbox::DS->SetLoopTimeout(1000);
 797         };
 798         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 799         undef $eof_r;
 800         my $sig = {
 801                 CHLD => \&PublicInbox::DS::enqueue_reap,
 802                 QUIT => $quit,
 803                 INT => $quit,
 804                 TERM => $quit,
 805                 HUP => \&noop,
 806                 USR1 => \&noop,
 807                 USR2 => \&noop,
 808         };
 809         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 810         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 811         undef $sig;
 812         local $SIG{PIPE} = 'IGNORE';
 813         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 814                 undef $sigfd;
 815                 PublicInbox::DS->SetLoopTimeout(5000);
 816         } else {
 817                 # wake up every second to accept signals if we don't
 818                 # have signalfd or IO::KQueue:
 819                 PublicInbox::DS::sig_setmask($oldset);
 820                 PublicInbox::DS->SetLoopTimeout(1000);
 821         }
 822         PublicInbox::DS->SetPostLoopCallback(sub {
 823                 my ($dmap, undef) = @_;
 824                 if (@st = defined($path) ? stat($path) : ()) {
 825                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 826                                 warn "$path dev/ino changed, quitting\n";
 827                                 $path = undef;
 828                         }
 829                 } elsif (defined($path)) {
 830                         warn "stat($path): $!, quitting ...\n";
 831                         undef $path; # don't unlink
 832                         $quit->();
 833                 }
 834                 return 1 if defined($path);
 835                 my $now = now();
 836                 my $n = 0;
 837                 for my $s (values %$dmap) {
 838                         $s->can('busy') or next;
 839                         if ($s->busy($now)) {
 840                                 ++$n;
 841                         } else {
 842                                 $s->close;
 843                         }
 844                 }
 845                 $n; # true: continue, false: stop
 846         });
 847
 848         # STDIN was redirected to /dev/null above, closing STDERR and
 849         # STDOUT will cause the calling `lei' client process to finish
 850         # reading the <$daemon> pipe.
 851         openlog($path, 'pid', 'user');
 852         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 853         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 854                 syslog('crit', "$@") if $@;
 855         });
 856         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 857         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 858         # $daemon pipe to `lei' closed, main loop begins:
 859         PublicInbox::DS->EventLoop;
 860         @$on_destroy = (); # cancel on_destroy if we get here
 861         exit($exit_code // 0);
 862 }
 863
 864 # for users w/o Socket::Msghdr
 865 sub oneshot {
 866         my ($main_pkg) = @_;
 867         my $exit = $main_pkg->can('exit'); # caller may override exit()
 868         local $quit = $exit if $exit;
 869         local %PATH2CFG;
 870         umask(077) // die("umask(077): $!");
 871         dispatch((bless {
 872                 0 => *STDIN{GLOB},
 873                 1 => *STDOUT{GLOB},
 874                 2 => *STDERR{GLOB},
 875                 env => \%ENV
 876         }, __PACKAGE__), @ARGV);
 877 }
 878
 879 # ensures stdout hits the FS before sock disconnects so a client
 880 # can immediately reread it
 881 sub DESTROY {
 882         my ($self) = @_;
 883         $self->{1}->autoflush(1) if $self->{1};
 884         stop_pager($self);
 885 }
 886
 887 1;