lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 222         "exclude message(s) on stdin from `q' search results",
 223         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 224
 225 'purge-mailsource' => [ 'LOCATION|--all',
 226         'remove imported messages from IMAP, Maildirs, and MH',
 227         qw(exact! all jobs:i indexed), @c_opt ],
 228
 229 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 230         qw(import! kw! interval=s recursive|r
 231         exclude=s include=s), @c_opt ],
 232 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 233                 qw(format|f=s z), @c_opt ],
 234 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 235 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 236 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 237         qw(prune), @c_opt ],
 238
 239 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 240         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 241         verbose|v+ incremental!),
 242          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 243          @c_opt ],
 244 'import' => [ 'LOCATION...|--stdin',
 245         'one-time import/update from URL or filesystem',
 246         qw(stdin| offset=i recursive|r exclude=s include|I=s
 247         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 248         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 249 'forget-mail-sync' => [ 'LOCATION...',
 250         'forget sync information for a mail folder', @c_opt ],
 251 'export-kw' => [ 'LOCATION...|--all',
 252         'one-time export of keywords of sync sources',
 253         qw(all:s mode=s), @c_opt ],
 254 'convert' => [ 'LOCATION...|--stdin',
 255         'one-time conversion from URL or filesystem to another format',
 256         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 257         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 258 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 259         "use a patch to generate a query for `lei q --stdin'",
 260         qw(stdin| want|w=s@ uri debug), @c_opt ],
 261 'config' => [ '[...]', sub {
 262                 'git-config(1) wrapper for '._config_path($_[0]);
 263         }, qw(config-file|system|global|file|f=s), # for conflict detection
 264          qw(c=s@ C=s@), pass_through('git config') ],
 265 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 266         qw(pretty ascii dir=s), @c_opt ],
 267
 268 'init' => [ '[DIRNAME]', sub {
 269         "initialize storage, default: ".store_path($_[0]);
 270         }, @c_opt ],
 271 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 272         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 273         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 274 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 275 'help' => [ '[SUBCOMMAND]', 'show help' ],
 276
 277 # TODO
 278 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 279 #       'rewrite git history in an attempt to improve compression',
 280 #       qw(gc!), @c_opt ],
 281 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 282 #
 283 # internal commands are prefixed with '_'
 284 '_complete' => [ '[...]', 'internal shell completion helper',
 285                 pass_through('everything') ],
 286 ); # @CMD
 287
 288 # switch descriptions, try to keep consistent across commands
 289 # $spec: Getopt::Long option specification
 290 # $spec => [@ALLOWED_VALUES (default is first), $description],
 291 # $spec => $description
 292 # "$SUB_COMMAND TAB $spec" => as above
 293 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 294                         'specify message input format' ];
 295 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 296
 297 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 298 my %OPTDESC = (
 299 'help|h' => 'show this built-in help',
 300 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 301 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 302 'quiet|q' => 'be quiet',
 303 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 304         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 305
 306 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 307 'globoff|g' => "do not match locations using '*?' wildcards ".
 308                 "and\xa0'[]'\x{a0}ranges",
 309 'invert-match|v' => 'select non-matching lines',
 310 'color!' => 'disable color (for --format=text)',
 311 'verbose|v+' => 'be more verbose',
 312 'external!' => 'do not use externals',
 313 'mail!' => 'do not look in mail storage for OID',
 314 'cwd!' => 'do not look in git repo of current working directory',
 315 'oid-a|A=s' => 'pre-image OID',
 316 'path-a|a=s' => 'pre-image pathname associated with OID',
 317 'path-b|b=s' => 'post-image pathname associated with OID',
 318 'git-dir=s@' => 'additional git repository to scan',
 319 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 320         "proxy for (e.g. `socks5h://0:9050')" ],
 321 'torsocks=s' => ['VAL|auto|no|yes',
 322                 'whether or not to wrap git and curl commands with torsocks'],
 323 'no-torsocks' => 'alias for --torsocks=no',
 324 'save' =>  "save a search for `lei up'",
 325 'import-remote!' => 'do not memoize remote messages into local store',
 326
 327 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 328
 329 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 330                 'deduplication strategy'],
 331 'threads|t+' =>
 332         'return all messages in the same threads as the actual match(es)',
 333
 334 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 335                 'search prefixes to extract (default: dfpost7)' ],
 336
 337 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 338         'run command(s) or perform ops when done writing to output ' .
 339         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 340         'nothing otherwise)' ],
 341
 342 'augment|a' => 'augment --output destination instead of clobbering',
 343
 344 'output|mfolder|o=s' => [ 'MFOLDER',
 345         "destination (e.g.\xa0`/path/to/Maildir', ".
 346         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 347 'mua=s' => [ 'CMD',
 348         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 349
 350 'inbox-version=i' => [ 'NUM|1|2',
 351                 'force a public-inbox version with --mirror'],
 352 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 353
 354 # public-inbox-index options
 355 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 356 'compact' => 'run compact index after mirroring',
 357 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 358         "indexlevel with --mirror (default: full)" ],
 359 'max_size|max-size=s' => [ 'SIZE',
 360         'do not index messages larger than SIZE (default: infinity)' ],
 361 'batch_size|batch-size=s' => [ 'SIZE',
 362         'flush changes to OS after given number of bytes (default: 1m)' ],
 363 'sequential_shard|sequential-shard' =>
 364         'index Xapian shards sequentially for slow storage',
 365 'skip-docdata' =>
 366         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 367
 368 'format|f=s     q' => [
 369         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 370                 'specify output format, default depends on --output'],
 371 'exclude=s@     q' => [ 'LOCATION',
 372                 'exclude specified external(s) from search' ],
 373 'include|I=s@   q' => [ 'LOCATION',
 374                 'include specified external(s) in search' ],
 375 'only=s@        q' => [ 'LOCATION',
 376                 'only use specified external(s) for search' ],
 377 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 378                 'control number of search and writer jobs' ],
 379 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 380
 381 'in-format|F=s' => $stdin_formats,
 382 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 383                         'listing output format' ],
 384 'l      ls-search' => 'long listing format',
 385 'format|f=s     ls-external' => $ls_format,
 386
 387 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 388 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 389
 390 'sort|s=s' => [ 'VAL|received|relevance|docid',
 391                 "order of results is `--output'-dependent"],
 392 'reverse|r' => 'reverse search results', # like sort(1)
 393
 394 'boost=i' => 'increase/decrease priority of results (default: 0)',
 395
 396 'local' => 'limit operations to the local filesystem',
 397 'local!' => 'exclude results from the local filesystem',
 398 'remote' => 'limit operations to those requiring network access',
 399 'remote!' => 'prevent operations requiring network access',
 400
 401 'all:s  up' => ['local', 'update all (local) saved searches' ],
 402
 403 'mid=s' => 'specify the Message-ID of a message',
 404 'oid=s' => 'specify the git object ID of a message',
 405
 406 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 407 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 408 'include=s' => 'include mailboxes/newsgroups based on pattern',
 409
 410 'exact' => 'operate on exact header matches only',
 411 'exact!' => 'rely on content match instead of exact header matches',
 412
 413 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 414
 415 'kw!' => 'disable/enable importing keywords (aka "flags")',
 416
 417 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 418 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 419
 420 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 421 ); # %OPTDESC
 422
 423 my %CONFIG_KEYS = (
 424         'leistore.dir' => 'top-level storage location',
 425 );
 426
 427 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 428
 429 sub _drop_wq {
 430         my ($self) = @_;
 431         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 432                 if ($wq->wq_kill) {
 433                         $wq->wq_close(0, undef, $self);
 434                 } elsif ($wq->wq_kill_old) {
 435                         $wq->wq_wait_old(undef, $self);
 436                 }
 437                 $wq->DESTROY;
 438         }
 439 }
 440
 441 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 442 sub x_it ($$) {
 443         my ($self, $code) = @_;
 444         # make sure client sees stdout before exit
 445         $self->{1}->autoflush(1) if $self->{1};
 446         dump_and_clear_log();
 447         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 448                 send($s, "x_it $code", MSG_EOR);
 449         } # else ignore if client disconnected
 450 }
 451
 452 sub err ($;@) {
 453         my $self = shift;
 454         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 455         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 456         print $err @_, @eor and return;
 457         my $old_err = delete $self->{2};
 458         close($old_err) if $! == EPIPE && $old_err;
 459         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 460         print $err @_, @eor or print STDERR @_, @eor;
 461 }
 462
 463 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 464
 465 sub fail_handler ($;$$) {
 466         my ($lei, $code, $io) = @_;
 467         close($io) if $io; # needed to avoid warnings on SIGPIPE
 468         _drop_wq($lei);
 469         x_it($lei, $code // (1 << 8));
 470 }
 471
 472 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 473         fail_handler($_[0], 13, delete $_[0]->{1});
 474 }
 475
 476 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 477 sub sigint_reap {
 478         my ($pgid) = @_;
 479         dwaitpid($pgid) if kill('-INT', $pgid);
 480 }
 481
 482 sub fail ($$;$) {
 483         my ($self, $buf, $exit_code) = @_;
 484         err($self, $buf) if defined $buf;
 485         # calls fail_handler:
 486         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 487         x_it($self, ($exit_code // 1) << 8);
 488         undef;
 489 }
 490
 491 sub out ($;@) {
 492         my $self = shift;
 493         return if print { $self->{1} // return } @_; # likely
 494         return note_sigpipe($self, 1) if $! == EPIPE;
 495         my $err = "error writing to output: $!";
 496         delete $self->{1};
 497         fail($self, $err);
 498 }
 499
 500 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 501
 502 sub child_error { # passes non-fatal curl exit codes to user
 503         my ($self, $child_error, $msg) = @_; # child_error is $?
 504         $self->err($msg) if $msg;
 505         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 506                 # send to the parent lei-daemon or to lei(1) client
 507                 send($s, "child_error $child_error", MSG_EOR);
 508         } elsif (!$PublicInbox::DS::in_loop) {
 509                 $self->{child_error} = $child_error;
 510         } # else noop if client disconnected
 511 }
 512
 513 sub note_sigpipe { # triggers sigpipe_handler
 514         my ($self, $fd) = @_;
 515         close(delete($self->{$fd})); # explicit close silences Perl warning
 516         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 517         x_it($self, 13);
 518 }
 519
 520 sub _lei_atfork_child {
 521         my ($self, $persist) = @_;
 522         # we need to explicitly close things which are on stack
 523         if ($persist) {
 524                 chdir '/' or die "chdir(/): $!";
 525                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 526                 if (my $cfg = $self->{cfg}) {
 527                         delete $cfg->{-lei_store};
 528                 }
 529         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 530                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 531                 STDERR->autoflush(1);
 532         }
 533         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 534         if (my $op_c = delete $self->{pkt_op_c}) {
 535                 close(delete $op_c->{sock});
 536         }
 537         if (my $pgr = delete $self->{pgr}) {
 538                 close($_) for (@$pgr[1,2]);
 539         }
 540         close $listener if $listener;
 541         undef $listener;
 542         undef $dir_idle;
 543         %PATH2CFG = ();
 544         undef $errors_log;
 545         $quit = \&CORE::exit;
 546         $self->{-eml_noisy} or # only "lei import" sets this atm
 547                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 548         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 549 }
 550
 551 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 552         my ($self) = @_;
 553         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 554                 $op->close; # PublicInbox::PktOp::close
 555         }
 556         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 557         close $unclosed_after_die;
 558 }
 559
 560 sub pkt_op_pair {
 561         my ($self) = @_;
 562         require PublicInbox::OnDestroy;
 563         require PublicInbox::PktOp;
 564         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 565         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 566         $end;
 567 }
 568
 569 sub workers_start {
 570         my ($lei, $wq, $jobs, $ops) = @_;
 571         $ops = {
 572                 '!' => [ \&fail_handler, $lei ],
 573                 '|' => [ \&sigpipe_handler, $lei ],
 574                 'x_it' => [ \&x_it, $lei ],
 575                 'child_error' => [ \&child_error, $lei ],
 576                 ($ops ? %$ops : ()),
 577         };
 578         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 579         my $end = $lei->pkt_op_pair;
 580         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 581         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 582         delete $lei->{pkt_op_p};
 583         my $op_c = delete $lei->{pkt_op_c};
 584         @$end = ();
 585         $lei->event_step_init;
 586         ($op_c, $ops);
 587 }
 588
 589 sub _help {
 590         require PublicInbox::LeiHelp;
 591         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 592 }
 593
 594 sub optparse ($$$) {
 595         my ($self, $cmd, $argv) = @_;
 596         # allow _complete --help to complete, not show help
 597         return 1 if substr($cmd, 0, 1) eq '_';
 598         $self->{cmd} = $cmd;
 599         $OPT = $self->{opt} //= {};
 600         my $info = $CMD{$cmd} // [ '[...]' ];
 601         my ($proto, undef, @spec) = @$info;
 602         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 603         push @spec, qw(help|h);
 604         my $lone_dash;
 605         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 606                 $lone_dash = $spec[0];
 607                 $OPT->{$spec[0]} = \(my $var);
 608                 push @spec, '' => \$var;
 609         }
 610         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 611                 return _help($self, "bad arguments or options for $cmd");
 612         return _help($self) if $OPT->{help};
 613
 614         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 615
 616         # "-" aliases "stdin" or "clear"
 617         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 618
 619         my $i = 0;
 620         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 621         my ($err, $inf);
 622         my @args = split(/ /, $proto);
 623         for my $var (@args) {
 624                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 625                         $inf = defined($argv->[$i]) and last;
 626                         $var =~ s/\.\.\.\z//;
 627                         $err = "$var not supplied";
 628                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 629                         $argv->[$i++] // ($err = "$var not supplied");
 630                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 631                         $inf = 1;
 632                         last;
 633                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 634                         $i++;
 635                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 636                         $inf = 1 if index($var, '...') > 0;
 637                         my @or = split(/\|/, $var);
 638                         my $ok;
 639                         for my $o (@or) {
 640                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 641                                         my $sw = $1;
 642                                         # assume pipe/regular file on stdin
 643                                         # w/o args means stdin
 644                                         if ($sw eq 'stdin' && !@$argv &&
 645                                                         (-p $self->{0} ||
 646                                                          -f _) && -r _) {
 647                                                 $OPT->{stdin} //= 1;
 648                                         }
 649                                         $ok = defined($OPT->{$sw});
 650                                         last if $ok;
 651                                 } elsif (defined($argv->[$i])) {
 652                                         $ok = 1;
 653                                         $i++;
 654                                         last;
 655                                 } # else continue looping
 656                         }
 657                         last if $ok;
 658                         my $last = pop @or;
 659                         $err = join(', ', @or) . " or $last must be set";
 660                 } else {
 661                         warn "BUG: can't parse `$var' in $proto";
 662                 }
 663                 last if $err;
 664         }
 665         if (!$inf && scalar(@$argv) > scalar(@args)) {
 666                 $err //= 'too many arguments';
 667         }
 668         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 669 }
 670
 671 sub _tmp_cfg { # for lei -c <name>=<value> ...
 672         my ($self) = @_;
 673         my $cfg = _lei_cfg($self, 1);
 674         require File::Temp;
 675         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 676         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 677         $ft->autoflush(1);
 678         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 679 [include]
 680         path = $cfg->{-f}
 681 EOM
 682         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 683         for (@{$self->{opt}->{c}}) {
 684                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 685 `-c $_' is not of the form -c <name>=<value>'
 686 EOM
 687                 my $name = $1;
 688                 my $value = $2 // 1;
 689                 _config($self, '--add', $name, $value);
 690                 if (defined(my $v = $tmp->{$name})) {
 691                         if (ref($v) eq 'ARRAY') {
 692                                 push @$v, $value;
 693                         } else {
 694                                 $tmp->{$name} = [ $v, $value ];
 695                         }
 696                 } else {
 697                         $tmp->{$name} = $value;
 698                 }
 699         }
 700 }
 701
 702 sub lazy_cb ($$$) {
 703         my ($self, $cmd, $pfx) = @_;
 704         my $ucmd = $cmd;
 705         $ucmd =~ tr/-/_/;
 706         my $cb;
 707         $cb = $self->can($pfx.$ucmd) and return $cb;
 708         my $base = $ucmd;
 709         $base =~ s/_([a-z])/\u$1/g;
 710         my $pkg = "PublicInbox::Lei\u$base";
 711         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 712                 $pkg->can($pfx.$ucmd) : undef;
 713 }
 714
 715 sub dispatch {
 716         my ($self, $cmd, @argv) = @_;
 717         local $current_lei = $self; # for __WARN__
 718         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 719         dump_and_clear_log("from previous run\n");
 720         return _help($self, 'no command given') unless defined($cmd);
 721         # do not support Getopt bundling for this
 722         while ($cmd eq '-C' || $cmd eq '-c') {
 723                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 724                                         '-C DIRECTORY' : '-c <name>=<value>');
 725                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 726                 $cmd = shift(@argv) // return _help($self, 'no command given');
 727         }
 728         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 729                 optparse($self, $cmd, \@argv) or return;
 730                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 731                 if (my $chdir = $self->{opt}->{C}) {
 732                         for my $d (@$chdir) {
 733                                 next if $d eq ''; # same as git(1)
 734                                 chdir $d or return fail($self, "cd $d: $!");
 735                         }
 736                         if (delete $self->{3}) { # update cwd for rel2abs
 737                                 opendir my $dh, '.' or
 738                                         return fail($self, "opendir . $!");
 739                                 $self->{3} = $dh;
 740                         }
 741                 }
 742                 $cb->($self, @argv);
 743         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 744                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 745                         or return _help($self, 'bad arguments or options');
 746                 _help($self);
 747         } else {
 748                 fail($self, "`$cmd' is not an lei command");
 749         }
 750 }
 751
 752 sub _lei_cfg ($;$) {
 753         my ($self, $creat) = @_;
 754         return $self->{cfg} if $self->{cfg};
 755         my $f = _config_path($self);
 756         my @st = stat($f);
 757         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 758         my ($sto, $sto_dir);
 759         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 760                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 761                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 762         }
 763         if (!@st) {
 764                 unless ($creat) {
 765                         delete $self->{cfg};
 766                         return bless {}, 'PublicInbox::Config';
 767                 }
 768                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 769                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 770                 open my $fh, '>>', $f or die "open($f): $!\n";
 771                 @st = stat($fh) or die "fstat($f): $!\n";
 772                 $cur_st = pack('dd', $st[10], $st[7]);
 773                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 774         }
 775         my $cfg = PublicInbox::Config->git_config_dump($f);
 776         $cfg->{-st} = $cur_st;
 777         $cfg->{'-f'} = $f;
 778         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 779                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 780                                                 store_path($self))) {
 781                 $cfg->{-lei_store} = $sto;
 782         }
 783         if (scalar(keys %PATH2CFG) > 5) {
 784                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 785                 for my $k (keys %PATH2CFG) {
 786                         delete($PATH2CFG{$k}) unless -f $k
 787                 }
 788         }
 789         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 790 }
 791
 792 sub _lei_store ($;$) {
 793         my ($self, $creat) = @_;
 794         my $cfg = _lei_cfg($self, $creat);
 795         $cfg->{-lei_store} //= do {
 796                 require PublicInbox::LeiStore;
 797                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 798                 return unless $creat || -d $dir;
 799                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 800         };
 801 }
 802
 803 sub _config {
 804         my ($self, @argv) = @_;
 805         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 806         my $cfg = _lei_cfg($self, 1);
 807         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 808         my %rdr = map { $_ => $self->{$_} } (0..2);
 809         waitpid(spawn($cmd, \%env, \%rdr), 0);
 810 }
 811
 812 sub lei_config {
 813         my ($self, @argv) = @_;
 814         $self->{opt}->{'config-file'} and return fail $self,
 815                 "config file switches not supported by `lei config'";
 816         _config(@_);
 817         x_it($self, $?) if $?;
 818 }
 819
 820 sub lei_daemon_pid { puts shift, $$ }
 821
 822 sub lei_daemon_kill {
 823         my ($self) = @_;
 824         my $sig = $self->{opt}->{signal} // 'TERM';
 825         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 826 }
 827
 828 # Shell completion helper.  Used by lei-completion.bash and hopefully
 829 # other shells.  Try to do as much here as possible to avoid redundancy
 830 # and improve maintainability.
 831 sub lei__complete {
 832         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 833         shift @argv; # ignore "lei", the entire command is sent
 834         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 835         my $cmd = shift @argv;
 836         my $info = $CMD{$cmd} // do { # filter matching commands
 837                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 838                 return;
 839         };
 840         my ($proto, undef, @spec) = @$info;
 841         my $cur = pop @argv;
 842         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 843         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 844                 # gross special case since the only git-config options
 845                 # Consider moving to a table if we need more special cases
 846                 # we use Getopt::Long for are the ones we reject, so these
 847                 # are the ones we don't reject:
 848                 if ($cmd eq 'config') {
 849                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 850                         @spec = qw(add z|null get get-all unset unset-all
 851                                 replace-all get-urlmatch
 852                                 remove-section rename-section
 853                                 name-only list|l edit|e
 854                                 get-color-name get-colorbool);
 855                         # fall-through
 856                 }
 857                 # generate short/long names from Getopt::Long specs
 858                 puts $self, grep(/$re/, qw(--help -h -C), map {
 859                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 860                         } elsif (s/\+\z//) { # verbose|v+
 861                         } elsif (s/!\z//) {
 862                                 # negation: mail! => no-mail|mail
 863                                 s/([\w\-]+)/$1|no-$1/g
 864                         }
 865                         map {
 866                                 my $x = length > 1 ? "--$_" : "-$_";
 867                                 $x eq $_cur ? () : $x;
 868                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 869                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 870         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 871                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 872         }
 873
 874         # switch args (e.g. lei q -f mbox<TAB>)
 875         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 876                 my $opt = quotemeta $1;
 877                 puts $self, map {
 878                         my $v = $OPTDESC{$_};
 879                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 880                         # get rid of ALL CAPS placeholder (e.g "OUT")
 881                         # (TODO: completion for external paths)
 882                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 883                         @v;
 884                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 885         }
 886         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 887                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 888         }
 889         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 890         # proto parsing.
 891 }
 892
 893 sub exec_buf ($$) {
 894         my ($argv, $env) = @_;
 895         my $argc = scalar @$argv;
 896         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 897         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 898         $buf;
 899 }
 900
 901 sub start_mua {
 902         my ($self) = @_;
 903         my $mua = $self->{opt}->{mua} // return;
 904         my $mfolder = $self->{ovv}->{dst};
 905         my (@cmd, $replaced);
 906         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 907                 @cmd = ($mua, '-f');
 908         # TODO: help wanted: other common FOSS MUAs
 909         } else {
 910                 require Text::ParseWords;
 911                 @cmd = Text::ParseWords::shellwords($mua);
 912                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 913                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 914         }
 915         push @cmd, $mfolder unless defined($replaced);
 916         if ($self->{sock}) { # lei(1) client process runs it
 917                 # restore terminal: echo $query | lei q --stdin --mua=...
 918                 my $io = [];
 919                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 920                 send_exec_cmd($self, $io, \@cmd, {});
 921         }
 922         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 923                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 924         }
 925         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 926         $self->{opt}->{quiet} = 1;
 927         delete $self->{-progress};
 928         delete $self->{opt}->{verbose};
 929 }
 930
 931 sub send_exec_cmd { # tell script/lei to execute a command
 932         my ($self, $io, $cmd, $env) = @_;
 933         my $sock = $self->{sock} // die 'lei client gone';
 934         my $fds = [ map { fileno($_) } @$io ];
 935         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 936 }
 937
 938 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 939         my ($self) = @_;
 940         my $alerts = $self->{opt}->{alert} // return;
 941         my $sock = $self->{sock};
 942         while (my $op = shift(@$alerts)) {
 943                 if ($op eq ':WINCH') {
 944                         # hit the process group that started the MUA
 945                         send($sock, '-WINCH', MSG_EOR) if $sock;
 946                 } elsif ($op eq ':bell') {
 947                         out($self, "\a");
 948                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 949                         push @$alerts, split(/(?<!\\),/, $op);
 950                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 951                         my $cmd = $1; # run an arbitrary command
 952                         require Text::ParseWords;
 953                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 954                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 955                 } else {
 956                         err($self, "W: unsupported --alert=$op"); # non-fatal
 957                 }
 958         }
 959 }
 960
 961 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 962 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 963
 964 # this also normalizes the path
 965 sub path_to_fd {
 966         my ($self, $path) = @_;
 967         $path = rel2abs($self, $path);
 968         $path =~ tr!/!/!s;
 969         $path_to_fd{$path} // (
 970                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 971                         fail($self, "cannot open $path from daemon") : -1
 972         );
 973 }
 974
 975 # caller needs to "-t $self->{1}" to check if tty
 976 sub start_pager {
 977         my ($self) = @_;
 978         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 979         chomp(my $pager = <$fh> // '');
 980         close($fh) or warn "`git var PAGER' error: \$?=$?";
 981         return if $pager eq 'cat' || $pager eq '';
 982         my $new_env = { LESS => 'FRX', LV => '-c' };
 983         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 984         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 985         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 986         my $pgr = [ undef, @$rdr{1, 2} ];
 987         my $env = $self->{env};
 988         if ($self->{sock}) { # lei(1) process runs it
 989                 delete @$new_env{keys %$env}; # only set iff unset
 990                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 991         } else {
 992                 die 'BUG: start_pager w/o socket';
 993         }
 994         $self->{1} = $wpager;
 995         $self->{2} = $wpager if -t $self->{2};
 996         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 997         $self->{pgr} = $pgr;
 998 }
 999
1000 sub stop_pager {
1001         my ($self) = @_;
1002         my $pgr = delete($self->{pgr}) or return;
1003         $self->{2} = $pgr->[2];
1004         # do not restore original stdout, just close it so we error out
1005         close(delete($self->{1})) if $self->{1};
1006 }
1007
1008 sub accept_dispatch { # Listener {post_accept} callback
1009         my ($sock) = @_; # ignore other
1010         $sock->autoflush(1);
1011         my $self = bless { sock => $sock }, __PACKAGE__;
1012         vec(my $rvec = '', fileno($sock), 1) = 1;
1013         select($rvec, undef, undef, 60) or
1014                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1015         # (4096 * 33) >MAX_ARG_STRLEN
1016         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1017         if (!defined($fds[0])) {
1018                 warn(my $msg = "recv_cmd failed: $!");
1019                 return send($sock, $msg, MSG_EOR);
1020         } else {
1021                 my $i = 0;
1022                 for my $fd (@fds) {
1023                         open($self->{$i++}, '+<&=', $fd) and next;
1024                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1025                 }
1026                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1027         }
1028         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1029         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1030         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1031                 return send($sock, 'request command truncated', MSG_EOR);
1032         my ($argc, @argv) = split(/\0/, $buf, -1);
1033         undef $buf;
1034         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1035         if (chdir($self->{3})) {
1036                 local %ENV = %env;
1037                 $self->{env} = \%env;
1038                 eval { dispatch($self, @argv) };
1039                 send($sock, $@, MSG_EOR) if $@;
1040         } else {
1041                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1042         }
1043 }
1044
1045 sub dclose {
1046         my ($self) = @_;
1047         delete $self->{-progress};
1048         _drop_wq($self);
1049         close(delete $self->{1}) if $self->{1}; # may reap_compress
1050         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1051 }
1052
1053 # for long-running results
1054 sub event_step {
1055         my ($self) = @_;
1056         local %ENV = %{$self->{env}};
1057         my $sock = $self->{sock};
1058         local $current_lei = $self;
1059         eval {
1060                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1061                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1062                                 return if $! == EAGAIN;
1063                                 next if $! == EINTR;
1064                                 last if $! == ECONNRESET;
1065                                 die "recvmsg: $!";
1066                         }
1067                         for my $fd (@fds) {
1068                                 open my $rfh, '+<&=', $fd;
1069                         }
1070                         die "unrecognized client signal: $buf";
1071                 }
1072                 dclose($self);
1073         };
1074         if (my $err = $@) {
1075                 eval { $self->fail($err) };
1076                 dclose($self);
1077         }
1078 }
1079
1080 sub event_step_init {
1081         my ($self) = @_;
1082         return if $self->{-event_init_done}++;
1083         if (my $sock = $self->{sock}) { # using DS->EventLoop
1084                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1085         }
1086 }
1087
1088 sub noop {}
1089
1090 sub oldset { $oldset }
1091
1092 sub dump_and_clear_log {
1093         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1094                 my @pfx = @_;
1095                 unshift(@pfx, "$errors_log ") if @pfx;
1096                 warn @pfx, do { local $/; <STDIN> };
1097                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1098         }
1099 }
1100
1101 # lei(1) calls this when it can't connect
1102 sub lazy_start {
1103         my ($path, $errno, $narg) = @_;
1104         local ($errors_log, $listener);
1105         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1106         $errors_log = "$sock_dir/errors.log";
1107         my $addr = pack_sockaddr_un($path);
1108         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1109         $lk->lock_acquire;
1110         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1111         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1112                 return if connect($listener, $addr); # another process won
1113                 if ($errno == ECONNREFUSED && -S $path) {
1114                         unlink($path) or die "unlink($path): $!";
1115                 }
1116         } else {
1117                 $! = $errno; # allow interpolation to stringify in die
1118                 die "connect($path): $!";
1119         }
1120         umask(077) // die("umask(077): $!");
1121         bind($listener, $addr) or die "bind($path): $!";
1122         listen($listener, 1024) or die "listen: $!";
1123         $lk->lock_release;
1124         undef $lk;
1125         my @st = stat($path) or die "stat($path): $!";
1126         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1127         local $oldset = PublicInbox::DS::block_signals();
1128         if ($narg == 5) {
1129                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1130                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1131                         require PublicInbox::CmdIPC4;
1132                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1133                         PublicInbox::CmdIPC4->can('recv_cmd4');
1134                 };
1135         }
1136         $recv_cmd or die <<"";
1137 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1138
1139         require PublicInbox::Listener;
1140         require PublicInbox::PktOp;
1141         (-p STDOUT) or die "E: stdout must be a pipe\n";
1142         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1143         STDIN->autoflush(1);
1144         dump_and_clear_log("from previous daemon process:\n");
1145         POSIX::setsid() > 0 or die "setsid: $!";
1146         my $pid = fork // die "fork: $!";
1147         return if $pid;
1148         $0 = "lei-daemon $path";
1149         local %PATH2CFG;
1150         $listener->blocking(0);
1151         my $exit_code;
1152         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1153         local $quit = do {
1154                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1155                 sub {
1156                         $exit_code //= shift;
1157                         my $lis = $pil or exit($exit_code);
1158                         # closing eof_p triggers \&noop wakeup
1159                         $listener = $eof_p = $pil = $path = undef;
1160                         $lis->close; # DS::close
1161                         PublicInbox::DS->SetLoopTimeout(1000);
1162                 };
1163         };
1164         my $sig = {
1165                 CHLD => \&PublicInbox::DS::enqueue_reap,
1166                 QUIT => $quit,
1167                 INT => $quit,
1168                 TERM => $quit,
1169                 HUP => \&noop,
1170                 USR1 => \&noop,
1171                 USR2 => \&noop,
1172         };
1173         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1174         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1175         undef $sig;
1176         local $SIG{PIPE} = 'IGNORE';
1177         require PublicInbox::DirIdle;
1178         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1179                 # just rely on wakeup ot hit PostLoopCallback set below
1180                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1181         }, 1);
1182         if ($sigfd) {
1183                 undef $sigfd; # unref, already in DS::DescriptorMap
1184         } else {
1185                 # wake up every second to accept signals if we don't
1186                 # have signalfd or IO::KQueue:
1187                 PublicInbox::DS::sig_setmask($oldset);
1188                 PublicInbox::DS->SetLoopTimeout(1000);
1189         }
1190         PublicInbox::DS->SetPostLoopCallback(sub {
1191                 my ($dmap, undef) = @_;
1192                 if (@st = defined($path) ? stat($path) : ()) {
1193                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1194                                 warn "$path dev/ino changed, quitting\n";
1195                                 $path = undef;
1196                         }
1197                 } elsif (defined($path)) { # ENOENT is common
1198                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1199                         undef $path;
1200                         $quit->();
1201                 }
1202                 return 1 if defined($path);
1203                 my $now = now();
1204                 my $n = 0;
1205                 for my $s (values %$dmap) {
1206                         $s->can('busy') or next;
1207                         if ($s->busy($now)) {
1208                                 ++$n;
1209                         } else {
1210                                 $s->close;
1211                         }
1212                 }
1213                 $n; # true: continue, false: stop
1214         });
1215
1216         # STDIN was redirected to /dev/null above, closing STDERR and
1217         # STDOUT will cause the calling `lei' client process to finish
1218         # reading the <$daemon> pipe.
1219         local $SIG{__WARN__} = sub {
1220                 $current_lei ? err($current_lei, @_) : warn(
1221                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1222         };
1223         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1224         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1225         # $daemon pipe to `lei' closed, main loop begins:
1226         PublicInbox::DS->EventLoop;
1227         exit($exit_code // 0);
1228 }
1229
1230 sub busy { 1 } # prevent daemon-shutdown if client is connected
1231
1232 # ensures stdout hits the FS before sock disconnects so a client
1233 # can immediately reread it
1234 sub DESTROY {
1235         my ($self) = @_;
1236         $self->{1}->autoflush(1) if $self->{1};
1237         stop_pager($self);
1238         # preserve $? for ->fail or ->x_it code
1239 }
1240
1241 sub wq_done_wait { # dwaitpid callback
1242         my ($arg, $pid) = @_;
1243         my ($wq, $lei) = @$arg;
1244         my $err_type = $lei->{-err_type};
1245         $? and $lei->child_error($?,
1246                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1247         $lei->dclose;
1248 }
1249
1250 sub fchdir {
1251         my ($lei) = @_;
1252         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1253         chdir($dh) || $lei->fail("fchdir: $!");
1254 }
1255
1256 sub wq_eof { # EOF callback for main daemon
1257         my ($lei) = @_;
1258         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1259         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1260 }
1261
1262 1;