lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'prune-mail-sync' => [ 'LOCATION...|--all',
 249         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 250 'export-kw' => [ 'LOCATION...|--all',
 251         'one-time export of keywords of sync sources',
 252         qw(all:s mode=s), @c_opt ],
 253 'convert' => [ 'LOCATION...|--stdin',
 254         'one-time conversion from URL or filesystem to another format',
 255         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 256         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 257 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 258         "use a patch to generate a query for `lei q --stdin'",
 259         qw(stdin| want|w=s@ uri debug), @c_opt ],
 260 'config' => [ '[...]', sub {
 261                 'git-config(1) wrapper for '._config_path($_[0]);
 262         }, qw(config-file|system|global|file|f=s), # for conflict detection
 263          qw(c=s@ C=s@), pass_through('git config') ],
 264 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 265         qw(pretty ascii dir=s), @c_opt ],
 266
 267 'init' => [ '[DIRNAME]', sub {
 268         "initialize storage, default: ".store_path($_[0]);
 269         }, @c_opt ],
 270 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 271         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 272         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 273 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 274 'help' => [ '[SUBCOMMAND]', 'show help' ],
 275
 276 # TODO
 277 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 278 #       'rewrite git history in an attempt to improve compression',
 279 #       qw(gc!), @c_opt ],
 280 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 281 #
 282 # internal commands are prefixed with '_'
 283 '_complete' => [ '[...]', 'internal shell completion helper',
 284                 pass_through('everything') ],
 285 ); # @CMD
 286
 287 # switch descriptions, try to keep consistent across commands
 288 # $spec: Getopt::Long option specification
 289 # $spec => [@ALLOWED_VALUES (default is first), $description],
 290 # $spec => $description
 291 # "$SUB_COMMAND TAB $spec" => as above
 292 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 293                         'specify message input format' ];
 294 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 295
 296 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 297 my %OPTDESC = (
 298 'help|h' => 'show this built-in help',
 299 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 300 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 301 'quiet|q' => 'be quiet',
 302 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 303         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 304
 305 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 306 'globoff|g' => "do not match locations using '*?' wildcards ".
 307                 "and\xa0'[]'\x{a0}ranges",
 308 'invert-match|v' => 'select non-matching lines',
 309 'color!' => 'disable color (for --format=text)',
 310 'verbose|v+' => 'be more verbose',
 311 'external!' => 'do not use externals',
 312 'mail!' => 'do not look in mail storage for OID',
 313 'cwd!' => 'do not look in git repo of current working directory',
 314 'oid-a|A=s' => 'pre-image OID',
 315 'path-a|a=s' => 'pre-image pathname associated with OID',
 316 'path-b|b=s' => 'post-image pathname associated with OID',
 317 'git-dir=s@' => 'additional git repository to scan',
 318 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 319         "proxy for (e.g. `socks5h://0:9050')" ],
 320 'torsocks=s' => ['VAL|auto|no|yes',
 321                 'whether or not to wrap git and curl commands with torsocks'],
 322 'no-torsocks' => 'alias for --torsocks=no',
 323 'save' =>  "save a search for `lei up'",
 324 'import-remote!' => 'do not memoize remote messages into local store',
 325
 326 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 327
 328 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 329                 'deduplication strategy'],
 330 'threads|t+' =>
 331         'return all messages in the same threads as the actual match(es)',
 332
 333 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 334                 'search prefixes to extract (default: dfpost7)' ],
 335
 336 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 337         'run command(s) or perform ops when done writing to output ' .
 338         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 339         'nothing otherwise)' ],
 340
 341 'augment|a' => 'augment --output destination instead of clobbering',
 342
 343 'output|mfolder|o=s' => [ 'MFOLDER',
 344         "destination (e.g.\xa0`/path/to/Maildir', ".
 345         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 346 'mua=s' => [ 'CMD',
 347         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 348
 349 'inbox-version=i' => [ 'NUM|1|2',
 350                 'force a public-inbox version with --mirror'],
 351 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 352
 353 # public-inbox-index options
 354 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 355 'compact' => 'run compact index after mirroring',
 356 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 357         "indexlevel with --mirror (default: full)" ],
 358 'max_size|max-size=s' => [ 'SIZE',
 359         'do not index messages larger than SIZE (default: infinity)' ],
 360 'batch_size|batch-size=s' => [ 'SIZE',
 361         'flush changes to OS after given number of bytes (default: 1m)' ],
 362 'sequential_shard|sequential-shard' =>
 363         'index Xapian shards sequentially for slow storage',
 364 'skip-docdata' =>
 365         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 366
 367 'format|f=s     q' => [
 368         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 369                 'specify output format, default depends on --output'],
 370 'exclude=s@     q' => [ 'LOCATION',
 371                 'exclude specified external(s) from search' ],
 372 'include|I=s@   q' => [ 'LOCATION',
 373                 'include specified external(s) in search' ],
 374 'only=s@        q' => [ 'LOCATION',
 375                 'only use specified external(s) for search' ],
 376 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 377                 'control number of search and writer jobs' ],
 378 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 379
 380 'in-format|F=s' => $stdin_formats,
 381 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 382                         'listing output format' ],
 383 'l      ls-search' => 'long listing format',
 384 'format|f=s     ls-external' => $ls_format,
 385
 386 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 387 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 388
 389 'sort|s=s' => [ 'VAL|received|relevance|docid',
 390                 "order of results is `--output'-dependent"],
 391 'reverse|r' => 'reverse search results', # like sort(1)
 392
 393 'boost=i' => 'increase/decrease priority of results (default: 0)',
 394
 395 'local' => 'limit operations to the local filesystem',
 396 'local!' => 'exclude results from the local filesystem',
 397 'remote' => 'limit operations to those requiring network access',
 398 'remote!' => 'prevent operations requiring network access',
 399
 400 'all:s  up' => ['local', 'update all (local) saved searches' ],
 401
 402 'mid=s' => 'specify the Message-ID of a message',
 403 'oid=s' => 'specify the git object ID of a message',
 404
 405 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 406 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 407 'include=s' => 'include mailboxes/newsgroups based on pattern',
 408
 409 'exact' => 'operate on exact header matches only',
 410 'exact!' => 'rely on content match instead of exact header matches',
 411
 412 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 413
 414 'kw!' => 'disable/enable importing keywords (aka "flags")',
 415
 416 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 417 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 418
 419 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 420 ); # %OPTDESC
 421
 422 my %CONFIG_KEYS = (
 423         'leistore.dir' => 'top-level storage location',
 424 );
 425
 426 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1); # internal workers
 427
 428 sub _drop_wq {
 429         my ($self) = @_;
 430         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 431                 if ($wq->wq_kill) {
 432                         $wq->wq_close(0, undef, $self);
 433                 } elsif ($wq->wq_kill_old) {
 434                         $wq->wq_wait_old(undef, $self);
 435                 }
 436                 $wq->DESTROY;
 437         }
 438 }
 439
 440 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 441 sub x_it ($$) {
 442         my ($self, $code) = @_;
 443         # make sure client sees stdout before exit
 444         $self->{1}->autoflush(1) if $self->{1};
 445         dump_and_clear_log();
 446         if ($self->{pkt_op_p}) { # to top lei-daemon
 447                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 448         } elsif ($self->{sock}) { # to lei(1) client
 449                 send($self->{sock}, "x_it $code", MSG_EOR);
 450         } # else ignore if client disconnected
 451 }
 452
 453 sub err ($;@) {
 454         my $self = shift;
 455         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 456         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 457         print $err @_, @eor and return;
 458         my $old_err = delete $self->{2};
 459         close($old_err) if $! == EPIPE && $old_err;
 460         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 461         print $err @_, @eor or print STDERR @_, @eor;
 462 }
 463
 464 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 465
 466 sub fail_handler ($;$$) {
 467         my ($lei, $code, $io) = @_;
 468         close($io) if $io; # needed to avoid warnings on SIGPIPE
 469         _drop_wq($lei);
 470         x_it($lei, $code // (1 << 8));
 471 }
 472
 473 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 474         fail_handler($_[0], 13, delete $_[0]->{1});
 475 }
 476
 477 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 478 sub sigint_reap {
 479         my ($pgid) = @_;
 480         dwaitpid($pgid) if kill('-INT', $pgid);
 481 }
 482
 483 sub fail ($$;$) {
 484         my ($self, $buf, $exit_code) = @_;
 485         $self->{failed}++;
 486         err($self, $buf) if defined $buf;
 487         # calls fail_handler:
 488         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 489         x_it($self, ($exit_code // 1) << 8);
 490         undef;
 491 }
 492
 493 sub out ($;@) {
 494         my $self = shift;
 495         return if print { $self->{1} // return } @_; # likely
 496         return note_sigpipe($self, 1) if $! == EPIPE;
 497         my $err = "error writing to output: $!";
 498         delete $self->{1};
 499         fail($self, $err);
 500 }
 501
 502 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 503
 504 sub child_error { # passes non-fatal curl exit codes to user
 505         my ($self, $child_error, $msg) = @_; # child_error is $?
 506         $self->err($msg) if $msg;
 507         if ($self->{pkt_op_p}) { # to top lei-daemon
 508                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 509         } elsif ($self->{sock}) { # to lei(1) client
 510                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 511         } # else noop if client disconnected
 512 }
 513
 514 sub note_sigpipe { # triggers sigpipe_handler
 515         my ($self, $fd) = @_;
 516         close(delete($self->{$fd})); # explicit close silences Perl warning
 517         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 518         x_it($self, 13);
 519 }
 520
 521 sub _lei_atfork_child {
 522         my ($self, $persist) = @_;
 523         # we need to explicitly close things which are on stack
 524         if ($persist) {
 525                 chdir '/' or die "chdir(/): $!";
 526                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 527                 if (my $cfg = $self->{cfg}) {
 528                         delete $cfg->{-lei_store};
 529                 }
 530         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 531                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 532                 STDERR->autoflush(1);
 533         }
 534         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 535         if (my $op_c = delete $self->{pkt_op_c}) {
 536                 close(delete $op_c->{sock});
 537         }
 538         if (my $pgr = delete $self->{pgr}) {
 539                 close($_) for (@$pgr[1,2]);
 540         }
 541         close $listener if $listener;
 542         undef $listener;
 543         undef $dir_idle;
 544         %PATH2CFG = ();
 545         undef $errors_log;
 546         $quit = \&CORE::exit;
 547         $self->{-eml_noisy} or # only "lei import" sets this atm
 548                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 549         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 550 }
 551
 552 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 553         my ($self) = @_;
 554         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 555                 $op->close; # PublicInbox::PktOp::close
 556         }
 557         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 558         close $pkt_op_p->{op_p};
 559 }
 560
 561 sub pkt_op_pair {
 562         my ($self) = @_;
 563         require PublicInbox::OnDestroy;
 564         require PublicInbox::PktOp;
 565         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 566         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 567         $end;
 568 }
 569
 570 sub workers_start {
 571         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 572         $ops = {
 573                 '!' => [ \&fail_handler, $lei ],
 574                 '|' => [ \&sigpipe_handler, $lei ],
 575                 'x_it' => [ \&x_it, $lei ],
 576                 'child_error' => [ \&child_error, $lei ],
 577                 ($ops ? %$ops : ()),
 578         };
 579         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 580         my $end = $lei->pkt_op_pair;
 581         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 582         $flds->{lei} = $lei;
 583         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 584         delete $lei->{pkt_op_p};
 585         my $op_c = delete $lei->{pkt_op_c};
 586         # {-lei_sock} persists script/lei process until ops->{''} EOF callback
 587         $op_c->{-lei_sock} = $lei->{sock};
 588         @$end = ();
 589         $lei->event_step_init;
 590         ($op_c, $ops);
 591 }
 592
 593 # call this when we're ready to wait on events and yield to other clients
 594 sub wait_wq_events {
 595         my ($lei, $op_c, $ops) = @_;
 596         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 597                 $wq->wq_close(1);
 598         }
 599         $op_c->{ops} = $ops;
 600 }
 601
 602 sub _help {
 603         require PublicInbox::LeiHelp;
 604         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 605 }
 606
 607 sub optparse ($$$) {
 608         my ($self, $cmd, $argv) = @_;
 609         # allow _complete --help to complete, not show help
 610         return 1 if substr($cmd, 0, 1) eq '_';
 611         $self->{cmd} = $cmd;
 612         $OPT = $self->{opt} //= {};
 613         my $info = $CMD{$cmd} // [ '[...]' ];
 614         my ($proto, undef, @spec) = @$info;
 615         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 616         push @spec, qw(help|h);
 617         my $lone_dash;
 618         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 619                 $lone_dash = $spec[0];
 620                 $OPT->{$spec[0]} = \(my $var);
 621                 push @spec, '' => \$var;
 622         }
 623         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 624                 return _help($self, "bad arguments or options for $cmd");
 625         return _help($self) if $OPT->{help};
 626
 627         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 628
 629         # "-" aliases "stdin" or "clear"
 630         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 631
 632         my $i = 0;
 633         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 634         my ($err, $inf);
 635         my @args = split(/ /, $proto);
 636         for my $var (@args) {
 637                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 638                         $inf = defined($argv->[$i]) and last;
 639                         $var =~ s/\.\.\.\z//;
 640                         $err = "$var not supplied";
 641                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 642                         $argv->[$i++] // ($err = "$var not supplied");
 643                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 644                         $inf = 1;
 645                         last;
 646                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 647                         $i++;
 648                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 649                         $inf = 1 if index($var, '...') > 0;
 650                         my @or = split(/\|/, $var);
 651                         my $ok;
 652                         for my $o (@or) {
 653                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 654                                         my $sw = $1;
 655                                         # assume pipe/regular file on stdin
 656                                         # w/o args means stdin
 657                                         if ($sw eq 'stdin' && !@$argv &&
 658                                                         (-p $self->{0} ||
 659                                                          -f _) && -r _) {
 660                                                 $OPT->{stdin} //= 1;
 661                                         }
 662                                         $ok = defined($OPT->{$sw});
 663                                         last if $ok;
 664                                 } elsif (defined($argv->[$i])) {
 665                                         $ok = 1;
 666                                         $i++;
 667                                         last;
 668                                 } # else continue looping
 669                         }
 670                         last if $ok;
 671                         my $last = pop @or;
 672                         $err = join(', ', @or) . " or $last must be set";
 673                 } else {
 674                         warn "BUG: can't parse `$var' in $proto";
 675                 }
 676                 last if $err;
 677         }
 678         if (!$inf && scalar(@$argv) > scalar(@args)) {
 679                 $err //= 'too many arguments';
 680         }
 681         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 682 }
 683
 684 sub _tmp_cfg { # for lei -c <name>=<value> ...
 685         my ($self) = @_;
 686         my $cfg = _lei_cfg($self, 1);
 687         require File::Temp;
 688         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 689         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 690         $ft->autoflush(1);
 691         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 692 [include]
 693         path = $cfg->{-f}
 694 EOM
 695         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 696         for (@{$self->{opt}->{c}}) {
 697                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 698 `-c $_' is not of the form -c <name>=<value>'
 699 EOM
 700                 my $name = $1;
 701                 my $value = $2 // 1;
 702                 _config($self, '--add', $name, $value);
 703                 if (defined(my $v = $tmp->{$name})) {
 704                         if (ref($v) eq 'ARRAY') {
 705                                 push @$v, $value;
 706                         } else {
 707                                 $tmp->{$name} = [ $v, $value ];
 708                         }
 709                 } else {
 710                         $tmp->{$name} = $value;
 711                 }
 712         }
 713 }
 714
 715 sub lazy_cb ($$$) {
 716         my ($self, $cmd, $pfx) = @_;
 717         my $ucmd = $cmd;
 718         $ucmd =~ tr/-/_/;
 719         my $cb;
 720         $cb = $self->can($pfx.$ucmd) and return $cb;
 721         my $base = $ucmd;
 722         $base =~ s/_([a-z])/\u$1/g;
 723         my $pkg = "PublicInbox::Lei\u$base";
 724         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 725                 $pkg->can($pfx.$ucmd) : undef;
 726 }
 727
 728 sub dispatch {
 729         my ($self, $cmd, @argv) = @_;
 730         local $current_lei = $self; # for __WARN__
 731         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 732         dump_and_clear_log("from previous run\n");
 733         return _help($self, 'no command given') unless defined($cmd);
 734         # do not support Getopt bundling for this
 735         while ($cmd eq '-C' || $cmd eq '-c') {
 736                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 737                                         '-C DIRECTORY' : '-c <name>=<value>');
 738                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 739                 $cmd = shift(@argv) // return _help($self, 'no command given');
 740         }
 741         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 742                 optparse($self, $cmd, \@argv) or return;
 743                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 744                 if (my $chdir = $self->{opt}->{C}) {
 745                         for my $d (@$chdir) {
 746                                 next if $d eq ''; # same as git(1)
 747                                 chdir $d or return fail($self, "cd $d: $!");
 748                         }
 749                         if (delete $self->{3}) { # update cwd for rel2abs
 750                                 opendir my $dh, '.' or
 751                                         return fail($self, "opendir . $!");
 752                                 $self->{3} = $dh;
 753                         }
 754                 }
 755                 $cb->($self, @argv);
 756         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 757                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 758                         or return _help($self, 'bad arguments or options');
 759                 _help($self);
 760         } else {
 761                 fail($self, "`$cmd' is not an lei command");
 762         }
 763 }
 764
 765 sub _lei_cfg ($;$) {
 766         my ($self, $creat) = @_;
 767         return $self->{cfg} if $self->{cfg};
 768         my $f = _config_path($self);
 769         my @st = stat($f);
 770         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 771         my ($sto, $sto_dir);
 772         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 773                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 774                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 775         }
 776         if (!@st) {
 777                 unless ($creat) {
 778                         delete $self->{cfg};
 779                         return bless {}, 'PublicInbox::Config';
 780                 }
 781                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 782                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 783                 open my $fh, '>>', $f or die "open($f): $!\n";
 784                 @st = stat($fh) or die "fstat($f): $!\n";
 785                 $cur_st = pack('dd', $st[10], $st[7]);
 786                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 787         }
 788         my $cfg = PublicInbox::Config->git_config_dump($f);
 789         $cfg->{-st} = $cur_st;
 790         $cfg->{'-f'} = $f;
 791         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 792                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 793                                                 store_path($self))) {
 794                 $cfg->{-lei_store} = $sto;
 795         }
 796         if (scalar(keys %PATH2CFG) > 5) {
 797                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 798                 for my $k (keys %PATH2CFG) {
 799                         delete($PATH2CFG{$k}) unless -f $k
 800                 }
 801         }
 802         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 803 }
 804
 805 sub _lei_store ($;$) {
 806         my ($self, $creat) = @_;
 807         my $cfg = _lei_cfg($self, $creat);
 808         $cfg->{-lei_store} //= do {
 809                 require PublicInbox::LeiStore;
 810                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 811                 return unless $creat || -d $dir;
 812                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 813         };
 814 }
 815
 816 sub _config {
 817         my ($self, @argv) = @_;
 818         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 819         my $cfg = _lei_cfg($self, 1);
 820         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 821         my %rdr = map { $_ => $self->{$_} } (0..2);
 822         waitpid(spawn($cmd, \%env, \%rdr), 0);
 823 }
 824
 825 sub lei_config {
 826         my ($self, @argv) = @_;
 827         $self->{opt}->{'config-file'} and return fail $self,
 828                 "config file switches not supported by `lei config'";
 829         _config(@_);
 830         x_it($self, $?) if $?;
 831 }
 832
 833 sub lei_daemon_pid { puts shift, $$ }
 834
 835 sub lei_daemon_kill {
 836         my ($self) = @_;
 837         my $sig = $self->{opt}->{signal} // 'TERM';
 838         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 839 }
 840
 841 # Shell completion helper.  Used by lei-completion.bash and hopefully
 842 # other shells.  Try to do as much here as possible to avoid redundancy
 843 # and improve maintainability.
 844 sub lei__complete {
 845         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 846         shift @argv; # ignore "lei", the entire command is sent
 847         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 848         my $cmd = shift @argv;
 849         my $info = $CMD{$cmd} // do { # filter matching commands
 850                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 851                 return;
 852         };
 853         my ($proto, undef, @spec) = @$info;
 854         my $cur = pop @argv;
 855         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 856         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 857                 # gross special case since the only git-config options
 858                 # Consider moving to a table if we need more special cases
 859                 # we use Getopt::Long for are the ones we reject, so these
 860                 # are the ones we don't reject:
 861                 if ($cmd eq 'config') {
 862                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 863                         @spec = qw(add z|null get get-all unset unset-all
 864                                 replace-all get-urlmatch
 865                                 remove-section rename-section
 866                                 name-only list|l edit|e
 867                                 get-color-name get-colorbool);
 868                         # fall-through
 869                 }
 870                 # generate short/long names from Getopt::Long specs
 871                 puts $self, grep(/$re/, qw(--help -h -C), map {
 872                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 873                         } elsif (s/\+\z//) { # verbose|v+
 874                         } elsif (s/!\z//) {
 875                                 # negation: mail! => no-mail|mail
 876                                 s/([\w\-]+)/$1|no-$1/g
 877                         }
 878                         map {
 879                                 my $x = length > 1 ? "--$_" : "-$_";
 880                                 $x eq $_cur ? () : $x;
 881                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 882                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 883         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 884                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 885         }
 886
 887         # switch args (e.g. lei q -f mbox<TAB>)
 888         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 889                 my $opt = quotemeta $1;
 890                 puts $self, map {
 891                         my $v = $OPTDESC{$_};
 892                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 893                         # get rid of ALL CAPS placeholder (e.g "OUT")
 894                         # (TODO: completion for external paths)
 895                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 896                         @v;
 897                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 898         }
 899         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 900                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 901         }
 902         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 903         # proto parsing.
 904 }
 905
 906 sub exec_buf ($$) {
 907         my ($argv, $env) = @_;
 908         my $argc = scalar @$argv;
 909         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 910         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 911         $buf;
 912 }
 913
 914 sub start_mua {
 915         my ($self) = @_;
 916         my $mua = $self->{opt}->{mua} // return;
 917         my $mfolder = $self->{ovv}->{dst};
 918         my (@cmd, $replaced);
 919         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 920                 @cmd = ($mua, '-f');
 921         # TODO: help wanted: other common FOSS MUAs
 922         } else {
 923                 require Text::ParseWords;
 924                 @cmd = Text::ParseWords::shellwords($mua);
 925                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 926                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 927         }
 928         push @cmd, $mfolder unless defined($replaced);
 929         if ($self->{sock}) { # lei(1) client process runs it
 930                 # restore terminal: echo $query | lei q --stdin --mua=...
 931                 my $io = [];
 932                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 933                 send_exec_cmd($self, $io, \@cmd, {});
 934         }
 935         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 936                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 937         }
 938         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 939         $self->{opt}->{quiet} = 1;
 940         delete $self->{-progress};
 941         delete $self->{opt}->{verbose};
 942 }
 943
 944 sub send_exec_cmd { # tell script/lei to execute a command
 945         my ($self, $io, $cmd, $env) = @_;
 946         my $sock = $self->{sock} // die 'lei client gone';
 947         my $fds = [ map { fileno($_) } @$io ];
 948         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 949 }
 950
 951 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 952         my ($self) = @_;
 953         my $alerts = $self->{opt}->{alert} // return;
 954         my $sock = $self->{sock};
 955         while (my $op = shift(@$alerts)) {
 956                 if ($op eq ':WINCH') {
 957                         # hit the process group that started the MUA
 958                         send($sock, '-WINCH', MSG_EOR) if $sock;
 959                 } elsif ($op eq ':bell') {
 960                         out($self, "\a");
 961                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 962                         push @$alerts, split(/(?<!\\),/, $op);
 963                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 964                         my $cmd = $1; # run an arbitrary command
 965                         require Text::ParseWords;
 966                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 967                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 968                 } else {
 969                         err($self, "W: unsupported --alert=$op"); # non-fatal
 970                 }
 971         }
 972 }
 973
 974 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 975 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 976
 977 # this also normalizes the path
 978 sub path_to_fd {
 979         my ($self, $path) = @_;
 980         $path = rel2abs($self, $path);
 981         $path =~ tr!/!/!s;
 982         $path_to_fd{$path} // (
 983                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 984                         fail($self, "cannot open $path from daemon") : -1
 985         );
 986 }
 987
 988 # caller needs to "-t $self->{1}" to check if tty
 989 sub start_pager {
 990         my ($self) = @_;
 991         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 992         chomp(my $pager = <$fh> // '');
 993         close($fh) or warn "`git var PAGER' error: \$?=$?";
 994         return if $pager eq 'cat' || $pager eq '';
 995         my $new_env = { LESS => 'FRX', LV => '-c' };
 996         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 997         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 998         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 999         my $pgr = [ undef, @$rdr{1, 2} ];
1000         my $env = $self->{env};
1001         if ($self->{sock}) { # lei(1) process runs it
1002                 delete @$new_env{keys %$env}; # only set iff unset
1003                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1004         } else {
1005                 die 'BUG: start_pager w/o socket';
1006         }
1007         $self->{1} = $wpager;
1008         $self->{2} = $wpager if -t $self->{2};
1009         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1010         $self->{pgr} = $pgr;
1011 }
1012
1013 sub stop_pager {
1014         my ($self) = @_;
1015         my $pgr = delete($self->{pgr}) or return;
1016         $self->{2} = $pgr->[2];
1017         # do not restore original stdout, just close it so we error out
1018         close(delete($self->{1})) if $self->{1};
1019 }
1020
1021 sub accept_dispatch { # Listener {post_accept} callback
1022         my ($sock) = @_; # ignore other
1023         $sock->autoflush(1);
1024         my $self = bless { sock => $sock }, __PACKAGE__;
1025         vec(my $rvec = '', fileno($sock), 1) = 1;
1026         select($rvec, undef, undef, 60) or
1027                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1028         # (4096 * 33) >MAX_ARG_STRLEN
1029         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1030         if (!defined($fds[0])) {
1031                 warn(my $msg = "recv_cmd failed: $!");
1032                 return send($sock, $msg, MSG_EOR);
1033         } else {
1034                 my $i = 0;
1035                 for my $fd (@fds) {
1036                         open($self->{$i++}, '+<&=', $fd) and next;
1037                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1038                 }
1039                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1040         }
1041         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1042         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1043         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1044                 return send($sock, 'request command truncated', MSG_EOR);
1045         my ($argc, @argv) = split(/\0/, $buf, -1);
1046         undef $buf;
1047         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1048         if (chdir($self->{3})) {
1049                 local %ENV = %env;
1050                 $self->{env} = \%env;
1051                 eval { dispatch($self, @argv) };
1052                 send($sock, $@, MSG_EOR) if $@;
1053         } else {
1054                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1055         }
1056 }
1057
1058 sub dclose {
1059         my ($self) = @_;
1060         delete $self->{-progress};
1061         _drop_wq($self) if $self->{failed};
1062         close(delete $self->{1}) if $self->{1}; # may reap_compress
1063         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1064 }
1065
1066 # for long-running results
1067 sub event_step {
1068         my ($self) = @_;
1069         local %ENV = %{$self->{env}};
1070         my $sock = $self->{sock};
1071         local $current_lei = $self;
1072         eval {
1073                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1074                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1075                                 return if $! == EAGAIN;
1076                                 next if $! == EINTR;
1077                                 last if $! == ECONNRESET;
1078                                 die "recvmsg: $!";
1079                         }
1080                         for my $fd (@fds) {
1081                                 open my $rfh, '+<&=', $fd;
1082                         }
1083                         die "unrecognized client signal: $buf";
1084                 }
1085                 dclose($self);
1086         };
1087         if (my $err = $@) {
1088                 eval { $self->fail($err) };
1089                 dclose($self);
1090         }
1091 }
1092
1093 sub event_step_init {
1094         my ($self) = @_;
1095         return if $self->{-event_init_done}++;
1096         if (my $sock = $self->{sock}) { # using DS->EventLoop
1097                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1098         }
1099 }
1100
1101 sub noop {}
1102
1103 sub oldset { $oldset }
1104
1105 sub dump_and_clear_log {
1106         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1107                 my @pfx = @_;
1108                 unshift(@pfx, "$errors_log ") if @pfx;
1109                 warn @pfx, do { local $/; <STDIN> };
1110                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1111         }
1112 }
1113
1114 # lei(1) calls this when it can't connect
1115 sub lazy_start {
1116         my ($path, $errno, $narg) = @_;
1117         local ($errors_log, $listener);
1118         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1119         $errors_log = "$sock_dir/errors.log";
1120         my $addr = pack_sockaddr_un($path);
1121         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1122         $lk->lock_acquire;
1123         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1124         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1125                 return if connect($listener, $addr); # another process won
1126                 if ($errno == ECONNREFUSED && -S $path) {
1127                         unlink($path) or die "unlink($path): $!";
1128                 }
1129         } else {
1130                 $! = $errno; # allow interpolation to stringify in die
1131                 die "connect($path): $!";
1132         }
1133         umask(077) // die("umask(077): $!");
1134         bind($listener, $addr) or die "bind($path): $!";
1135         listen($listener, 1024) or die "listen: $!";
1136         $lk->lock_release;
1137         undef $lk;
1138         my @st = stat($path) or die "stat($path): $!";
1139         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1140         local $oldset = PublicInbox::DS::block_signals();
1141         if ($narg == 5) {
1142                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1143                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1144                         require PublicInbox::CmdIPC4;
1145                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1146                         PublicInbox::CmdIPC4->can('recv_cmd4');
1147                 };
1148         }
1149         $recv_cmd or die <<"";
1150 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1151
1152         require PublicInbox::Listener;
1153         require PublicInbox::PktOp;
1154         (-p STDOUT) or die "E: stdout must be a pipe\n";
1155         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1156         STDIN->autoflush(1);
1157         dump_and_clear_log("from previous daemon process:\n");
1158         POSIX::setsid() > 0 or die "setsid: $!";
1159         my $pid = fork // die "fork: $!";
1160         return if $pid;
1161         $0 = "lei-daemon $path";
1162         local %PATH2CFG;
1163         $listener->blocking(0);
1164         my $exit_code;
1165         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1166         local $quit = do {
1167                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1168                 sub {
1169                         $exit_code //= shift;
1170                         my $lis = $pil or exit($exit_code);
1171                         # closing eof_p triggers \&noop wakeup
1172                         $listener = $eof_p = $pil = $path = undef;
1173                         $lis->close; # DS::close
1174                         PublicInbox::DS->SetLoopTimeout(1000);
1175                 };
1176         };
1177         my $sig = {
1178                 CHLD => \&PublicInbox::DS::enqueue_reap,
1179                 QUIT => $quit,
1180                 INT => $quit,
1181                 TERM => $quit,
1182                 HUP => \&noop,
1183                 USR1 => \&noop,
1184                 USR2 => \&noop,
1185         };
1186         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1187         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1188         undef $sig;
1189         local $SIG{PIPE} = 'IGNORE';
1190         require PublicInbox::DirIdle;
1191         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1192                 # just rely on wakeup ot hit PostLoopCallback set below
1193                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1194         }, 1);
1195         if ($sigfd) {
1196                 undef $sigfd; # unref, already in DS::DescriptorMap
1197         } else {
1198                 # wake up every second to accept signals if we don't
1199                 # have signalfd or IO::KQueue:
1200                 PublicInbox::DS::sig_setmask($oldset);
1201                 PublicInbox::DS->SetLoopTimeout(1000);
1202         }
1203         PublicInbox::DS->SetPostLoopCallback(sub {
1204                 my ($dmap, undef) = @_;
1205                 if (@st = defined($path) ? stat($path) : ()) {
1206                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1207                                 warn "$path dev/ino changed, quitting\n";
1208                                 $path = undef;
1209                         }
1210                 } elsif (defined($path)) { # ENOENT is common
1211                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1212                         undef $path;
1213                         $quit->();
1214                 }
1215                 return 1 if defined($path);
1216                 my $now = now();
1217                 my $n = 0;
1218                 for my $s (values %$dmap) {
1219                         $s->can('busy') or next;
1220                         if ($s->busy($now)) {
1221                                 ++$n;
1222                         } else {
1223                                 $s->close;
1224                         }
1225                 }
1226                 $n; # true: continue, false: stop
1227         });
1228
1229         # STDIN was redirected to /dev/null above, closing STDERR and
1230         # STDOUT will cause the calling `lei' client process to finish
1231         # reading the <$daemon> pipe.
1232         local $SIG{__WARN__} = sub {
1233                 $current_lei ? err($current_lei, @_) : warn(
1234                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1235         };
1236         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1237         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1238         # $daemon pipe to `lei' closed, main loop begins:
1239         PublicInbox::DS->EventLoop;
1240         exit($exit_code // 0);
1241 }
1242
1243 sub busy { 1 } # prevent daemon-shutdown if client is connected
1244
1245 # ensures stdout hits the FS before sock disconnects so a client
1246 # can immediately reread it
1247 sub DESTROY {
1248         my ($self) = @_;
1249         $self->{1}->autoflush(1) if $self->{1};
1250         stop_pager($self);
1251         # preserve $? for ->fail or ->x_it code
1252 }
1253
1254 sub wq_done_wait { # dwaitpid callback
1255         my ($arg, $pid) = @_;
1256         my ($wq, $lei) = @$arg;
1257         my $err_type = $lei->{-err_type};
1258         $? and $lei->child_error($?,
1259                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1260         $lei->dclose;
1261 }
1262
1263 sub fchdir {
1264         my ($lei) = @_;
1265         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1266         chdir($dh) || $lei->fail("fchdir: $!");
1267 }
1268
1269 sub wq_eof { # EOF callback for main daemon
1270         my ($lei) = @_;
1271         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1272         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1273 }
1274
1275 1;