lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g stdin|
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset keywords on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! kw|keywords|flags! interval=s recursive|r
 156         exclude=s include=s) ],
 157 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 158                 qw(format|f=s z) ],
 159 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 161 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 162         qw(prune) ],
 163
 164 'import' => [ 'URLS_OR_PATHNAMES...|--stdin',
 165         'one-time import/update from URL or filesystem',
 166         qw(stdin| offset=i recursive|r exclude=s include|I=s
 167         format|f=s kw|keywords|flags!),
 168         ],
 169
 170 'config' => [ '[...]', sub {
 171                 'git-config(1) wrapper for '._config_path($_[0]);
 172         }, qw(config-file|system|global|file|f=s), # for conflict detection
 173         pass_through('git config') ],
 174 'init' => [ '[PATHNAME]', sub {
 175                 'initialize storage, default: '._store_path($_[0]);
 176         }, qw(quiet|q) ],
 177 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 178         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 179 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 180 'help' => [ '[SUBCOMMAND]', 'show help' ],
 181
 182 # XXX do we need this?
 183 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 184
 185 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 186         'rewrite git history in an attempt to improve compression',
 187         'gc!' ],
 188
 189 # internal commands are prefixed with '_'
 190 '_complete' => [ '[...]', 'internal shell completion helper',
 191                 pass_through('everything') ],
 192 ); # @CMD
 193
 194 # switch descriptions, try to keep consistent across commands
 195 # $spec: Getopt::Long option specification
 196 # $spec => [@ALLOWED_VALUES (default is first), $description],
 197 # $spec => $description
 198 # "$SUB_COMMAND TAB $spec" => as above
 199 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 200                         'specify message input format' ];
 201 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 202
 203 my %OPTDESC = (
 204 'help|h' => 'show this built-in help',
 205 'quiet|q' => 'be quiet',
 206 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 207 'verbose|v' => 'be more verbose',
 208 'solve!' => 'do not attempt to reconstruct blobs from emails',
 209 'torsocks=s' => ['auto|no|yes',
 210                 'whether or not to wrap git and curl commands with torsocks'],
 211 'no-torsocks' => 'alias for --torsocks=no',
 212 'save-as=s' => ['NAME', 'save a search terms by given name'],
 213
 214 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 215
 216 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 217                 'deduplication strategy'],
 218 'show   thread|t' => 'display entire thread a message belongs to',
 219 'q      thread|t' =>
 220         'return all messages in the same thread as the actual match(es)',
 221 'augment|a' => 'augment --output destination instead of clobbering',
 222
 223 'output|mfolder|o=s' => [ 'DEST',
 224         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 225 'mua-cmd|mua=s' => [ 'COMMAND',
 226         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 227
 228 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 229                         'message/object output format' ],
 230 'mark   format|f=s' => $stdin_formats,
 231 'forget format|f=s' => $stdin_formats,
 232 'q      format|f=s' => [
 233         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 234                 'specify output format, default depends on --output'],
 235 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 236                 'exclude specified external(s) from search' ],
 237 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 238                 'include specified external(s) in search' ],
 239 'q      only=s@' => [ 'URL_OR_PATHNAME',
 240                 'only use specified external(s) for search' ],
 241
 242 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 243                 'control number of search and writer jobs' ],
 244
 245 'import format|f=s' => $stdin_formats,
 246
 247 'ls-query       format|f=s' => $ls_format,
 248 'ls-external    format|f=s' => $ls_format,
 249
 250 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 251 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 252
 253 'sort|s=s' => [ 'VAL|received,relevance,docid',
 254                 "order of results `--output'-dependent"],
 255 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 256
 257 'boost=i' => 'increase/decrease priority of results (default: 0)',
 258
 259 'local' => 'limit operations to the local filesystem',
 260 'local!' => 'exclude results from the local filesystem',
 261 'remote' => 'limit operations to those requiring network access',
 262 'remote!' => 'prevent operations requiring network access',
 263
 264 'mid=s' => 'specify the Message-ID of a message',
 265 'oid=s' => 'specify the git object ID of a message',
 266
 267 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 268 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 269 'include=s' => 'include mailboxes/newsgroups based on pattern',
 270
 271 'exact' => 'operate on exact header matches only',
 272 'exact!' => 'rely on content match instead of exact header matches',
 273
 274 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 275 'jobs:i' => 'set parallelism level',
 276
 277 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 278 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 279
 280 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 281 ); # %OPTDESC
 282
 283 my %CONFIG_KEYS = (
 284         'leistore.dir' => 'top-level storage location',
 285 );
 286
 287 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 288 sub x_it ($$) {
 289         my ($self, $code) = @_;
 290         # make sure client sees stdout before exit
 291         $self->{1}->autoflush(1) if $self->{1};
 292         dump_and_clear_log();
 293         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 294                 send($s, "x_it $code", MSG_EOR);
 295         } elsif ($self->{oneshot}) {
 296                 # don't want to end up using $? from child processes
 297                 for my $f (qw(lxs l2m)) {
 298                         my $wq = delete $self->{$f} or next;
 299                         $wq->DESTROY;
 300                 }
 301                 # cleanup anything that has tempfiles
 302                 delete @$self{qw(ovv dedupe)};
 303                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 304                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 305                         kill $signum, $$;
 306                         sleep(1) while 1; # wait for signal
 307                 } else {
 308                         $quit->($code >> 8);
 309                 }
 310         } # else ignore if client disconnected
 311 }
 312
 313 sub err ($;@) {
 314         my $self = shift;
 315         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 316         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 317         print $err @_, @eor and return;
 318         my $old_err = delete $self->{2};
 319         close($old_err) if $! == EPIPE && $old_err;
 320         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 321         print $err @_, @eor or print STDERR @_, @eor;
 322 }
 323
 324 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 325
 326 sub fail_handler ($;$$) {
 327         my ($lei, $code, $io) = @_;
 328         for my $f (qw(imp lxs l2m)) {
 329                 my $wq = delete $lei->{$f} or next;
 330                 $wq->wq_wait_old($lei) if $wq->wq_kill_old; # lei-daemon
 331         }
 332         close($io) if $io; # needed to avoid warnings on SIGPIPE
 333         $lei->x_it($code // (1 >> 8));
 334 }
 335
 336 sub sigpipe_handler { # handles SIGPIPE from l2m/lxs workers
 337         fail_handler($_[0], 13, delete $_[0]->{1});
 338 }
 339
 340 sub fail ($$;$) {
 341         my ($self, $buf, $exit_code) = @_;
 342         err($self, $buf) if defined $buf;
 343         # calls fail_handler:
 344         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 345         x_it($self, ($exit_code // 1) << 8);
 346         undef;
 347 }
 348
 349 sub out ($;@) {
 350         my $self = shift;
 351         return if print { $self->{1} // return } @_; # likely
 352         return note_sigpipe($self, 1) if $! == EPIPE;
 353         my $err = "error writing to stdout: $!";
 354         delete $self->{1};
 355         fail($self, $err);
 356 }
 357
 358 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 359
 360 sub child_error { # passes non-fatal curl exit codes to user
 361         my ($self, $child_error, $msg) = @_; # child_error is $?
 362         $self->err($msg) if $msg;
 363         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 364                 # send to the parent lei-daemon or to lei(1) client
 365                 send($s, "child_error $child_error", MSG_EOR);
 366         } elsif (!$PublicInbox::DS::in_loop) {
 367                 $self->{child_error} = $child_error;
 368         } # else noop if client disconnected
 369 }
 370
 371 sub note_sigpipe { # triggers sigpipe_handler
 372         my ($self, $fd) = @_;
 373         close(delete($self->{$fd})); # explicit close silences Perl warning
 374         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 375         x_it($self, 13);
 376 }
 377
 378 sub lei_atfork_child {
 379         my ($self, $persist) = @_;
 380         # we need to explicitly close things which are on stack
 381         if ($persist) {
 382                 my @io = delete @$self{0,1,2};
 383                 unless ($self->{oneshot}) {
 384                         close($_) for @io;
 385                 }
 386         } else {
 387                 delete $self->{0};
 388         }
 389         for (delete @$self{qw(3 sock old_1 au_done)}) {
 390                 close($_) if defined($_);
 391         }
 392         if (my $op_c = delete $self->{pkt_op_c}) {
 393                 close(delete $op_c->{sock});
 394         }
 395         if (my $pgr = delete $self->{pgr}) {
 396                 close($_) for (@$pgr[1,2]);
 397         }
 398         close $listener if $listener;
 399         undef $listener;
 400         %PATH2CFG = ();
 401         undef $errors_log;
 402         $quit = \&CORE::exit;
 403         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 404 }
 405
 406 sub _help ($;$) {
 407         my ($self, $errmsg) = @_;
 408         my $cmd = $self->{cmd} // 'COMMAND';
 409         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 410         my @top = ($cmd, shift(@info) // ());
 411         my $cmd_desc = shift(@info);
 412         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 413         my @opt_desc;
 414         my $lpad = 2;
 415         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 416                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 417                 my $arg_vals = '';
 418                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 419
 420                 # lower-case is a keyword (e.g. `content', `oid'),
 421                 # ALL_CAPS is a string description (e.g. `PATH')
 422                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 423                         $desc .= "\ndefault: `$1'";
 424                 }
 425                 my (@vals, @s, @l);
 426                 my $x = $sw;
 427                 if ($x =~ s/!\z//) { # solve! => --no-solve
 428                         $x = "no-$x";
 429                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 430                         @vals = (' [', undef, ']');
 431                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 432                         @vals = (' ', undef);
 433                 } # else: no args $x = 'thread|t'
 434                 for (split(/\|/, $x)) { # help|h
 435                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 436                 }
 437                 if (!scalar(@vals)) { # no args 'thread|t'
 438                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 439                         $vals[1] = $1;
 440                 } else {
 441                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 442                 }
 443                 if ($arg_vals =~ /([,\|])/) {
 444                         my $sep = $1;
 445                         my @allow = split(/\Q$sep\E/, $arg_vals);
 446                         my $must = $sep eq '|' ? 'Must' : 'Can';
 447                         @allow = map { "`$_'" } @allow;
 448                         my $last = pop @allow;
 449                         $desc .= "\n$must be one of: " .
 450                                 join(', ', @allow) . " or $last";
 451                 }
 452                 my $lhs = join(', ', @s, @l) . join('', @vals);
 453                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 454                         $lhs =~ s/\A--/- , --/;
 455                 } else {
 456                         $lhs =~ s/\A--/    --/; # pad if no short options
 457                 }
 458                 $lpad = length($lhs) if length($lhs) > $lpad;
 459                 push @opt_desc, $lhs, $desc;
 460         }
 461         my $msg = $errmsg ? "E: $errmsg\n" : '';
 462         $msg .= <<EOF;
 463 usage: lei @top
 464   $cmd_desc
 465
 466 EOF
 467         $lpad += 2;
 468         local $Text::Wrap::columns = 78 - $lpad;
 469         my $padding = ' ' x ($lpad + 2);
 470         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 471                 $msg .= '  '.pack("A$lpad", $lhs);
 472                 $rhs = wrap('', '', $rhs);
 473                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 474                 $msg .= $rhs;
 475                 $msg .= "\n";
 476         }
 477         my $out = $self->{$errmsg ? 2 : 1};
 478         start_pager($self) if -t $out;
 479         print $out $msg;
 480         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 481         undef;
 482 }
 483
 484 sub optparse ($$$) {
 485         my ($self, $cmd, $argv) = @_;
 486         $self->{cmd} = $cmd;
 487         $OPT = $self->{opt} = {};
 488         my $info = $CMD{$cmd} // [ '[...]' ];
 489         my ($proto, undef, @spec) = @$info;
 490         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 491         push @spec, qw(help|h);
 492         my $lone_dash;
 493         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 494                 $lone_dash = $spec[0];
 495                 $OPT->{$spec[0]} = \(my $var);
 496                 push @spec, '' => \$var;
 497         }
 498         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 499                 return _help($self, "bad arguments or options for $cmd");
 500         return _help($self) if $OPT->{help};
 501
 502         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 503
 504         # "-" aliases "stdin" or "clear"
 505         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 506
 507         my $i = 0;
 508         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 509         my ($err, $inf);
 510         my @args = split(/ /, $proto);
 511         for my $var (@args) {
 512                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 513                         $inf = defined($argv->[$i]) and last;
 514                         $var =~ s/\.\.\.\z//;
 515                         $err = "$var not supplied";
 516                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 517                         $argv->[$i++] // ($err = "$var not supplied");
 518                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 519                         $inf = 1;
 520                         last;
 521                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 522                         $i++;
 523                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 524                         $inf = 1 if index($var, '...') > 0;
 525                         my @or = split(/\|/, $var);
 526                         my $ok;
 527                         for my $o (@or) {
 528                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 529                                         $ok = defined($OPT->{$1});
 530                                         last if $ok;
 531                                 } elsif (defined($argv->[$i])) {
 532                                         $ok = 1;
 533                                         $i++;
 534                                         last;
 535                                 } # else continue looping
 536                         }
 537                         last if $ok;
 538                         my $last = pop @or;
 539                         $err = join(', ', @or) . " or $last must be set";
 540                 } else {
 541                         warn "BUG: can't parse `$var' in $proto";
 542                 }
 543                 last if $err;
 544         }
 545         if (!$inf && scalar(@$argv) > scalar(@args)) {
 546                 $err //= 'too many arguments';
 547         }
 548         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 549 }
 550
 551 sub dispatch {
 552         my ($self, $cmd, @argv) = @_;
 553         local $current_lei = $self; # for __WARN__
 554         dump_and_clear_log("from previous run\n");
 555         return _help($self, 'no command given') unless defined($cmd);
 556         my $func = "lei_$cmd";
 557         $func =~ tr/-/_/;
 558         if (my $cb = __PACKAGE__->can($func)) {
 559                 optparse($self, $cmd, \@argv) or return;
 560                 $cb->($self, @argv);
 561         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 562                 my $opt = {};
 563                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 564                         return _help($self, 'bad arguments or options');
 565                 _help($self);
 566         } else {
 567                 fail($self, "`$cmd' is not an lei command");
 568         }
 569 }
 570
 571 sub _lei_cfg ($;$) {
 572         my ($self, $creat) = @_;
 573         my $f = _config_path($self);
 574         my @st = stat($f);
 575         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 576         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 577                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 578         }
 579         if (!@st) {
 580                 unless ($creat) {
 581                         delete $self->{cfg};
 582                         return;
 583                 }
 584                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 585                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 586                 open my $fh, '>>', $f or die "open($f): $!\n";
 587                 @st = stat($fh) or die "fstat($f): $!\n";
 588                 $cur_st = pack('dd', $st[10], $st[7]);
 589                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 590         }
 591         my $cfg = PublicInbox::Config::git_config_dump($f);
 592         $cfg->{-st} = $cur_st;
 593         $cfg->{'-f'} = $f;
 594         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 595 }
 596
 597 sub _lei_store ($;$) {
 598         my ($self, $creat) = @_;
 599         my $cfg = _lei_cfg($self, $creat);
 600         $cfg->{-lei_store} //= do {
 601                 require PublicInbox::LeiStore;
 602                 my $dir = $cfg->{'leistore.dir'};
 603                 $dir //= $creat ? _store_path($self) : return;
 604                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 605         };
 606 }
 607
 608 sub lei_show {
 609         my ($self, @argv) = @_;
 610 }
 611
 612 sub lei_mark {
 613         my ($self, @argv) = @_;
 614 }
 615
 616 sub _config {
 617         my ($self, @argv) = @_;
 618         my $env = $self->{env};
 619         delete local $env->{GIT_CONFIG};
 620         delete local $ENV{GIT_CONFIG};
 621         my $cfg = _lei_cfg($self, 1);
 622         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 623         my %rdr = map { $_ => $self->{$_} } (0..2);
 624         waitpid(spawn($cmd, $env, \%rdr), 0);
 625 }
 626
 627 sub lei_config {
 628         my ($self, @argv) = @_;
 629         $self->{opt}->{'config-file'} and return fail $self,
 630                 "config file switches not supported by `lei config'";
 631         _config(@_);
 632         x_it($self, $?) if $?;
 633 }
 634
 635 sub lei_import {
 636         require PublicInbox::LeiImport;
 637         PublicInbox::LeiImport->call(@_);
 638 }
 639
 640 sub lei_init {
 641         my ($self, $dir) = @_;
 642         my $cfg = _lei_cfg($self, 1);
 643         my $cur = $cfg->{'leistore.dir'};
 644         $dir //= _store_path($self);
 645         $dir = rel2abs($self, $dir);
 646         my @cur = stat($cur) if defined($cur);
 647         $cur = File::Spec->canonpath($cur // $dir);
 648         my @dir = stat($dir);
 649         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 650         if (@cur) {
 651                 if ($cur eq $dir) {
 652                         _lei_store($self, 1)->done;
 653                         return qerr($self, $exists);
 654                 }
 655
 656                 # some folks like symlinks and bind mounts :P
 657                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 658                         lei_config($self, 'leistore.dir', $dir);
 659                         _lei_store($self, 1)->done;
 660                         return qerr($self, "$exists (as $cur)");
 661                 }
 662                 return fail($self, <<"");
 663 E: leistore.dir=$cur already initialized and it is not $dir
 664
 665         }
 666         lei_config($self, 'leistore.dir', $dir);
 667         _lei_store($self, 1)->done;
 668         $exists //= "I: leistore.dir=$dir newly initialized";
 669         return qerr($self, $exists);
 670 }
 671
 672 sub lei_daemon_pid { puts shift, $$ }
 673
 674 sub lei_daemon_kill {
 675         my ($self) = @_;
 676         my $sig = $self->{opt}->{signal} // 'TERM';
 677         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 678 }
 679
 680 sub lei_help { _help($_[0]) }
 681
 682 # Shell completion helper.  Used by lei-completion.bash and hopefully
 683 # other shells.  Try to do as much here as possible to avoid redundancy
 684 # and improve maintainability.
 685 sub lei__complete {
 686         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 687         shift @argv; # ignore "lei", the entire command is sent
 688         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 689         my $cmd = shift @argv;
 690         my $info = $CMD{$cmd} // do { # filter matching commands
 691                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 692                 return;
 693         };
 694         my ($proto, undef, @spec) = @$info;
 695         my $cur = pop @argv;
 696         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 697         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 698                 # gross special case since the only git-config options
 699                 # Consider moving to a table if we need more special cases
 700                 # we use Getopt::Long for are the ones we reject, so these
 701                 # are the ones we don't reject:
 702                 if ($cmd eq 'config') {
 703                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 704                         @spec = qw(add z|null get get-all unset unset-all
 705                                 replace-all get-urlmatch
 706                                 remove-section rename-section
 707                                 name-only list|l edit|e
 708                                 get-color-name get-colorbool);
 709                         # fall-through
 710                 }
 711                 puts $self, grep(/$re/, map { # generate short/long names
 712                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 713                         } else { # negation: solve! => no-solve|solve
 714                                 s/\A(.+)!\z/no-$1|$1/;
 715                         }
 716                         map {
 717                                 my $x = length > 1 ? "--$_" : "-$_";
 718                                 $x eq $cur ? () : $x;
 719                         } split(/\|/, $_, -1) # help|h
 720                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 721         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 722                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 723         }
 724
 725         # switch args (e.g. lei q -f mbox<TAB>)
 726         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 727                 my $opt = quotemeta $1;
 728                 puts $self, map {
 729                         my $v = $OPTDESC{$_};
 730                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 731                         # get rid of ALL CAPS placeholder (e.g "OUT")
 732                         # (TODO: completion for external paths)
 733                         shift(@v) if uc($v[0]) eq $v[0];
 734                         @v;
 735                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 736         }
 737         $cmd =~ tr/-/_/;
 738         if (my $sub = $self->can("_complete_$cmd")) {
 739                 puts $self, $sub->($self, @argv, $cur);
 740         }
 741         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 742         # proto parsing.
 743 }
 744
 745 sub exec_buf ($$) {
 746         my ($argv, $env) = @_;
 747         my $argc = scalar @$argv;
 748         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 749         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 750         $buf;
 751 }
 752
 753 sub start_mua {
 754         my ($self) = @_;
 755         my $mua = $self->{opt}->{'mua-cmd'} // return;
 756         my $mfolder = $self->{ovv}->{dst};
 757         my (@cmd, $replaced);
 758         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 759                 @cmd = ($mua, '-f');
 760         # TODO: help wanted: other common FOSS MUAs
 761         } else {
 762                 require Text::ParseWords;
 763                 my @cmd = Text::ParseWords::shellwords($mua);
 764                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 765                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 766         }
 767         push @cmd, $mfolder unless defined($replaced);
 768         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 769                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 770         } elsif ($self->{oneshot}) {
 771                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 772         }
 773         delete $self->{-progress};
 774 }
 775
 776 # caller needs to "-t $self->{1}" to check if tty
 777 sub start_pager {
 778         my ($self) = @_;
 779         my $env = $self->{env};
 780         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 781         chomp(my $pager = <$fh> // '');
 782         close($fh) or warn "`git var PAGER' error: \$?=$?";
 783         return if $pager eq 'cat' || $pager eq '';
 784         # TODO TIOCGWINSZ
 785         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 786         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 787         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 788         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 789         my $pgr = [ undef, @$rdr{1, 2} ];
 790         if (my $sock = $self->{sock}) { # lei(1) process runs it
 791                 delete @$new_env{keys %$env}; # only set iff unset
 792                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 793                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 794         } elsif ($self->{oneshot}) {
 795                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 796                 $pgr->[3] = $$; # ew'll reap it
 797         } else {
 798                 die 'BUG: start_pager w/o socket';
 799         }
 800         $self->{1} = $wpager;
 801         $self->{2} = $wpager if -t $self->{2};
 802         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 803         $self->{pgr} = $pgr;
 804 }
 805
 806 sub stop_pager {
 807         my ($self) = @_;
 808         my $pgr = delete($self->{pgr}) or return;
 809         $self->{2} = $pgr->[2];
 810         # do not restore original stdout, just close it so we error out
 811         close(delete($self->{1})) if $self->{1};
 812         my $pid = $pgr->[0];
 813         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 814 }
 815
 816 sub accept_dispatch { # Listener {post_accept} callback
 817         my ($sock) = @_; # ignore other
 818         $sock->autoflush(1);
 819         my $self = bless { sock => $sock }, __PACKAGE__;
 820         vec(my $rvec = '', fileno($sock), 1) = 1;
 821         select($rvec, undef, undef, 60) or
 822                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 823         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 824         if (scalar(@fds) == 4) {
 825                 for my $i (0..3) {
 826                         my $fd = shift(@fds);
 827                         open($self->{$i}, '+<&=', $fd) and next;
 828                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 829                 }
 830         } else {
 831                 my $msg = "recv_cmd failed: $!";
 832                 warn $msg;
 833                 return send($sock, $msg, MSG_EOR);
 834         }
 835         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 836         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 837         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 838         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 839                 return send($sock, 'request command truncated', MSG_EOR);
 840         my ($argc, @argv) = split(/\0/, $buf, -1);
 841         undef $buf;
 842         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 843         if (chdir($self->{3})) {
 844                 local %ENV = %env;
 845                 $self->{env} = \%env;
 846                 eval { dispatch($self, @argv) };
 847                 send($sock, $@, MSG_EOR) if $@;
 848         } else {
 849                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 850         }
 851 }
 852
 853 sub dclose {
 854         my ($self) = @_;
 855         delete $self->{-progress};
 856         for my $f (qw(lxs l2m)) {
 857                 my $wq = delete $self->{$f} or next;
 858                 if ($wq->wq_kill) {
 859                         $wq->wq_close
 860                 } elsif ($wq->wq_kill_old) {
 861                         $wq->wq_wait_old($self);
 862                 }
 863         }
 864         close(delete $self->{1}) if $self->{1}; # may reap_compress
 865         $self->close if $self->{sock}; # PublicInbox::DS::close
 866 }
 867
 868 # for long-running results
 869 sub event_step {
 870         my ($self) = @_;
 871         local %ENV = %{$self->{env}};
 872         my $sock = $self->{sock};
 873         local $current_lei = $self;
 874         eval {
 875                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 876                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 877                                 return if $! == EAGAIN;
 878                                 next if $! == EINTR;
 879                                 last if $! == ECONNRESET;
 880                                 die "recvmsg: $!";
 881                         }
 882                         for my $fd (@fds) {
 883                                 open my $rfh, '+<&=', $fd;
 884                         }
 885                         die "unrecognized client signal: $buf";
 886                 }
 887                 dclose($self);
 888         };
 889         if (my $err = $@) {
 890                 eval { $self->fail($err) };
 891                 dclose($self);
 892         }
 893 }
 894
 895 sub event_step_init {
 896         my ($self) = @_;
 897         if (my $sock = $self->{sock}) { # using DS->EventLoop
 898                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 899         }
 900 }
 901
 902 sub noop {}
 903
 904 our $oldset; sub oldset { $oldset }
 905
 906 sub dump_and_clear_log {
 907         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 908                 my @pfx = @_;
 909                 unshift(@pfx, "$errors_log ") if @pfx;
 910                 warn @pfx, do { local $/; <STDIN> };
 911                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 912         }
 913 }
 914
 915 # lei(1) calls this when it can't connect
 916 sub lazy_start {
 917         my ($path, $errno, $narg) = @_;
 918         if ($errno == ECONNREFUSED) {
 919                 unlink($path) or die "unlink($path): $!";
 920         } elsif ($errno != ENOENT) {
 921                 $! = $errno; # allow interpolation to stringify in die
 922                 die "connect($path): $!";
 923         }
 924         if (eval { require BSD::Resource }) {
 925                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 926                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 927                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 928         }
 929         umask(077) // die("umask(077): $!");
 930         local $listener;
 931         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 932         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 933         listen($listener, 1024) or die "listen: $!";
 934         my @st = stat($path) or die "stat($path): $!";
 935         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 936         local $oldset = PublicInbox::DS::block_signals();
 937         if ($narg == 5) {
 938                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 939                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 940                         require PublicInbox::CmdIPC4;
 941                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 942                         PublicInbox::CmdIPC4->can('recv_cmd4');
 943                 };
 944         }
 945         $recv_cmd or die <<"";
 946 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 947
 948         require PublicInbox::Listener;
 949         require PublicInbox::EOFpipe;
 950         (-p STDOUT) or die "E: stdout must be a pipe\n";
 951         local $errors_log;
 952         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 953         $errors_log .= 'errors.log';
 954         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 955         STDIN->autoflush(1);
 956         dump_and_clear_log("from previous daemon process:\n");
 957         POSIX::setsid() > 0 or die "setsid: $!";
 958         my $pid = fork // die "fork: $!";
 959         return if $pid;
 960         $0 = "lei-daemon $path";
 961         local %PATH2CFG;
 962         $listener->blocking(0);
 963         my $exit_code;
 964         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 965         local $quit = do {
 966                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 967                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 968                 sub {
 969                         $exit_code //= shift;
 970                         my $lis = $pil or exit($exit_code);
 971                         # closing eof_w triggers \&noop wakeup
 972                         $listener = $eof_w = $pil = $path = undef;
 973                         $lis->close; # DS::close
 974                         PublicInbox::DS->SetLoopTimeout(1000);
 975                 };
 976         };
 977         my $sig = {
 978                 CHLD => \&PublicInbox::DS::enqueue_reap,
 979                 QUIT => $quit,
 980                 INT => $quit,
 981                 TERM => $quit,
 982                 HUP => \&noop,
 983                 USR1 => \&noop,
 984                 USR2 => \&noop,
 985         };
 986         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 987         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 988         undef $sig;
 989         local $SIG{PIPE} = 'IGNORE';
 990         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 991                 undef $sigfd;
 992                 PublicInbox::DS->SetLoopTimeout(5000);
 993         } else {
 994                 # wake up every second to accept signals if we don't
 995                 # have signalfd or IO::KQueue:
 996                 PublicInbox::DS::sig_setmask($oldset);
 997                 PublicInbox::DS->SetLoopTimeout(1000);
 998         }
 999         PublicInbox::DS->SetPostLoopCallback(sub {
1000                 my ($dmap, undef) = @_;
1001                 if (@st = defined($path) ? stat($path) : ()) {
1002                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1003                                 warn "$path dev/ino changed, quitting\n";
1004                                 $path = undef;
1005                         }
1006                 } elsif (defined($path)) { # ENOENT is common
1007                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1008                         undef $path;
1009                         $quit->();
1010                 }
1011                 return 1 if defined($path);
1012                 my $now = now();
1013                 my $n = 0;
1014                 for my $s (values %$dmap) {
1015                         $s->can('busy') or next;
1016                         if ($s->busy($now)) {
1017                                 ++$n;
1018                         } else {
1019                                 $s->close;
1020                         }
1021                 }
1022                 $n; # true: continue, false: stop
1023         });
1024
1025         # STDIN was redirected to /dev/null above, closing STDERR and
1026         # STDOUT will cause the calling `lei' client process to finish
1027         # reading the <$daemon> pipe.
1028         local $SIG{__WARN__} = sub {
1029                 $current_lei ? err($current_lei, @_) : warn(
1030                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1031         };
1032         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1033         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1034         # $daemon pipe to `lei' closed, main loop begins:
1035         PublicInbox::DS->EventLoop;
1036         exit($exit_code // 0);
1037 }
1038
1039 # for users w/o Socket::Msghdr installed or Inline::C enabled
1040 sub oneshot {
1041         my ($main_pkg) = @_;
1042         my $exit = $main_pkg->can('exit'); # caller may override exit()
1043         local $quit = $exit if $exit;
1044         local %PATH2CFG;
1045         umask(077) // die("umask(077): $!");
1046         my $self = bless {
1047                 oneshot => 1,
1048                 0 => *STDIN{GLOB},
1049                 1 => *STDOUT{GLOB},
1050                 2 => *STDERR{GLOB},
1051                 env => \%ENV
1052         }, __PACKAGE__;
1053         dispatch($self, @ARGV);
1054         x_it($self, $self->{child_error}) if $self->{child_error};
1055 }
1056
1057 # ensures stdout hits the FS before sock disconnects so a client
1058 # can immediately reread it
1059 sub DESTROY {
1060         my ($self) = @_;
1061         $self->{1}->autoflush(1) if $self->{1};
1062         stop_pager($self);
1063         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1064                 waitpid($mua_pid, 0);
1065         }
1066 }
1067
1068 1;