lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         mua-cmd|mua=s no-torsocks torsocks=s verbose|v
 108         received-after=s received-before=s sent-after=s sent-since=s),
 109         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 110
 111 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 112         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 113         pass_through('git show') ],
 114
 115 'add-external' => [ 'URL_OR_PATHNAME',
 116         'add/set priority of a publicinbox|extindex for extra matches',
 117         qw(boost=i quiet|q) ],
 118 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 119         qw(format|f=s z|0 local remote quiet|q) ],
 120 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 121         'exclude further results from a publicinbox|extindex',
 122         qw(prune quiet|q) ],
 123
 124 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 125                 qw(name-only format|f=s z) ],
 126 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 127 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 128
 129 'plonk' => [ '--thread|--from=IDENT',
 130         'exclude mail matching From: or thread from non-Message-ID searches',
 131         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 132 'mark' => [ 'MESSAGE_FLAGS...',
 133         'set/unset flags on message(s) from stdin',
 134         qw(stdin| oid=s exact by-mid|mid:s) ],
 135 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 136         "exclude message(s) on stdin from `q' search results",
 137         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 138
 139 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 140         'remove imported messages from IMAP, Maildirs, and MH',
 141         qw(exact! all jobs:i indexed) ],
 142
 143 # code repos are used for `show' to solve blobs from patch mails
 144 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 145         qw(boost=i) ],
 146 'ls-coderepo' => [ '[FILTER_TERMS...]',
 147                 'list known code repos', qw(format|f=s z) ],
 148 'forget-coderepo' => [ 'PATHNAME',
 149         'stop using repo to solve blobs from patches',
 150         qw(prune) ],
 151
 152 'add-watch' => [ '[URL_OR_PATHNAME]',
 153                 'watch for new messages and flag changes',
 154         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 155 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 156                 qw(format|f=s z) ],
 157 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 158 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 160         qw(prune) ],
 161
 162 'import' => [ 'URL_OR_PATHNAME|--stdin',
 163         'one-shot import/update from URL or filesystem',
 164         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 165         ],
 166
 167 'config' => [ '[...]', sub {
 168                 'git-config(1) wrapper for '._config_path($_[0]);
 169         }, qw(config-file|system|global|file|f=s), # for conflict detection
 170         pass_through('git config') ],
 171 'init' => [ '[PATHNAME]', sub {
 172                 'initialize storage, default: '._store_path($_[0]);
 173         }, qw(quiet|q) ],
 174 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 175         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 176 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 177 'help' => [ '[SUBCOMMAND]', 'show help' ],
 178
 179 # XXX do we need this?
 180 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 181
 182 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 183         'rewrite git history in an attempt to improve compression',
 184         'gc!' ],
 185
 186 # internal commands are prefixed with '_'
 187 '_complete' => [ '[...]', 'internal shell completion helper',
 188                 pass_through('everything') ],
 189 ); # @CMD
 190
 191 # switch descriptions, try to keep consistent across commands
 192 # $spec: Getopt::Long option specification
 193 # $spec => [@ALLOWED_VALUES (default is first), $description],
 194 # $spec => $description
 195 # "$SUB_COMMAND TAB $spec" => as above
 196 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 197                 'specify message input format' ];
 198 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 199
 200 my %OPTDESC = (
 201 'help|h' => 'show this built-in help',
 202 'quiet|q' => 'be quiet',
 203 'verbose|v' => 'be more verbose',
 204 'solve!' => 'do not attempt to reconstruct blobs from emails',
 205 'torsocks=s' => ['auto|no|yes',
 206                 'whether or not to wrap git and curl commands with torsocks'],
 207 'no-torsocks' => 'alias for --torsocks=no',
 208 'save-as=s' => ['NAME', 'save a search terms by given name'],
 209
 210 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 211
 212 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 213                 'deduplication strategy'],
 214 'show   thread|t' => 'display entire thread a message belongs to',
 215 'q      thread|t' =>
 216         'return all messages in the same thread as the actual match(es)',
 217 'augment|a' => 'augment --output destination instead of clobbering',
 218
 219 'output|mfolder|o=s' => [ 'DEST',
 220         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 221 'mua-cmd|mua=s' => [ 'COMMAND',
 222         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 223
 224 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 225                         'message/object output format' ],
 226 'mark   format|f=s' => $stdin_formats,
 227 'forget format|f=s' => $stdin_formats,
 228 'q      format|f=s' => [
 229         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 230                 'specify output format, default depends on --output'],
 231 'ls-query       format|f=s' => $ls_format,
 232 'ls-external    format|f=s' => $ls_format,
 233
 234 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 235 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 236
 237 'sort|s=s' => [ 'VAL|received,relevance,docid',
 238                 "order of results `--output'-dependent"],
 239 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 240
 241 'boost=i' => 'increase/decrease priority of results (default: 0)',
 242
 243 'local' => 'limit operations to the local filesystem',
 244 'local!' => 'exclude results from the local filesystem',
 245 'remote' => 'limit operations to those requiring network access',
 246 'remote!' => 'prevent operations requiring network access',
 247
 248 'mid=s' => 'specify the Message-ID of a message',
 249 'oid=s' => 'specify the git object ID of a message',
 250
 251 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 252 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 253 'include=s' => 'include mailboxes/newsgroups based on pattern',
 254
 255 'exact' => 'operate on exact header matches only',
 256 'exact!' => 'rely on content match instead of exact header matches',
 257
 258 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 259 'jobs:i' => 'set parallelism level',
 260
 261 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 262 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 263
 264 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 265 ); # %OPTDESC
 266
 267 my %CONFIG_KEYS = (
 268         'leistore.dir' => 'top-level storage location',
 269 );
 270
 271 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 272 sub x_it ($$) {
 273         my ($self, $code) = @_;
 274         # make sure client sees stdout before exit
 275         $self->{1}->autoflush(1) if $self->{1};
 276         dump_and_clear_log();
 277         if (my $sock = $self->{sock}) {
 278                 send($sock, "x_it $code", MSG_EOR);
 279         } elsif (my $signum = ($code & 127)) { # oneshot, usually SIGPIPE (13)
 280                 $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 281                 kill $signum, $$;
 282                 sleep; # wait for signal
 283         } else { # oneshot
 284                 # don't want to end up using $? from child processes
 285                 for my $f (qw(lxs l2m)) {
 286                         my $wq = delete $self->{$f} or next;
 287                         $wq->DESTROY;
 288                 }
 289                 $quit->($code >> 8);
 290         }
 291 }
 292
 293 sub err ($;@) {
 294         my $self = shift;
 295         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 296         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 297         print $err @_, $eor and return;
 298         my $old_err = delete $self->{2};
 299         close($old_err) if $! == EPIPE && $old_err;;
 300         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 301         print $err @_, $eor or print STDERR @_, $eor;
 302 }
 303
 304 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 305
 306 sub fail ($$;$) {
 307         my ($self, $buf, $exit_code) = @_;
 308         err($self, $buf);
 309         x_it($self, ($exit_code // 1) << 8);
 310         undef;
 311 }
 312
 313 sub out ($;@) {
 314         my $self = shift;
 315         return if print { $self->{1} // return } @_; # likely
 316         return note_sigpipe($self, 1) if $! == EPIPE;
 317         my $err = "error writing to stdout: $!";
 318         delete $self->{1};
 319         fail($self, $err);
 320 }
 321
 322 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 323
 324 sub child_error { # passes non-fatal curl exit codes to user
 325         my ($self, $child_error) = @_; # child_error is $?
 326         if (my $sock = $self->{sock}) { # send to lei(1) client
 327                 send($sock, "child_error $child_error", MSG_EOR);
 328         } else { # oneshot
 329                 $self->{child_error} = $child_error;
 330         }
 331         undef;
 332 }
 333
 334 sub atfork_prepare_wq {
 335         my ($self, $wq) = @_;
 336         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 337         if (my $sock = $self->{sock}) {
 338                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 339         }
 340         if (my $pgr = $self->{pgr}) {
 341                 push @$tcafc, @$pgr[1,2];
 342         }
 343         if (my $old_1 = $self->{old_1}) {
 344                 push @$tcafc, $old_1;
 345         }
 346         for my $f (qw(lxs l2m)) {
 347                 my $ipc = $self->{$f} or next;
 348                 push @$tcafc, grep { defined }
 349                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 350         }
 351 }
 352
 353 sub io_restore ($$) {
 354         my ($dst, $src) = @_;
 355         for my $i (0..2) { # standard FDs
 356                 my $io = delete $src->{$i} or next;
 357                 $dst->{$i} = $io;
 358         }
 359         for my $i (3..9) { # named (non-standard) FDs
 360                 my $io = $src->{$i} or next;
 361                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 362                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 363                 $dst->{$f} = $io;
 364                 delete $src->{$i};
 365         }
 366 }
 367
 368 # triggers sigpipe_handler
 369 sub note_sigpipe {
 370         my ($self, $fd) = @_;
 371         close(delete($self->{$fd})); # explicit close silences Perl warning
 372         syswrite($self->{op_pipe}, '!') if $self->{op_pipe};
 373         x_it($self, 13);
 374 }
 375
 376 sub atfork_child_wq {
 377         my ($self, $wq) = @_;
 378         io_restore($self, $wq);
 379         -p $self->{op_pipe} or die 'BUG: {op_pipe} expected';
 380         io_restore($self->{l2m}, $wq);
 381         %PATH2CFG = ();
 382         undef $errors_log;
 383         $quit = \&CORE::exit;
 384         $current_lei = $self; # for SIG{__WARN__}
 385 }
 386
 387 sub io_extract ($;@) {
 388         my ($obj, @fields) = @_;
 389         my @io;
 390         for my $f (@fields) {
 391                 my $io = delete $obj->{$f} or next;
 392                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 393                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 394                 push @io, $io;
 395         }
 396         @io
 397 }
 398
 399 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 400 sub atfork_parent_wq {
 401         my ($self, $wq) = @_;
 402         my $env = delete $self->{env}; # env is inherited at fork
 403         my $lei = bless { %$self }, ref($self);
 404         if (my $dedupe = delete $lei->{dedupe}) {
 405                 $lei->{dedupe} = $wq->deep_clone($dedupe);
 406         }
 407         $self->{env} = $env;
 408         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 409         my @io = (delete(@$lei{qw(0 1 2)}),
 410                         io_extract($lei, qw(sock op_pipe startq)));
 411         my $l2m = $lei->{l2m};
 412         if ($l2m && $l2m != $wq) { # $wq == lxs
 413                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 414                         push @io, io_extract($l2m, '-wq_s1');
 415                         $l2m->{-wq_s1} = $wq_s1;
 416                 }
 417                 $l2m->wq_close(1);
 418         }
 419         ($lei, @io);
 420 }
 421
 422 sub _help ($;$) {
 423         my ($self, $errmsg) = @_;
 424         my $cmd = $self->{cmd} // 'COMMAND';
 425         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 426         my @top = ($cmd, shift(@info) // ());
 427         my $cmd_desc = shift(@info);
 428         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 429         my @opt_desc;
 430         my $lpad = 2;
 431         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 432                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 433                 my $arg_vals = '';
 434                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 435
 436                 # lower-case is a keyword (e.g. `content', `oid'),
 437                 # ALL_CAPS is a string description (e.g. `PATH')
 438                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 439                         $desc .= "\ndefault: `$1'";
 440                 }
 441                 my (@vals, @s, @l);
 442                 my $x = $sw;
 443                 if ($x =~ s/!\z//) { # solve! => --no-solve
 444                         $x = "no-$x";
 445                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 446                         @vals = (' [', undef, ']');
 447                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 448                         @vals = (' ', undef);
 449                 } # else: no args $x = 'thread|t'
 450                 for (split(/\|/, $x)) { # help|h
 451                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 452                 }
 453                 if (!scalar(@vals)) { # no args 'thread|t'
 454                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 455                         $vals[1] = $1;
 456                 } else {
 457                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 458                 }
 459                 if ($arg_vals =~ /([,\|])/) {
 460                         my $sep = $1;
 461                         my @allow = split(/\Q$sep\E/, $arg_vals);
 462                         my $must = $sep eq '|' ? 'Must' : 'Can';
 463                         @allow = map { "`$_'" } @allow;
 464                         my $last = pop @allow;
 465                         $desc .= "\n$must be one of: " .
 466                                 join(', ', @allow) . " or $last";
 467                 }
 468                 my $lhs = join(', ', @s, @l) . join('', @vals);
 469                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 470                         $lhs =~ s/\A--/- , --/;
 471                 } else {
 472                         $lhs =~ s/\A--/    --/; # pad if no short options
 473                 }
 474                 $lpad = length($lhs) if length($lhs) > $lpad;
 475                 push @opt_desc, $lhs, $desc;
 476         }
 477         my $msg = $errmsg ? "E: $errmsg\n" : '';
 478         $msg .= <<EOF;
 479 usage: lei @top
 480   $cmd_desc
 481
 482 EOF
 483         $lpad += 2;
 484         local $Text::Wrap::columns = 78 - $lpad;
 485         my $padding = ' ' x ($lpad + 2);
 486         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 487                 $msg .= '  '.pack("A$lpad", $lhs);
 488                 $rhs = wrap('', '', $rhs);
 489                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 490                 $msg .= $rhs;
 491                 $msg .= "\n";
 492         }
 493         print { $self->{$errmsg ? 2 : 1} } $msg;
 494         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 495         undef;
 496 }
 497
 498 sub optparse ($$$) {
 499         my ($self, $cmd, $argv) = @_;
 500         $self->{cmd} = $cmd;
 501         $OPT = $self->{opt} = {};
 502         my $info = $CMD{$cmd} // [ '[...]' ];
 503         my ($proto, undef, @spec) = @$info;
 504         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 505         push @spec, qw(help|h);
 506         my $lone_dash;
 507         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 508                 $lone_dash = $spec[0];
 509                 $OPT->{$spec[0]} = \(my $var);
 510                 push @spec, '' => \$var;
 511         }
 512         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 513                 return _help($self, "bad arguments or options for $cmd");
 514         return _help($self) if $OPT->{help};
 515
 516         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 517
 518         # "-" aliases "stdin" or "clear"
 519         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 520
 521         my $i = 0;
 522         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 523         my ($err, $inf);
 524         my @args = split(/ /, $proto);
 525         for my $var (@args) {
 526                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 527                         $inf = defined($argv->[$i]) and last;
 528                         $var =~ s/\.\.\.\z//;
 529                         $err = "$var not supplied";
 530                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 531                         $argv->[$i++] // ($err = "$var not supplied");
 532                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 533                         $inf = 1;
 534                         last;
 535                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 536                         $i++;
 537                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 538                         my @or = split(/\|/, $var);
 539                         my $ok;
 540                         for my $o (@or) {
 541                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 542                                         $ok = defined($OPT->{$1});
 543                                         last;
 544                                 } elsif (defined($argv->[$i])) {
 545                                         $ok = 1;
 546                                         $i++;
 547                                         last;
 548                                 } # else continue looping
 549                         }
 550                         last if $ok;
 551                         my $last = pop @or;
 552                         $err = join(', ', @or) . " or $last must be set";
 553                 } else {
 554                         warn "BUG: can't parse `$var' in $proto";
 555                 }
 556                 last if $err;
 557         }
 558         if (!$inf && scalar(@$argv) > scalar(@args)) {
 559                 $err //= 'too many arguments';
 560         }
 561         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 562 }
 563
 564 sub dispatch {
 565         my ($self, $cmd, @argv) = @_;
 566         local $current_lei = $self; # for __WARN__
 567         dump_and_clear_log("from previous run\n");
 568         return _help($self, 'no command given') unless defined($cmd);
 569         my $func = "lei_$cmd";
 570         $func =~ tr/-/_/;
 571         if (my $cb = __PACKAGE__->can($func)) {
 572                 optparse($self, $cmd, \@argv) or return;
 573                 $cb->($self, @argv);
 574         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 575                 my $opt = {};
 576                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 577                         return _help($self, 'bad arguments or options');
 578                 _help($self);
 579         } else {
 580                 fail($self, "`$cmd' is not an lei command");
 581         }
 582 }
 583
 584 sub _lei_cfg ($;$) {
 585         my ($self, $creat) = @_;
 586         my $f = _config_path($self);
 587         my @st = stat($f);
 588         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 589         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 590                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 591         }
 592         if (!@st) {
 593                 unless ($creat) {
 594                         delete $self->{cfg};
 595                         return;
 596                 }
 597                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 598                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 599                 open my $fh, '>>', $f or die "open($f): $!\n";
 600                 @st = stat($fh) or die "fstat($f): $!\n";
 601                 $cur_st = pack('dd', $st[10], $st[7]);
 602                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 603         }
 604         my $cfg = PublicInbox::Config::git_config_dump($f);
 605         $cfg->{-st} = $cur_st;
 606         $cfg->{'-f'} = $f;
 607         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 608 }
 609
 610 sub _lei_store ($;$) {
 611         my ($self, $creat) = @_;
 612         my $cfg = _lei_cfg($self, $creat);
 613         $cfg->{-lei_store} //= do {
 614                 require PublicInbox::LeiStore;
 615                 my $dir = $cfg->{'leistore.dir'};
 616                 $dir //= $creat ? _store_path($self) : return;
 617                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 618         };
 619 }
 620
 621 sub lei_show {
 622         my ($self, @argv) = @_;
 623 }
 624
 625 sub lei_mark {
 626         my ($self, @argv) = @_;
 627 }
 628
 629 sub _config {
 630         my ($self, @argv) = @_;
 631         my $env = $self->{env};
 632         delete local $env->{GIT_CONFIG};
 633         delete local $ENV{GIT_CONFIG};
 634         my $cfg = _lei_cfg($self, 1);
 635         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 636         my %rdr = map { $_ => $self->{$_} } (0..2);
 637         waitpid(spawn($cmd, $env, \%rdr), 0);
 638 }
 639
 640 sub lei_config {
 641         my ($self, @argv) = @_;
 642         $self->{opt}->{'config-file'} and return fail $self,
 643                 "config file switches not supported by `lei config'";
 644         _config(@_);
 645         x_it($self, $?) if $?;
 646 }
 647
 648 sub lei_init {
 649         my ($self, $dir) = @_;
 650         my $cfg = _lei_cfg($self, 1);
 651         my $cur = $cfg->{'leistore.dir'};
 652         $dir //= _store_path($self);
 653         $dir = rel2abs($self, $dir);
 654         my @cur = stat($cur) if defined($cur);
 655         $cur = File::Spec->canonpath($cur // $dir);
 656         my @dir = stat($dir);
 657         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 658         if (@cur) {
 659                 if ($cur eq $dir) {
 660                         _lei_store($self, 1)->done;
 661                         return qerr($self, $exists);
 662                 }
 663
 664                 # some folks like symlinks and bind mounts :P
 665                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 666                         lei_config($self, 'leistore.dir', $dir);
 667                         _lei_store($self, 1)->done;
 668                         return qerr($self, "$exists (as $cur)");
 669                 }
 670                 return fail($self, <<"");
 671 E: leistore.dir=$cur already initialized and it is not $dir
 672
 673         }
 674         lei_config($self, 'leistore.dir', $dir);
 675         _lei_store($self, 1)->done;
 676         $exists //= "I: leistore.dir=$dir newly initialized";
 677         return qerr($self, $exists);
 678 }
 679
 680 sub lei_daemon_pid { puts shift, $$ }
 681
 682 sub lei_daemon_kill {
 683         my ($self) = @_;
 684         my $sig = $self->{opt}->{signal} // 'TERM';
 685         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 686 }
 687
 688 sub lei_help { _help($_[0]) }
 689
 690 # Shell completion helper.  Used by lei-completion.bash and hopefully
 691 # other shells.  Try to do as much here as possible to avoid redundancy
 692 # and improve maintainability.
 693 sub lei__complete {
 694         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 695         shift @argv; # ignore "lei", the entire command is sent
 696         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 697         my $cmd = shift @argv;
 698         my $info = $CMD{$cmd} // do { # filter matching commands
 699                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 700                 return;
 701         };
 702         my ($proto, undef, @spec) = @$info;
 703         my $cur = pop @argv;
 704         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 705         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 706                 # gross special case since the only git-config options
 707                 # Consider moving to a table if we need more special cases
 708                 # we use Getopt::Long for are the ones we reject, so these
 709                 # are the ones we don't reject:
 710                 if ($cmd eq 'config') {
 711                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 712                         @spec = qw(add z|null get get-all unset unset-all
 713                                 replace-all get-urlmatch
 714                                 remove-section rename-section
 715                                 name-only list|l edit|e
 716                                 get-color-name get-colorbool);
 717                         # fall-through
 718                 }
 719                 puts $self, grep(/$re/, map { # generate short/long names
 720                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 721                         } else { # negation: solve! => no-solve|solve
 722                                 s/\A(.+)!\z/no-$1|$1/;
 723                         }
 724                         map {
 725                                 my $x = length > 1 ? "--$_" : "-$_";
 726                                 $x eq $cur ? () : $x;
 727                         } split(/\|/, $_, -1) # help|h
 728                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 729         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 730                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 731         }
 732
 733         # switch args (e.g. lei q -f mbox<TAB>)
 734         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 735                 my $opt = quotemeta $1;
 736                 puts $self, map {
 737                         my $v = $OPTDESC{$_};
 738                         $v = $v->[0] if ref($v);
 739                         my @v = split(/\|/, $v);
 740                         # get rid of ALL CAPS placeholder (e.g "OUT")
 741                         # (TODO: completion for external paths)
 742                         shift(@v) if uc($v[0]) eq $v[0];
 743                         @v;
 744                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 745         }
 746         $cmd =~ tr/-/_/;
 747         if (my $sub = $self->can("_complete_$cmd")) {
 748                 puts $self, $sub->($self, @argv, $cur);
 749         }
 750         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 751         # proto parsing.
 752 }
 753
 754 sub exec_buf ($$) {
 755         my ($argv, $env) = @_;
 756         my $argc = scalar @$argv;
 757         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 758         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 759         $buf;
 760 }
 761
 762 sub start_mua {
 763         my ($self) = @_;
 764         my $mua = $self->{opt}->{'mua-cmd'} // return;
 765         my $mfolder = $self->{ovv}->{dst};
 766         my (@cmd, $replaced);
 767         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 768                 @cmd = ($mua, '-f');
 769         # TODO: help wanted: other common FOSS MUAs
 770         } else {
 771                 require Text::ParseWords;
 772                 my @cmd = Text::ParseWords::shellwords($mua);
 773                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 774                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 775         }
 776         push @cmd, $mfolder unless defined($replaced);
 777         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 778                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 779         } else { # oneshot
 780                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 781         }
 782 }
 783
 784 # caller needs to "-t $self->{1}" to check if tty
 785 sub start_pager {
 786         my ($self) = @_;
 787         my $env = $self->{env};
 788         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 789         chomp(my $pager = <$fh> // '');
 790         close($fh) or warn "`git var PAGER' error: \$?=$?";
 791         return if $pager eq 'cat' || $pager eq '';
 792         # TODO TIOCGWINSZ
 793         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 794         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 795         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 796         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 797         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 798         if (my $sock = $self->{sock}) { # lei(1) process runs it
 799                 delete @$new_env{keys %$env}; # only set iff unset
 800                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 801                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 802         } else {
 803                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 804         }
 805         $self->{1} = $wpager;
 806         $self->{2} = $wpager if -t $self->{2};
 807         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 808         $self->{pgr} = $pgr;
 809 }
 810
 811 sub stop_pager {
 812         my ($self) = @_;
 813         my $pgr = delete($self->{pgr}) or return;
 814         $self->{2} = $pgr->[2];
 815         # do not restore original stdout, just close it so we error out
 816         close(delete($self->{1})) if $self->{1};
 817         my $pid = $pgr->[0];
 818         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 819 }
 820
 821 sub accept_dispatch { # Listener {post_accept} callback
 822         my ($sock) = @_; # ignore other
 823         $sock->autoflush(1);
 824         my $self = bless { sock => $sock }, __PACKAGE__;
 825         vec(my $rvec = '', fileno($sock), 1) = 1;
 826         select($rvec, undef, undef, 1) or
 827                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 828         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 829         if (scalar(@fds) == 4) {
 830                 for my $i (0..3) {
 831                         my $fd = shift(@fds);
 832                         open($self->{$i}, '+<&=', $fd) and next;
 833                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 834                 }
 835         } else {
 836                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 837         }
 838         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 839         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 840         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 841         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 842                 return send($sock, 'request command truncated', MSG_EOR);
 843         my ($argc, @argv) = split(/\0/, $buf, -1);
 844         undef $buf;
 845         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 846         if (chdir($self->{3})) {
 847                 local %ENV = %env;
 848                 $self->{env} = \%env;
 849                 eval { dispatch($self, @argv) };
 850                 send($sock, $@, MSG_EOR) if $@;
 851         } else {
 852                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 853         }
 854 }
 855
 856 sub dclose {
 857         my ($self) = @_;
 858         for my $f (qw(lxs l2m)) {
 859                 my $wq = delete $self->{$f} or next;
 860                 if ($wq->wq_kill) {
 861                         $wq->wq_close
 862                 } elsif ($wq->wq_kill_old) {
 863                         $wq->wq_wait_old($self);
 864                 }
 865         }
 866         close(delete $self->{1}) if $self->{1}; # may reap_compress
 867         $self->close if $self->{sock}; # PublicInbox::DS::close
 868 }
 869
 870 # for long-running results
 871 sub event_step {
 872         my ($self) = @_;
 873         local %ENV = %{$self->{env}};
 874         my $sock = $self->{sock};
 875         local $current_lei = $self;
 876         eval {
 877                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 878                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 879                                 return if $! == EAGAIN;
 880                                 next if $! == EINTR;
 881                                 last if $! == ECONNRESET;
 882                                 die "recvmsg: $!";
 883                         }
 884                         for my $fd (@fds) {
 885                                 open my $rfh, '+<&=', $fd;
 886                         }
 887                         die "unrecognized client signal: $buf";
 888                 }
 889                 dclose($self);
 890         };
 891         if (my $err = $@) {
 892                 eval { $self->fail($err) };
 893                 dclose($self);
 894         }
 895 }
 896
 897 sub event_step_init {
 898         my ($self) = @_;
 899         if (my $sock = $self->{sock}) { # using DS->EventLoop
 900                 $sock->blocking(0);
 901                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 902         }
 903 }
 904
 905 sub noop {}
 906
 907 our $oldset; sub oldset { $oldset }
 908
 909 sub dump_and_clear_log {
 910         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 911                 my @pfx = @_;
 912                 unshift(@pfx, "$errors_log ") if @pfx;
 913                 warn @pfx, do { local $/; <STDIN> };
 914                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 915         }
 916 }
 917
 918 # lei(1) calls this when it can't connect
 919 sub lazy_start {
 920         my ($path, $errno, $narg) = @_;
 921         if ($errno == ECONNREFUSED) {
 922                 unlink($path) or die "unlink($path): $!";
 923         } elsif ($errno != ENOENT) {
 924                 $! = $errno; # allow interpolation to stringify in die
 925                 die "connect($path): $!";
 926         }
 927         if (eval { require BSD::Resource }) {
 928                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 929                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 930                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 931         }
 932         umask(077) // die("umask(077): $!");
 933         local $listener;
 934         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 935         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 936         listen($listener, 1024) or die "listen: $!";
 937         my @st = stat($path) or die "stat($path): $!";
 938         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 939         local $oldset = PublicInbox::DS::block_signals();
 940         if ($narg == 5) {
 941                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 942                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 943                         require PublicInbox::CmdIPC4;
 944                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 945                         PublicInbox::CmdIPC4->can('recv_cmd4');
 946                 };
 947         }
 948         $recv_cmd or die <<"";
 949 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 950
 951         require PublicInbox::Listener;
 952         require PublicInbox::EOFpipe;
 953         (-p STDOUT) or die "E: stdout must be a pipe\n";
 954         local $errors_log;
 955         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 956         $errors_log .= 'errors.log';
 957         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 958         STDIN->autoflush(1);
 959         dump_and_clear_log("from previous daemon process:\n");
 960         POSIX::setsid() > 0 or die "setsid: $!";
 961         my $pid = fork // die "fork: $!";
 962         return if $pid;
 963         $0 = "lei-daemon $path";
 964         local %PATH2CFG;
 965         $listener->blocking(0);
 966         my $exit_code;
 967         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 968         local $quit = do {
 969                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 970                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 971                 sub {
 972                         $exit_code //= shift;
 973                         my $lis = $pil or exit($exit_code);
 974                         # closing eof_w triggers \&noop wakeup
 975                         $listener = $eof_w = $pil = $path = undef;
 976                         $lis->close; # DS::close
 977                         PublicInbox::DS->SetLoopTimeout(1000);
 978                 };
 979         };
 980         my $sig = {
 981                 CHLD => \&PublicInbox::DS::enqueue_reap,
 982                 QUIT => $quit,
 983                 INT => $quit,
 984                 TERM => $quit,
 985                 HUP => \&noop,
 986                 USR1 => \&noop,
 987                 USR2 => \&noop,
 988         };
 989         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 990         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 991         undef $sig;
 992         local $SIG{PIPE} = 'IGNORE';
 993         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 994                 undef $sigfd;
 995                 PublicInbox::DS->SetLoopTimeout(5000);
 996         } else {
 997                 # wake up every second to accept signals if we don't
 998                 # have signalfd or IO::KQueue:
 999                 PublicInbox::DS::sig_setmask($oldset);
1000                 PublicInbox::DS->SetLoopTimeout(1000);
1001         }
1002         PublicInbox::DS->SetPostLoopCallback(sub {
1003                 my ($dmap, undef) = @_;
1004                 if (@st = defined($path) ? stat($path) : ()) {
1005                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1006                                 warn "$path dev/ino changed, quitting\n";
1007                                 $path = undef;
1008                         }
1009                 } elsif (defined($path)) { # ENOENT is common
1010                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1011                         undef $path;
1012                         $quit->();
1013                 }
1014                 return 1 if defined($path);
1015                 my $now = now();
1016                 my $n = 0;
1017                 for my $s (values %$dmap) {
1018                         $s->can('busy') or next;
1019                         if ($s->busy($now)) {
1020                                 ++$n;
1021                         } else {
1022                                 $s->close;
1023                         }
1024                 }
1025                 $n; # true: continue, false: stop
1026         });
1027
1028         # STDIN was redirected to /dev/null above, closing STDERR and
1029         # STDOUT will cause the calling `lei' client process to finish
1030         # reading the <$daemon> pipe.
1031         local $SIG{__WARN__} = sub {
1032                 $current_lei ? err($current_lei, @_) : warn(
1033                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1034         };
1035         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1036         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1037         # $daemon pipe to `lei' closed, main loop begins:
1038         PublicInbox::DS->EventLoop;
1039         exit($exit_code // 0);
1040 }
1041
1042 # for users w/o Socket::Msghdr installed or Inline::C enabled
1043 sub oneshot {
1044         my ($main_pkg) = @_;
1045         my $exit = $main_pkg->can('exit'); # caller may override exit()
1046         local $quit = $exit if $exit;
1047         local %PATH2CFG;
1048         umask(077) // die("umask(077): $!");
1049         my $self = bless {
1050                 0 => *STDIN{GLOB},
1051                 1 => *STDOUT{GLOB},
1052                 2 => *STDERR{GLOB},
1053                 env => \%ENV
1054         }, __PACKAGE__;
1055         dispatch($self, @ARGV);
1056         x_it($self, $self->{child_error}) if $self->{child_error};
1057 }
1058
1059 # ensures stdout hits the FS before sock disconnects so a client
1060 # can immediately reread it
1061 sub DESTROY {
1062         my ($self) = @_;
1063         $self->{1}->autoflush(1) if $self->{1};
1064         stop_pager($self);
1065         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1066                 waitpid($mua_pid, 0);
1067         }
1068 }
1069
1070 1;