lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g stdin|
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset keywords on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! kw|keywords|flags! interval=s recursive|r
 156         exclude=s include=s) ],
 157 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 158                 qw(format|f=s z) ],
 159 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 161 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 162         qw(prune) ],
 163
 164 'import' => [ 'URLS_OR_PATHNAMES...|--stdin',
 165         'one-time import/update from URL or filesystem',
 166         qw(stdin| offset=i recursive|r exclude=s include|I=s
 167         format|f=s kw|keywords|flags!),
 168         ],
 169
 170 'config' => [ '[...]', sub {
 171                 'git-config(1) wrapper for '._config_path($_[0]);
 172         }, qw(config-file|system|global|file|f=s), # for conflict detection
 173         pass_through('git config') ],
 174 'init' => [ '[PATHNAME]', sub {
 175                 'initialize storage, default: '._store_path($_[0]);
 176         }, qw(quiet|q) ],
 177 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 178         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 179 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 180 'help' => [ '[SUBCOMMAND]', 'show help' ],
 181
 182 # XXX do we need this?
 183 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 184
 185 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 186         'rewrite git history in an attempt to improve compression',
 187         'gc!' ],
 188
 189 # internal commands are prefixed with '_'
 190 '_complete' => [ '[...]', 'internal shell completion helper',
 191                 pass_through('everything') ],
 192 ); # @CMD
 193
 194 # switch descriptions, try to keep consistent across commands
 195 # $spec: Getopt::Long option specification
 196 # $spec => [@ALLOWED_VALUES (default is first), $description],
 197 # $spec => $description
 198 # "$SUB_COMMAND TAB $spec" => as above
 199 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 200                         'specify message input format' ];
 201 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 202
 203 my %OPTDESC = (
 204 'help|h' => 'show this built-in help',
 205 'quiet|q' => 'be quiet',
 206 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 207 'verbose|v' => 'be more verbose',
 208 'solve!' => 'do not attempt to reconstruct blobs from emails',
 209 'torsocks=s' => ['auto|no|yes',
 210                 'whether or not to wrap git and curl commands with torsocks'],
 211 'no-torsocks' => 'alias for --torsocks=no',
 212 'save-as=s' => ['NAME', 'save a search terms by given name'],
 213
 214 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 215
 216 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 217                 'deduplication strategy'],
 218 'show   thread|t' => 'display entire thread a message belongs to',
 219 'q      thread|t' =>
 220         'return all messages in the same thread as the actual match(es)',
 221 'augment|a' => 'augment --output destination instead of clobbering',
 222
 223 'output|mfolder|o=s' => [ 'DEST',
 224         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 225 'mua-cmd|mua=s' => [ 'COMMAND',
 226         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 227
 228 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 229                         'message/object output format' ],
 230 'mark   format|f=s' => $stdin_formats,
 231 'forget format|f=s' => $stdin_formats,
 232 'q      format|f=s' => [
 233         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 234                 'specify output format, default depends on --output'],
 235 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 236                 'exclude specified external(s) from search' ],
 237 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 238                 'include specified external(s) in search' ],
 239 'q      only=s@' => [ 'URL_OR_PATHNAME',
 240                 'only use specified external(s) for search' ],
 241
 242 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 243                 'control number of search and writer jobs' ],
 244
 245 'import format|f=s' => $stdin_formats,
 246
 247 'ls-query       format|f=s' => $ls_format,
 248 'ls-external    format|f=s' => $ls_format,
 249
 250 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 251 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 252
 253 'sort|s=s' => [ 'VAL|received,relevance,docid',
 254                 "order of results `--output'-dependent"],
 255 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 256
 257 'boost=i' => 'increase/decrease priority of results (default: 0)',
 258
 259 'local' => 'limit operations to the local filesystem',
 260 'local!' => 'exclude results from the local filesystem',
 261 'remote' => 'limit operations to those requiring network access',
 262 'remote!' => 'prevent operations requiring network access',
 263
 264 'mid=s' => 'specify the Message-ID of a message',
 265 'oid=s' => 'specify the git object ID of a message',
 266
 267 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 268 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 269 'include=s' => 'include mailboxes/newsgroups based on pattern',
 270
 271 'exact' => 'operate on exact header matches only',
 272 'exact!' => 'rely on content match instead of exact header matches',
 273
 274 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 275 'jobs:i' => 'set parallelism level',
 276
 277 'kw|keywords|flags!' => 'disable/enable importing flags',
 278
 279 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 280 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 281
 282 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 283 ); # %OPTDESC
 284
 285 my %CONFIG_KEYS = (
 286         'leistore.dir' => 'top-level storage location',
 287 );
 288
 289 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 290 sub x_it ($$) {
 291         my ($self, $code) = @_;
 292         # make sure client sees stdout before exit
 293         $self->{1}->autoflush(1) if $self->{1};
 294         dump_and_clear_log();
 295         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 296                 send($s, "x_it $code", MSG_EOR);
 297         } elsif ($self->{oneshot}) {
 298                 # don't want to end up using $? from child processes
 299                 for my $f (qw(lxs l2m)) {
 300                         my $wq = delete $self->{$f} or next;
 301                         $wq->DESTROY;
 302                 }
 303                 # cleanup anything that has tempfiles
 304                 delete @$self{qw(ovv dedupe)};
 305                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 306                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 307                         kill $signum, $$;
 308                         sleep(1) while 1; # wait for signal
 309                 } else {
 310                         $quit->($code >> 8);
 311                 }
 312         } # else ignore if client disconnected
 313 }
 314
 315 sub err ($;@) {
 316         my $self = shift;
 317         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 318         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 319         print $err @_, @eor and return;
 320         my $old_err = delete $self->{2};
 321         close($old_err) if $! == EPIPE && $old_err;
 322         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 323         print $err @_, @eor or print STDERR @_, @eor;
 324 }
 325
 326 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 327
 328 sub fail_handler ($;$$) {
 329         my ($lei, $code, $io) = @_;
 330         for my $f (qw(imp lxs l2m)) {
 331                 my $wq = delete $lei->{$f} or next;
 332                 $wq->wq_wait_old($lei) if $wq->wq_kill_old; # lei-daemon
 333         }
 334         close($io) if $io; # needed to avoid warnings on SIGPIPE
 335         $lei->x_it($code // (1 >> 8));
 336 }
 337
 338 sub sigpipe_handler { # handles SIGPIPE from l2m/lxs workers
 339         fail_handler($_[0], 13, delete $_[0]->{1});
 340 }
 341
 342 sub fail ($$;$) {
 343         my ($self, $buf, $exit_code) = @_;
 344         err($self, $buf) if defined $buf;
 345         # calls fail_handler:
 346         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 347         x_it($self, ($exit_code // 1) << 8);
 348         undef;
 349 }
 350
 351 sub out ($;@) {
 352         my $self = shift;
 353         return if print { $self->{1} // return } @_; # likely
 354         return note_sigpipe($self, 1) if $! == EPIPE;
 355         my $err = "error writing to stdout: $!";
 356         delete $self->{1};
 357         fail($self, $err);
 358 }
 359
 360 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 361
 362 sub child_error { # passes non-fatal curl exit codes to user
 363         my ($self, $child_error, $msg) = @_; # child_error is $?
 364         $self->err($msg) if $msg;
 365         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 366                 # send to the parent lei-daemon or to lei(1) client
 367                 send($s, "child_error $child_error", MSG_EOR);
 368         } elsif (!$PublicInbox::DS::in_loop) {
 369                 $self->{child_error} = $child_error;
 370         } # else noop if client disconnected
 371 }
 372
 373 sub note_sigpipe { # triggers sigpipe_handler
 374         my ($self, $fd) = @_;
 375         close(delete($self->{$fd})); # explicit close silences Perl warning
 376         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 377         x_it($self, 13);
 378 }
 379
 380 sub lei_atfork_child {
 381         my ($self, $persist) = @_;
 382         # we need to explicitly close things which are on stack
 383         if ($persist) {
 384                 my @io = delete @$self{0,1,2};
 385                 unless ($self->{oneshot}) {
 386                         close($_) for @io;
 387                 }
 388         } else {
 389                 delete $self->{0};
 390         }
 391         for (delete @$self{qw(3 sock old_1 au_done)}) {
 392                 close($_) if defined($_);
 393         }
 394         if (my $op_c = delete $self->{pkt_op_c}) {
 395                 close(delete $op_c->{sock});
 396         }
 397         if (my $pgr = delete $self->{pgr}) {
 398                 close($_) for (@$pgr[1,2]);
 399         }
 400         close $listener if $listener;
 401         undef $listener;
 402         %PATH2CFG = ();
 403         undef $errors_log;
 404         $quit = \&CORE::exit;
 405         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 406 }
 407
 408 sub _help ($;$) {
 409         my ($self, $errmsg) = @_;
 410         my $cmd = $self->{cmd} // 'COMMAND';
 411         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 412         my @top = ($cmd, shift(@info) // ());
 413         my $cmd_desc = shift(@info);
 414         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 415         my @opt_desc;
 416         my $lpad = 2;
 417         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 418                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 419                 my $arg_vals = '';
 420                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 421
 422                 # lower-case is a keyword (e.g. `content', `oid'),
 423                 # ALL_CAPS is a string description (e.g. `PATH')
 424                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 425                         $desc .= "\ndefault: `$1'";
 426                 }
 427                 my (@vals, @s, @l);
 428                 my $x = $sw;
 429                 if ($x =~ s/!\z//) { # solve! => --no-solve
 430                         $x =~ s/(\A|\|)/$1no-/g
 431                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 432                         @vals = (' [', undef, ']');
 433                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 434                         @vals = (' ', undef);
 435                 } # else: no args $x = 'thread|t'
 436                 for (split(/\|/, $x)) { # help|h
 437                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 438                 }
 439                 if (!scalar(@vals)) { # no args 'thread|t'
 440                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 441                         $vals[1] = $1;
 442                 } else {
 443                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 444                 }
 445                 if ($arg_vals =~ /([,\|])/) {
 446                         my $sep = $1;
 447                         my @allow = split(/\Q$sep\E/, $arg_vals);
 448                         my $must = $sep eq '|' ? 'Must' : 'Can';
 449                         @allow = map { "`$_'" } @allow;
 450                         my $last = pop @allow;
 451                         $desc .= "\n$must be one of: " .
 452                                 join(', ', @allow) . " or $last";
 453                 }
 454                 my $lhs = join(', ', @s, @l) . join('', @vals);
 455                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 456                         $lhs =~ s/\A--/- , --/;
 457                 } else {
 458                         $lhs =~ s/\A--/    --/; # pad if no short options
 459                 }
 460                 $lpad = length($lhs) if length($lhs) > $lpad;
 461                 push @opt_desc, $lhs, $desc;
 462         }
 463         my $msg = $errmsg ? "E: $errmsg\n" : '';
 464         $msg .= <<EOF;
 465 usage: lei @top
 466   $cmd_desc
 467
 468 EOF
 469         $lpad += 2;
 470         local $Text::Wrap::columns = 78 - $lpad;
 471         my $padding = ' ' x ($lpad + 2);
 472         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 473                 $msg .= '  '.pack("A$lpad", $lhs);
 474                 $rhs = wrap('', '', $rhs);
 475                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 476                 $msg .= $rhs;
 477                 $msg .= "\n";
 478         }
 479         my $out = $self->{$errmsg ? 2 : 1};
 480         start_pager($self) if -t $out;
 481         print $out $msg;
 482         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 483         undef;
 484 }
 485
 486 sub optparse ($$$) {
 487         my ($self, $cmd, $argv) = @_;
 488         $self->{cmd} = $cmd;
 489         $OPT = $self->{opt} = {};
 490         my $info = $CMD{$cmd} // [ '[...]' ];
 491         my ($proto, undef, @spec) = @$info;
 492         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 493         push @spec, qw(help|h);
 494         my $lone_dash;
 495         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 496                 $lone_dash = $spec[0];
 497                 $OPT->{$spec[0]} = \(my $var);
 498                 push @spec, '' => \$var;
 499         }
 500         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 501                 return _help($self, "bad arguments or options for $cmd");
 502         return _help($self) if $OPT->{help};
 503
 504         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 505
 506         # "-" aliases "stdin" or "clear"
 507         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 508
 509         my $i = 0;
 510         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 511         my ($err, $inf);
 512         my @args = split(/ /, $proto);
 513         for my $var (@args) {
 514                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 515                         $inf = defined($argv->[$i]) and last;
 516                         $var =~ s/\.\.\.\z//;
 517                         $err = "$var not supplied";
 518                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 519                         $argv->[$i++] // ($err = "$var not supplied");
 520                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 521                         $inf = 1;
 522                         last;
 523                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 524                         $i++;
 525                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 526                         $inf = 1 if index($var, '...') > 0;
 527                         my @or = split(/\|/, $var);
 528                         my $ok;
 529                         for my $o (@or) {
 530                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 531                                         $ok = defined($OPT->{$1});
 532                                         last if $ok;
 533                                 } elsif (defined($argv->[$i])) {
 534                                         $ok = 1;
 535                                         $i++;
 536                                         last;
 537                                 } # else continue looping
 538                         }
 539                         last if $ok;
 540                         my $last = pop @or;
 541                         $err = join(', ', @or) . " or $last must be set";
 542                 } else {
 543                         warn "BUG: can't parse `$var' in $proto";
 544                 }
 545                 last if $err;
 546         }
 547         if (!$inf && scalar(@$argv) > scalar(@args)) {
 548                 $err //= 'too many arguments';
 549         }
 550         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 551 }
 552
 553 sub dispatch {
 554         my ($self, $cmd, @argv) = @_;
 555         local $current_lei = $self; # for __WARN__
 556         dump_and_clear_log("from previous run\n");
 557         return _help($self, 'no command given') unless defined($cmd);
 558         my $func = "lei_$cmd";
 559         $func =~ tr/-/_/;
 560         if (my $cb = __PACKAGE__->can($func)) {
 561                 optparse($self, $cmd, \@argv) or return;
 562                 $cb->($self, @argv);
 563         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 564                 my $opt = {};
 565                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 566                         return _help($self, 'bad arguments or options');
 567                 _help($self);
 568         } else {
 569                 fail($self, "`$cmd' is not an lei command");
 570         }
 571 }
 572
 573 sub _lei_cfg ($;$) {
 574         my ($self, $creat) = @_;
 575         my $f = _config_path($self);
 576         my @st = stat($f);
 577         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 578         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 579                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 580         }
 581         if (!@st) {
 582                 unless ($creat) {
 583                         delete $self->{cfg};
 584                         return;
 585                 }
 586                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 587                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 588                 open my $fh, '>>', $f or die "open($f): $!\n";
 589                 @st = stat($fh) or die "fstat($f): $!\n";
 590                 $cur_st = pack('dd', $st[10], $st[7]);
 591                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 592         }
 593         my $cfg = PublicInbox::Config::git_config_dump($f);
 594         $cfg->{-st} = $cur_st;
 595         $cfg->{'-f'} = $f;
 596         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 597 }
 598
 599 sub _lei_store ($;$) {
 600         my ($self, $creat) = @_;
 601         my $cfg = _lei_cfg($self, $creat);
 602         $cfg->{-lei_store} //= do {
 603                 require PublicInbox::LeiStore;
 604                 my $dir = $cfg->{'leistore.dir'};
 605                 $dir //= $creat ? _store_path($self) : return;
 606                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 607         };
 608 }
 609
 610 sub lei_show {
 611         my ($self, @argv) = @_;
 612 }
 613
 614 sub lei_mark {
 615         my ($self, @argv) = @_;
 616 }
 617
 618 sub _config {
 619         my ($self, @argv) = @_;
 620         my $env = $self->{env};
 621         delete local $env->{GIT_CONFIG};
 622         delete local $ENV{GIT_CONFIG};
 623         my $cfg = _lei_cfg($self, 1);
 624         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 625         my %rdr = map { $_ => $self->{$_} } (0..2);
 626         waitpid(spawn($cmd, $env, \%rdr), 0);
 627 }
 628
 629 sub lei_config {
 630         my ($self, @argv) = @_;
 631         $self->{opt}->{'config-file'} and return fail $self,
 632                 "config file switches not supported by `lei config'";
 633         _config(@_);
 634         x_it($self, $?) if $?;
 635 }
 636
 637 sub lei_import {
 638         require PublicInbox::LeiImport;
 639         PublicInbox::LeiImport->call(@_);
 640 }
 641
 642 sub lei_init {
 643         my ($self, $dir) = @_;
 644         my $cfg = _lei_cfg($self, 1);
 645         my $cur = $cfg->{'leistore.dir'};
 646         $dir //= _store_path($self);
 647         $dir = rel2abs($self, $dir);
 648         my @cur = stat($cur) if defined($cur);
 649         $cur = File::Spec->canonpath($cur // $dir);
 650         my @dir = stat($dir);
 651         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 652         if (@cur) {
 653                 if ($cur eq $dir) {
 654                         _lei_store($self, 1)->done;
 655                         return qerr($self, $exists);
 656                 }
 657
 658                 # some folks like symlinks and bind mounts :P
 659                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 660                         lei_config($self, 'leistore.dir', $dir);
 661                         _lei_store($self, 1)->done;
 662                         return qerr($self, "$exists (as $cur)");
 663                 }
 664                 return fail($self, <<"");
 665 E: leistore.dir=$cur already initialized and it is not $dir
 666
 667         }
 668         lei_config($self, 'leistore.dir', $dir);
 669         _lei_store($self, 1)->done;
 670         $exists //= "I: leistore.dir=$dir newly initialized";
 671         return qerr($self, $exists);
 672 }
 673
 674 sub lei_daemon_pid { puts shift, $$ }
 675
 676 sub lei_daemon_kill {
 677         my ($self) = @_;
 678         my $sig = $self->{opt}->{signal} // 'TERM';
 679         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 680 }
 681
 682 sub lei_help { _help($_[0]) }
 683
 684 # Shell completion helper.  Used by lei-completion.bash and hopefully
 685 # other shells.  Try to do as much here as possible to avoid redundancy
 686 # and improve maintainability.
 687 sub lei__complete {
 688         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 689         shift @argv; # ignore "lei", the entire command is sent
 690         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 691         my $cmd = shift @argv;
 692         my $info = $CMD{$cmd} // do { # filter matching commands
 693                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 694                 return;
 695         };
 696         my ($proto, undef, @spec) = @$info;
 697         my $cur = pop @argv;
 698         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 699         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 700                 # gross special case since the only git-config options
 701                 # Consider moving to a table if we need more special cases
 702                 # we use Getopt::Long for are the ones we reject, so these
 703                 # are the ones we don't reject:
 704                 if ($cmd eq 'config') {
 705                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 706                         @spec = qw(add z|null get get-all unset unset-all
 707                                 replace-all get-urlmatch
 708                                 remove-section rename-section
 709                                 name-only list|l edit|e
 710                                 get-color-name get-colorbool);
 711                         # fall-through
 712                 }
 713                 puts $self, grep(/$re/, map { # generate short/long names
 714                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 715                         } elsif (s/!\z//) {
 716                                 # negation: solve! => no-solve|solve
 717                                 s/([\w\-]+)/$1|no-$1/g
 718                         }
 719                         map {
 720                                 my $x = length > 1 ? "--$_" : "-$_";
 721                                 $x eq $cur ? () : $x;
 722                         } split(/\|/, $_, -1) # help|h
 723                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 724         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 725                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 726         }
 727
 728         # switch args (e.g. lei q -f mbox<TAB>)
 729         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 730                 my $opt = quotemeta $1;
 731                 puts $self, map {
 732                         my $v = $OPTDESC{$_};
 733                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 734                         # get rid of ALL CAPS placeholder (e.g "OUT")
 735                         # (TODO: completion for external paths)
 736                         shift(@v) if uc($v[0]) eq $v[0];
 737                         @v;
 738                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 739         }
 740         $cmd =~ tr/-/_/;
 741         if (my $sub = $self->can("_complete_$cmd")) {
 742                 puts $self, $sub->($self, @argv, $cur);
 743         }
 744         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 745         # proto parsing.
 746 }
 747
 748 sub exec_buf ($$) {
 749         my ($argv, $env) = @_;
 750         my $argc = scalar @$argv;
 751         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 752         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 753         $buf;
 754 }
 755
 756 sub start_mua {
 757         my ($self) = @_;
 758         my $mua = $self->{opt}->{'mua-cmd'} // return;
 759         my $mfolder = $self->{ovv}->{dst};
 760         my (@cmd, $replaced);
 761         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 762                 @cmd = ($mua, '-f');
 763         # TODO: help wanted: other common FOSS MUAs
 764         } else {
 765                 require Text::ParseWords;
 766                 my @cmd = Text::ParseWords::shellwords($mua);
 767                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 768                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 769         }
 770         push @cmd, $mfolder unless defined($replaced);
 771         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 772                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 773         } elsif ($self->{oneshot}) {
 774                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 775         }
 776         delete $self->{-progress};
 777 }
 778
 779 # caller needs to "-t $self->{1}" to check if tty
 780 sub start_pager {
 781         my ($self) = @_;
 782         my $env = $self->{env};
 783         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 784         chomp(my $pager = <$fh> // '');
 785         close($fh) or warn "`git var PAGER' error: \$?=$?";
 786         return if $pager eq 'cat' || $pager eq '';
 787         # TODO TIOCGWINSZ
 788         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 789         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 790         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 791         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 792         my $pgr = [ undef, @$rdr{1, 2} ];
 793         if (my $sock = $self->{sock}) { # lei(1) process runs it
 794                 delete @$new_env{keys %$env}; # only set iff unset
 795                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 796                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 797         } elsif ($self->{oneshot}) {
 798                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 799                 $pgr->[3] = $$; # ew'll reap it
 800         } else {
 801                 die 'BUG: start_pager w/o socket';
 802         }
 803         $self->{1} = $wpager;
 804         $self->{2} = $wpager if -t $self->{2};
 805         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 806         $self->{pgr} = $pgr;
 807 }
 808
 809 sub stop_pager {
 810         my ($self) = @_;
 811         my $pgr = delete($self->{pgr}) or return;
 812         $self->{2} = $pgr->[2];
 813         # do not restore original stdout, just close it so we error out
 814         close(delete($self->{1})) if $self->{1};
 815         my $pid = $pgr->[0];
 816         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 817 }
 818
 819 sub accept_dispatch { # Listener {post_accept} callback
 820         my ($sock) = @_; # ignore other
 821         $sock->autoflush(1);
 822         my $self = bless { sock => $sock }, __PACKAGE__;
 823         vec(my $rvec = '', fileno($sock), 1) = 1;
 824         select($rvec, undef, undef, 60) or
 825                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 826         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 827         if (scalar(@fds) == 4) {
 828                 for my $i (0..3) {
 829                         my $fd = shift(@fds);
 830                         open($self->{$i}, '+<&=', $fd) and next;
 831                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 832                 }
 833         } else {
 834                 my $msg = "recv_cmd failed: $!";
 835                 warn $msg;
 836                 return send($sock, $msg, MSG_EOR);
 837         }
 838         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 839         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 840         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 841         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 842                 return send($sock, 'request command truncated', MSG_EOR);
 843         my ($argc, @argv) = split(/\0/, $buf, -1);
 844         undef $buf;
 845         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 846         if (chdir($self->{3})) {
 847                 local %ENV = %env;
 848                 $self->{env} = \%env;
 849                 eval { dispatch($self, @argv) };
 850                 send($sock, $@, MSG_EOR) if $@;
 851         } else {
 852                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 853         }
 854 }
 855
 856 sub dclose {
 857         my ($self) = @_;
 858         delete $self->{-progress};
 859         for my $f (qw(lxs l2m)) {
 860                 my $wq = delete $self->{$f} or next;
 861                 if ($wq->wq_kill) {
 862                         $wq->wq_close
 863                 } elsif ($wq->wq_kill_old) {
 864                         $wq->wq_wait_old($self);
 865                 }
 866         }
 867         close(delete $self->{1}) if $self->{1}; # may reap_compress
 868         $self->close if $self->{sock}; # PublicInbox::DS::close
 869 }
 870
 871 # for long-running results
 872 sub event_step {
 873         my ($self) = @_;
 874         local %ENV = %{$self->{env}};
 875         my $sock = $self->{sock};
 876         local $current_lei = $self;
 877         eval {
 878                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 879                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 880                                 return if $! == EAGAIN;
 881                                 next if $! == EINTR;
 882                                 last if $! == ECONNRESET;
 883                                 die "recvmsg: $!";
 884                         }
 885                         for my $fd (@fds) {
 886                                 open my $rfh, '+<&=', $fd;
 887                         }
 888                         die "unrecognized client signal: $buf";
 889                 }
 890                 dclose($self);
 891         };
 892         if (my $err = $@) {
 893                 eval { $self->fail($err) };
 894                 dclose($self);
 895         }
 896 }
 897
 898 sub event_step_init {
 899         my ($self) = @_;
 900         if (my $sock = $self->{sock}) { # using DS->EventLoop
 901                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 902         }
 903 }
 904
 905 sub noop {}
 906
 907 our $oldset; sub oldset { $oldset }
 908
 909 sub dump_and_clear_log {
 910         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 911                 my @pfx = @_;
 912                 unshift(@pfx, "$errors_log ") if @pfx;
 913                 warn @pfx, do { local $/; <STDIN> };
 914                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 915         }
 916 }
 917
 918 # lei(1) calls this when it can't connect
 919 sub lazy_start {
 920         my ($path, $errno, $narg) = @_;
 921         if ($errno == ECONNREFUSED) {
 922                 unlink($path) or die "unlink($path): $!";
 923         } elsif ($errno != ENOENT) {
 924                 $! = $errno; # allow interpolation to stringify in die
 925                 die "connect($path): $!";
 926         }
 927         if (eval { require BSD::Resource }) {
 928                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 929                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 930                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 931         }
 932         umask(077) // die("umask(077): $!");
 933         local $listener;
 934         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 935         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 936         listen($listener, 1024) or die "listen: $!";
 937         my @st = stat($path) or die "stat($path): $!";
 938         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 939         local $oldset = PublicInbox::DS::block_signals();
 940         if ($narg == 5) {
 941                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 942                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 943                         require PublicInbox::CmdIPC4;
 944                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 945                         PublicInbox::CmdIPC4->can('recv_cmd4');
 946                 };
 947         }
 948         $recv_cmd or die <<"";
 949 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 950
 951         require PublicInbox::Listener;
 952         require PublicInbox::EOFpipe;
 953         (-p STDOUT) or die "E: stdout must be a pipe\n";
 954         local $errors_log;
 955         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 956         $errors_log .= 'errors.log';
 957         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 958         STDIN->autoflush(1);
 959         dump_and_clear_log("from previous daemon process:\n");
 960         POSIX::setsid() > 0 or die "setsid: $!";
 961         my $pid = fork // die "fork: $!";
 962         return if $pid;
 963         $0 = "lei-daemon $path";
 964         local %PATH2CFG;
 965         $listener->blocking(0);
 966         my $exit_code;
 967         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 968         local $quit = do {
 969                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 970                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 971                 sub {
 972                         $exit_code //= shift;
 973                         my $lis = $pil or exit($exit_code);
 974                         # closing eof_w triggers \&noop wakeup
 975                         $listener = $eof_w = $pil = $path = undef;
 976                         $lis->close; # DS::close
 977                         PublicInbox::DS->SetLoopTimeout(1000);
 978                 };
 979         };
 980         my $sig = {
 981                 CHLD => \&PublicInbox::DS::enqueue_reap,
 982                 QUIT => $quit,
 983                 INT => $quit,
 984                 TERM => $quit,
 985                 HUP => \&noop,
 986                 USR1 => \&noop,
 987                 USR2 => \&noop,
 988         };
 989         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 990         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 991         undef $sig;
 992         local $SIG{PIPE} = 'IGNORE';
 993         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 994                 undef $sigfd;
 995                 PublicInbox::DS->SetLoopTimeout(5000);
 996         } else {
 997                 # wake up every second to accept signals if we don't
 998                 # have signalfd or IO::KQueue:
 999                 PublicInbox::DS::sig_setmask($oldset);
1000                 PublicInbox::DS->SetLoopTimeout(1000);
1001         }
1002         PublicInbox::DS->SetPostLoopCallback(sub {
1003                 my ($dmap, undef) = @_;
1004                 if (@st = defined($path) ? stat($path) : ()) {
1005                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1006                                 warn "$path dev/ino changed, quitting\n";
1007                                 $path = undef;
1008                         }
1009                 } elsif (defined($path)) { # ENOENT is common
1010                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1011                         undef $path;
1012                         $quit->();
1013                 }
1014                 return 1 if defined($path);
1015                 my $now = now();
1016                 my $n = 0;
1017                 for my $s (values %$dmap) {
1018                         $s->can('busy') or next;
1019                         if ($s->busy($now)) {
1020                                 ++$n;
1021                         } else {
1022                                 $s->close;
1023                         }
1024                 }
1025                 $n; # true: continue, false: stop
1026         });
1027
1028         # STDIN was redirected to /dev/null above, closing STDERR and
1029         # STDOUT will cause the calling `lei' client process to finish
1030         # reading the <$daemon> pipe.
1031         local $SIG{__WARN__} = sub {
1032                 $current_lei ? err($current_lei, @_) : warn(
1033                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1034         };
1035         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1036         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1037         # $daemon pipe to `lei' closed, main loop begins:
1038         PublicInbox::DS->EventLoop;
1039         exit($exit_code // 0);
1040 }
1041
1042 # for users w/o Socket::Msghdr installed or Inline::C enabled
1043 sub oneshot {
1044         my ($main_pkg) = @_;
1045         my $exit = $main_pkg->can('exit'); # caller may override exit()
1046         local $quit = $exit if $exit;
1047         local %PATH2CFG;
1048         umask(077) // die("umask(077): $!");
1049         my $self = bless {
1050                 oneshot => 1,
1051                 0 => *STDIN{GLOB},
1052                 1 => *STDOUT{GLOB},
1053                 2 => *STDERR{GLOB},
1054                 env => \%ENV
1055         }, __PACKAGE__;
1056         dispatch($self, @ARGV);
1057         x_it($self, $self->{child_error}) if $self->{child_error};
1058 }
1059
1060 # ensures stdout hits the FS before sock disconnects so a client
1061 # can immediately reread it
1062 sub DESTROY {
1063         my ($self) = @_;
1064         $self->{1}->autoflush(1) if $self->{1};
1065         stop_pager($self);
1066         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1067                 waitpid($mua_pid, 0);
1068         }
1069 }
1070
1071 1;