lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn popen_rd);
  24 use PublicInbox::Lock;
  25 use PublicInbox::Eml;
  26 use PublicInbox::Import;
  27 use PublicInbox::ContentHash qw(git_sha);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 use Sys::Syslog qw(openlog syslog closelog);
  32 our $quit = \&CORE::exit;
  33 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  34         $recv_cmd, $send_cmd);
  35 my $GLP = Getopt::Long::Parser->new;
  36 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  37 my $GLP_PASS = Getopt::Long::Parser->new;
  38 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  39
  40 our %PATH2CFG; # persistent for socket daemon
  41 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         my $cwd;
  81         if (defined $pwd) {
  82                 my $xcwd = $self->{3} //
  83                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  84                 if (my @st_pwd = stat($pwd)) {
  85                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  86                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  87                                 $self->{env}->{PWD} = $pwd = undef;
  88                 } else { # PWD was invalid
  89                         $self->{env}->{PWD} = $pwd = undef;
  90                 }
  91         }
  92         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  93         File::Spec->rel2abs($p, $pwd);
  94 }
  95
  96 # abs_path resolves symlinks in parent iff all parents exist
  97 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  98
  99 sub canonpath_harder {
 100         my $p = $_[-1]; # $_[0] may be self
 101         $p = File::Spec->canonpath($p);
 102         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 103 }
 104
 105 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 109                 .'/lei');
 110 }
 111
 112 sub store_path ($) { share_path($_[0]) . '/store' }
 113
 114 sub _config_path ($) {
 115         my ($self) = @_;
 116         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 117                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 118                 .'/lei/config');
 119 }
 120
 121 sub cache_dir ($) {
 122         my ($self) = @_;
 123         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 124                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 125                 .'/lei');
 126 }
 127
 128 sub url_folder_cache {
 129         my ($self) = @_;
 130         require PublicInbox::SharedKV; # URI => updated_at_sec_
 131         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 132 }
 133
 134 sub ale {
 135         my ($self) = @_;
 136         $self->{ale} //= do {
 137                 require PublicInbox::LeiALE;
 138                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 139         };
 140 }
 141
 142 sub index_opt {
 143         # TODO: drop underscore variants everywhere, they're undocumented
 144         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 145         max_size|max-size=s sequential-shard
 146         batch_size|batch-size=s skip-docdata)
 147 }
 148
 149 my @c_opt = qw(c=s@ C=s@ quiet|q);
 150 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 151 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 152         import-remote!);
 153
 154 # we don't support -C as an alias for --find-copies since it's already
 155 # used for chdir
 156 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 157         output-indicator-context=s indent-heuristic!
 158         minimal patience histogram anchored=s@ diff-algorithm=s
 159         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 160         word-diff:s word-diff-regex=s color-words:s no-renames
 161         rename-empty! check ws-error-highlight=s full-index binary
 162         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 163         find-copies-harder irreversible-delete|D l=i diff-filter=s
 164         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 165         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 166         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 167         inter-hunk-context=i function-context|W exit-code ext-diff
 168         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 169         line-prefix=s);
 170
 171 # we generate shell completion + help using %CMD and %OPTDESC,
 172 # see lei__complete() and PublicInbox::LeiHelp
 173 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 174 our %CMD = ( # sorted in order of importance/use:
 175 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 176         'stdin|', # /|\z/ must be first for lone dash
 177         @lxs_opt, @net_opt,
 178         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 179         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 180         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 181         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 182
 183 'up' => [ 'OUTPUT...|--all', 'update saved search',
 184         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+
 185         remote-fudge-time=s all:s), @c_opt ],
 186
 187 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 188         'stdin|', # /|\z/ must be first for lone dash
 189         # some of these options are ridiculous for lcat
 190         @lxs_opt, @net_opt,
 191         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 192         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 193         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 194         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 195
 196 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 197         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 198         @lxs_opt, @net_opt, @c_opt ],
 199
 200 'rediff' => [ '--stdin|LOCATION...',
 201                 'regenerate a diff with different options',
 202         'stdin|', # /|\z/ must be first for lone dash
 203         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 204         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 205
 206 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 207         'stdin|', # /|\z/ must be first for lone dash
 208         qw(verbose|v+ color:s no-color raw-header),
 209         @diff_opt, @net_opt, @c_opt ],
 210
 211 'add-external' => [ 'LOCATION',
 212         'add/set priority of a publicinbox|extindex for extra matches',
 213         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 214         @c_opt, index_opt(), @net_opt ],
 215 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 216         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 217 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 218 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 219                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 220 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 221                 qw(z|0 ascii l pretty url), @c_opt ],
 222 'forget-external' => [ 'LOCATION...|--prune',
 223         'exclude further results from a publicinbox|extindex',
 224         qw(prune), @c_opt ],
 225
 226 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 227                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 228 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 229                 qw(verbose|v+), @c_opt ],
 230 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 231                         @c_opt ],
 232 'rm' => [ '--stdin|LOCATION...',
 233         'remove a message from the index and prevent reindexing',
 234         'stdin|', # /|\z/ must be first for lone dash
 235         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 236 'plonk' => [ '--threads|--from=IDENT',
 237         'exclude mail matching From: or threads from non-Message-ID searches',
 238         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 239 'tag' => [ 'KEYWORDS...',
 240         'set/unset keywords and/or labels on message(s)',
 241         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 242         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 243
 244 'purge-mailsource' => [ 'LOCATION|--all',
 245         'remove imported messages from IMAP, Maildirs, and MH',
 246         qw(exact! all jobs:i indexed), @c_opt ],
 247
 248 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 249         qw(poll-interval=s state=s recursive|r), @c_opt ],
 250 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 251         qw(recursive|r), @c_opt ],
 252 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 253                 qw(l z|0), @c_opt ],
 254 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 255 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 256 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 257         qw(prune), @c_opt ],
 258
 259 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 260         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 261         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 262          @c_opt ],
 263 'import' => [ 'LOCATION...|--stdin',
 264         'one-time import/update from URL or filesystem',
 265         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 266         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 267         @net_opt, @c_opt ],
 268 'forget-mail-sync' => [ 'LOCATION...',
 269         'forget sync information for a mail folder', @c_opt ],
 270 'refresh-mail-sync' => [ 'LOCATION...|--all',
 271         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 272 'export-kw' => [ 'LOCATION...|--all',
 273         'one-time export of keywords of sync sources',
 274         qw(all:s mode=s), @net_opt, @c_opt ],
 275 'convert' => [ 'LOCATION...|--stdin',
 276         'one-time conversion from URL or filesystem to another format',
 277         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 278         @net_opt, @c_opt ],
 279 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 280         "use a patch to generate a query for `lei q --stdin'",
 281         qw(stdin| want|w=s@ uri debug), @c_opt ],
 282 'config' => [ '[...]', sub {
 283                 'git-config(1) wrapper for '._config_path($_[0]);
 284         }, qw(config-file|system|global|file|f=s), # for conflict detection
 285          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 286 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 287         qw(stdin| pretty ascii dir=s), @c_opt ],
 288
 289 'init' => [ '[DIRNAME]', sub {
 290         "initialize storage, default: ".store_path($_[0]);
 291         }, @c_opt ],
 292 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 293         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 294         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 295 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 296 'help' => [ '[SUBCOMMAND]', 'show help' ],
 297
 298 # TODO
 299 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 300 #       'rewrite git history in an attempt to improve compression',
 301 #       qw(gc!), @c_opt ],
 302 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 303 #
 304 # internal commands are prefixed with '_'
 305 '_complete' => [ '[...]', 'internal shell completion helper',
 306                 pass_through('everything') ],
 307 ); # @CMD
 308
 309 # switch descriptions, try to keep consistent across commands
 310 # $spec: Getopt::Long option specification
 311 # $spec => [@ALLOWED_VALUES (default is first), $description],
 312 # $spec => $description
 313 # "$SUB_COMMAND TAB $spec" => as above
 314 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 315                         'specify message input format' ];
 316 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 317
 318 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 319 my %OPTDESC = (
 320 'help|h' => 'show this built-in help',
 321 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 322 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 323 'quiet|q' => 'be quiet',
 324 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 325         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 326
 327 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 328 'globoff|g' => "do not match locations using '*?' wildcards ".
 329                 "and\xa0'[]'\x{a0}ranges",
 330 'invert-match|v' => 'select non-matching lines',
 331 'color!' => 'disable color (for --format=text)',
 332 'verbose|v+' => 'be more verbose',
 333 'external!' => 'do not use externals',
 334 'mail!' => 'do not look in mail storage for OID',
 335 'cwd!' => 'do not look in git repo of current working directory',
 336 'oid-a|A=s' => 'pre-image OID',
 337 'path-a|a=s' => 'pre-image pathname associated with OID',
 338 'path-b|b=s' => 'post-image pathname associated with OID',
 339 'git-dir=s@' => 'additional git repository to scan',
 340 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 341 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 342         "proxy for (e.g. `socks5h://0:9050')" ],
 343 'torsocks=s' => ['VAL|auto|no|yes',
 344                 'whether or not to wrap git and curl commands with torsocks'],
 345 'no-torsocks' => 'alias for --torsocks=no',
 346 'save!' =>  "do not save a search for `lei up'",
 347 'import-remote!' => 'do not memoize remote messages into local store',
 348
 349 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 350
 351 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 352                 'deduplication strategy'],
 353 'threads|t+' =>
 354         'return all messages in the same threads as the actual match(es)',
 355
 356 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 357                 'search prefixes to extract (default: dfpost7)' ],
 358
 359 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 360         'run command(s) or perform ops when done writing to output ' .
 361         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 362         'nothing otherwise)' ],
 363
 364 'augment|a' => 'augment --output destination instead of clobbering',
 365
 366 'output|mfolder|o=s' => [ 'MFOLDER',
 367         "destination (e.g.\xa0`/path/to/Maildir', ".
 368         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 369 'mua=s' => [ 'CMD',
 370         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 371 'new-only       import' => 'only import new messages from IMAP source',
 372
 373 'inbox-version=i' => [ 'NUM|1|2',
 374                 'force a public-inbox version with --mirror'],
 375 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 376
 377 # public-inbox-index options
 378 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 379 'compact' => 'run compact index after mirroring',
 380 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 381         "indexlevel with --mirror (default: full)" ],
 382 'max_size|max-size=s' => [ 'SIZE',
 383         'do not index messages larger than SIZE (default: infinity)' ],
 384 'batch_size|batch-size=s' => [ 'SIZE',
 385         'flush changes to OS after given number of bytes (default: 1m)' ],
 386 'sequential-shard' =>
 387         'index Xapian shards sequentially for slow storage',
 388 'skip-docdata' =>
 389         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 390
 391 'format|f=s     q' => [
 392         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 393                 'specify output format, default depends on --output'],
 394 'exclude=s@     q' => [ 'LOCATION',
 395                 'exclude specified external(s) from search' ],
 396 'include|I=s@   q' => [ 'LOCATION',
 397                 'include specified external(s) in search' ],
 398 'only=s@        q' => [ 'LOCATION',
 399                 'only use specified external(s) for search' ],
 400 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 401                 'control number of search and writer jobs' ],
 402 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 403
 404 'in-format|F=s' => $stdin_formats,
 405 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 406                         'listing output format' ],
 407 'l      ls-search' => 'long listing format',
 408 'l      ls-watch' => 'long listing format',
 409 'l      ls-mail-source' => 'long listing format',
 410 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 411 'format|f=s     ls-external' => $ls_format,
 412
 413 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 414 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 415
 416 'sort|s=s' => [ 'VAL|received|relevance|docid',
 417                 "order of results is `--output'-dependent"],
 418 'reverse|r' => 'reverse search results', # like sort(1)
 419
 420 'boost=i' => 'increase/decrease priority of results (default: 0)',
 421
 422 'local' => 'limit operations to the local filesystem',
 423 'local!' => 'exclude results from the local filesystem',
 424 'remote' => 'limit operations to those requiring network access',
 425 'remote!' => 'prevent operations requiring network access',
 426
 427 # up, refresh-mail-sync, export-kw
 428 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 429
 430 'remote-fudge-time=s' => [ 'INTERVAL',
 431         'look for mail INTERVAL older than the last successful query' ],
 432
 433 'mid=s' => 'specify the Message-ID of a message',
 434 'oid=s' => 'specify the git object ID of a message',
 435
 436 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 437 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 438 'include=s' => 'include mailboxes/newsgroups based on pattern',
 439
 440 'exact' => 'operate on exact header matches only',
 441 'exact!' => 'rely on content match instead of exact header matches',
 442
 443 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 444
 445 'kw!' => 'disable/enable importing keywords (aka "flags")',
 446
 447 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 448 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 449
 450 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 451 ); # %OPTDESC
 452
 453 my %CONFIG_KEYS = (
 454         'leistore.dir' => 'top-level storage location',
 455 );
 456
 457 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 458
 459 sub _drop_wq {
 460         my ($self) = @_;
 461         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 462                 if ($wq->wq_kill) {
 463                         $wq->wq_close(0, undef, $self);
 464                 } elsif ($wq->wq_kill_old) {
 465                         $wq->wq_wait_old(undef, $self);
 466                 }
 467                 $wq->DESTROY;
 468         }
 469 }
 470
 471 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 472 sub x_it ($$) {
 473         my ($self, $code) = @_;
 474         # make sure client sees stdout before exit
 475         $self->{1}->autoflush(1) if $self->{1};
 476         stop_pager($self);
 477         if ($self->{pkt_op_p}) { # worker => lei-daemon
 478                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 479         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 480                 send($self->{sock}, "x_it $code", MSG_EOR);
 481         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 482                 exit($code >> 8);
 483         } # else ignore if client disconnected
 484 }
 485
 486 sub err ($;@) {
 487         my $self = shift;
 488         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 489         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 490         print $err @_, @eor and return;
 491         my $old_err = delete $self->{2};
 492         close($old_err) if $! == EPIPE && $old_err;
 493         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 494         print $err @_, @eor or print STDERR @_, @eor;
 495 }
 496
 497 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 498
 499 sub qfin { # show message on finalization (LeiFinmsg)
 500         my ($lei, $msg) = @_;
 501         return if $lei->{opt}->{quiet};
 502         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 503 }
 504
 505 sub fail_handler ($;$$) {
 506         my ($lei, $code, $io) = @_;
 507         close($io) if $io; # needed to avoid warnings on SIGPIPE
 508         _drop_wq($lei);
 509         x_it($lei, $code // (1 << 8));
 510 }
 511
 512 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 513         fail_handler($_[0], 13, delete $_[0]->{1});
 514 }
 515
 516 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 517 sub sigint_reap {
 518         my ($pgid) = @_;
 519         dwaitpid($pgid) if kill('-INT', $pgid);
 520 }
 521
 522 sub fail ($$;$) {
 523         my ($self, $buf, $exit_code) = @_;
 524         $self->{failed}++;
 525         err($self, $buf) if defined $buf;
 526         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 527         x_it($self, ($exit_code // 1) << 8);
 528         undef;
 529 }
 530
 531 sub out ($;@) {
 532         my $self = shift;
 533         return if print { $self->{1} // return } @_; # likely
 534         return note_sigpipe($self, 1) if $! == EPIPE;
 535         my $err = "error writing to output: $!";
 536         delete $self->{1};
 537         fail($self, $err);
 538 }
 539
 540 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 541
 542 sub child_error { # passes non-fatal curl exit codes to user
 543         my ($self, $child_error, $msg) = @_; # child_error is $?
 544         $child_error ||= 1 << 8;
 545         $self->err($msg) if $msg;
 546         if ($self->{pkt_op_p}) { # to top lei-daemon
 547                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 548         } elsif ($self->{sock}) { # to lei(1) client
 549                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 550         } else { # non-lei admin command
 551                 $self->{child_error} ||= $child_error;
 552         } # else noop if client disconnected
 553 }
 554
 555 sub note_sigpipe { # triggers sigpipe_handler
 556         my ($self, $fd) = @_;
 557         close(delete($self->{$fd})); # explicit close silences Perl warning
 558         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 559         x_it($self, 13);
 560 }
 561
 562 sub _lei_atfork_child {
 563         my ($self, $persist) = @_;
 564         # we need to explicitly close things which are on stack
 565         if ($persist) {
 566                 chdir '/' or die "chdir(/): $!";
 567                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 568                 if (my $cfg = $self->{cfg}) {
 569                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 570                 }
 571         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 572                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 573                 STDERR->autoflush(1);
 574         }
 575         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 576         if (my $op_c = delete $self->{pkt_op_c}) {
 577                 close(delete $op_c->{sock});
 578         }
 579         if (my $pgr = delete $self->{pgr}) {
 580                 close($_) for (@$pgr[1,2]);
 581         }
 582         close $listener if $listener;
 583         undef $listener;
 584         $dir_idle->force_close if $dir_idle;
 585         undef $dir_idle;
 586         %PATH2CFG = ();
 587         $MDIR2CFGPATH = {};
 588         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 589         undef $errors_log;
 590         $quit = \&CORE::exit;
 591         $self->{-eml_noisy} or # only "lei import" sets this atm
 592                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 593         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 594 }
 595
 596 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 597         my ($self) = @_;
 598         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 599                 $op->close; # PublicInbox::PktOp::close
 600         }
 601         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 602         close $pkt_op_p->{op_p};
 603 }
 604
 605 sub pkt_op_pair {
 606         my ($self) = @_;
 607         require PublicInbox::OnDestroy;
 608         require PublicInbox::PktOp;
 609         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 610         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 611         $end;
 612 }
 613
 614 sub incr {
 615         my ($self, $field, $nr) = @_;
 616         $self->{counters}->{$field} += $nr;
 617 }
 618
 619 sub pkt_ops {
 620         my ($lei, $ops) = @_;
 621         $ops->{fail_handler} = [ $lei ];
 622         $ops->{sigpipe_handler} = [ $lei ];
 623         $ops->{x_it} = [ $lei ];
 624         $ops->{child_error} = [ $lei ];
 625         $ops->{incr} = [ $lei ];
 626         $ops;
 627 }
 628
 629 sub workers_start {
 630         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 631         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 632         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 633         my $end = $lei->pkt_op_pair;
 634         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 635         $flds->{lei} = $lei;
 636         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 637         delete $lei->{pkt_op_p};
 638         my $op_c = delete $lei->{pkt_op_c};
 639         @$end = ();
 640         $lei->event_step_init;
 641         ($op_c, $ops);
 642 }
 643
 644 # call this when we're ready to wait on events and yield to other clients
 645 sub wait_wq_events {
 646         my ($lei, $op_c, $ops) = @_;
 647         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 648                 $wq->wq_close(1);
 649         }
 650         $op_c->{ops} = $ops;
 651 }
 652
 653 sub _help {
 654         require PublicInbox::LeiHelp;
 655         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 656 }
 657
 658 sub optparse ($$$) {
 659         my ($self, $cmd, $argv) = @_;
 660         # allow _complete --help to complete, not show help
 661         return 1 if substr($cmd, 0, 1) eq '_';
 662         $self->{cmd} = $cmd;
 663         $OPT = $self->{opt} //= {};
 664         my $info = $CMD{$cmd} // [ '[...]' ];
 665         my ($proto, undef, @spec) = @$info;
 666         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 667         push @spec, qw(help|h);
 668         my $lone_dash;
 669         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 670                 $lone_dash = $spec[0];
 671                 $OPT->{$spec[0]} = \(my $var);
 672                 push @spec, '' => \$var;
 673         }
 674         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 675                 return _help($self, "bad arguments or options for $cmd");
 676         return _help($self) if $OPT->{help};
 677
 678         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 679
 680         # "-" aliases "stdin" or "clear"
 681         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 682
 683         my $i = 0;
 684         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 685         my ($err, $inf);
 686         my @args = split(/ /, $proto);
 687         for my $var (@args) {
 688                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 689                         $inf = defined($argv->[$i]) and last;
 690                         $var =~ s/\.\.\.\z//;
 691                         $err = "$var not supplied";
 692                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 693                         $argv->[$i++] // ($err = "$var not supplied");
 694                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 695                         $inf = 1;
 696                         last;
 697                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 698                         $i++;
 699                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 700                         $inf = 1 if index($var, '...') > 0;
 701                         my @or = split(/\|/, $var);
 702                         my $ok;
 703                         for my $o (@or) {
 704                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 705                                         my $sw = $1;
 706                                         # assume pipe/regular file on stdin
 707                                         # w/o args means stdin
 708                                         if ($sw eq 'stdin' && !@$argv &&
 709                                                         (-p $self->{0} ||
 710                                                          -f _) && -r _) {
 711                                                 $OPT->{stdin} //= 1;
 712                                         }
 713                                         $ok = defined($OPT->{$sw});
 714                                         last if $ok;
 715                                 } elsif (defined($argv->[$i])) {
 716                                         $ok = 1;
 717                                         $i++;
 718                                         last;
 719                                 } # else continue looping
 720                         }
 721                         last if $ok;
 722                         my $last = pop @or;
 723                         $err = join(', ', @or) . " or $last must be set";
 724                 } else {
 725                         warn "BUG: can't parse `$var' in $proto";
 726                 }
 727                 last if $err;
 728         }
 729         if (!$inf && scalar(@$argv) > scalar(@args)) {
 730                 $err //= 'too many arguments';
 731         }
 732         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 733 }
 734
 735 sub _tmp_cfg { # for lei -c <name>=<value> ...
 736         my ($self) = @_;
 737         my $cfg = _lei_cfg($self, 1);
 738         require File::Temp;
 739         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 740         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 741         $ft->autoflush(1);
 742         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 743 [include]
 744         path = $cfg->{-f}
 745 EOM
 746         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 747         for (@{$self->{opt}->{c}}) {
 748                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 749 `-c $_' is not of the form -c <name>=<value>'
 750 EOM
 751                 my $name = $1;
 752                 my $value = $2 // 1;
 753                 _config($self, '--add', $name, $value);
 754                 if (defined(my $v = $tmp->{$name})) {
 755                         if (ref($v) eq 'ARRAY') {
 756                                 push @$v, $value;
 757                         } else {
 758                                 $tmp->{$name} = [ $v, $value ];
 759                         }
 760                 } else {
 761                         $tmp->{$name} = $value;
 762                 }
 763         }
 764 }
 765
 766 sub lazy_cb ($$$) {
 767         my ($self, $cmd, $pfx) = @_;
 768         my $ucmd = $cmd;
 769         $ucmd =~ tr/-/_/;
 770         my $cb;
 771         $cb = $self->can($pfx.$ucmd) and return $cb;
 772         my $base = $ucmd;
 773         $base =~ s/_([a-z])/\u$1/g;
 774         my $pkg = "PublicInbox::Lei\u$base";
 775         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 776                 $pkg->can($pfx.$ucmd) : undef;
 777 }
 778
 779 sub dispatch {
 780         my ($self, $cmd, @argv) = @_;
 781         fchdir($self) or return;
 782         local %ENV = %{$self->{env}};
 783         local $current_lei = $self; # for __WARN__
 784         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 785         return _help($self, 'no command given') unless defined($cmd);
 786         # do not support Getopt bundling for this
 787         while ($cmd eq '-C' || $cmd eq '-c') {
 788                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 789                                         '-C DIRECTORY' : '-c <name>=<value>');
 790                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 791                 $cmd = shift(@argv) // return _help($self, 'no command given');
 792         }
 793         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 794                 optparse($self, $cmd, \@argv) or return;
 795                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 796                 if (my $chdir = $self->{opt}->{C}) {
 797                         for my $d (@$chdir) {
 798                                 next if $d eq ''; # same as git(1)
 799                                 chdir $d or return fail($self, "cd $d: $!");
 800                         }
 801                         open $self->{3}, '.' or return fail($self, "open . $!");
 802                 }
 803                 $cb->($self, @argv);
 804         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 805                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 806                         or return _help($self, 'bad arguments or options');
 807                 _help($self);
 808         } else {
 809                 fail($self, "`$cmd' is not an lei command");
 810         }
 811 }
 812
 813 sub _lei_cfg ($;$) {
 814         my ($self, $creat) = @_;
 815         return $self->{cfg} if $self->{cfg};
 816         my $f = _config_path($self);
 817         my @st = stat($f);
 818         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 819         my ($sto, $sto_dir, $watches, $lne);
 820         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 821                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 822                 ($sto, $sto_dir, $watches, $lne) =
 823                                 @$cfg{qw(-lei_store leistore.dir -watches
 824                                         -lei_note_event)};
 825         }
 826         if (!@st) {
 827                 unless ($creat) {
 828                         delete $self->{cfg};
 829                         return bless {}, 'PublicInbox::Config';
 830                 }
 831                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 832                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 833                 open my $fh, '>>', $f or die "open($f): $!\n";
 834                 @st = stat($fh) or die "fstat($f): $!\n";
 835                 $cur_st = pack('dd', $st[10], $st[7]);
 836                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 837         }
 838         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 839         $cfg->{-st} = $cur_st;
 840         $cfg->{'-f'} = $f;
 841         if ($sto && canonpath_harder($sto_dir // store_path($self))
 842                         eq canonpath_harder($cfg->{'leistore.dir'} //
 843                                                 store_path($self))) {
 844                 $cfg->{-lei_store} = $sto;
 845                 $cfg->{-lei_note_event} = $lne;
 846                 $cfg->{-watches} = $watches if $watches;
 847         }
 848         if (scalar(keys %PATH2CFG) > 5) {
 849                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 850                 for my $k (keys %PATH2CFG) {
 851                         delete($PATH2CFG{$k}) unless -f $k
 852                 }
 853         }
 854         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 855         refresh_watches($self);
 856         $cfg;
 857 }
 858
 859 sub _lei_store ($;$) {
 860         my ($self, $creat) = @_;
 861         my $cfg = _lei_cfg($self, $creat) // return;
 862         $cfg->{-lei_store} //= do {
 863                 require PublicInbox::LeiStore;
 864                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 865                 return unless $creat || -d $dir;
 866                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 867         };
 868 }
 869
 870 sub _config {
 871         my ($self, @argv) = @_;
 872         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 873         my $cfg = _lei_cfg($self, 1);
 874         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 875         my %rdr = map { $_ => $self->{$_} } (0..2);
 876         waitpid(spawn($cmd, \%env, \%rdr), 0);
 877 }
 878
 879 sub lei_daemon_pid { puts shift, $$ }
 880
 881 sub lei_daemon_kill {
 882         my ($self) = @_;
 883         my $sig = $self->{opt}->{signal} // 'TERM';
 884         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 885 }
 886
 887 # Shell completion helper.  Used by lei-completion.bash and hopefully
 888 # other shells.  Try to do as much here as possible to avoid redundancy
 889 # and improve maintainability.
 890 sub lei__complete {
 891         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 892         shift @argv; # ignore "lei", the entire command is sent
 893         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 894         my $cmd = shift @argv;
 895         my $info = $CMD{$cmd} // do { # filter matching commands
 896                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 897                 return;
 898         };
 899         my ($proto, undef, @spec) = @$info;
 900         my $cur = pop @argv;
 901         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 902         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 903                 # gross special case since the only git-config options
 904                 # Consider moving to a table if we need more special cases
 905                 # we use Getopt::Long for are the ones we reject, so these
 906                 # are the ones we don't reject:
 907                 if ($cmd eq 'config') {
 908                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 909                         @spec = qw(add z|null get get-all unset unset-all
 910                                 replace-all get-urlmatch
 911                                 remove-section rename-section
 912                                 name-only list|l edit|e
 913                                 get-color-name get-colorbool);
 914                         # fall-through
 915                 }
 916                 # generate short/long names from Getopt::Long specs
 917                 puts $self, grep(/$re/, qw(--help -h -C), map {
 918                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 919                         } elsif (s/\+\z//) { # verbose|v+
 920                         } elsif (s/!\z//) {
 921                                 # negation: mail! => no-mail|mail
 922                                 s/([\w\-]+)/$1|no-$1/g
 923                         }
 924                         map {
 925                                 my $x = length > 1 ? "--$_" : "-$_";
 926                                 $x eq $_cur ? () : $x;
 927                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 928                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 929         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 930                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 931         }
 932
 933         # switch args (e.g. lei q -f mbox<TAB>)
 934         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 935                 my $opt = quotemeta $1;
 936                 puts $self, map {
 937                         my $v = $OPTDESC{$_};
 938                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 939                         # get rid of ALL CAPS placeholder (e.g "OUT")
 940                         # (TODO: completion for external paths)
 941                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 942                         @v;
 943                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 944         }
 945         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 946                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 947         }
 948         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 949         # proto parsing.
 950 }
 951
 952 sub exec_buf ($$) {
 953         my ($argv, $env) = @_;
 954         my $argc = scalar @$argv;
 955         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 956         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 957         $buf;
 958 }
 959
 960 sub start_mua {
 961         my ($self) = @_;
 962         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 963                 refresh_watches($self);
 964         }
 965         my $mua = $self->{opt}->{mua} // return;
 966         my $mfolder = $self->{ovv}->{dst};
 967         my (@cmd, $replaced);
 968         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 969                 @cmd = ($mua, '-f');
 970         # TODO: help wanted: other common FOSS MUAs
 971         } else {
 972                 require Text::ParseWords;
 973                 @cmd = Text::ParseWords::shellwords($mua);
 974                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 975                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 976         }
 977         push @cmd, $mfolder unless defined($replaced);
 978         if ($self->{sock}) { # lei(1) client process runs it
 979                 # restore terminal: echo $query | lei q --stdin --mua=...
 980                 my $io = [];
 981                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 982                 send_exec_cmd($self, $io, \@cmd, {});
 983         }
 984         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 985                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 986         }
 987         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 988         $self->{opt}->{quiet} = 1;
 989         delete $self->{-progress};
 990         delete $self->{opt}->{verbose};
 991 }
 992
 993 sub send_exec_cmd { # tell script/lei to execute a command
 994         my ($self, $io, $cmd, $env) = @_;
 995         my $sock = $self->{sock} // die 'lei client gone';
 996         my $fds = [ map { fileno($_) } @$io ];
 997         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 998 }
 999
1000 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1001         my ($self) = @_;
1002         my $alerts = $self->{opt}->{alert} // return;
1003         my $sock = $self->{sock};
1004         while (my $op = shift(@$alerts)) {
1005                 if ($op eq ':WINCH') {
1006                         # hit the process group that started the MUA
1007                         send($sock, '-WINCH', MSG_EOR) if $sock;
1008                 } elsif ($op eq ':bell') {
1009                         out($self, "\a");
1010                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1011                         push @$alerts, split(/(?<!\\),/, $op);
1012                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1013                         my $cmd = $1; # run an arbitrary command
1014                         require Text::ParseWords;
1015                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1016                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1017                 } else {
1018                         err($self, "W: unsupported --alert=$op"); # non-fatal
1019                 }
1020         }
1021 }
1022
1023 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1024 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1025
1026 # this also normalizes the path
1027 sub path_to_fd {
1028         my ($self, $path) = @_;
1029         $path = rel2abs($self, $path);
1030         $path =~ tr!/!/!s;
1031         $path_to_fd{$path} // (
1032                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1033                         fail($self, "cannot open $path from daemon") : -1
1034         );
1035 }
1036
1037 # caller needs to "-t $self->{1}" to check if tty
1038 sub start_pager {
1039         my ($self, $new_env) = @_;
1040         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1041         chomp(my $pager = <$fh> // '');
1042         close($fh) or warn "`git var PAGER' error: \$?=$?";
1043         return if $pager eq 'cat' || $pager eq '';
1044         $new_env //= {};
1045         $new_env->{LESS} //= 'FRX';
1046         $new_env->{LV} //= '-c';
1047         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1048         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1049         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1050         my $pgr = [ undef, @$rdr{1, 2} ];
1051         my $env = $self->{env};
1052         if ($self->{sock}) { # lei(1) process runs it
1053                 delete @$new_env{keys %$env}; # only set iff unset
1054                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1055         } else {
1056                 die 'BUG: start_pager w/o socket';
1057         }
1058         $self->{1} = $wpager;
1059         $self->{2} = $wpager if -t $self->{2};
1060         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1061         $self->{pgr} = $pgr;
1062 }
1063
1064 # display a message for user before spawning full-screen $VISUAL
1065 sub pgr_err {
1066         my ($self, @msg) = @_;
1067         return $self->err(@msg) unless $self->{sock} && -t $self->{2};
1068         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1069         print { $self->{2} } @msg;
1070         $self->{2}->autoflush(1);
1071         stop_pager($self);
1072         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1073 }
1074
1075 sub stop_pager {
1076         my ($self) = @_;
1077         my $pgr = delete($self->{pgr}) or return;
1078         $self->{2} = $pgr->[2];
1079         close(delete($self->{1})) if $self->{1};
1080         $self->{1} = $pgr->[1];
1081 }
1082
1083 sub accept_dispatch { # Listener {post_accept} callback
1084         my ($sock) = @_; # ignore other
1085         $sock->autoflush(1);
1086         my $self = bless { sock => $sock }, __PACKAGE__;
1087         vec(my $rvec = '', fileno($sock), 1) = 1;
1088         select($rvec, undef, undef, 60) or
1089                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1090         # (4096 * 33) >MAX_ARG_STRLEN
1091         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1092         if (!defined($fds[0])) {
1093                 warn(my $msg = "recv_cmd failed: $!");
1094                 return send($sock, $msg, MSG_EOR);
1095         } else {
1096                 my $i = 0;
1097                 for my $fd (@fds) {
1098                         open($self->{$i++}, '+<&=', $fd) and next;
1099                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1100                 }
1101                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1102         }
1103         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1104         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1105         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1106                 return send($sock, 'request command truncated', MSG_EOR);
1107         my ($argc, @argv) = split(/\0/, $buf, -1);
1108         undef $buf;
1109         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1110         $self->{env} = \%env;
1111         eval { dispatch($self, @argv) };
1112         send($sock, $@, MSG_EOR) if $@;
1113 }
1114
1115 sub dclose {
1116         my ($self) = @_;
1117         delete $self->{-progress};
1118         _drop_wq($self) if $self->{failed};
1119         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1120 }
1121
1122 # for long-running results
1123 sub event_step {
1124         my ($self) = @_;
1125         local %ENV = %{$self->{env}};
1126         local $current_lei = $self;
1127         eval {
1128                 my $buf;
1129                 while (my @fds = $recv_cmd->($self->{sock}, $buf, 4096)) {
1130                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1131                                 return if $! == EAGAIN;
1132                                 next if $! == EINTR;
1133                                 last if $! == ECONNRESET;
1134                                 die "recvmsg: $!";
1135                         }
1136                         for (@fds) { open my $rfh, '+<&=', $_ }
1137                 }
1138                 if ($buf eq '') {
1139                         _drop_wq($self); # EOF, client disconnected
1140                         dclose($self);
1141                 } elsif ($buf =~ /\A(STOP|CONT)\z/) {
1142                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1143                                 $wq->wq_kill($buf) or $wq->wq_kill_old($buf);
1144                         }
1145                 } else {
1146                         die "unrecognized client signal: $buf";
1147                 }
1148         };
1149         if (my $err = $@) {
1150                 eval { $self->fail($err) };
1151                 dclose($self);
1152         }
1153 }
1154
1155 sub event_step_init {
1156         my ($self) = @_;
1157         my $sock = $self->{sock} or return;
1158         $self->{-event_init_done} //= do { # persist til $ops done
1159                 $sock->blocking(0);
1160                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1161                 $sock;
1162         };
1163 }
1164
1165 sub noop {}
1166
1167 sub oldset { $oldset }
1168
1169 sub dump_and_clear_log {
1170         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1171                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1172                 chomp(my @lines = <STDIN>);
1173                 truncate(STDIN, 0) or
1174                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1175                 for my $l (@lines) { syslog('warning', '%s', $l) }
1176                 closelog(); # don't share across fork
1177         }
1178 }
1179
1180 sub cfg2lei ($) {
1181         my ($cfg) = @_;
1182         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1183         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1184         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1185         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1186         open($lei->{3}, '/') or die "open /: $!";
1187         my ($x, $y);
1188         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1189         $lei->{sock} = $x;
1190         require PublicInbox::LeiSelfSocket;
1191         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1192         $lei;
1193 }
1194
1195 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1196         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1197         my $fn = $ev->fullname;
1198         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1199                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1200                 $nc = '' if $ev->IN_DELETE;
1201                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1202                         my $cfg = $PATH2CFG{$f} // next;
1203                         eval {
1204                                 my $lei = cfg2lei($cfg);
1205                                 $lei->dispatch('note-event',
1206                                                 "maildir:$mdir", $nc, $bn, $fn);
1207                         };
1208                         warn "E: note-event $f: $@\n" if $@;
1209                 }
1210         }
1211         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1212                 $ev->cancel;
1213         }
1214         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1215                 delete $MDIR2CFGPATH->{$1};
1216         }
1217         if (!-e $fn) { # config file or Maildir gone
1218                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1219                         delete $cfgpaths->{$fn};
1220                 }
1221                 delete $PATH2CFG{$fn};
1222         }
1223 }
1224
1225 # lei(1) calls this when it can't connect
1226 sub lazy_start {
1227         my ($path, $errno, $narg) = @_;
1228         local ($errors_log, $listener);
1229         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1230         $errors_log = "$sock_dir/errors.log";
1231         my $addr = pack_sockaddr_un($path);
1232         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1233         umask(077) // die("umask(077): $!");
1234         $lk->lock_acquire;
1235         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1236         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1237                 return if connect($listener, $addr); # another process won
1238                 if ($errno == ECONNREFUSED && -S $path) {
1239                         unlink($path) or die "unlink($path): $!";
1240                 }
1241         } else {
1242                 $! = $errno; # allow interpolation to stringify in die
1243                 die "connect($path): $!";
1244         }
1245         bind($listener, $addr) or die "bind($path): $!";
1246         $lk->lock_release;
1247         undef $lk;
1248         my @st = stat($path) or die "stat($path): $!";
1249         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1250         local $oldset = PublicInbox::DS::block_signals();
1251         if ($narg == 5) {
1252                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1253                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1254                         require PublicInbox::CmdIPC4;
1255                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1256                         PublicInbox::CmdIPC4->can('recv_cmd4');
1257                 };
1258         }
1259         $recv_cmd or die <<"";
1260 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1261
1262         require PublicInbox::Listener;
1263         require PublicInbox::PktOp;
1264         (-p STDOUT) or die "E: stdout must be a pipe\n";
1265         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1266         STDIN->autoflush(1);
1267         dump_and_clear_log();
1268         POSIX::setsid() > 0 or die "setsid: $!";
1269         my $pid = fork // die "fork: $!";
1270         return if $pid;
1271         $0 = "lei-daemon $path";
1272         local %PATH2CFG;
1273         local $MDIR2CFGPATH;
1274         $listener->blocking(0);
1275         my $exit_code;
1276         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1277         local $quit = do {
1278                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1279                 sub {
1280                         $exit_code //= shift;
1281                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1282                         my $lis = $pil or exit($exit_code);
1283                         # closing eof_p triggers \&noop wakeup
1284                         $listener = $eof_p = $pil = $path = undef;
1285                         $lis->close; # DS::close
1286                         PublicInbox::DS->SetLoopTimeout(1000);
1287                 };
1288         };
1289         my $sig = {
1290                 CHLD => \&PublicInbox::DS::enqueue_reap,
1291                 QUIT => $quit,
1292                 INT => $quit,
1293                 TERM => $quit,
1294                 HUP => \&noop,
1295                 USR1 => \&noop,
1296                 USR2 => \&noop,
1297         };
1298         require PublicInbox::DirIdle;
1299         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1300                 # just rely on wakeup to hit PostLoopCallback set below
1301                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1302         }, 1);
1303         PublicInbox::DS->SetPostLoopCallback(sub {
1304                 my ($dmap, undef) = @_;
1305                 if (@st = defined($path) ? stat($path) : ()) {
1306                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1307                                 warn "$path dev/ino changed, quitting\n";
1308                                 $path = undef;
1309                         }
1310                 } elsif (defined($path)) { # ENOENT is common
1311                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1312                         undef $path;
1313                         $quit->();
1314                 }
1315                 return 1 if defined($path);
1316                 my $now = now();
1317                 my $n = 0;
1318                 for my $s (values %$dmap) {
1319                         $s->can('busy') or next;
1320                         if ($s->busy($now)) {
1321                                 ++$n;
1322                         } else {
1323                                 $s->close;
1324                         }
1325                 }
1326                 $n; # true: continue, false: stop
1327         });
1328
1329         # STDIN was redirected to /dev/null above, closing STDERR and
1330         # STDOUT will cause the calling `lei' client process to finish
1331         # reading the <$daemon> pipe.
1332         local $SIG{__WARN__} = sub {
1333                 $current_lei ? err($current_lei, @_) : warn(
1334                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1335         };
1336         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1337         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1338         # $daemon pipe to `lei' closed, main loop begins:
1339         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1340         warn "event loop error: $@\n" if $@;
1341         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1342         PublicInbox::DS::sig_setmask($oldset);
1343         dump_and_clear_log();
1344         exit($exit_code // 0);
1345 }
1346
1347 sub busy { 1 } # prevent daemon-shutdown if client is connected
1348
1349 # ensures stdout hits the FS before sock disconnects so a client
1350 # can immediately reread it
1351 sub DESTROY {
1352         my ($self) = @_;
1353         if (my $counters = delete $self->{counters}) {
1354                 for my $k (sort keys %$counters) {
1355                         my $nr = $counters->{$k};
1356                         $self->child_error(0, "$nr $k messages");
1357                 }
1358         }
1359         $self->{1}->autoflush(1) if $self->{1};
1360         stop_pager($self);
1361         dump_and_clear_log();
1362         # preserve $? for ->fail or ->x_it code
1363 }
1364
1365 sub wq_done_wait { # dwaitpid callback
1366         my ($arg, $pid) = @_;
1367         my ($wq, $lei) = @$arg;
1368         my $err_type = $lei->{-err_type};
1369         $? and $lei->child_error($?,
1370                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1371         $lei->dclose;
1372 }
1373
1374 sub fchdir {
1375         my ($lei) = @_;
1376         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1377         chdir($dh) || $lei->fail("fchdir: $!");
1378 }
1379
1380 sub wq_eof { # EOF callback for main daemon
1381         my ($lei) = @_;
1382         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1383         $wq1->wq_wait_old($wq1->can('_wq_done_wait') // \&wq_done_wait, $lei);
1384 }
1385
1386 sub watch_state_ok ($) {
1387         my ($state) = $_[-1]; # $_[0] may be $self
1388         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1389 }
1390
1391 sub cancel_maildir_watch ($$) {
1392         my ($d, $cfg_f) = @_;
1393         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1394         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1395                 delete $MDIR2CFGPATH->{$d};
1396         for my $x (@{$w // []}) { $x->cancel }
1397 }
1398
1399 sub add_maildir_watch ($$) {
1400         my ($d, $cfg_f) = @_;
1401         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1402                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1403                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1404         }
1405 }
1406
1407 sub refresh_watches {
1408         my ($lei) = @_;
1409         $dir_idle or return;
1410         my $cfg = _lei_cfg($lei) or return;
1411         my $old = $cfg->{-watches};
1412         my $watches = $cfg->{-watches} //= {};
1413         my %seen;
1414         my $cfg_f = $cfg->{'-f'};
1415         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1416                 my $url = substr($w, length('watch.'), -length('.state'));
1417                 require PublicInbox::LeiWatch;
1418                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1419                 $seen{$url} = undef;
1420                 my $state = $cfg->get_1("watch.$url.state");
1421                 if (!watch_state_ok($state)) {
1422                         $lei->err("watch.$url.state=$state not supported");
1423                         next;
1424                 }
1425                 if ($url =~ /\Amaildir:(.+)/i) {
1426                         my $d = canonpath_harder($1);
1427                         if ($state eq 'pause') {
1428                                 cancel_maildir_watch($d, $cfg_f);
1429                         } else {
1430                                 add_maildir_watch($d, $cfg_f);
1431                         }
1432                 } else { # TODO: imap/nntp/jmap
1433                         $lei->child_error(0, "E: watch $url not supported, yet")
1434                 }
1435         }
1436
1437         # add all known Maildir folders as implicit watches
1438         my $lms = $lei->lms;
1439         if ($lms) {
1440                 $lms->lms_write_prepare;
1441                 for my $d ($lms->folders('maildir:')) {
1442                         substr($d, 0, length('maildir:')) = '';
1443
1444                         # fixup old bugs while we're iterating:
1445                         my $cd = canonpath_harder($d);
1446                         my $f = "maildir:$cd";
1447                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1448                         next if $watches->{$f}; # may be set to pause
1449                         require PublicInbox::LeiWatch;
1450                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1451                         $seen{$f} = undef;
1452                         add_maildir_watch($cd, $cfg_f);
1453                 }
1454         }
1455         if ($old) { # cull old non-existent entries
1456                 for my $url (keys %$old) {
1457                         next if exists $seen{$url};
1458                         delete $old->{$url};
1459                         if ($url =~ /\Amaildir:(.+)/i) {
1460                                 my $d = canonpath_harder($1);
1461                                 cancel_maildir_watch($d, $cfg_f);
1462                         } else { # TODO: imap/nntp/jmap
1463                                 $lei->child_error(0, "E: watch $url TODO");
1464                         }
1465                 }
1466         }
1467         if (scalar keys %$watches) {
1468                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1469         } else {
1470                 delete $cfg->{-watches};
1471         }
1472 }
1473
1474 # TODO: support SHA-256
1475 sub git_oid {
1476         my $eml = $_[-1];
1477         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1478         git_sha(1, $eml);
1479 }
1480
1481 sub lms {
1482         my ($lei, $rw) = @_;
1483         my $sto = $lei->{sto} // _lei_store($lei) // return;
1484         require PublicInbox::LeiMailSync;
1485         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1486         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1487 }
1488
1489 sub sto_done_request {
1490         my ($lei, $sock) = @_;
1491         eval {
1492                 if ($sock //= $lei->{sock}) { # issue, async wait
1493                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1494                 } else { # forcibly wait
1495                         my $wait = $lei->{sto}->wq_do('done');
1496                 }
1497         };
1498         $lei->err($@) if $@;
1499 }
1500
1501 sub cfg_dump ($$) {
1502         my ($lei, $f) = @_;
1503         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1504         return $ret if !$@;
1505         $lei->err($@);
1506         undef;
1507 }
1508
1509 1;