lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  32         $recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  40 our %LIVE_SOCK; # "GLOB(0x....)" => $lei->{sock}
  41
  42 # TBD: this is a documentation mechanism to show a subcommand
  43 # (may) pass options through to another command:
  44 sub pass_through { $GLP_PASS }
  45
  46 my $OPT;
  47 sub opt_dash ($$) {
  48         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  49         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  50         my $cb = sub { # Getopt::Long "<>" catch-all handler
  51                 my ($arg) = @_;
  52                 if ($arg =~ /\A-($re_str)\z/) {
  53                         $OPT->{$key} = $1;
  54                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  55                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  56                 # lone (single) dash is handled elsewhere
  57                 } elsif (substr($arg, 0, 1) eq '-') {
  58                         if ($OPT->{'--'}) {
  59                                 push @{$OPT->{-argv}}, $arg;
  60                         } else {
  61                                 die "bad argument: $arg\n";
  62                         }
  63                 } else {
  64                         push @{$OPT->{-argv}}, $arg;
  65                 }
  66         };
  67         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  68 }
  69
  70 # rel2abs preserves symlinks in parent, unlike abs_path
  71 sub rel2abs {
  72         my ($self, $p) = @_;
  73         if (index($p, '/') == 0) { # already absolute
  74                 $p =~ tr!/!/!s; # squeeze redundant slashes
  75                 chop($p) if substr($p, -1, 1) eq '/';
  76                 return $p;
  77         }
  78         my $pwd = $self->{env}->{PWD};
  79         my $cwd;
  80         if (defined $pwd) {
  81                 my $xcwd = $self->{3} //
  82                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  83                 if (my @st_pwd = stat($pwd)) {
  84                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  85                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  86                                 $self->{env}->{PWD} = $pwd = undef;
  87                 } else { # PWD was invalid
  88                         $self->{env}->{PWD} = $pwd = undef;
  89                 }
  90         }
  91         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  92         File::Spec->rel2abs($p, $pwd);
  93 }
  94
  95 # abs_path resolves symlinks in parent iff all parents exist
  96 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  97
  98 sub canonpath_harder {
  99         my $p = $_[-1]; # $_[0] may be self
 100         $p = File::Spec->canonpath($p);
 101         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 102 }
 103
 104 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 108                 .'/lei');
 109 }
 110
 111 sub store_path ($) { share_path($_[0]) . '/store' }
 112
 113 sub _config_path ($) {
 114         my ($self) = @_;
 115         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 116                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 117                 .'/lei/config');
 118 }
 119
 120 sub cache_dir ($) {
 121         my ($self) = @_;
 122         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 123                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 124                 .'/lei');
 125 }
 126
 127 sub url_folder_cache {
 128         my ($self) = @_;
 129         require PublicInbox::SharedKV; # URI => updated_at_sec_
 130         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 131 }
 132
 133 sub ale {
 134         my ($self) = @_;
 135         $self->{ale} //= do {
 136                 require PublicInbox::LeiALE;
 137                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 138         };
 139 }
 140
 141 sub index_opt {
 142         # TODO: drop underscore variants everywhere, they're undocumented
 143         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 144         max_size|max-size=s sequential-shard
 145         batch_size|batch-size=s skip-docdata)
 146 }
 147
 148 my @c_opt = qw(c=s@ C=s@ quiet|q);
 149 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 150         import-remote! no-torsocks torsocks=s),
 151         PublicInbox::LeiQuery::curl_opt());
 152
 153 # we don't support -C as an alias for --find-copies since it's already
 154 # used for chdir
 155 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 156         output-indicator-context=s indent-heuristic!
 157         minimal patience histogram anchored=s@ diff-algorithm=s
 158         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 159         word-diff:s word-diff-regex=s color-words:s no-renames
 160         rename-empty! check ws-error-highlight=s full-index binary
 161         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 162         find-copies-harder irreversible-delete|D l=i diff-filter=s
 163         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 164         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 165         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 166         inter-hunk-context=i function-context|W exit-code ext-diff
 167         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 168         line-prefix=s);
 169
 170 # we generate shell completion + help using %CMD and %OPTDESC,
 171 # see lei__complete() and PublicInbox::LeiHelp
 172 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 173 our %CMD = ( # sorted in order of importance/use:
 174 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 175         'stdin|', # /|\z/ must be first for lone dash
 176         @lxs_opt,
 177         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 178         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 179         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 180         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 181
 182 'up' => [ 'OUTPUT...|--all', 'update saved search',
 183         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 184
 185 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 186         'stdin|', # /|\z/ must be first for lone dash
 187         # some of these options are ridiculous for lcat
 188         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 189         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 190         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 191         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 192
 193 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 194         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 195         @lxs_opt, @c_opt ],
 196
 197 'rediff' => [ '--stdin|LOCATION...',
 198                 'regenerate a diff with different options',
 199         'stdin|', # /|\z/ must be first for lone dash
 200         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 201         @diff_opt, @lxs_opt, @c_opt ],
 202
 203 'add-external' => [ 'LOCATION',
 204         'add/set priority of a publicinbox|extindex for extra matches',
 205         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 206         verbose|v+), @c_opt, index_opt(),
 207         PublicInbox::LeiQuery::curl_opt() ],
 208 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 209         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 210 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 211 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 212                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 213 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 214                 qw(z|0 ascii l url), @c_opt ],
 215 'forget-external' => [ 'LOCATION...|--prune',
 216         'exclude further results from a publicinbox|extindex',
 217         qw(prune), @c_opt ],
 218
 219 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 220                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 221 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 222                 qw(verbose|v+), @c_opt ],
 223 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 224                         @c_opt ],
 225 'rm' => [ '--stdin|LOCATION...',
 226         'remove a message from the index and prevent reindexing',
 227         'stdin|', # /|\z/ must be first for lone dash
 228         @c_opt ],
 229 'plonk' => [ '--threads|--from=IDENT',
 230         'exclude mail matching From: or threads from non-Message-ID searches',
 231         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 232 'tag' => [ 'KEYWORDS...',
 233         'set/unset keywords and/or labels on message(s)',
 234         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 235         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 236         pass_through('-kw:foo for delete') ],
 237
 238 'purge-mailsource' => [ 'LOCATION|--all',
 239         'remove imported messages from IMAP, Maildirs, and MH',
 240         qw(exact! all jobs:i indexed), @c_opt ],
 241
 242 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 243         qw(poll-interval=s state=s recursive|r), @c_opt ],
 244 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 245         qw(recursive|r), @c_opt ],
 246 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 247                 qw(l z|0), @c_opt ],
 248 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 249 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 250 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 251         qw(prune), @c_opt ],
 252
 253 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 254         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 255         verbose|v+ incremental!),
 256          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 257          @c_opt ],
 258 'import' => [ 'LOCATION...|--stdin',
 259         'one-time import/update from URL or filesystem',
 260         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 261         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 262         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 263 'forget-mail-sync' => [ 'LOCATION...',
 264         'forget sync information for a mail folder', @c_opt ],
 265 'prune-mail-sync' => [ 'LOCATION...|--all',
 266         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 267 'export-kw' => [ 'LOCATION...|--all',
 268         'one-time export of keywords of sync sources',
 269         qw(all:s mode=s), @c_opt ],
 270 'convert' => [ 'LOCATION...|--stdin',
 271         'one-time conversion from URL or filesystem to another format',
 272         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 273         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 274 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 275         "use a patch to generate a query for `lei q --stdin'",
 276         qw(stdin| want|w=s@ uri debug), @c_opt ],
 277 'config' => [ '[...]', sub {
 278                 'git-config(1) wrapper for '._config_path($_[0]);
 279         }, qw(config-file|system|global|file|f=s), # for conflict detection
 280          qw(c=s@ C=s@), pass_through('git config') ],
 281 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 282         qw(pretty ascii dir=s), @c_opt ],
 283
 284 'init' => [ '[DIRNAME]', sub {
 285         "initialize storage, default: ".store_path($_[0]);
 286         }, @c_opt ],
 287 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 288         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 289         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 290 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 291 'help' => [ '[SUBCOMMAND]', 'show help' ],
 292
 293 # TODO
 294 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 295 #       'rewrite git history in an attempt to improve compression',
 296 #       qw(gc!), @c_opt ],
 297 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 298 #
 299 # internal commands are prefixed with '_'
 300 '_complete' => [ '[...]', 'internal shell completion helper',
 301                 pass_through('everything') ],
 302 ); # @CMD
 303
 304 # switch descriptions, try to keep consistent across commands
 305 # $spec: Getopt::Long option specification
 306 # $spec => [@ALLOWED_VALUES (default is first), $description],
 307 # $spec => $description
 308 # "$SUB_COMMAND TAB $spec" => as above
 309 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 310                         'specify message input format' ];
 311 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 312
 313 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 314 my %OPTDESC = (
 315 'help|h' => 'show this built-in help',
 316 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 317 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 318 'quiet|q' => 'be quiet',
 319 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 320         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 321
 322 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 323 'globoff|g' => "do not match locations using '*?' wildcards ".
 324                 "and\xa0'[]'\x{a0}ranges",
 325 'invert-match|v' => 'select non-matching lines',
 326 'color!' => 'disable color (for --format=text)',
 327 'verbose|v+' => 'be more verbose',
 328 'external!' => 'do not use externals',
 329 'mail!' => 'do not look in mail storage for OID',
 330 'cwd!' => 'do not look in git repo of current working directory',
 331 'oid-a|A=s' => 'pre-image OID',
 332 'path-a|a=s' => 'pre-image pathname associated with OID',
 333 'path-b|b=s' => 'post-image pathname associated with OID',
 334 'git-dir=s@' => 'additional git repository to scan',
 335 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 336 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 337         "proxy for (e.g. `socks5h://0:9050')" ],
 338 'torsocks=s' => ['VAL|auto|no|yes',
 339                 'whether or not to wrap git and curl commands with torsocks'],
 340 'no-torsocks' => 'alias for --torsocks=no',
 341 'save!' =>  "do not save a search for `lei up'",
 342 'import-remote!' => 'do not memoize remote messages into local store',
 343
 344 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 345
 346 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 347                 'deduplication strategy'],
 348 'threads|t+' =>
 349         'return all messages in the same threads as the actual match(es)',
 350
 351 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 352                 'search prefixes to extract (default: dfpost7)' ],
 353
 354 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 355         'run command(s) or perform ops when done writing to output ' .
 356         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 357         'nothing otherwise)' ],
 358
 359 'augment|a' => 'augment --output destination instead of clobbering',
 360
 361 'output|mfolder|o=s' => [ 'MFOLDER',
 362         "destination (e.g.\xa0`/path/to/Maildir', ".
 363         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 364 'mua=s' => [ 'CMD',
 365         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 366 'new-only       import' => 'only import new messages from IMAP source',
 367
 368 'inbox-version=i' => [ 'NUM|1|2',
 369                 'force a public-inbox version with --mirror'],
 370 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 371
 372 # public-inbox-index options
 373 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 374 'compact' => 'run compact index after mirroring',
 375 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 376         "indexlevel with --mirror (default: full)" ],
 377 'max_size|max-size=s' => [ 'SIZE',
 378         'do not index messages larger than SIZE (default: infinity)' ],
 379 'batch_size|batch-size=s' => [ 'SIZE',
 380         'flush changes to OS after given number of bytes (default: 1m)' ],
 381 'sequential-shard' =>
 382         'index Xapian shards sequentially for slow storage',
 383 'skip-docdata' =>
 384         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 385
 386 'format|f=s     q' => [
 387         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 388                 'specify output format, default depends on --output'],
 389 'exclude=s@     q' => [ 'LOCATION',
 390                 'exclude specified external(s) from search' ],
 391 'include|I=s@   q' => [ 'LOCATION',
 392                 'include specified external(s) in search' ],
 393 'only=s@        q' => [ 'LOCATION',
 394                 'only use specified external(s) for search' ],
 395 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 396                 'control number of search and writer jobs' ],
 397 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 398
 399 'in-format|F=s' => $stdin_formats,
 400 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 401                         'listing output format' ],
 402 'l      ls-search' => 'long listing format',
 403 'l      ls-watch' => 'long listing format',
 404 'l      ls-mail-source' => 'long listing format',
 405 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 406 'format|f=s     ls-external' => $ls_format,
 407
 408 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 409 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 410
 411 'sort|s=s' => [ 'VAL|received|relevance|docid',
 412                 "order of results is `--output'-dependent"],
 413 'reverse|r' => 'reverse search results', # like sort(1)
 414
 415 'boost=i' => 'increase/decrease priority of results (default: 0)',
 416
 417 'local' => 'limit operations to the local filesystem',
 418 'local!' => 'exclude results from the local filesystem',
 419 'remote' => 'limit operations to those requiring network access',
 420 'remote!' => 'prevent operations requiring network access',
 421
 422 'all:s  up' => ['local', 'update all (local) saved searches' ],
 423
 424 'mid=s' => 'specify the Message-ID of a message',
 425 'oid=s' => 'specify the git object ID of a message',
 426
 427 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 428 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 429 'include=s' => 'include mailboxes/newsgroups based on pattern',
 430
 431 'exact' => 'operate on exact header matches only',
 432 'exact!' => 'rely on content match instead of exact header matches',
 433
 434 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 435
 436 'kw!' => 'disable/enable importing keywords (aka "flags")',
 437
 438 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 439 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 440
 441 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 442 ); # %OPTDESC
 443
 444 my %CONFIG_KEYS = (
 445         'leistore.dir' => 'top-level storage location',
 446 );
 447
 448 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 449
 450 sub _drop_wq {
 451         my ($self) = @_;
 452         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 453                 if ($wq->wq_kill) {
 454                         $wq->wq_close(0, undef, $self);
 455                 } elsif ($wq->wq_kill_old) {
 456                         $wq->wq_wait_old(undef, $self);
 457                 }
 458                 $wq->DESTROY;
 459         }
 460 }
 461
 462 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 463 sub x_it ($$) {
 464         my ($self, $code) = @_;
 465         # make sure client sees stdout before exit
 466         $self->{1}->autoflush(1) if $self->{1};
 467         dump_and_clear_log();
 468         stop_pager($self);
 469         if ($self->{pkt_op_p}) { # to top lei-daemon
 470                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 471         } elsif ($self->{sock}) { # to lei(1) client
 472                 send($self->{sock}, "x_it $code", MSG_EOR);
 473         } # else ignore if client disconnected
 474 }
 475
 476 sub err ($;@) {
 477         my $self = shift;
 478         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 479         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 480         print $err @_, @eor and return;
 481         my $old_err = delete $self->{2};
 482         close($old_err) if $! == EPIPE && $old_err;
 483         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 484         print $err @_, @eor or print STDERR @_, @eor;
 485 }
 486
 487 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 488
 489 sub fail_handler ($;$$) {
 490         my ($lei, $code, $io) = @_;
 491         close($io) if $io; # needed to avoid warnings on SIGPIPE
 492         _drop_wq($lei);
 493         x_it($lei, $code // (1 << 8));
 494 }
 495
 496 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 497         fail_handler($_[0], 13, delete $_[0]->{1});
 498 }
 499
 500 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 501 sub sigint_reap {
 502         my ($pgid) = @_;
 503         dwaitpid($pgid) if kill('-INT', $pgid);
 504 }
 505
 506 sub fail ($$;$) {
 507         my ($self, $buf, $exit_code) = @_;
 508         $self->{failed}++;
 509         err($self, $buf) if defined $buf;
 510         # calls fail_handler:
 511         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 512         x_it($self, ($exit_code // 1) << 8);
 513         undef;
 514 }
 515
 516 sub out ($;@) {
 517         my $self = shift;
 518         return if print { $self->{1} // return } @_; # likely
 519         return note_sigpipe($self, 1) if $! == EPIPE;
 520         my $err = "error writing to output: $!";
 521         delete $self->{1};
 522         fail($self, $err);
 523 }
 524
 525 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 526
 527 sub child_error { # passes non-fatal curl exit codes to user
 528         my ($self, $child_error, $msg) = @_; # child_error is $?
 529         $self->err($msg) if $msg;
 530         if ($self->{pkt_op_p}) { # to top lei-daemon
 531                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 532         } elsif ($self->{sock}) { # to lei(1) client
 533                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 534         } # else noop if client disconnected
 535 }
 536
 537 sub note_sigpipe { # triggers sigpipe_handler
 538         my ($self, $fd) = @_;
 539         close(delete($self->{$fd})); # explicit close silences Perl warning
 540         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 541         x_it($self, 13);
 542 }
 543
 544 sub _lei_atfork_child {
 545         my ($self, $persist) = @_;
 546         # we need to explicitly close things which are on stack
 547         if ($persist) {
 548                 chdir '/' or die "chdir(/): $!";
 549                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 550                 if (my $cfg = $self->{cfg}) {
 551                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 552                 }
 553         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 554                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 555                 STDERR->autoflush(1);
 556         }
 557         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 558         if (my $op_c = delete $self->{pkt_op_c}) {
 559                 close(delete $op_c->{sock});
 560         }
 561         if (my $pgr = delete $self->{pgr}) {
 562                 close($_) for (@$pgr[1,2]);
 563         }
 564         close $listener if $listener;
 565         undef $listener;
 566         $dir_idle->force_close if $dir_idle;
 567         %PATH2CFG = ();
 568         $MDIR2CFGPATH = {};
 569         %LIVE_SOCK = ();
 570         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 571         undef $errors_log;
 572         $quit = \&CORE::exit;
 573         $self->{-eml_noisy} or # only "lei import" sets this atm
 574                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 575         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 576 }
 577
 578 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 579         my ($self) = @_;
 580         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 581                 $op->close; # PublicInbox::PktOp::close
 582         }
 583         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 584         close $pkt_op_p->{op_p};
 585 }
 586
 587 sub pkt_op_pair {
 588         my ($self) = @_;
 589         require PublicInbox::OnDestroy;
 590         require PublicInbox::PktOp;
 591         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 592         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 593         $end;
 594 }
 595
 596 sub incr {
 597         my ($self, $field, $nr) = @_;
 598         $self->{counters}->{$field} += $nr;
 599 }
 600
 601 sub workers_start {
 602         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 603         $ops = {
 604                 '!' => [ \&fail_handler, $lei ],
 605                 '|' => [ \&sigpipe_handler, $lei ],
 606                 'x_it' => [ \&x_it, $lei ],
 607                 'child_error' => [ \&child_error, $lei ],
 608                 'incr' => [ \&incr, $lei ],
 609                 ($ops ? %$ops : ()),
 610         };
 611         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 612         my $end = $lei->pkt_op_pair;
 613         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 614         $flds->{lei} = $lei;
 615         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 616         delete $lei->{pkt_op_p};
 617         my $op_c = delete $lei->{pkt_op_c};
 618         @$end = ();
 619         $lei->event_step_init;
 620         ($op_c, $ops);
 621 }
 622
 623 # call this when we're ready to wait on events and yield to other clients
 624 sub wait_wq_events {
 625         my ($lei, $op_c, $ops) = @_;
 626         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 627                 $wq->wq_close(1);
 628         }
 629         $op_c->{ops} = $ops;
 630 }
 631
 632 sub _help {
 633         require PublicInbox::LeiHelp;
 634         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 635 }
 636
 637 sub optparse ($$$) {
 638         my ($self, $cmd, $argv) = @_;
 639         # allow _complete --help to complete, not show help
 640         return 1 if substr($cmd, 0, 1) eq '_';
 641         $self->{cmd} = $cmd;
 642         $OPT = $self->{opt} //= {};
 643         my $info = $CMD{$cmd} // [ '[...]' ];
 644         my ($proto, undef, @spec) = @$info;
 645         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 646         push @spec, qw(help|h);
 647         my $lone_dash;
 648         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 649                 $lone_dash = $spec[0];
 650                 $OPT->{$spec[0]} = \(my $var);
 651                 push @spec, '' => \$var;
 652         }
 653         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 654                 return _help($self, "bad arguments or options for $cmd");
 655         return _help($self) if $OPT->{help};
 656
 657         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 658
 659         # "-" aliases "stdin" or "clear"
 660         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 661
 662         my $i = 0;
 663         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 664         my ($err, $inf);
 665         my @args = split(/ /, $proto);
 666         for my $var (@args) {
 667                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 668                         $inf = defined($argv->[$i]) and last;
 669                         $var =~ s/\.\.\.\z//;
 670                         $err = "$var not supplied";
 671                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 672                         $argv->[$i++] // ($err = "$var not supplied");
 673                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 674                         $inf = 1;
 675                         last;
 676                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 677                         $i++;
 678                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 679                         $inf = 1 if index($var, '...') > 0;
 680                         my @or = split(/\|/, $var);
 681                         my $ok;
 682                         for my $o (@or) {
 683                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 684                                         my $sw = $1;
 685                                         # assume pipe/regular file on stdin
 686                                         # w/o args means stdin
 687                                         if ($sw eq 'stdin' && !@$argv &&
 688                                                         (-p $self->{0} ||
 689                                                          -f _) && -r _) {
 690                                                 $OPT->{stdin} //= 1;
 691                                         }
 692                                         $ok = defined($OPT->{$sw});
 693                                         last if $ok;
 694                                 } elsif (defined($argv->[$i])) {
 695                                         $ok = 1;
 696                                         $i++;
 697                                         last;
 698                                 } # else continue looping
 699                         }
 700                         last if $ok;
 701                         my $last = pop @or;
 702                         $err = join(', ', @or) . " or $last must be set";
 703                 } else {
 704                         warn "BUG: can't parse `$var' in $proto";
 705                 }
 706                 last if $err;
 707         }
 708         if (!$inf && scalar(@$argv) > scalar(@args)) {
 709                 $err //= 'too many arguments';
 710         }
 711         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 712 }
 713
 714 sub _tmp_cfg { # for lei -c <name>=<value> ...
 715         my ($self) = @_;
 716         my $cfg = _lei_cfg($self, 1);
 717         require File::Temp;
 718         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 719         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 720         $ft->autoflush(1);
 721         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 722 [include]
 723         path = $cfg->{-f}
 724 EOM
 725         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 726         for (@{$self->{opt}->{c}}) {
 727                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 728 `-c $_' is not of the form -c <name>=<value>'
 729 EOM
 730                 my $name = $1;
 731                 my $value = $2 // 1;
 732                 _config($self, '--add', $name, $value);
 733                 if (defined(my $v = $tmp->{$name})) {
 734                         if (ref($v) eq 'ARRAY') {
 735                                 push @$v, $value;
 736                         } else {
 737                                 $tmp->{$name} = [ $v, $value ];
 738                         }
 739                 } else {
 740                         $tmp->{$name} = $value;
 741                 }
 742         }
 743 }
 744
 745 sub lazy_cb ($$$) {
 746         my ($self, $cmd, $pfx) = @_;
 747         my $ucmd = $cmd;
 748         $ucmd =~ tr/-/_/;
 749         my $cb;
 750         $cb = $self->can($pfx.$ucmd) and return $cb;
 751         my $base = $ucmd;
 752         $base =~ s/_([a-z])/\u$1/g;
 753         my $pkg = "PublicInbox::Lei\u$base";
 754         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 755                 $pkg->can($pfx.$ucmd) : undef;
 756 }
 757
 758 sub dispatch {
 759         my ($self, $cmd, @argv) = @_;
 760         local $current_lei = $self; # for __WARN__
 761         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 762         dump_and_clear_log("from previous run\n");
 763         return _help($self, 'no command given') unless defined($cmd);
 764         # do not support Getopt bundling for this
 765         while ($cmd eq '-C' || $cmd eq '-c') {
 766                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 767                                         '-C DIRECTORY' : '-c <name>=<value>');
 768                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 769                 $cmd = shift(@argv) // return _help($self, 'no command given');
 770         }
 771         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 772                 optparse($self, $cmd, \@argv) or return;
 773                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 774                 if (my $chdir = $self->{opt}->{C}) {
 775                         for my $d (@$chdir) {
 776                                 next if $d eq ''; # same as git(1)
 777                                 chdir $d or return fail($self, "cd $d: $!");
 778                         }
 779                         open $self->{3}, '.' or return fail($self, "open . $!");
 780                 }
 781                 $cb->($self, @argv);
 782         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 783                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 784                         or return _help($self, 'bad arguments or options');
 785                 _help($self);
 786         } else {
 787                 fail($self, "`$cmd' is not an lei command");
 788         }
 789 }
 790
 791 sub _lei_cfg ($;$) {
 792         my ($self, $creat) = @_;
 793         return $self->{cfg} if $self->{cfg};
 794         my $f = _config_path($self);
 795         my @st = stat($f);
 796         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 797         my ($sto, $sto_dir, $watches, $lne);
 798         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 799                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 800                 ($sto, $sto_dir, $watches, $lne) =
 801                                 @$cfg{qw(-lei_store leistore.dir -watches
 802                                         -lei_note_event)};
 803         }
 804         if (!@st) {
 805                 unless ($creat) {
 806                         delete $self->{cfg};
 807                         return bless {}, 'PublicInbox::Config';
 808                 }
 809                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 810                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 811                 open my $fh, '>>', $f or die "open($f): $!\n";
 812                 @st = stat($fh) or die "fstat($f): $!\n";
 813                 $cur_st = pack('dd', $st[10], $st[7]);
 814                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 815         }
 816         my $cfg = PublicInbox::Config->git_config_dump($f);
 817         $cfg->{-st} = $cur_st;
 818         $cfg->{'-f'} = $f;
 819         if ($sto && canonpath_harder($sto_dir // store_path($self))
 820                         eq canonpath_harder($cfg->{'leistore.dir'} //
 821                                                 store_path($self))) {
 822                 $cfg->{-lei_store} = $sto;
 823                 $cfg->{-lei_note_event} = $lne;
 824                 $cfg->{-watches} = $watches if $watches;
 825         }
 826         if (scalar(keys %PATH2CFG) > 5) {
 827                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 828                 for my $k (keys %PATH2CFG) {
 829                         delete($PATH2CFG{$k}) unless -f $k
 830                 }
 831         }
 832         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 833         refresh_watches($self);
 834         $cfg;
 835 }
 836
 837 sub _lei_store ($;$) {
 838         my ($self, $creat) = @_;
 839         my $cfg = _lei_cfg($self, $creat) // return;
 840         $cfg->{-lei_store} //= do {
 841                 require PublicInbox::LeiStore;
 842                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 843                 return unless $creat || -d $dir;
 844                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 845         };
 846 }
 847
 848 sub _config {
 849         my ($self, @argv) = @_;
 850         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 851         my $cfg = _lei_cfg($self, 1);
 852         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 853         my %rdr = map { $_ => $self->{$_} } (0..2);
 854         waitpid(spawn($cmd, \%env, \%rdr), 0);
 855 }
 856
 857 sub lei_config {
 858         my ($self, @argv) = @_;
 859         $self->{opt}->{'config-file'} and return fail $self,
 860                 "config file switches not supported by `lei config'";
 861         _config(@_);
 862         x_it($self, $?) if $?;
 863 }
 864
 865 sub lei_daemon_pid { puts shift, $$ }
 866
 867 sub lei_daemon_kill {
 868         my ($self) = @_;
 869         my $sig = $self->{opt}->{signal} // 'TERM';
 870         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 871 }
 872
 873 # Shell completion helper.  Used by lei-completion.bash and hopefully
 874 # other shells.  Try to do as much here as possible to avoid redundancy
 875 # and improve maintainability.
 876 sub lei__complete {
 877         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 878         shift @argv; # ignore "lei", the entire command is sent
 879         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 880         my $cmd = shift @argv;
 881         my $info = $CMD{$cmd} // do { # filter matching commands
 882                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 883                 return;
 884         };
 885         my ($proto, undef, @spec) = @$info;
 886         my $cur = pop @argv;
 887         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 888         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 889                 # gross special case since the only git-config options
 890                 # Consider moving to a table if we need more special cases
 891                 # we use Getopt::Long for are the ones we reject, so these
 892                 # are the ones we don't reject:
 893                 if ($cmd eq 'config') {
 894                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 895                         @spec = qw(add z|null get get-all unset unset-all
 896                                 replace-all get-urlmatch
 897                                 remove-section rename-section
 898                                 name-only list|l edit|e
 899                                 get-color-name get-colorbool);
 900                         # fall-through
 901                 }
 902                 # generate short/long names from Getopt::Long specs
 903                 puts $self, grep(/$re/, qw(--help -h -C), map {
 904                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 905                         } elsif (s/\+\z//) { # verbose|v+
 906                         } elsif (s/!\z//) {
 907                                 # negation: mail! => no-mail|mail
 908                                 s/([\w\-]+)/$1|no-$1/g
 909                         }
 910                         map {
 911                                 my $x = length > 1 ? "--$_" : "-$_";
 912                                 $x eq $_cur ? () : $x;
 913                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 914                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 915         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 916                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 917         }
 918
 919         # switch args (e.g. lei q -f mbox<TAB>)
 920         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 921                 my $opt = quotemeta $1;
 922                 puts $self, map {
 923                         my $v = $OPTDESC{$_};
 924                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 925                         # get rid of ALL CAPS placeholder (e.g "OUT")
 926                         # (TODO: completion for external paths)
 927                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 928                         @v;
 929                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 930         }
 931         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 932                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 933         }
 934         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 935         # proto parsing.
 936 }
 937
 938 sub exec_buf ($$) {
 939         my ($argv, $env) = @_;
 940         my $argc = scalar @$argv;
 941         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 942         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 943         $buf;
 944 }
 945
 946 sub start_mua {
 947         my ($self) = @_;
 948         my $mua = $self->{opt}->{mua} // return;
 949         my $mfolder = $self->{ovv}->{dst};
 950         my (@cmd, $replaced);
 951         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 952                 @cmd = ($mua, '-f');
 953         # TODO: help wanted: other common FOSS MUAs
 954         } else {
 955                 require Text::ParseWords;
 956                 @cmd = Text::ParseWords::shellwords($mua);
 957                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 958                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 959         }
 960         push @cmd, $mfolder unless defined($replaced);
 961         if ($self->{sock}) { # lei(1) client process runs it
 962                 # restore terminal: echo $query | lei q --stdin --mua=...
 963                 my $io = [];
 964                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 965                 send_exec_cmd($self, $io, \@cmd, {});
 966         }
 967         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 968                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 969         }
 970         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 971         $self->{opt}->{quiet} = 1;
 972         delete $self->{-progress};
 973         delete $self->{opt}->{verbose};
 974 }
 975
 976 sub send_exec_cmd { # tell script/lei to execute a command
 977         my ($self, $io, $cmd, $env) = @_;
 978         my $sock = $self->{sock} // die 'lei client gone';
 979         my $fds = [ map { fileno($_) } @$io ];
 980         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 981 }
 982
 983 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 984         my ($self) = @_;
 985         my $alerts = $self->{opt}->{alert} // return;
 986         my $sock = $self->{sock};
 987         while (my $op = shift(@$alerts)) {
 988                 if ($op eq ':WINCH') {
 989                         # hit the process group that started the MUA
 990                         send($sock, '-WINCH', MSG_EOR) if $sock;
 991                 } elsif ($op eq ':bell') {
 992                         out($self, "\a");
 993                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 994                         push @$alerts, split(/(?<!\\),/, $op);
 995                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 996                         my $cmd = $1; # run an arbitrary command
 997                         require Text::ParseWords;
 998                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 999                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1000                 } else {
1001                         err($self, "W: unsupported --alert=$op"); # non-fatal
1002                 }
1003         }
1004 }
1005
1006 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1007 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1008
1009 # this also normalizes the path
1010 sub path_to_fd {
1011         my ($self, $path) = @_;
1012         $path = rel2abs($self, $path);
1013         $path =~ tr!/!/!s;
1014         $path_to_fd{$path} // (
1015                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1016                         fail($self, "cannot open $path from daemon") : -1
1017         );
1018 }
1019
1020 # caller needs to "-t $self->{1}" to check if tty
1021 sub start_pager {
1022         my ($self) = @_;
1023         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1024         chomp(my $pager = <$fh> // '');
1025         close($fh) or warn "`git var PAGER' error: \$?=$?";
1026         return if $pager eq 'cat' || $pager eq '';
1027         my $new_env = { LESS => 'FRX', LV => '-c' };
1028         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1029         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1030         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1031         my $pgr = [ undef, @$rdr{1, 2} ];
1032         my $env = $self->{env};
1033         if ($self->{sock}) { # lei(1) process runs it
1034                 delete @$new_env{keys %$env}; # only set iff unset
1035                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1036         } else {
1037                 die 'BUG: start_pager w/o socket';
1038         }
1039         $self->{1} = $wpager;
1040         $self->{2} = $wpager if -t $self->{2};
1041         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1042         $self->{pgr} = $pgr;
1043 }
1044
1045 sub stop_pager {
1046         my ($self) = @_;
1047         my $pgr = delete($self->{pgr}) or return;
1048         $self->{2} = $pgr->[2];
1049         # do not restore original stdout, just close it so we error out
1050         close(delete($self->{1})) if $self->{1};
1051 }
1052
1053 sub accept_dispatch { # Listener {post_accept} callback
1054         my ($sock) = @_; # ignore other
1055         $sock->autoflush(1);
1056         my $self = bless { sock => $sock }, __PACKAGE__;
1057         vec(my $rvec = '', fileno($sock), 1) = 1;
1058         select($rvec, undef, undef, 60) or
1059                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1060         # (4096 * 33) >MAX_ARG_STRLEN
1061         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1062         if (!defined($fds[0])) {
1063                 warn(my $msg = "recv_cmd failed: $!");
1064                 return send($sock, $msg, MSG_EOR);
1065         } else {
1066                 my $i = 0;
1067                 for my $fd (@fds) {
1068                         open($self->{$i++}, '+<&=', $fd) and next;
1069                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1070                 }
1071                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1072         }
1073         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1074         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1075         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1076                 return send($sock, 'request command truncated', MSG_EOR);
1077         my ($argc, @argv) = split(/\0/, $buf, -1);
1078         undef $buf;
1079         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1080         if (chdir($self->{3})) {
1081                 local %ENV = %env;
1082                 $self->{env} = \%env;
1083                 eval { dispatch($self, @argv) };
1084                 send($sock, $@, MSG_EOR) if $@;
1085         } else {
1086                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1087         }
1088 }
1089
1090 sub dclose {
1091         my ($self) = @_;
1092         delete $self->{-progress};
1093         _drop_wq($self) if $self->{failed};
1094         close(delete $self->{1}) if $self->{1}; # may reap_compress
1095         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1096 }
1097
1098 # for long-running results
1099 sub event_step {
1100         my ($self) = @_;
1101         local %ENV = %{$self->{env}};
1102         my $sock = $self->{sock};
1103         local $current_lei = $self;
1104         eval {
1105                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1106                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1107                                 return if $! == EAGAIN;
1108                                 next if $! == EINTR;
1109                                 last if $! == ECONNRESET;
1110                                 die "recvmsg: $!";
1111                         }
1112                         for my $fd (@fds) {
1113                                 open my $rfh, '+<&=', $fd;
1114                         }
1115                         die "unrecognized client signal: $buf";
1116                 }
1117                 _drop_wq($self); # EOF, client disconnected
1118                 dclose($self);
1119         };
1120         if (my $err = $@) {
1121                 eval { $self->fail($err) };
1122                 dclose($self);
1123         }
1124 }
1125
1126 sub event_step_init {
1127         my ($self) = @_;
1128         my $sock = $self->{sock} or return;
1129         $self->{-event_init_done} //= do { # persist til $ops done
1130                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1131                 $sock;
1132         };
1133 }
1134
1135 sub noop {}
1136
1137 sub oldset { $oldset }
1138
1139 sub dump_and_clear_log {
1140         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1141                 my @pfx = @_;
1142                 unshift(@pfx, "$errors_log ") if @pfx;
1143                 warn @pfx, do { local $/; <STDIN> };
1144                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1145         }
1146 }
1147
1148 sub cfg2lei ($) {
1149         my ($cfg) = @_;
1150         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1151         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1152         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1153         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1154         open($lei->{3}, '/') or die "open /: $!";
1155         chdir($lei->{3}) or die "chdir /': $!";
1156         my ($x, $y);
1157         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1158         $lei->{sock} = $x;
1159         require PublicInbox::LeiSelfSocket;
1160         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1161         $lei;
1162 }
1163
1164 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1165         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1166         my $fn = $ev->fullname;
1167         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1168                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1169                 $nc = '' if $ev->IN_DELETE;
1170                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1171                         my $cfg = $PATH2CFG{$f} // next;
1172                         eval {
1173                                 local %ENV = %{$cfg->{-env}};
1174                                 my $lei = cfg2lei($cfg);
1175                                 $lei->dispatch('note-event',
1176                                                 "maildir:$mdir", $nc, $bn, $fn);
1177                         };
1178                         warn "E note-event $f: $@\n" if $@;
1179                 }
1180         }
1181         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1182                 $ev->cancel;
1183         }
1184         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1185                 delete $MDIR2CFGPATH->{$1};
1186         }
1187         if (!-e $fn) { # config file or Maildir gone
1188                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1189                         delete $cfgpaths->{$fn};
1190                 }
1191                 delete $PATH2CFG{$fn};
1192         }
1193 }
1194
1195 # lei(1) calls this when it can't connect
1196 sub lazy_start {
1197         my ($path, $errno, $narg) = @_;
1198         local ($errors_log, $listener);
1199         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1200         $errors_log = "$sock_dir/errors.log";
1201         my $addr = pack_sockaddr_un($path);
1202         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1203         $lk->lock_acquire;
1204         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1205         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1206                 return if connect($listener, $addr); # another process won
1207                 if ($errno == ECONNREFUSED && -S $path) {
1208                         unlink($path) or die "unlink($path): $!";
1209                 }
1210         } else {
1211                 $! = $errno; # allow interpolation to stringify in die
1212                 die "connect($path): $!";
1213         }
1214         umask(077) // die("umask(077): $!");
1215         bind($listener, $addr) or die "bind($path): $!";
1216         $lk->lock_release;
1217         undef $lk;
1218         my @st = stat($path) or die "stat($path): $!";
1219         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1220         local $oldset = PublicInbox::DS::block_signals();
1221         if ($narg == 5) {
1222                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1223                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1224                         require PublicInbox::CmdIPC4;
1225                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1226                         PublicInbox::CmdIPC4->can('recv_cmd4');
1227                 };
1228         }
1229         $recv_cmd or die <<"";
1230 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1231
1232         require PublicInbox::Listener;
1233         require PublicInbox::PktOp;
1234         (-p STDOUT) or die "E: stdout must be a pipe\n";
1235         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1236         STDIN->autoflush(1);
1237         dump_and_clear_log("from previous daemon process:\n");
1238         POSIX::setsid() > 0 or die "setsid: $!";
1239         my $pid = fork // die "fork: $!";
1240         return if $pid;
1241         $0 = "lei-daemon $path";
1242         local %PATH2CFG;
1243         local $MDIR2CFGPATH;
1244         $listener->blocking(0);
1245         my $exit_code;
1246         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1247         local $quit = do {
1248                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1249                 sub {
1250                         $exit_code //= shift;
1251                         my $lis = $pil or exit($exit_code);
1252                         # closing eof_p triggers \&noop wakeup
1253                         $listener = $eof_p = $pil = $path = undef;
1254                         $lis->close; # DS::close
1255                         PublicInbox::DS->SetLoopTimeout(1000);
1256                 };
1257         };
1258         my $sig = {
1259                 CHLD => \&PublicInbox::DS::enqueue_reap,
1260                 QUIT => $quit,
1261                 INT => $quit,
1262                 TERM => $quit,
1263                 HUP => \&noop,
1264                 USR1 => \&noop,
1265                 USR2 => \&noop,
1266         };
1267         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1268         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1269         undef $sig;
1270         local $SIG{PIPE} = 'IGNORE';
1271         require PublicInbox::DirIdle;
1272         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1273                 # just rely on wakeup to hit PostLoopCallback set below
1274                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1275         }, 1);
1276         if ($sigfd) {
1277                 undef $sigfd; # unref, already in DS::DescriptorMap
1278         } else {
1279                 # wake up every second to accept signals if we don't
1280                 # have signalfd or IO::KQueue:
1281                 PublicInbox::DS::sig_setmask($oldset);
1282                 PublicInbox::DS->SetLoopTimeout(1000);
1283         }
1284         PublicInbox::DS->SetPostLoopCallback(sub {
1285                 my ($dmap, undef) = @_;
1286                 if (@st = defined($path) ? stat($path) : ()) {
1287                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1288                                 warn "$path dev/ino changed, quitting\n";
1289                                 $path = undef;
1290                         }
1291                 } elsif (defined($path)) { # ENOENT is common
1292                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1293                         undef $path;
1294                         $quit->();
1295                 }
1296                 return 1 if defined($path);
1297                 my $now = now();
1298                 my $n = 0;
1299                 for my $s (values %$dmap) {
1300                         $s->can('busy') or next;
1301                         if ($s->busy($now)) {
1302                                 ++$n;
1303                         } else {
1304                                 $s->close;
1305                         }
1306                 }
1307                 $n; # true: continue, false: stop
1308         });
1309
1310         # STDIN was redirected to /dev/null above, closing STDERR and
1311         # STDOUT will cause the calling `lei' client process to finish
1312         # reading the <$daemon> pipe.
1313         local $SIG{__WARN__} = sub {
1314                 $current_lei ? err($current_lei, @_) : warn(
1315                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1316         };
1317         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1318         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1319         # $daemon pipe to `lei' closed, main loop begins:
1320         PublicInbox::DS->EventLoop;
1321         exit($exit_code // 0);
1322 }
1323
1324 sub busy { 1 } # prevent daemon-shutdown if client is connected
1325
1326 # ensures stdout hits the FS before sock disconnects so a client
1327 # can immediately reread it
1328 sub DESTROY {
1329         my ($self) = @_;
1330         if (my $counters = delete $self->{counters}) {
1331                 for my $k (sort keys %$counters) {
1332                         my $nr = $counters->{$k};
1333                         $self->child_error(1 << 8, "$nr $k messages");
1334                 }
1335         }
1336         $self->{1}->autoflush(1) if $self->{1};
1337         stop_pager($self);
1338         # preserve $? for ->fail or ->x_it code
1339 }
1340
1341 sub wq_done_wait { # dwaitpid callback
1342         my ($arg, $pid) = @_;
1343         my ($wq, $lei) = @$arg;
1344         my $err_type = $lei->{-err_type};
1345         $? and $lei->child_error($?,
1346                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1347         $lei->dclose;
1348 }
1349
1350 sub fchdir {
1351         my ($lei) = @_;
1352         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1353         chdir($dh) || $lei->fail("fchdir: $!");
1354 }
1355
1356 sub wq_eof { # EOF callback for main daemon
1357         my ($lei) = @_;
1358         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1359         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1360 }
1361
1362 sub watch_state_ok ($) {
1363         my ($state) = $_[-1]; # $_[0] may be $self
1364         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1365 }
1366
1367 sub cancel_maildir_watch ($$) {
1368         my ($d, $cfg_f) = @_;
1369         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1370         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1371                 delete $MDIR2CFGPATH->{$d};
1372         for my $x (@{$w // []}) { $x->cancel }
1373 }
1374
1375 sub add_maildir_watch ($$) {
1376         my ($d, $cfg_f) = @_;
1377         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1378                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1379                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1380         }
1381 }
1382
1383 sub refresh_watches {
1384         my ($lei) = @_;
1385         my $cfg = _lei_cfg($lei) or return;
1386         my $old = $cfg->{-watches};
1387         my $watches = $cfg->{-watches} //= {};
1388         my %seen;
1389         my $cfg_f = $cfg->{'-f'};
1390         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1391                 my $url = substr($w, length('watch.'), -length('.state'));
1392                 require PublicInbox::LeiWatch;
1393                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1394                 $seen{$url} = undef;
1395                 my $state = $cfg->get_1("watch.$url", 'state');
1396                 if (!watch_state_ok($state)) {
1397                         $lei->err("watch.$url.state=$state not supported");
1398                         next;
1399                 }
1400                 if ($url =~ /\Amaildir:(.+)/i) {
1401                         my $d = canonpath_harder($1);
1402                         if ($state eq 'pause') {
1403                                 cancel_maildir_watch($d, $cfg_f);
1404                         } else {
1405                                 add_maildir_watch($d, $cfg_f);
1406                         }
1407                 } else { # TODO: imap/nntp/jmap
1408                         $lei->child_error(1, "E: watch $url not supported, yet")
1409                 }
1410         }
1411
1412         # add all known Maildir folders as implicit watches
1413         my $sto = $lei->_lei_store;
1414         my $renames = 0;
1415         if (my $lms = $sto ? $sto->search->lms : undef) {
1416                 for my $d ($lms->folders('maildir:')) {
1417                         substr($d, 0, length('maildir:')) = '';
1418                         my $cd = canonpath_harder($d);
1419                         my $f = "maildir:$cd";
1420
1421                         # fixup old bugs while we're iterating:
1422                         if ($d ne $cd) {
1423                                 $sto->ipc_do('lms_rename_folder',
1424                                                 "maildir:$d", $f);
1425                                 ++$renames;
1426                         }
1427                         next if $watches->{$f}; # may be set to pause
1428                         require PublicInbox::LeiWatch;
1429                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1430                         $seen{$f} = undef;
1431                         add_maildir_watch($cd, $cfg_f);
1432                 }
1433         }
1434         $lei->sto_done_request if $renames;
1435         if ($old) { # cull old non-existent entries
1436                 for my $url (keys %$old) {
1437                         next if exists $seen{$url};
1438                         delete $old->{$url};
1439                         if ($url =~ /\Amaildir:(.+)/i) {
1440                                 my $d = canonpath_harder($1);
1441                                 cancel_maildir_watch($d, $cfg_f);
1442                         } else { # TODO: imap/nntp/jmap
1443                                 $lei->child_error(1, "E: watch $url TODO");
1444                         }
1445                 }
1446         }
1447         if (scalar keys %$watches) {
1448                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1449         } else {
1450                 delete $cfg->{-watches};
1451         }
1452 }
1453
1454 sub git_blob_id {
1455         my ($lei, $eml) = @_;
1456         ($lei->{sto} // _lei_store($lei, 1))->git_blob_id($eml);
1457 }
1458
1459 sub lms { # read-only LeiMailSync
1460         my ($lei) = @_;
1461         my $lse = $lei->{lse} // do {
1462                 my $sto = $lei->{sto} // _lei_store($lei);
1463                 $sto ? $sto->search : undef
1464         };
1465         $lse ? $lse->lms : undef;
1466 }
1467
1468 sub sto_done_request { # only call this from lei-daemon process (not workers)
1469         my ($lei, $sock) = @_;
1470         if ($sock //= $lei->{sock}) {
1471                 $LIVE_SOCK{"$sock"} = $sock;
1472                 $lei->{sto}->ipc_do('done', "$sock"); # issue, async wait
1473         } else { # forcibly wait
1474                 my $wait = $lei->{sto}->ipc_do('done');
1475         }
1476 }
1477
1478 sub sto_done_complete { # called in lei-daemon when LeiStore->done is complete
1479         my ($sock_str) = @_;
1480         delete $LIVE_SOCK{$sock_str}; # frees {sock} for waiting lei clients
1481 }
1482
1483 1;