lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'export-kw' => [ 'LOCATION...|--all',
 249         'one-time export of keywords of sync sources',
 250         qw(all:s mode=s), @c_opt ],
 251 'convert' => [ 'LOCATION...|--stdin',
 252         'one-time conversion from URL or filesystem to another format',
 253         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 254         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 255 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 256         "use a patch to generate a query for `lei q --stdin'",
 257         qw(stdin| want|w=s@ uri debug), @c_opt ],
 258 'config' => [ '[...]', sub {
 259                 'git-config(1) wrapper for '._config_path($_[0]);
 260         }, qw(config-file|system|global|file|f=s), # for conflict detection
 261          qw(c=s@ C=s@), pass_through('git config') ],
 262 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 263         qw(pretty ascii dir=s), @c_opt ],
 264
 265 'init' => [ '[DIRNAME]', sub {
 266         "initialize storage, default: ".store_path($_[0]);
 267         }, @c_opt ],
 268 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 269         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 270         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 271 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 272 'help' => [ '[SUBCOMMAND]', 'show help' ],
 273
 274 # TODO
 275 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 276 #       'rewrite git history in an attempt to improve compression',
 277 #       qw(gc!), @c_opt ],
 278 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 279 #
 280 # internal commands are prefixed with '_'
 281 '_complete' => [ '[...]', 'internal shell completion helper',
 282                 pass_through('everything') ],
 283 ); # @CMD
 284
 285 # switch descriptions, try to keep consistent across commands
 286 # $spec: Getopt::Long option specification
 287 # $spec => [@ALLOWED_VALUES (default is first), $description],
 288 # $spec => $description
 289 # "$SUB_COMMAND TAB $spec" => as above
 290 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 291                         'specify message input format' ];
 292 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 293
 294 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 295 my %OPTDESC = (
 296 'help|h' => 'show this built-in help',
 297 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 298 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 299 'quiet|q' => 'be quiet',
 300 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 301         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 302
 303 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 304 'globoff|g' => "do not match locations using '*?' wildcards ".
 305                 "and\xa0'[]'\x{a0}ranges",
 306 'invert-match|v' => 'select non-matching lines',
 307 'color!' => 'disable color (for --format=text)',
 308 'verbose|v+' => 'be more verbose',
 309 'external!' => 'do not use externals',
 310 'mail!' => 'do not look in mail storage for OID',
 311 'cwd!' => 'do not look in git repo of current working directory',
 312 'oid-a|A=s' => 'pre-image OID',
 313 'path-a|a=s' => 'pre-image pathname associated with OID',
 314 'path-b|b=s' => 'post-image pathname associated with OID',
 315 'git-dir=s@' => 'additional git repository to scan',
 316 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 317         "proxy for (e.g. `socks5h://0:9050')" ],
 318 'torsocks=s' => ['VAL|auto|no|yes',
 319                 'whether or not to wrap git and curl commands with torsocks'],
 320 'no-torsocks' => 'alias for --torsocks=no',
 321 'save' =>  "save a search for `lei up'",
 322 'import-remote!' => 'do not memoize remote messages into local store',
 323
 324 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 325
 326 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 327                 'deduplication strategy'],
 328 'threads|t+' =>
 329         'return all messages in the same threads as the actual match(es)',
 330
 331 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 332                 'search prefixes to extract (default: dfpost7)' ],
 333
 334 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 335         'run command(s) or perform ops when done writing to output ' .
 336         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 337         'nothing otherwise)' ],
 338
 339 'augment|a' => 'augment --output destination instead of clobbering',
 340
 341 'output|mfolder|o=s' => [ 'MFOLDER',
 342         "destination (e.g.\xa0`/path/to/Maildir', ".
 343         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 344 'mua=s' => [ 'CMD',
 345         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 346
 347 'inbox-version=i' => [ 'NUM|1|2',
 348                 'force a public-inbox version with --mirror'],
 349 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 350
 351 # public-inbox-index options
 352 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 353 'compact' => 'run compact index after mirroring',
 354 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 355         "indexlevel with --mirror (default: full)" ],
 356 'max_size|max-size=s' => [ 'SIZE',
 357         'do not index messages larger than SIZE (default: infinity)' ],
 358 'batch_size|batch-size=s' => [ 'SIZE',
 359         'flush changes to OS after given number of bytes (default: 1m)' ],
 360 'sequential_shard|sequential-shard' =>
 361         'index Xapian shards sequentially for slow storage',
 362 'skip-docdata' =>
 363         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 364
 365 'format|f=s     q' => [
 366         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 367                 'specify output format, default depends on --output'],
 368 'exclude=s@     q' => [ 'LOCATION',
 369                 'exclude specified external(s) from search' ],
 370 'include|I=s@   q' => [ 'LOCATION',
 371                 'include specified external(s) in search' ],
 372 'only=s@        q' => [ 'LOCATION',
 373                 'only use specified external(s) for search' ],
 374 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 375                 'control number of search and writer jobs' ],
 376 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 377
 378 'in-format|F=s' => $stdin_formats,
 379 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 380                         'listing output format' ],
 381 'l      ls-search' => 'long listing format',
 382 'format|f=s     ls-external' => $ls_format,
 383
 384 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 385 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 386
 387 'sort|s=s' => [ 'VAL|received|relevance|docid',
 388                 "order of results is `--output'-dependent"],
 389 'reverse|r' => 'reverse search results', # like sort(1)
 390
 391 'boost=i' => 'increase/decrease priority of results (default: 0)',
 392
 393 'local' => 'limit operations to the local filesystem',
 394 'local!' => 'exclude results from the local filesystem',
 395 'remote' => 'limit operations to those requiring network access',
 396 'remote!' => 'prevent operations requiring network access',
 397
 398 'all:s  up' => ['local', 'update all (local) saved searches' ],
 399
 400 'mid=s' => 'specify the Message-ID of a message',
 401 'oid=s' => 'specify the git object ID of a message',
 402
 403 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 404 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 405 'include=s' => 'include mailboxes/newsgroups based on pattern',
 406
 407 'exact' => 'operate on exact header matches only',
 408 'exact!' => 'rely on content match instead of exact header matches',
 409
 410 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 411
 412 'kw!' => 'disable/enable importing keywords (aka "flags")',
 413
 414 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 415 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 416
 417 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 418 ); # %OPTDESC
 419
 420 my %CONFIG_KEYS = (
 421         'leistore.dir' => 'top-level storage location',
 422 );
 423
 424 my @WQ_KEYS = qw(lxs l2m wq1 ikw); # internal workers
 425
 426 sub _drop_wq {
 427         my ($self) = @_;
 428         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 429                 if ($wq->wq_kill) {
 430                         $wq->wq_close(0, undef, $self);
 431                 } elsif ($wq->wq_kill_old) {
 432                         $wq->wq_wait_old(undef, $self);
 433                 }
 434                 $wq->DESTROY;
 435         }
 436 }
 437
 438 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 439 sub x_it ($$) {
 440         my ($self, $code) = @_;
 441         # make sure client sees stdout before exit
 442         $self->{1}->autoflush(1) if $self->{1};
 443         dump_and_clear_log();
 444         if ($self->{pkt_op_p}) { # to top lei-daemon
 445                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 446         } elsif ($self->{sock}) { # to lei(1) client
 447                 send($self->{sock}, "x_it $code", MSG_EOR);
 448         } # else ignore if client disconnected
 449 }
 450
 451 sub err ($;@) {
 452         my $self = shift;
 453         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 454         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 455         print $err @_, @eor and return;
 456         my $old_err = delete $self->{2};
 457         close($old_err) if $! == EPIPE && $old_err;
 458         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         print $err @_, @eor or print STDERR @_, @eor;
 460 }
 461
 462 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 463
 464 sub fail_handler ($;$$) {
 465         my ($lei, $code, $io) = @_;
 466         close($io) if $io; # needed to avoid warnings on SIGPIPE
 467         _drop_wq($lei);
 468         x_it($lei, $code // (1 << 8));
 469 }
 470
 471 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 472         fail_handler($_[0], 13, delete $_[0]->{1});
 473 }
 474
 475 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 476 sub sigint_reap {
 477         my ($pgid) = @_;
 478         dwaitpid($pgid) if kill('-INT', $pgid);
 479 }
 480
 481 sub fail ($$;$) {
 482         my ($self, $buf, $exit_code) = @_;
 483         $self->{failed}++;
 484         err($self, $buf) if defined $buf;
 485         # calls fail_handler:
 486         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 487         x_it($self, ($exit_code // 1) << 8);
 488         undef;
 489 }
 490
 491 sub out ($;@) {
 492         my $self = shift;
 493         return if print { $self->{1} // return } @_; # likely
 494         return note_sigpipe($self, 1) if $! == EPIPE;
 495         my $err = "error writing to output: $!";
 496         delete $self->{1};
 497         fail($self, $err);
 498 }
 499
 500 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 501
 502 sub child_error { # passes non-fatal curl exit codes to user
 503         my ($self, $child_error, $msg) = @_; # child_error is $?
 504         $self->err($msg) if $msg;
 505         if ($self->{pkt_op_p}) { # to top lei-daemon
 506                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 507         } elsif ($self->{sock}) { # to lei(1) client
 508                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 509         } # else noop if client disconnected
 510 }
 511
 512 sub note_sigpipe { # triggers sigpipe_handler
 513         my ($self, $fd) = @_;
 514         close(delete($self->{$fd})); # explicit close silences Perl warning
 515         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 516         x_it($self, 13);
 517 }
 518
 519 sub _lei_atfork_child {
 520         my ($self, $persist) = @_;
 521         # we need to explicitly close things which are on stack
 522         if ($persist) {
 523                 chdir '/' or die "chdir(/): $!";
 524                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 525                 if (my $cfg = $self->{cfg}) {
 526                         delete $cfg->{-lei_store};
 527                 }
 528         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 529                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 530                 STDERR->autoflush(1);
 531         }
 532         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 533         if (my $op_c = delete $self->{pkt_op_c}) {
 534                 close(delete $op_c->{sock});
 535         }
 536         if (my $pgr = delete $self->{pgr}) {
 537                 close($_) for (@$pgr[1,2]);
 538         }
 539         close $listener if $listener;
 540         undef $listener;
 541         undef $dir_idle;
 542         %PATH2CFG = ();
 543         undef $errors_log;
 544         $quit = \&CORE::exit;
 545         $self->{-eml_noisy} or # only "lei import" sets this atm
 546                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 547         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 548 }
 549
 550 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 551         my ($self) = @_;
 552         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 553                 $op->close; # PublicInbox::PktOp::close
 554         }
 555         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 556         close $pkt_op_p->{op_p};
 557 }
 558
 559 sub pkt_op_pair {
 560         my ($self) = @_;
 561         require PublicInbox::OnDestroy;
 562         require PublicInbox::PktOp;
 563         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 564         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 565         $end;
 566 }
 567
 568 sub workers_start {
 569         my ($lei, $wq, $jobs, $ops) = @_;
 570         $ops = {
 571                 '!' => [ \&fail_handler, $lei ],
 572                 '|' => [ \&sigpipe_handler, $lei ],
 573                 'x_it' => [ \&x_it, $lei ],
 574                 'child_error' => [ \&child_error, $lei ],
 575                 ($ops ? %$ops : ()),
 576         };
 577         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 578         my $end = $lei->pkt_op_pair;
 579         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 580         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 581         delete $lei->{pkt_op_p};
 582         my $op_c = delete $lei->{pkt_op_c};
 583         @$end = ();
 584         $lei->event_step_init;
 585         ($op_c, $ops);
 586 }
 587
 588 sub _help {
 589         require PublicInbox::LeiHelp;
 590         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 591 }
 592
 593 sub optparse ($$$) {
 594         my ($self, $cmd, $argv) = @_;
 595         # allow _complete --help to complete, not show help
 596         return 1 if substr($cmd, 0, 1) eq '_';
 597         $self->{cmd} = $cmd;
 598         $OPT = $self->{opt} //= {};
 599         my $info = $CMD{$cmd} // [ '[...]' ];
 600         my ($proto, undef, @spec) = @$info;
 601         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 602         push @spec, qw(help|h);
 603         my $lone_dash;
 604         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 605                 $lone_dash = $spec[0];
 606                 $OPT->{$spec[0]} = \(my $var);
 607                 push @spec, '' => \$var;
 608         }
 609         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 610                 return _help($self, "bad arguments or options for $cmd");
 611         return _help($self) if $OPT->{help};
 612
 613         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 614
 615         # "-" aliases "stdin" or "clear"
 616         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 617
 618         my $i = 0;
 619         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 620         my ($err, $inf);
 621         my @args = split(/ /, $proto);
 622         for my $var (@args) {
 623                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 624                         $inf = defined($argv->[$i]) and last;
 625                         $var =~ s/\.\.\.\z//;
 626                         $err = "$var not supplied";
 627                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 628                         $argv->[$i++] // ($err = "$var not supplied");
 629                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 630                         $inf = 1;
 631                         last;
 632                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 633                         $i++;
 634                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 635                         $inf = 1 if index($var, '...') > 0;
 636                         my @or = split(/\|/, $var);
 637                         my $ok;
 638                         for my $o (@or) {
 639                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 640                                         my $sw = $1;
 641                                         # assume pipe/regular file on stdin
 642                                         # w/o args means stdin
 643                                         if ($sw eq 'stdin' && !@$argv &&
 644                                                         (-p $self->{0} ||
 645                                                          -f _) && -r _) {
 646                                                 $OPT->{stdin} //= 1;
 647                                         }
 648                                         $ok = defined($OPT->{$sw});
 649                                         last if $ok;
 650                                 } elsif (defined($argv->[$i])) {
 651                                         $ok = 1;
 652                                         $i++;
 653                                         last;
 654                                 } # else continue looping
 655                         }
 656                         last if $ok;
 657                         my $last = pop @or;
 658                         $err = join(', ', @or) . " or $last must be set";
 659                 } else {
 660                         warn "BUG: can't parse `$var' in $proto";
 661                 }
 662                 last if $err;
 663         }
 664         if (!$inf && scalar(@$argv) > scalar(@args)) {
 665                 $err //= 'too many arguments';
 666         }
 667         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 668 }
 669
 670 sub _tmp_cfg { # for lei -c <name>=<value> ...
 671         my ($self) = @_;
 672         my $cfg = _lei_cfg($self, 1);
 673         require File::Temp;
 674         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 675         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 676         $ft->autoflush(1);
 677         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 678 [include]
 679         path = $cfg->{-f}
 680 EOM
 681         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 682         for (@{$self->{opt}->{c}}) {
 683                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 684 `-c $_' is not of the form -c <name>=<value>'
 685 EOM
 686                 my $name = $1;
 687                 my $value = $2 // 1;
 688                 _config($self, '--add', $name, $value);
 689                 if (defined(my $v = $tmp->{$name})) {
 690                         if (ref($v) eq 'ARRAY') {
 691                                 push @$v, $value;
 692                         } else {
 693                                 $tmp->{$name} = [ $v, $value ];
 694                         }
 695                 } else {
 696                         $tmp->{$name} = $value;
 697                 }
 698         }
 699 }
 700
 701 sub lazy_cb ($$$) {
 702         my ($self, $cmd, $pfx) = @_;
 703         my $ucmd = $cmd;
 704         $ucmd =~ tr/-/_/;
 705         my $cb;
 706         $cb = $self->can($pfx.$ucmd) and return $cb;
 707         my $base = $ucmd;
 708         $base =~ s/_([a-z])/\u$1/g;
 709         my $pkg = "PublicInbox::Lei\u$base";
 710         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 711                 $pkg->can($pfx.$ucmd) : undef;
 712 }
 713
 714 sub dispatch {
 715         my ($self, $cmd, @argv) = @_;
 716         local $current_lei = $self; # for __WARN__
 717         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 718         dump_and_clear_log("from previous run\n");
 719         return _help($self, 'no command given') unless defined($cmd);
 720         # do not support Getopt bundling for this
 721         while ($cmd eq '-C' || $cmd eq '-c') {
 722                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 723                                         '-C DIRECTORY' : '-c <name>=<value>');
 724                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 725                 $cmd = shift(@argv) // return _help($self, 'no command given');
 726         }
 727         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 728                 optparse($self, $cmd, \@argv) or return;
 729                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 730                 if (my $chdir = $self->{opt}->{C}) {
 731                         for my $d (@$chdir) {
 732                                 next if $d eq ''; # same as git(1)
 733                                 chdir $d or return fail($self, "cd $d: $!");
 734                         }
 735                         if (delete $self->{3}) { # update cwd for rel2abs
 736                                 opendir my $dh, '.' or
 737                                         return fail($self, "opendir . $!");
 738                                 $self->{3} = $dh;
 739                         }
 740                 }
 741                 $cb->($self, @argv);
 742         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 743                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 744                         or return _help($self, 'bad arguments or options');
 745                 _help($self);
 746         } else {
 747                 fail($self, "`$cmd' is not an lei command");
 748         }
 749 }
 750
 751 sub _lei_cfg ($;$) {
 752         my ($self, $creat) = @_;
 753         return $self->{cfg} if $self->{cfg};
 754         my $f = _config_path($self);
 755         my @st = stat($f);
 756         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 757         my ($sto, $sto_dir);
 758         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 759                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 760                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 761         }
 762         if (!@st) {
 763                 unless ($creat) {
 764                         delete $self->{cfg};
 765                         return bless {}, 'PublicInbox::Config';
 766                 }
 767                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 768                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 769                 open my $fh, '>>', $f or die "open($f): $!\n";
 770                 @st = stat($fh) or die "fstat($f): $!\n";
 771                 $cur_st = pack('dd', $st[10], $st[7]);
 772                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 773         }
 774         my $cfg = PublicInbox::Config->git_config_dump($f);
 775         $cfg->{-st} = $cur_st;
 776         $cfg->{'-f'} = $f;
 777         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 778                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 779                                                 store_path($self))) {
 780                 $cfg->{-lei_store} = $sto;
 781         }
 782         if (scalar(keys %PATH2CFG) > 5) {
 783                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 784                 for my $k (keys %PATH2CFG) {
 785                         delete($PATH2CFG{$k}) unless -f $k
 786                 }
 787         }
 788         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 789 }
 790
 791 sub _lei_store ($;$) {
 792         my ($self, $creat) = @_;
 793         my $cfg = _lei_cfg($self, $creat);
 794         $cfg->{-lei_store} //= do {
 795                 require PublicInbox::LeiStore;
 796                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 797                 return unless $creat || -d $dir;
 798                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 799         };
 800 }
 801
 802 sub _config {
 803         my ($self, @argv) = @_;
 804         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 805         my $cfg = _lei_cfg($self, 1);
 806         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 807         my %rdr = map { $_ => $self->{$_} } (0..2);
 808         waitpid(spawn($cmd, \%env, \%rdr), 0);
 809 }
 810
 811 sub lei_config {
 812         my ($self, @argv) = @_;
 813         $self->{opt}->{'config-file'} and return fail $self,
 814                 "config file switches not supported by `lei config'";
 815         _config(@_);
 816         x_it($self, $?) if $?;
 817 }
 818
 819 sub lei_daemon_pid { puts shift, $$ }
 820
 821 sub lei_daemon_kill {
 822         my ($self) = @_;
 823         my $sig = $self->{opt}->{signal} // 'TERM';
 824         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 825 }
 826
 827 # Shell completion helper.  Used by lei-completion.bash and hopefully
 828 # other shells.  Try to do as much here as possible to avoid redundancy
 829 # and improve maintainability.
 830 sub lei__complete {
 831         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 832         shift @argv; # ignore "lei", the entire command is sent
 833         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 834         my $cmd = shift @argv;
 835         my $info = $CMD{$cmd} // do { # filter matching commands
 836                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 837                 return;
 838         };
 839         my ($proto, undef, @spec) = @$info;
 840         my $cur = pop @argv;
 841         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 842         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 843                 # gross special case since the only git-config options
 844                 # Consider moving to a table if we need more special cases
 845                 # we use Getopt::Long for are the ones we reject, so these
 846                 # are the ones we don't reject:
 847                 if ($cmd eq 'config') {
 848                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 849                         @spec = qw(add z|null get get-all unset unset-all
 850                                 replace-all get-urlmatch
 851                                 remove-section rename-section
 852                                 name-only list|l edit|e
 853                                 get-color-name get-colorbool);
 854                         # fall-through
 855                 }
 856                 # generate short/long names from Getopt::Long specs
 857                 puts $self, grep(/$re/, qw(--help -h -C), map {
 858                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 859                         } elsif (s/\+\z//) { # verbose|v+
 860                         } elsif (s/!\z//) {
 861                                 # negation: mail! => no-mail|mail
 862                                 s/([\w\-]+)/$1|no-$1/g
 863                         }
 864                         map {
 865                                 my $x = length > 1 ? "--$_" : "-$_";
 866                                 $x eq $_cur ? () : $x;
 867                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 868                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 869         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 870                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 871         }
 872
 873         # switch args (e.g. lei q -f mbox<TAB>)
 874         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 875                 my $opt = quotemeta $1;
 876                 puts $self, map {
 877                         my $v = $OPTDESC{$_};
 878                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 879                         # get rid of ALL CAPS placeholder (e.g "OUT")
 880                         # (TODO: completion for external paths)
 881                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 882                         @v;
 883                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 884         }
 885         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 886                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 887         }
 888         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 889         # proto parsing.
 890 }
 891
 892 sub exec_buf ($$) {
 893         my ($argv, $env) = @_;
 894         my $argc = scalar @$argv;
 895         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 896         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 897         $buf;
 898 }
 899
 900 sub start_mua {
 901         my ($self) = @_;
 902         my $mua = $self->{opt}->{mua} // return;
 903         my $mfolder = $self->{ovv}->{dst};
 904         my (@cmd, $replaced);
 905         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 906                 @cmd = ($mua, '-f');
 907         # TODO: help wanted: other common FOSS MUAs
 908         } else {
 909                 require Text::ParseWords;
 910                 @cmd = Text::ParseWords::shellwords($mua);
 911                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 912                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 913         }
 914         push @cmd, $mfolder unless defined($replaced);
 915         if ($self->{sock}) { # lei(1) client process runs it
 916                 # restore terminal: echo $query | lei q --stdin --mua=...
 917                 my $io = [];
 918                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 919                 send_exec_cmd($self, $io, \@cmd, {});
 920         }
 921         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 922                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 923         }
 924         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 925         $self->{opt}->{quiet} = 1;
 926         delete $self->{-progress};
 927         delete $self->{opt}->{verbose};
 928 }
 929
 930 sub send_exec_cmd { # tell script/lei to execute a command
 931         my ($self, $io, $cmd, $env) = @_;
 932         my $sock = $self->{sock} // die 'lei client gone';
 933         my $fds = [ map { fileno($_) } @$io ];
 934         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 935 }
 936
 937 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 938         my ($self) = @_;
 939         my $alerts = $self->{opt}->{alert} // return;
 940         my $sock = $self->{sock};
 941         while (my $op = shift(@$alerts)) {
 942                 if ($op eq ':WINCH') {
 943                         # hit the process group that started the MUA
 944                         send($sock, '-WINCH', MSG_EOR) if $sock;
 945                 } elsif ($op eq ':bell') {
 946                         out($self, "\a");
 947                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 948                         push @$alerts, split(/(?<!\\),/, $op);
 949                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 950                         my $cmd = $1; # run an arbitrary command
 951                         require Text::ParseWords;
 952                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 953                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 954                 } else {
 955                         err($self, "W: unsupported --alert=$op"); # non-fatal
 956                 }
 957         }
 958 }
 959
 960 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 961 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 962
 963 # this also normalizes the path
 964 sub path_to_fd {
 965         my ($self, $path) = @_;
 966         $path = rel2abs($self, $path);
 967         $path =~ tr!/!/!s;
 968         $path_to_fd{$path} // (
 969                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 970                         fail($self, "cannot open $path from daemon") : -1
 971         );
 972 }
 973
 974 # caller needs to "-t $self->{1}" to check if tty
 975 sub start_pager {
 976         my ($self) = @_;
 977         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 978         chomp(my $pager = <$fh> // '');
 979         close($fh) or warn "`git var PAGER' error: \$?=$?";
 980         return if $pager eq 'cat' || $pager eq '';
 981         my $new_env = { LESS => 'FRX', LV => '-c' };
 982         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 983         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 984         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 985         my $pgr = [ undef, @$rdr{1, 2} ];
 986         my $env = $self->{env};
 987         if ($self->{sock}) { # lei(1) process runs it
 988                 delete @$new_env{keys %$env}; # only set iff unset
 989                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 990         } else {
 991                 die 'BUG: start_pager w/o socket';
 992         }
 993         $self->{1} = $wpager;
 994         $self->{2} = $wpager if -t $self->{2};
 995         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 996         $self->{pgr} = $pgr;
 997 }
 998
 999 sub stop_pager {
1000         my ($self) = @_;
1001         my $pgr = delete($self->{pgr}) or return;
1002         $self->{2} = $pgr->[2];
1003         # do not restore original stdout, just close it so we error out
1004         close(delete($self->{1})) if $self->{1};
1005 }
1006
1007 sub accept_dispatch { # Listener {post_accept} callback
1008         my ($sock) = @_; # ignore other
1009         $sock->autoflush(1);
1010         my $self = bless { sock => $sock }, __PACKAGE__;
1011         vec(my $rvec = '', fileno($sock), 1) = 1;
1012         select($rvec, undef, undef, 60) or
1013                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1014         # (4096 * 33) >MAX_ARG_STRLEN
1015         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1016         if (!defined($fds[0])) {
1017                 warn(my $msg = "recv_cmd failed: $!");
1018                 return send($sock, $msg, MSG_EOR);
1019         } else {
1020                 my $i = 0;
1021                 for my $fd (@fds) {
1022                         open($self->{$i++}, '+<&=', $fd) and next;
1023                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1024                 }
1025                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1026         }
1027         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1028         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1029         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1030                 return send($sock, 'request command truncated', MSG_EOR);
1031         my ($argc, @argv) = split(/\0/, $buf, -1);
1032         undef $buf;
1033         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1034         if (chdir($self->{3})) {
1035                 local %ENV = %env;
1036                 $self->{env} = \%env;
1037                 eval { dispatch($self, @argv) };
1038                 send($sock, $@, MSG_EOR) if $@;
1039         } else {
1040                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1041         }
1042 }
1043
1044 sub dclose {
1045         my ($self) = @_;
1046         delete $self->{-progress};
1047         _drop_wq($self) if $self->{failed};
1048         close(delete $self->{1}) if $self->{1}; # may reap_compress
1049         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1050 }
1051
1052 # for long-running results
1053 sub event_step {
1054         my ($self) = @_;
1055         local %ENV = %{$self->{env}};
1056         my $sock = $self->{sock};
1057         local $current_lei = $self;
1058         eval {
1059                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1060                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1061                                 return if $! == EAGAIN;
1062                                 next if $! == EINTR;
1063                                 last if $! == ECONNRESET;
1064                                 die "recvmsg: $!";
1065                         }
1066                         for my $fd (@fds) {
1067                                 open my $rfh, '+<&=', $fd;
1068                         }
1069                         die "unrecognized client signal: $buf";
1070                 }
1071                 dclose($self);
1072         };
1073         if (my $err = $@) {
1074                 eval { $self->fail($err) };
1075                 dclose($self);
1076         }
1077 }
1078
1079 sub event_step_init {
1080         my ($self) = @_;
1081         return if $self->{-event_init_done}++;
1082         if (my $sock = $self->{sock}) { # using DS->EventLoop
1083                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1084         }
1085 }
1086
1087 sub noop {}
1088
1089 sub oldset { $oldset }
1090
1091 sub dump_and_clear_log {
1092         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1093                 my @pfx = @_;
1094                 unshift(@pfx, "$errors_log ") if @pfx;
1095                 warn @pfx, do { local $/; <STDIN> };
1096                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1097         }
1098 }
1099
1100 # lei(1) calls this when it can't connect
1101 sub lazy_start {
1102         my ($path, $errno, $narg) = @_;
1103         local ($errors_log, $listener);
1104         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1105         $errors_log = "$sock_dir/errors.log";
1106         my $addr = pack_sockaddr_un($path);
1107         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1108         $lk->lock_acquire;
1109         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1110         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1111                 return if connect($listener, $addr); # another process won
1112                 if ($errno == ECONNREFUSED && -S $path) {
1113                         unlink($path) or die "unlink($path): $!";
1114                 }
1115         } else {
1116                 $! = $errno; # allow interpolation to stringify in die
1117                 die "connect($path): $!";
1118         }
1119         umask(077) // die("umask(077): $!");
1120         bind($listener, $addr) or die "bind($path): $!";
1121         listen($listener, 1024) or die "listen: $!";
1122         $lk->lock_release;
1123         undef $lk;
1124         my @st = stat($path) or die "stat($path): $!";
1125         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1126         local $oldset = PublicInbox::DS::block_signals();
1127         if ($narg == 5) {
1128                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1129                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1130                         require PublicInbox::CmdIPC4;
1131                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1132                         PublicInbox::CmdIPC4->can('recv_cmd4');
1133                 };
1134         }
1135         $recv_cmd or die <<"";
1136 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1137
1138         require PublicInbox::Listener;
1139         require PublicInbox::PktOp;
1140         (-p STDOUT) or die "E: stdout must be a pipe\n";
1141         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1142         STDIN->autoflush(1);
1143         dump_and_clear_log("from previous daemon process:\n");
1144         POSIX::setsid() > 0 or die "setsid: $!";
1145         my $pid = fork // die "fork: $!";
1146         return if $pid;
1147         $0 = "lei-daemon $path";
1148         local %PATH2CFG;
1149         $listener->blocking(0);
1150         my $exit_code;
1151         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1152         local $quit = do {
1153                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1154                 sub {
1155                         $exit_code //= shift;
1156                         my $lis = $pil or exit($exit_code);
1157                         # closing eof_p triggers \&noop wakeup
1158                         $listener = $eof_p = $pil = $path = undef;
1159                         $lis->close; # DS::close
1160                         PublicInbox::DS->SetLoopTimeout(1000);
1161                 };
1162         };
1163         my $sig = {
1164                 CHLD => \&PublicInbox::DS::enqueue_reap,
1165                 QUIT => $quit,
1166                 INT => $quit,
1167                 TERM => $quit,
1168                 HUP => \&noop,
1169                 USR1 => \&noop,
1170                 USR2 => \&noop,
1171         };
1172         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1173         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1174         undef $sig;
1175         local $SIG{PIPE} = 'IGNORE';
1176         require PublicInbox::DirIdle;
1177         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1178                 # just rely on wakeup ot hit PostLoopCallback set below
1179                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1180         }, 1);
1181         if ($sigfd) {
1182                 undef $sigfd; # unref, already in DS::DescriptorMap
1183         } else {
1184                 # wake up every second to accept signals if we don't
1185                 # have signalfd or IO::KQueue:
1186                 PublicInbox::DS::sig_setmask($oldset);
1187                 PublicInbox::DS->SetLoopTimeout(1000);
1188         }
1189         PublicInbox::DS->SetPostLoopCallback(sub {
1190                 my ($dmap, undef) = @_;
1191                 if (@st = defined($path) ? stat($path) : ()) {
1192                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1193                                 warn "$path dev/ino changed, quitting\n";
1194                                 $path = undef;
1195                         }
1196                 } elsif (defined($path)) { # ENOENT is common
1197                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1198                         undef $path;
1199                         $quit->();
1200                 }
1201                 return 1 if defined($path);
1202                 my $now = now();
1203                 my $n = 0;
1204                 for my $s (values %$dmap) {
1205                         $s->can('busy') or next;
1206                         if ($s->busy($now)) {
1207                                 ++$n;
1208                         } else {
1209                                 $s->close;
1210                         }
1211                 }
1212                 $n; # true: continue, false: stop
1213         });
1214
1215         # STDIN was redirected to /dev/null above, closing STDERR and
1216         # STDOUT will cause the calling `lei' client process to finish
1217         # reading the <$daemon> pipe.
1218         local $SIG{__WARN__} = sub {
1219                 $current_lei ? err($current_lei, @_) : warn(
1220                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1221         };
1222         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1223         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1224         # $daemon pipe to `lei' closed, main loop begins:
1225         PublicInbox::DS->EventLoop;
1226         exit($exit_code // 0);
1227 }
1228
1229 sub busy { 1 } # prevent daemon-shutdown if client is connected
1230
1231 # ensures stdout hits the FS before sock disconnects so a client
1232 # can immediately reread it
1233 sub DESTROY {
1234         my ($self) = @_;
1235         $self->{1}->autoflush(1) if $self->{1};
1236         stop_pager($self);
1237         # preserve $? for ->fail or ->x_it code
1238 }
1239
1240 sub wq_done_wait { # dwaitpid callback
1241         my ($arg, $pid) = @_;
1242         my ($wq, $lei) = @$arg;
1243         my $err_type = $lei->{-err_type};
1244         $? and $lei->child_error($?,
1245                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1246         $lei->dclose;
1247 }
1248
1249 sub fchdir {
1250         my ($lei) = @_;
1251         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1252         chdir($dh) || $lei->fail("fchdir: $!");
1253 }
1254
1255 sub wq_eof { # EOF callback for main daemon
1256         my ($lei) = @_;
1257         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1258         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1259 }
1260
1261 1;