lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  32         $recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => undef }
  40
  41 # TBD: this is a documentation mechanism to show a subcommand
  42 # (may) pass options through to another command:
  43 sub pass_through { $GLP_PASS }
  44
  45 my $OPT;
  46 sub opt_dash ($$) {
  47         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  48         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  49         my $cb = sub { # Getopt::Long "<>" catch-all handler
  50                 my ($arg) = @_;
  51                 if ($arg =~ /\A-($re_str)\z/) {
  52                         $OPT->{$key} = $1;
  53                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  54                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  55                 # lone (single) dash is handled elsewhere
  56                 } elsif (substr($arg, 0, 1) eq '-') {
  57                         if ($OPT->{'--'}) {
  58                                 push @{$OPT->{-argv}}, $arg;
  59                         } else {
  60                                 die "bad argument: $arg\n";
  61                         }
  62                 } else {
  63                         push @{$OPT->{-argv}}, $arg;
  64                 }
  65         };
  66         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  67 }
  68
  69 # rel2abs preserves symlinks in parent, unlike abs_path
  70 sub rel2abs {
  71         my ($self, $p) = @_;
  72         if (index($p, '/') == 0) { # already absolute
  73                 $p =~ tr!/!/!s; # squeeze redundant slashes
  74                 chop($p) if substr($p, -1, 1) eq '/';
  75                 return $p;
  76         }
  77         my $pwd = $self->{env}->{PWD};
  78         my $cwd;
  79         if (defined $pwd) {
  80                 my $xcwd = $self->{3} //
  81                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  82                 if (my @st_pwd = stat($pwd)) {
  83                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  84                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  85                                 $self->{env}->{PWD} = $pwd = undef;
  86                 } else { # PWD was invalid
  87                         $self->{env}->{PWD} = $pwd = undef;
  88                 }
  89         }
  90         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  91         File::Spec->rel2abs($p, $pwd);
  92 }
  93
  94 # abs_path resolves symlinks in parent iff all parents exist
  95 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  96
  97 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  98         my ($self) = @_;
  99         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 100                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 101                 .'/lei');
 102 }
 103
 104 sub store_path ($) { share_path($_[0]) . '/store' }
 105
 106 sub _config_path ($) {
 107         my ($self) = @_;
 108         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 109                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 110                 .'/lei/config');
 111 }
 112
 113 sub cache_dir ($) {
 114         my ($self) = @_;
 115         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 116                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 117                 .'/lei');
 118 }
 119
 120 sub url_folder_cache {
 121         my ($self) = @_;
 122         require PublicInbox::SharedKV; # URI => updated_at_sec_
 123         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 124 }
 125
 126 sub ale {
 127         my ($self) = @_;
 128         $self->{ale} //= do {
 129                 require PublicInbox::LeiALE;
 130                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 131         };
 132 }
 133
 134 sub index_opt {
 135         # TODO: drop underscore variants everywhere, they're undocumented
 136         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 137         max_size|max-size=s sequential_shard|sequential-shard
 138         batch_size|batch-size=s skip-docdata)
 139 }
 140
 141 my @c_opt = qw(c=s@ C=s@ quiet|q);
 142 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 143         import-remote! no-torsocks torsocks=s),
 144         PublicInbox::LeiQuery::curl_opt());
 145
 146 # we don't support -C as an alias for --find-copies since it's already
 147 # used for chdir
 148 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 149         output-indicator-context=s indent-heuristic!
 150         minimal patience histogram anchored=s@ diff-algorithm=s
 151         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 152         word-diff:s word-diff-regex=s color-words:s no-renames
 153         rename-empty! check ws-error-highlight=s full-index binary
 154         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 155         find-copies-harder irreversible-delete|D l=i diff-filter=s
 156         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 157         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 158         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 159         inter-hunk-context=i function-context|W exit-code ext-diff
 160         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 161         line-prefix=s);
 162
 163 # we generate shell completion + help using %CMD and %OPTDESC,
 164 # see lei__complete() and PublicInbox::LeiHelp
 165 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 166 our %CMD = ( # sorted in order of importance/use:
 167 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 168         'stdin|', # /|\z/ must be first for lone dash
 169         @lxs_opt,
 170         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 171         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 172         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 173         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 174
 175 'up' => [ 'OUTPUT|--all', 'update saved search',
 176         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 177
 178 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 179         'stdin|', # /|\z/ must be first for lone dash
 180         # some of these options are ridiculous for lcat
 181         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 182         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 183         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 184         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 185
 186 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 187         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 188         @lxs_opt, @c_opt ],
 189
 190 'rediff' => [ '--stdin|LOCATION...',
 191                 'regenerate a diff with different options',
 192         'stdin|', # /|\z/ must be first for lone dash
 193         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 194         @diff_opt, @lxs_opt, @c_opt ],
 195
 196 'add-external' => [ 'LOCATION',
 197         'add/set priority of a publicinbox|extindex for extra matches',
 198         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 199         verbose|v+), @c_opt, index_opt(),
 200         PublicInbox::LeiQuery::curl_opt() ],
 201 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 202         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 203 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 204 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 205                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 206 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 207                 qw(z|0 ascii l url), @c_opt ],
 208 'forget-external' => [ 'LOCATION...|--prune',
 209         'exclude further results from a publicinbox|extindex',
 210         qw(prune), @c_opt ],
 211
 212 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 213                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 214 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 215                 qw(verbose|v+), @c_opt ],
 216 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 217                         @c_opt ],
 218 'rm' => [ '--stdin|LOCATION...',
 219         'remove a message from the index and prevent reindexing',
 220         'stdin|', # /|\z/ must be first for lone dash
 221         @c_opt ],
 222 'plonk' => [ '--threads|--from=IDENT',
 223         'exclude mail matching From: or threads from non-Message-ID searches',
 224         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 225 'tag' => [ 'KEYWORDS...',
 226         'set/unset keywords and/or labels on message(s)',
 227         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 228         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 229         pass_through('-kw:foo for delete') ],
 230
 231 'purge-mailsource' => [ 'LOCATION|--all',
 232         'remove imported messages from IMAP, Maildirs, and MH',
 233         qw(exact! all jobs:i indexed), @c_opt ],
 234
 235 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 236         qw(poll-interval=s state=s recursive|r), @c_opt ],
 237 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 238                 qw(l z|0), @c_opt ],
 239 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 240 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 241 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 242         qw(prune), @c_opt ],
 243
 244 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 245         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 246         verbose|v+ incremental!),
 247          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 248          @c_opt ],
 249 'import' => [ 'LOCATION...|--stdin',
 250         'one-time import/update from URL or filesystem',
 251         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 252         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 253         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 254 'forget-mail-sync' => [ 'LOCATION...',
 255         'forget sync information for a mail folder', @c_opt ],
 256 'prune-mail-sync' => [ 'LOCATION...|--all',
 257         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 258 'export-kw' => [ 'LOCATION...|--all',
 259         'one-time export of keywords of sync sources',
 260         qw(all:s mode=s), @c_opt ],
 261 'convert' => [ 'LOCATION...|--stdin',
 262         'one-time conversion from URL or filesystem to another format',
 263         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 264         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 265 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 266         "use a patch to generate a query for `lei q --stdin'",
 267         qw(stdin| want|w=s@ uri debug), @c_opt ],
 268 'config' => [ '[...]', sub {
 269                 'git-config(1) wrapper for '._config_path($_[0]);
 270         }, qw(config-file|system|global|file|f=s), # for conflict detection
 271          qw(c=s@ C=s@), pass_through('git config') ],
 272 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 273         qw(pretty ascii dir=s), @c_opt ],
 274
 275 'init' => [ '[DIRNAME]', sub {
 276         "initialize storage, default: ".store_path($_[0]);
 277         }, @c_opt ],
 278 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 279         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 280         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 281 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 282 'help' => [ '[SUBCOMMAND]', 'show help' ],
 283
 284 # TODO
 285 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 286 #       'rewrite git history in an attempt to improve compression',
 287 #       qw(gc!), @c_opt ],
 288 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 289 #
 290 # internal commands are prefixed with '_'
 291 '_complete' => [ '[...]', 'internal shell completion helper',
 292                 pass_through('everything') ],
 293 ); # @CMD
 294
 295 # switch descriptions, try to keep consistent across commands
 296 # $spec: Getopt::Long option specification
 297 # $spec => [@ALLOWED_VALUES (default is first), $description],
 298 # $spec => $description
 299 # "$SUB_COMMAND TAB $spec" => as above
 300 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 301                         'specify message input format' ];
 302 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 303
 304 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 305 my %OPTDESC = (
 306 'help|h' => 'show this built-in help',
 307 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 308 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 309 'quiet|q' => 'be quiet',
 310 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 311         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 312
 313 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 314 'globoff|g' => "do not match locations using '*?' wildcards ".
 315                 "and\xa0'[]'\x{a0}ranges",
 316 'invert-match|v' => 'select non-matching lines',
 317 'color!' => 'disable color (for --format=text)',
 318 'verbose|v+' => 'be more verbose',
 319 'external!' => 'do not use externals',
 320 'mail!' => 'do not look in mail storage for OID',
 321 'cwd!' => 'do not look in git repo of current working directory',
 322 'oid-a|A=s' => 'pre-image OID',
 323 'path-a|a=s' => 'pre-image pathname associated with OID',
 324 'path-b|b=s' => 'post-image pathname associated with OID',
 325 'git-dir=s@' => 'additional git repository to scan',
 326 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 327 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 328         "proxy for (e.g. `socks5h://0:9050')" ],
 329 'torsocks=s' => ['VAL|auto|no|yes',
 330                 'whether or not to wrap git and curl commands with torsocks'],
 331 'no-torsocks' => 'alias for --torsocks=no',
 332 'save' =>  "save a search for `lei up'",
 333 'import-remote!' => 'do not memoize remote messages into local store',
 334
 335 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 336
 337 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 338                 'deduplication strategy'],
 339 'threads|t+' =>
 340         'return all messages in the same threads as the actual match(es)',
 341
 342 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 343                 'search prefixes to extract (default: dfpost7)' ],
 344
 345 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 346         'run command(s) or perform ops when done writing to output ' .
 347         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 348         'nothing otherwise)' ],
 349
 350 'augment|a' => 'augment --output destination instead of clobbering',
 351
 352 'output|mfolder|o=s' => [ 'MFOLDER',
 353         "destination (e.g.\xa0`/path/to/Maildir', ".
 354         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 355 'mua=s' => [ 'CMD',
 356         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 357 'new-only       import' => 'only import new messages from IMAP source',
 358
 359 'inbox-version=i' => [ 'NUM|1|2',
 360                 'force a public-inbox version with --mirror'],
 361 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 362
 363 # public-inbox-index options
 364 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 365 'compact' => 'run compact index after mirroring',
 366 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 367         "indexlevel with --mirror (default: full)" ],
 368 'max_size|max-size=s' => [ 'SIZE',
 369         'do not index messages larger than SIZE (default: infinity)' ],
 370 'batch_size|batch-size=s' => [ 'SIZE',
 371         'flush changes to OS after given number of bytes (default: 1m)' ],
 372 'sequential_shard|sequential-shard' =>
 373         'index Xapian shards sequentially for slow storage',
 374 'skip-docdata' =>
 375         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 376
 377 'format|f=s     q' => [
 378         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 379                 'specify output format, default depends on --output'],
 380 'exclude=s@     q' => [ 'LOCATION',
 381                 'exclude specified external(s) from search' ],
 382 'include|I=s@   q' => [ 'LOCATION',
 383                 'include specified external(s) in search' ],
 384 'only=s@        q' => [ 'LOCATION',
 385                 'only use specified external(s) for search' ],
 386 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 387                 'control number of search and writer jobs' ],
 388 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 389
 390 'in-format|F=s' => $stdin_formats,
 391 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 392                         'listing output format' ],
 393 'l      ls-search' => 'long listing format',
 394 'l      ls-watch' => 'long listing format',
 395 'l      ls-mail-source' => 'long listing format',
 396 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 397 'format|f=s     ls-external' => $ls_format,
 398
 399 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 400 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 401
 402 'sort|s=s' => [ 'VAL|received|relevance|docid',
 403                 "order of results is `--output'-dependent"],
 404 'reverse|r' => 'reverse search results', # like sort(1)
 405
 406 'boost=i' => 'increase/decrease priority of results (default: 0)',
 407
 408 'local' => 'limit operations to the local filesystem',
 409 'local!' => 'exclude results from the local filesystem',
 410 'remote' => 'limit operations to those requiring network access',
 411 'remote!' => 'prevent operations requiring network access',
 412
 413 'all:s  up' => ['local', 'update all (local) saved searches' ],
 414
 415 'mid=s' => 'specify the Message-ID of a message',
 416 'oid=s' => 'specify the git object ID of a message',
 417
 418 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 419 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 420 'include=s' => 'include mailboxes/newsgroups based on pattern',
 421
 422 'exact' => 'operate on exact header matches only',
 423 'exact!' => 'rely on content match instead of exact header matches',
 424
 425 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 426
 427 'kw!' => 'disable/enable importing keywords (aka "flags")',
 428
 429 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 430 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 431
 432 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 433 ); # %OPTDESC
 434
 435 my %CONFIG_KEYS = (
 436         'leistore.dir' => 'top-level storage location',
 437 );
 438
 439 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 440
 441 sub _drop_wq {
 442         my ($self) = @_;
 443         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 444                 if ($wq->wq_kill) {
 445                         $wq->wq_close(0, undef, $self);
 446                 } elsif ($wq->wq_kill_old) {
 447                         $wq->wq_wait_old(undef, $self);
 448                 }
 449                 $wq->DESTROY;
 450         }
 451 }
 452
 453 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 454 sub x_it ($$) {
 455         my ($self, $code) = @_;
 456         # make sure client sees stdout before exit
 457         $self->{1}->autoflush(1) if $self->{1};
 458         dump_and_clear_log();
 459         stop_pager($self);
 460         if ($self->{pkt_op_p}) { # to top lei-daemon
 461                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 462         } elsif ($self->{sock}) { # to lei(1) client
 463                 send($self->{sock}, "x_it $code", MSG_EOR);
 464         } # else ignore if client disconnected
 465 }
 466
 467 sub err ($;@) {
 468         my $self = shift;
 469         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 470         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 471         print $err @_, @eor and return;
 472         my $old_err = delete $self->{2};
 473         close($old_err) if $! == EPIPE && $old_err;
 474         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 475         print $err @_, @eor or print STDERR @_, @eor;
 476 }
 477
 478 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 479
 480 sub fail_handler ($;$$) {
 481         my ($lei, $code, $io) = @_;
 482         close($io) if $io; # needed to avoid warnings on SIGPIPE
 483         _drop_wq($lei);
 484         x_it($lei, $code // (1 << 8));
 485 }
 486
 487 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 488         fail_handler($_[0], 13, delete $_[0]->{1});
 489 }
 490
 491 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 492 sub sigint_reap {
 493         my ($pgid) = @_;
 494         dwaitpid($pgid) if kill('-INT', $pgid);
 495 }
 496
 497 sub fail ($$;$) {
 498         my ($self, $buf, $exit_code) = @_;
 499         $self->{failed}++;
 500         err($self, $buf) if defined $buf;
 501         # calls fail_handler:
 502         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 503         x_it($self, ($exit_code // 1) << 8);
 504         undef;
 505 }
 506
 507 sub out ($;@) {
 508         my $self = shift;
 509         return if print { $self->{1} // return } @_; # likely
 510         return note_sigpipe($self, 1) if $! == EPIPE;
 511         my $err = "error writing to output: $!";
 512         delete $self->{1};
 513         fail($self, $err);
 514 }
 515
 516 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 517
 518 sub child_error { # passes non-fatal curl exit codes to user
 519         my ($self, $child_error, $msg) = @_; # child_error is $?
 520         $self->err($msg) if $msg;
 521         if ($self->{pkt_op_p}) { # to top lei-daemon
 522                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 523         } elsif ($self->{sock}) { # to lei(1) client
 524                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 525         } # else noop if client disconnected
 526 }
 527
 528 sub note_sigpipe { # triggers sigpipe_handler
 529         my ($self, $fd) = @_;
 530         close(delete($self->{$fd})); # explicit close silences Perl warning
 531         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 532         x_it($self, 13);
 533 }
 534
 535 sub _lei_atfork_child {
 536         my ($self, $persist) = @_;
 537         # we need to explicitly close things which are on stack
 538         if ($persist) {
 539                 chdir '/' or die "chdir(/): $!";
 540                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 541                 if (my $cfg = $self->{cfg}) {
 542                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 543                 }
 544         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 545                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 546                 STDERR->autoflush(1);
 547         }
 548         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 549         if (my $op_c = delete $self->{pkt_op_c}) {
 550                 close(delete $op_c->{sock});
 551         }
 552         if (my $pgr = delete $self->{pgr}) {
 553                 close($_) for (@$pgr[1,2]);
 554         }
 555         close $listener if $listener;
 556         undef $listener;
 557         undef $dir_idle;
 558         %PATH2CFG = ();
 559         $MDIR2CFGPATH = {};
 560         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 561         undef $errors_log;
 562         $quit = \&CORE::exit;
 563         $self->{-eml_noisy} or # only "lei import" sets this atm
 564                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 565         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 566 }
 567
 568 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 569         my ($self) = @_;
 570         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 571                 $op->close; # PublicInbox::PktOp::close
 572         }
 573         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 574         close $pkt_op_p->{op_p};
 575 }
 576
 577 sub pkt_op_pair {
 578         my ($self) = @_;
 579         require PublicInbox::OnDestroy;
 580         require PublicInbox::PktOp;
 581         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 582         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 583         $end;
 584 }
 585
 586 sub incr {
 587         my ($self, $field, $nr) = @_;
 588         $self->{counters}->{$field} += $nr;
 589 }
 590
 591 sub workers_start {
 592         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 593         $ops = {
 594                 '!' => [ \&fail_handler, $lei ],
 595                 '|' => [ \&sigpipe_handler, $lei ],
 596                 'x_it' => [ \&x_it, $lei ],
 597                 'child_error' => [ \&child_error, $lei ],
 598                 'incr' => [ \&incr, $lei ],
 599                 ($ops ? %$ops : ()),
 600         };
 601         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 602         my $end = $lei->pkt_op_pair;
 603         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 604         $flds->{lei} = $lei;
 605         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 606         delete $lei->{pkt_op_p};
 607         my $op_c = delete $lei->{pkt_op_c};
 608         @$end = ();
 609         $lei->event_step_init;
 610         ($op_c, $ops);
 611 }
 612
 613 # call this when we're ready to wait on events and yield to other clients
 614 sub wait_wq_events {
 615         my ($lei, $op_c, $ops) = @_;
 616         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 617                 $wq->wq_close(1);
 618         }
 619         $op_c->{ops} = $ops;
 620 }
 621
 622 sub _help {
 623         require PublicInbox::LeiHelp;
 624         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 625 }
 626
 627 sub optparse ($$$) {
 628         my ($self, $cmd, $argv) = @_;
 629         # allow _complete --help to complete, not show help
 630         return 1 if substr($cmd, 0, 1) eq '_';
 631         $self->{cmd} = $cmd;
 632         $OPT = $self->{opt} //= {};
 633         my $info = $CMD{$cmd} // [ '[...]' ];
 634         my ($proto, undef, @spec) = @$info;
 635         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 636         push @spec, qw(help|h);
 637         my $lone_dash;
 638         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 639                 $lone_dash = $spec[0];
 640                 $OPT->{$spec[0]} = \(my $var);
 641                 push @spec, '' => \$var;
 642         }
 643         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 644                 return _help($self, "bad arguments or options for $cmd");
 645         return _help($self) if $OPT->{help};
 646
 647         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 648
 649         # "-" aliases "stdin" or "clear"
 650         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 651
 652         my $i = 0;
 653         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 654         my ($err, $inf);
 655         my @args = split(/ /, $proto);
 656         for my $var (@args) {
 657                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 658                         $inf = defined($argv->[$i]) and last;
 659                         $var =~ s/\.\.\.\z//;
 660                         $err = "$var not supplied";
 661                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 662                         $argv->[$i++] // ($err = "$var not supplied");
 663                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 664                         $inf = 1;
 665                         last;
 666                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 667                         $i++;
 668                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 669                         $inf = 1 if index($var, '...') > 0;
 670                         my @or = split(/\|/, $var);
 671                         my $ok;
 672                         for my $o (@or) {
 673                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 674                                         my $sw = $1;
 675                                         # assume pipe/regular file on stdin
 676                                         # w/o args means stdin
 677                                         if ($sw eq 'stdin' && !@$argv &&
 678                                                         (-p $self->{0} ||
 679                                                          -f _) && -r _) {
 680                                                 $OPT->{stdin} //= 1;
 681                                         }
 682                                         $ok = defined($OPT->{$sw});
 683                                         last if $ok;
 684                                 } elsif (defined($argv->[$i])) {
 685                                         $ok = 1;
 686                                         $i++;
 687                                         last;
 688                                 } # else continue looping
 689                         }
 690                         last if $ok;
 691                         my $last = pop @or;
 692                         $err = join(', ', @or) . " or $last must be set";
 693                 } else {
 694                         warn "BUG: can't parse `$var' in $proto";
 695                 }
 696                 last if $err;
 697         }
 698         if (!$inf && scalar(@$argv) > scalar(@args)) {
 699                 $err //= 'too many arguments';
 700         }
 701         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 702 }
 703
 704 sub _tmp_cfg { # for lei -c <name>=<value> ...
 705         my ($self) = @_;
 706         my $cfg = _lei_cfg($self, 1);
 707         require File::Temp;
 708         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 709         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 710         $ft->autoflush(1);
 711         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 712 [include]
 713         path = $cfg->{-f}
 714 EOM
 715         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 716         for (@{$self->{opt}->{c}}) {
 717                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 718 `-c $_' is not of the form -c <name>=<value>'
 719 EOM
 720                 my $name = $1;
 721                 my $value = $2 // 1;
 722                 _config($self, '--add', $name, $value);
 723                 if (defined(my $v = $tmp->{$name})) {
 724                         if (ref($v) eq 'ARRAY') {
 725                                 push @$v, $value;
 726                         } else {
 727                                 $tmp->{$name} = [ $v, $value ];
 728                         }
 729                 } else {
 730                         $tmp->{$name} = $value;
 731                 }
 732         }
 733 }
 734
 735 sub lazy_cb ($$$) {
 736         my ($self, $cmd, $pfx) = @_;
 737         my $ucmd = $cmd;
 738         $ucmd =~ tr/-/_/;
 739         my $cb;
 740         $cb = $self->can($pfx.$ucmd) and return $cb;
 741         my $base = $ucmd;
 742         $base =~ s/_([a-z])/\u$1/g;
 743         my $pkg = "PublicInbox::Lei\u$base";
 744         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 745                 $pkg->can($pfx.$ucmd) : undef;
 746 }
 747
 748 sub dispatch {
 749         my ($self, $cmd, @argv) = @_;
 750         local $current_lei = $self; # for __WARN__
 751         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 752         dump_and_clear_log("from previous run\n");
 753         return _help($self, 'no command given') unless defined($cmd);
 754         # do not support Getopt bundling for this
 755         while ($cmd eq '-C' || $cmd eq '-c') {
 756                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 757                                         '-C DIRECTORY' : '-c <name>=<value>');
 758                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 759                 $cmd = shift(@argv) // return _help($self, 'no command given');
 760         }
 761         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 762                 optparse($self, $cmd, \@argv) or return;
 763                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 764                 if (my $chdir = $self->{opt}->{C}) {
 765                         for my $d (@$chdir) {
 766                                 next if $d eq ''; # same as git(1)
 767                                 chdir $d or return fail($self, "cd $d: $!");
 768                         }
 769                         open $self->{3}, '.' or return fail($self, "open . $!");
 770                 }
 771                 $cb->($self, @argv);
 772         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 773                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 774                         or return _help($self, 'bad arguments or options');
 775                 _help($self);
 776         } else {
 777                 fail($self, "`$cmd' is not an lei command");
 778         }
 779 }
 780
 781 sub _lei_cfg ($;$) {
 782         my ($self, $creat) = @_;
 783         return $self->{cfg} if $self->{cfg};
 784         my $f = _config_path($self);
 785         my @st = stat($f);
 786         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 787         my ($sto, $sto_dir, $watches, $lne);
 788         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 789                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 790                 ($sto, $sto_dir, $watches, $lne) =
 791                                 @$cfg{qw(-lei_store leistore.dir -watches
 792                                         -lei_note_event)};
 793         }
 794         if (!@st) {
 795                 unless ($creat) {
 796                         delete $self->{cfg};
 797                         return bless {}, 'PublicInbox::Config';
 798                 }
 799                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 800                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 801                 open my $fh, '>>', $f or die "open($f): $!\n";
 802                 @st = stat($fh) or die "fstat($f): $!\n";
 803                 $cur_st = pack('dd', $st[10], $st[7]);
 804                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 805         }
 806         my $cfg = PublicInbox::Config->git_config_dump($f);
 807         $cfg->{-st} = $cur_st;
 808         $cfg->{'-f'} = $f;
 809         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 810                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 811                                                 store_path($self))) {
 812                 $cfg->{-lei_store} = $sto;
 813                 $cfg->{-lei_note_event} = $lne;
 814                 $cfg->{-watches} = $watches if $watches;
 815         }
 816         if (scalar(keys %PATH2CFG) > 5) {
 817                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 818                 for my $k (keys %PATH2CFG) {
 819                         delete($PATH2CFG{$k}) unless -f $k
 820                 }
 821         }
 822         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 823 }
 824
 825 sub _lei_store ($;$) {
 826         my ($self, $creat) = @_;
 827         my $cfg = _lei_cfg($self, $creat) // return;
 828         $cfg->{-lei_store} //= do {
 829                 require PublicInbox::LeiStore;
 830                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 831                 return unless $creat || -d $dir;
 832                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 833         };
 834 }
 835
 836 sub _config {
 837         my ($self, @argv) = @_;
 838         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 839         my $cfg = _lei_cfg($self, 1);
 840         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 841         my %rdr = map { $_ => $self->{$_} } (0..2);
 842         waitpid(spawn($cmd, \%env, \%rdr), 0);
 843 }
 844
 845 sub lei_config {
 846         my ($self, @argv) = @_;
 847         $self->{opt}->{'config-file'} and return fail $self,
 848                 "config file switches not supported by `lei config'";
 849         _config(@_);
 850         x_it($self, $?) if $?;
 851 }
 852
 853 sub lei_daemon_pid { puts shift, $$ }
 854
 855 sub lei_daemon_kill {
 856         my ($self) = @_;
 857         my $sig = $self->{opt}->{signal} // 'TERM';
 858         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 859 }
 860
 861 # Shell completion helper.  Used by lei-completion.bash and hopefully
 862 # other shells.  Try to do as much here as possible to avoid redundancy
 863 # and improve maintainability.
 864 sub lei__complete {
 865         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 866         shift @argv; # ignore "lei", the entire command is sent
 867         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 868         my $cmd = shift @argv;
 869         my $info = $CMD{$cmd} // do { # filter matching commands
 870                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 871                 return;
 872         };
 873         my ($proto, undef, @spec) = @$info;
 874         my $cur = pop @argv;
 875         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 876         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 877                 # gross special case since the only git-config options
 878                 # Consider moving to a table if we need more special cases
 879                 # we use Getopt::Long for are the ones we reject, so these
 880                 # are the ones we don't reject:
 881                 if ($cmd eq 'config') {
 882                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 883                         @spec = qw(add z|null get get-all unset unset-all
 884                                 replace-all get-urlmatch
 885                                 remove-section rename-section
 886                                 name-only list|l edit|e
 887                                 get-color-name get-colorbool);
 888                         # fall-through
 889                 }
 890                 # generate short/long names from Getopt::Long specs
 891                 puts $self, grep(/$re/, qw(--help -h -C), map {
 892                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 893                         } elsif (s/\+\z//) { # verbose|v+
 894                         } elsif (s/!\z//) {
 895                                 # negation: mail! => no-mail|mail
 896                                 s/([\w\-]+)/$1|no-$1/g
 897                         }
 898                         map {
 899                                 my $x = length > 1 ? "--$_" : "-$_";
 900                                 $x eq $_cur ? () : $x;
 901                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 902                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 903         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 904                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 905         }
 906
 907         # switch args (e.g. lei q -f mbox<TAB>)
 908         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 909                 my $opt = quotemeta $1;
 910                 puts $self, map {
 911                         my $v = $OPTDESC{$_};
 912                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 913                         # get rid of ALL CAPS placeholder (e.g "OUT")
 914                         # (TODO: completion for external paths)
 915                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 916                         @v;
 917                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 918         }
 919         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 920                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 921         }
 922         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 923         # proto parsing.
 924 }
 925
 926 sub exec_buf ($$) {
 927         my ($argv, $env) = @_;
 928         my $argc = scalar @$argv;
 929         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 930         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 931         $buf;
 932 }
 933
 934 sub start_mua {
 935         my ($self) = @_;
 936         my $mua = $self->{opt}->{mua} // return;
 937         my $mfolder = $self->{ovv}->{dst};
 938         my (@cmd, $replaced);
 939         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 940                 @cmd = ($mua, '-f');
 941         # TODO: help wanted: other common FOSS MUAs
 942         } else {
 943                 require Text::ParseWords;
 944                 @cmd = Text::ParseWords::shellwords($mua);
 945                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 946                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 947         }
 948         push @cmd, $mfolder unless defined($replaced);
 949         if ($self->{sock}) { # lei(1) client process runs it
 950                 # restore terminal: echo $query | lei q --stdin --mua=...
 951                 my $io = [];
 952                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 953                 send_exec_cmd($self, $io, \@cmd, {});
 954         }
 955         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 956                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 957         }
 958         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 959         $self->{opt}->{quiet} = 1;
 960         delete $self->{-progress};
 961         delete $self->{opt}->{verbose};
 962 }
 963
 964 sub send_exec_cmd { # tell script/lei to execute a command
 965         my ($self, $io, $cmd, $env) = @_;
 966         my $sock = $self->{sock} // die 'lei client gone';
 967         my $fds = [ map { fileno($_) } @$io ];
 968         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 969 }
 970
 971 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 972         my ($self) = @_;
 973         my $alerts = $self->{opt}->{alert} // return;
 974         my $sock = $self->{sock};
 975         while (my $op = shift(@$alerts)) {
 976                 if ($op eq ':WINCH') {
 977                         # hit the process group that started the MUA
 978                         send($sock, '-WINCH', MSG_EOR) if $sock;
 979                 } elsif ($op eq ':bell') {
 980                         out($self, "\a");
 981                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 982                         push @$alerts, split(/(?<!\\),/, $op);
 983                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 984                         my $cmd = $1; # run an arbitrary command
 985                         require Text::ParseWords;
 986                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 987                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 988                 } else {
 989                         err($self, "W: unsupported --alert=$op"); # non-fatal
 990                 }
 991         }
 992 }
 993
 994 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 995 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 996
 997 # this also normalizes the path
 998 sub path_to_fd {
 999         my ($self, $path) = @_;
1000         $path = rel2abs($self, $path);
1001         $path =~ tr!/!/!s;
1002         $path_to_fd{$path} // (
1003                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1004                         fail($self, "cannot open $path from daemon") : -1
1005         );
1006 }
1007
1008 # caller needs to "-t $self->{1}" to check if tty
1009 sub start_pager {
1010         my ($self) = @_;
1011         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1012         chomp(my $pager = <$fh> // '');
1013         close($fh) or warn "`git var PAGER' error: \$?=$?";
1014         return if $pager eq 'cat' || $pager eq '';
1015         my $new_env = { LESS => 'FRX', LV => '-c' };
1016         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1017         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1018         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1019         my $pgr = [ undef, @$rdr{1, 2} ];
1020         my $env = $self->{env};
1021         if ($self->{sock}) { # lei(1) process runs it
1022                 delete @$new_env{keys %$env}; # only set iff unset
1023                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1024         } else {
1025                 die 'BUG: start_pager w/o socket';
1026         }
1027         $self->{1} = $wpager;
1028         $self->{2} = $wpager if -t $self->{2};
1029         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1030         $self->{pgr} = $pgr;
1031 }
1032
1033 sub stop_pager {
1034         my ($self) = @_;
1035         my $pgr = delete($self->{pgr}) or return;
1036         $self->{2} = $pgr->[2];
1037         # do not restore original stdout, just close it so we error out
1038         close(delete($self->{1})) if $self->{1};
1039 }
1040
1041 sub accept_dispatch { # Listener {post_accept} callback
1042         my ($sock) = @_; # ignore other
1043         $sock->autoflush(1);
1044         my $self = bless { sock => $sock }, __PACKAGE__;
1045         vec(my $rvec = '', fileno($sock), 1) = 1;
1046         select($rvec, undef, undef, 60) or
1047                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1048         # (4096 * 33) >MAX_ARG_STRLEN
1049         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1050         if (!defined($fds[0])) {
1051                 warn(my $msg = "recv_cmd failed: $!");
1052                 return send($sock, $msg, MSG_EOR);
1053         } else {
1054                 my $i = 0;
1055                 for my $fd (@fds) {
1056                         open($self->{$i++}, '+<&=', $fd) and next;
1057                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1058                 }
1059                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1060         }
1061         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1062         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1063         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1064                 return send($sock, 'request command truncated', MSG_EOR);
1065         my ($argc, @argv) = split(/\0/, $buf, -1);
1066         undef $buf;
1067         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1068         if (chdir($self->{3})) {
1069                 local %ENV = %env;
1070                 $self->{env} = \%env;
1071                 eval { dispatch($self, @argv) };
1072                 send($sock, $@, MSG_EOR) if $@;
1073         } else {
1074                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1075         }
1076 }
1077
1078 sub dclose {
1079         my ($self) = @_;
1080         delete $self->{-progress};
1081         _drop_wq($self) if $self->{failed};
1082         close(delete $self->{1}) if $self->{1}; # may reap_compress
1083         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1084 }
1085
1086 # for long-running results
1087 sub event_step {
1088         my ($self) = @_;
1089         local %ENV = %{$self->{env}};
1090         my $sock = $self->{sock};
1091         local $current_lei = $self;
1092         eval {
1093                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1094                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1095                                 return if $! == EAGAIN;
1096                                 next if $! == EINTR;
1097                                 last if $! == ECONNRESET;
1098                                 die "recvmsg: $!";
1099                         }
1100                         for my $fd (@fds) {
1101                                 open my $rfh, '+<&=', $fd;
1102                         }
1103                         die "unrecognized client signal: $buf";
1104                 }
1105                 _drop_wq($self); # EOF, client disconnected
1106                 dclose($self);
1107         };
1108         if (my $err = $@) {
1109                 eval { $self->fail($err) };
1110                 dclose($self);
1111         }
1112 }
1113
1114 sub event_step_init {
1115         my ($self) = @_;
1116         my $sock = $self->{sock} or return;
1117         $self->{-event_init_done} //= do { # persist til $ops done
1118                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1119                 $sock;
1120         };
1121 }
1122
1123 sub noop {}
1124
1125 sub oldset { $oldset }
1126
1127 sub dump_and_clear_log {
1128         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1129                 my @pfx = @_;
1130                 unshift(@pfx, "$errors_log ") if @pfx;
1131                 warn @pfx, do { local $/; <STDIN> };
1132                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1133         }
1134 }
1135
1136 sub cfg2lei ($) {
1137         my ($cfg) = @_;
1138         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1139         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1140         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1141         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1142         open($lei->{3}, '/') or die "open /: $!";
1143         chdir($lei->{3}) or die "chdir /': $!";
1144         my ($x, $y);
1145         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1146         $lei->{sock} = $x;
1147         require PublicInbox::LeiSelfSocket;
1148         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1149         $lei;
1150 }
1151
1152 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1153         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1154         my $fn = $ev->fullname;
1155         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1156                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1157                 $nc = '' if $ev->IN_DELETE;
1158                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1159                         my $cfg = $PATH2CFG{$f} // next;
1160                         eval {
1161                                 local %ENV = %{$cfg->{-env}};
1162                                 my $lei = cfg2lei($cfg);
1163                                 $lei->dispatch('note-event',
1164                                                 "maildir:$mdir", $nc, $bn, $fn);
1165                         };
1166                         warn "E note-event $f: $@\n" if $@;
1167                 }
1168         }
1169         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1170                 $ev->cancel;
1171         }
1172         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1173                 delete $MDIR2CFGPATH->{$1};
1174         }
1175         if (!-e $fn) { # config file or Maildir gone
1176                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1177                         delete $cfgpaths->{$fn};
1178                 }
1179                 delete $PATH2CFG{$fn};
1180         }
1181 }
1182
1183 # lei(1) calls this when it can't connect
1184 sub lazy_start {
1185         my ($path, $errno, $narg) = @_;
1186         local ($errors_log, $listener);
1187         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1188         $errors_log = "$sock_dir/errors.log";
1189         my $addr = pack_sockaddr_un($path);
1190         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1191         $lk->lock_acquire;
1192         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1193         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1194                 return if connect($listener, $addr); # another process won
1195                 if ($errno == ECONNREFUSED && -S $path) {
1196                         unlink($path) or die "unlink($path): $!";
1197                 }
1198         } else {
1199                 $! = $errno; # allow interpolation to stringify in die
1200                 die "connect($path): $!";
1201         }
1202         umask(077) // die("umask(077): $!");
1203         bind($listener, $addr) or die "bind($path): $!";
1204         listen($listener, 1024) or die "listen: $!";
1205         $lk->lock_release;
1206         undef $lk;
1207         my @st = stat($path) or die "stat($path): $!";
1208         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1209         local $oldset = PublicInbox::DS::block_signals();
1210         if ($narg == 5) {
1211                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1212                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1213                         require PublicInbox::CmdIPC4;
1214                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1215                         PublicInbox::CmdIPC4->can('recv_cmd4');
1216                 };
1217         }
1218         $recv_cmd or die <<"";
1219 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1220
1221         require PublicInbox::Listener;
1222         require PublicInbox::PktOp;
1223         (-p STDOUT) or die "E: stdout must be a pipe\n";
1224         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1225         STDIN->autoflush(1);
1226         dump_and_clear_log("from previous daemon process:\n");
1227         POSIX::setsid() > 0 or die "setsid: $!";
1228         my $pid = fork // die "fork: $!";
1229         return if $pid;
1230         $0 = "lei-daemon $path";
1231         local %PATH2CFG;
1232         local $MDIR2CFGPATH;
1233         $listener->blocking(0);
1234         my $exit_code;
1235         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1236         local $quit = do {
1237                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1238                 sub {
1239                         $exit_code //= shift;
1240                         my $lis = $pil or exit($exit_code);
1241                         # closing eof_p triggers \&noop wakeup
1242                         $listener = $eof_p = $pil = $path = undef;
1243                         $lis->close; # DS::close
1244                         PublicInbox::DS->SetLoopTimeout(1000);
1245                 };
1246         };
1247         my $sig = {
1248                 CHLD => \&PublicInbox::DS::enqueue_reap,
1249                 QUIT => $quit,
1250                 INT => $quit,
1251                 TERM => $quit,
1252                 HUP => \&noop,
1253                 USR1 => \&noop,
1254                 USR2 => \&noop,
1255         };
1256         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1257         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1258         undef $sig;
1259         local $SIG{PIPE} = 'IGNORE';
1260         require PublicInbox::DirIdle;
1261         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1262                 # just rely on wakeup to hit PostLoopCallback set below
1263                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1264         }, 1);
1265         if ($sigfd) {
1266                 undef $sigfd; # unref, already in DS::DescriptorMap
1267         } else {
1268                 # wake up every second to accept signals if we don't
1269                 # have signalfd or IO::KQueue:
1270                 PublicInbox::DS::sig_setmask($oldset);
1271                 PublicInbox::DS->SetLoopTimeout(1000);
1272         }
1273         PublicInbox::DS->SetPostLoopCallback(sub {
1274                 my ($dmap, undef) = @_;
1275                 if (@st = defined($path) ? stat($path) : ()) {
1276                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1277                                 warn "$path dev/ino changed, quitting\n";
1278                                 $path = undef;
1279                         }
1280                 } elsif (defined($path)) { # ENOENT is common
1281                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1282                         undef $path;
1283                         $quit->();
1284                 }
1285                 return 1 if defined($path);
1286                 my $now = now();
1287                 my $n = 0;
1288                 for my $s (values %$dmap) {
1289                         $s->can('busy') or next;
1290                         if ($s->busy($now)) {
1291                                 ++$n;
1292                         } else {
1293                                 $s->close;
1294                         }
1295                 }
1296                 $n; # true: continue, false: stop
1297         });
1298
1299         # STDIN was redirected to /dev/null above, closing STDERR and
1300         # STDOUT will cause the calling `lei' client process to finish
1301         # reading the <$daemon> pipe.
1302         local $SIG{__WARN__} = sub {
1303                 $current_lei ? err($current_lei, @_) : warn(
1304                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1305         };
1306         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1307         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1308         # $daemon pipe to `lei' closed, main loop begins:
1309         PublicInbox::DS->EventLoop;
1310         exit($exit_code // 0);
1311 }
1312
1313 sub busy { 1 } # prevent daemon-shutdown if client is connected
1314
1315 # ensures stdout hits the FS before sock disconnects so a client
1316 # can immediately reread it
1317 sub DESTROY {
1318         my ($self) = @_;
1319         if (my $counters = delete $self->{counters}) {
1320                 for my $k (sort keys %$counters) {
1321                         my $nr = $counters->{$k};
1322                         $self->child_error(1 << 8, "$nr $k messages");
1323                 }
1324         }
1325         $self->{1}->autoflush(1) if $self->{1};
1326         stop_pager($self);
1327         # preserve $? for ->fail or ->x_it code
1328 }
1329
1330 sub wq_done_wait { # dwaitpid callback
1331         my ($arg, $pid) = @_;
1332         my ($wq, $lei) = @$arg;
1333         my $err_type = $lei->{-err_type};
1334         $? and $lei->child_error($?,
1335                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1336         $lei->dclose;
1337 }
1338
1339 sub fchdir {
1340         my ($lei) = @_;
1341         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1342         chdir($dh) || $lei->fail("fchdir: $!");
1343 }
1344
1345 sub wq_eof { # EOF callback for main daemon
1346         my ($lei) = @_;
1347         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1348         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1349 }
1350
1351 sub watch_state_ok ($) {
1352         my ($state) = $_[-1]; # $_[0] may be $self
1353         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1354 }
1355
1356 sub refresh_watches {
1357         my ($lei) = @_;
1358         my $cfg = _lei_cfg($lei) or return;
1359         $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1360         my $watches = $cfg->{-watches} //= {};
1361         require PublicInbox::LeiWatch;
1362         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1363                 my $url = substr($w, length('watch.'), -length('.state'));
1364                 my $lw = $watches->{$w} //= PublicInbox::LeiWatch->new($url);
1365                 my $state = $cfg->get_1("watch.$url", 'state');
1366                 if (!watch_state_ok($state)) {
1367                         $lei->err("watch.$url.state=$state not supported");
1368                         next;
1369                 }
1370                 my $f = $cfg->{'-f'};
1371                 if ($url =~ /\Amaildir:(.+)/i) {
1372                         my $d = File::Spec->canonpath($1);
1373                         if ($state eq 'pause') {
1374                                 delete $MDIR2CFGPATH->{$d}->{$f};
1375                                 scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1376                                         delete $MDIR2CFGPATH->{$d};
1377                         } elsif (!exists($MDIR2CFGPATH->{$d}->{$f})) {
1378                                 $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1379                                 $MDIR2CFGPATH->{$d}->{$f} = undef;
1380                         }
1381                 } else { # TODO: imap/nntp/jmap
1382                         $lei->child_error(1,
1383                                 "E: watch $url not supported, yet");
1384                 }
1385         }
1386 }
1387
1388 1;