lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 124         import-remote!  no-torsocks torsocks=s),
 125         PublicInbox::LeiQuery::curl_opt());
 126
 127 # we generate shell completion + help using %CMD and %OPTDESC,
 128 # see lei__complete() and PublicInbox::LeiHelp
 129 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 130 our %CMD = ( # sorted in order of importance/use:
 131 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 132         'stdin|', # /|\z/ must be first for lone dash
 133         @lxs_opt,
 134         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 135         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 136         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 137         opt_dash('limit|n=i', '[0-9]+') ],
 138
 139 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 140         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 141         @lxs_opt, @c_opt ],
 142
 143 'add-external' => [ 'LOCATION',
 144         'add/set priority of a publicinbox|extindex for extra matches',
 145         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 146         verbose|v+), @c_opt, index_opt(),
 147         PublicInbox::LeiQuery::curl_opt() ],
 148 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 149         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 150 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 151 'forget-external' => [ 'LOCATION...|--prune',
 152         'exclude further results from a publicinbox|extindex',
 153         qw(prune), @c_opt ],
 154
 155 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 156                 qw(name-only format|f=s), @c_opt ],
 157 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 158 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 159
 160 'plonk' => [ '--threads|--from=IDENT',
 161         'exclude mail matching From: or threads from non-Message-ID searches',
 162         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 163 'mark' => [ 'KEYWORDS...',
 164         'set/unset keywords on message(s)',
 165         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 166         pass_through('-kw:foo for delete') ],
 167 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 168         "exclude message(s) on stdin from `q' search results",
 169         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 170
 171 'purge-mailsource' => [ 'LOCATION|--all',
 172         'remove imported messages from IMAP, Maildirs, and MH',
 173         qw(exact! all jobs:i indexed), @c_opt ],
 174
 175 # code repos are used for `show' to solve blobs from patch mails
 176 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 177         qw(boost=i), @c_opt ],
 178 'ls-coderepo' => [ '[FILTER_TERMS...]',
 179                 'list known code repos', qw(format|f=s z), @c_opt ],
 180 'forget-coderepo' => [ 'DIRNAME',
 181         'stop using repo to solve blobs from patches',
 182         qw(prune), @c_opt ],
 183
 184 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 185         qw(import! kw|keywords|flags! interval=s recursive|r
 186         exclude=s include=s), @c_opt ],
 187 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 188                 qw(format|f=s z), @c_opt ],
 189 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 190 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 191 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 192         qw(prune), @c_opt ],
 193
 194 'import' => [ 'LOCATION...|--stdin',
 195         'one-time import/update from URL or filesystem',
 196         qw(stdin| offset=i recursive|r exclude=s include|I=s
 197         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 198 'convert' => [ 'LOCATION...|--stdin',
 199         'one-time conversion from URL or filesystem to another format',
 200         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 201         lock=s@ kw|keywords|flags!), @c_opt ],
 202 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 203         "use a patch to generate a query for `lei q --stdin'",
 204         qw(stdin| want|w=s@ uri debug), @c_opt ],
 205 'config' => [ '[...]', sub {
 206                 'git-config(1) wrapper for '._config_path($_[0]);
 207         }, qw(config-file|system|global|file|f=s), # for conflict detection
 208          qw(c=s@ C=s@), pass_through('git config') ],
 209 'init' => [ '[DIRNAME]', sub {
 210         "initialize storage, default: ".store_path($_[0]);
 211         }, @c_opt ],
 212 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 213         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 214         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 215 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 216 'help' => [ '[SUBCOMMAND]', 'show help' ],
 217
 218 # XXX do we need this?
 219 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 220
 221 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 222         'rewrite git history in an attempt to improve compression',
 223         qw(gc!), @c_opt ],
 224
 225 # internal commands are prefixed with '_'
 226 '_complete' => [ '[...]', 'internal shell completion helper',
 227                 pass_through('everything') ],
 228 ); # @CMD
 229
 230 # switch descriptions, try to keep consistent across commands
 231 # $spec: Getopt::Long option specification
 232 # $spec => [@ALLOWED_VALUES (default is first), $description],
 233 # $spec => $description
 234 # "$SUB_COMMAND TAB $spec" => as above
 235 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 236                         'specify message input format' ];
 237 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 238
 239 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 240 my %OPTDESC = (
 241 'help|h' => 'show this built-in help',
 242 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 243 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 244 'quiet|q' => 'be quiet',
 245 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 246         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 247
 248 'globoff|g' => "do not match locations using '*?' wildcards ".
 249                 "and\xa0'[]'\x{a0}ranges",
 250 'verbose|v+' => 'be more verbose',
 251 'external!' => 'do not use externals',
 252 'solve!' => 'do not attempt to reconstruct blobs from emails',
 253 'torsocks=s' => ['VAL|auto|no|yes',
 254                 'whether or not to wrap git and curl commands with torsocks'],
 255 'no-torsocks' => 'alias for --torsocks=no',
 256 'save-as=s' => ['NAME', 'save a search terms by given name'],
 257 'import-remote!' => 'do not memoize remote messages into local store',
 258
 259 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 260
 261 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 262                 'deduplication strategy'],
 263 'threads|t+' =>
 264         'return all messages in the same threads as the actual match(es)',
 265
 266 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 267                 'search prefixes to extract (default: dfpost7)' ],
 268
 269 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 270         'run command(s) or perform ops when done writing to output ' .
 271         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 272         'nothing otherwise)' ],
 273
 274 'augment|a' => 'augment --output destination instead of clobbering',
 275
 276 'output|mfolder|o=s' => [ 'MFOLDER',
 277         "destination (e.g.\xa0`/path/to/Maildir', ".
 278         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 279 'mua=s' => [ 'CMD',
 280         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 281
 282 'inbox-version=i' => [ 'NUM|1|2',
 283                 'force a public-inbox version with --mirror'],
 284 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 285
 286 # public-inbox-index options
 287 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 288 'compact' => 'run compact index after mirroring',
 289 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 290         "indexlevel with --mirror (default: full)" ],
 291 'max_size|max-size=s' => [ 'SIZE',
 292         'do not index messages larger than SIZE (default: infinity)' ],
 293 'batch_size|batch-size=s' => [ 'SIZE',
 294         'flush changes to OS after given number of bytes (default: 1m)' ],
 295 'sequential_shard|sequential-shard' =>
 296         'index Xapian shards sequentially for slow storage',
 297 'skip-docdata' =>
 298         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 299
 300 'format|f=s     q' => [
 301         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 302                 'specify output format, default depends on --output'],
 303 'exclude=s@     q' => [ 'LOCATION',
 304                 'exclude specified external(s) from search' ],
 305 'include|I=s@   q' => [ 'LOCATION',
 306                 'include specified external(s) in search' ],
 307 'only=s@        q' => [ 'LOCATION',
 308                 'only use specified external(s) for search' ],
 309 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 310                 'control number of search and writer jobs' ],
 311 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 312
 313 'in-format|F=s' => $stdin_formats,
 314 'format|f=s     ls-query' => $ls_format,
 315 'format|f=s     ls-external' => $ls_format,
 316
 317 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 318 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 319
 320 'sort|s=s' => [ 'VAL|received|relevance|docid',
 321                 "order of results is `--output'-dependent"],
 322 'reverse|r' => 'reverse search results', # like sort(1)
 323
 324 'boost=i' => 'increase/decrease priority of results (default: 0)',
 325
 326 'local' => 'limit operations to the local filesystem',
 327 'local!' => 'exclude results from the local filesystem',
 328 'remote' => 'limit operations to those requiring network access',
 329 'remote!' => 'prevent operations requiring network access',
 330
 331 'mid=s' => 'specify the Message-ID of a message',
 332 'oid=s' => 'specify the git object ID of a message',
 333
 334 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 335 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 336 'include=s' => 'include mailboxes/newsgroups based on pattern',
 337
 338 'exact' => 'operate on exact header matches only',
 339 'exact!' => 'rely on content match instead of exact header matches',
 340
 341 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 342
 343 'kw|keywords|flags!' => 'disable/enable importing flags',
 344
 345 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 346 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 347
 348 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 349 ); # %OPTDESC
 350
 351 my %CONFIG_KEYS = (
 352         'leistore.dir' => 'top-level storage location',
 353 );
 354
 355 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q mark sol); # internal workers
 356
 357 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 358 sub x_it ($$) {
 359         my ($self, $code) = @_;
 360         # make sure client sees stdout before exit
 361         $self->{1}->autoflush(1) if $self->{1};
 362         dump_and_clear_log();
 363         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 364                 send($s, "x_it $code", MSG_EOR);
 365         } elsif ($self->{oneshot}) {
 366                 # don't want to end up using $? from child processes
 367                 for my $f (@WQ_KEYS) {
 368                         my $wq = delete $self->{$f} or next;
 369                         $wq->DESTROY;
 370                 }
 371                 # cleanup anything that has tempfiles or open file handles
 372                 %PATH2CFG = ();
 373                 delete @$self{qw(ovv dedupe sto cfg)};
 374                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 375                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 376                         kill $signum, $$;
 377                         sleep(1) while 1; # wait for signal
 378                 } else {
 379                         $quit->($code >> 8);
 380                 }
 381         } # else ignore if client disconnected
 382 }
 383
 384 sub err ($;@) {
 385         my $self = shift;
 386         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 387         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 388         print $err @_, @eor and return;
 389         my $old_err = delete $self->{2};
 390         close($old_err) if $! == EPIPE && $old_err;
 391         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 392         print $err @_, @eor or print STDERR @_, @eor;
 393 }
 394
 395 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 396
 397 sub fail_handler ($;$$) {
 398         my ($lei, $code, $io) = @_;
 399         for my $f (@WQ_KEYS) {
 400                 my $wq = delete $lei->{$f} or next;
 401                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 402         }
 403         close($io) if $io; # needed to avoid warnings on SIGPIPE
 404         x_it($lei, $code // (1 << 8));
 405 }
 406
 407 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 408         fail_handler($_[0], 13, delete $_[0]->{1});
 409 }
 410
 411 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 412 sub sigint_reap {
 413         my ($pgid) = @_;
 414         dwaitpid($pgid) if kill('-INT', $pgid);
 415 }
 416
 417 sub fail ($$;$) {
 418         my ($self, $buf, $exit_code) = @_;
 419         err($self, $buf) if defined $buf;
 420         # calls fail_handler:
 421         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 422         x_it($self, ($exit_code // 1) << 8);
 423         undef;
 424 }
 425
 426 sub out ($;@) {
 427         my $self = shift;
 428         return if print { $self->{1} // return } @_; # likely
 429         return note_sigpipe($self, 1) if $! == EPIPE;
 430         my $err = "error writing to output: $!";
 431         delete $self->{1};
 432         fail($self, $err);
 433 }
 434
 435 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 436
 437 sub child_error { # passes non-fatal curl exit codes to user
 438         my ($self, $child_error, $msg) = @_; # child_error is $?
 439         $self->err($msg) if $msg;
 440         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 441                 # send to the parent lei-daemon or to lei(1) client
 442                 send($s, "child_error $child_error", MSG_EOR);
 443         } elsif (!$PublicInbox::DS::in_loop) {
 444                 $self->{child_error} = $child_error;
 445         } # else noop if client disconnected
 446 }
 447
 448 sub note_sigpipe { # triggers sigpipe_handler
 449         my ($self, $fd) = @_;
 450         close(delete($self->{$fd})); # explicit close silences Perl warning
 451         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 452         x_it($self, 13);
 453 }
 454
 455 sub _lei_atfork_child {
 456         my ($self, $persist) = @_;
 457         # we need to explicitly close things which are on stack
 458         if ($persist) {
 459                 chdir '/' or die "chdir(/): $!";
 460                 my @io = delete @$self{qw(0 1 2 sock)};
 461                 unless ($self->{oneshot}) {
 462                         close($_) for @io;
 463                 }
 464                 if (my $cfg = $self->{cfg}) {
 465                         delete $cfg->{-lei_store};
 466                 }
 467         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 468                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 469         }
 470         for (delete @$self{qw(3 old_1 au_done)}) {
 471                 close($_) if defined($_);
 472         }
 473         if (my $op_c = delete $self->{pkt_op_c}) {
 474                 close(delete $op_c->{sock});
 475         }
 476         if (my $pgr = delete $self->{pgr}) {
 477                 close($_) for (@$pgr[1,2]);
 478         }
 479         close $listener if $listener;
 480         undef $listener;
 481         %PATH2CFG = ();
 482         undef $errors_log;
 483         $quit = \&CORE::exit;
 484         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 485 }
 486
 487 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 488         my ($self) = @_;
 489         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 490                 $op->close; # PublicInbox::PktOp::close
 491         }
 492         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 493         close $unclosed_after_die;
 494 }
 495
 496 sub pkt_op_pair {
 497         my ($self) = @_;
 498         require PublicInbox::OnDestroy;
 499         require PublicInbox::PktOp;
 500         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 501         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 502         $end;
 503 }
 504
 505 sub workers_start {
 506         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 507         $ops = {
 508                 '!' => [ \&fail_handler, $lei ],
 509                 '|' => [ \&sigpipe_handler, $lei ],
 510                 'x_it' => [ \&x_it, $lei ],
 511                 'child_error' => [ \&child_error, $lei ],
 512                 ($ops ? %$ops : ()),
 513         };
 514         $ops->{''} //= [ \&dclose, $lei ];
 515         my $end = $lei->pkt_op_pair;
 516         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 517         delete $lei->{pkt_op_p};
 518         my $op_c = delete $lei->{pkt_op_c};
 519         @$end = ();
 520         $lei->event_step_init;
 521         ($op_c, $ops);
 522 }
 523
 524 sub _help {
 525         require PublicInbox::LeiHelp;
 526         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 527 }
 528
 529 sub optparse ($$$) {
 530         my ($self, $cmd, $argv) = @_;
 531         # allow _complete --help to complete, not show help
 532         return 1 if substr($cmd, 0, 1) eq '_';
 533         $self->{cmd} = $cmd;
 534         $OPT = $self->{opt} //= {};
 535         my $info = $CMD{$cmd} // [ '[...]' ];
 536         my ($proto, undef, @spec) = @$info;
 537         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 538         push @spec, qw(help|h);
 539         my $lone_dash;
 540         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 541                 $lone_dash = $spec[0];
 542                 $OPT->{$spec[0]} = \(my $var);
 543                 push @spec, '' => \$var;
 544         }
 545         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 546                 return _help($self, "bad arguments or options for $cmd");
 547         return _help($self) if $OPT->{help};
 548
 549         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 550
 551         # "-" aliases "stdin" or "clear"
 552         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 553
 554         my $i = 0;
 555         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 556         my ($err, $inf);
 557         my @args = split(/ /, $proto);
 558         for my $var (@args) {
 559                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 560                         $inf = defined($argv->[$i]) and last;
 561                         $var =~ s/\.\.\.\z//;
 562                         $err = "$var not supplied";
 563                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 564                         $argv->[$i++] // ($err = "$var not supplied");
 565                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 566                         $inf = 1;
 567                         last;
 568                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 569                         $i++;
 570                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 571                         $inf = 1 if index($var, '...') > 0;
 572                         my @or = split(/\|/, $var);
 573                         my $ok;
 574                         for my $o (@or) {
 575                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 576                                         $ok = defined($OPT->{$1});
 577                                         last if $ok;
 578                                 } elsif (defined($argv->[$i])) {
 579                                         $ok = 1;
 580                                         $i++;
 581                                         last;
 582                                 } # else continue looping
 583                         }
 584                         last if $ok;
 585                         my $last = pop @or;
 586                         $err = join(', ', @or) . " or $last must be set";
 587                 } else {
 588                         warn "BUG: can't parse `$var' in $proto";
 589                 }
 590                 last if $err;
 591         }
 592         if (!$inf && scalar(@$argv) > scalar(@args)) {
 593                 $err //= 'too many arguments';
 594         }
 595         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 596 }
 597
 598 sub _tmp_cfg { # for lei -c <name>=<value> ...
 599         my ($self) = @_;
 600         my $cfg = _lei_cfg($self, 1);
 601         require File::Temp;
 602         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 603         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 604         $ft->autoflush(1);
 605         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 606 [include]
 607         path = $cfg->{-f}
 608 EOM
 609         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 610         for (@{$self->{opt}->{c}}) {
 611                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 612 `-c $_' is not of the form -c <name>=<value>'
 613 EOM
 614                 my $name = $1;
 615                 my $value = $2 // 1;
 616                 _config($self, '--add', $name, $value);
 617                 if (defined(my $v = $tmp->{$name})) {
 618                         if (ref($v) eq 'ARRAY') {
 619                                 push @$v, $value;
 620                         } else {
 621                                 $tmp->{$name} = [ $v, $value ];
 622                         }
 623                 } else {
 624                         $tmp->{$name} = $value;
 625                 }
 626         }
 627 }
 628
 629 sub lazy_cb ($$$) {
 630         my ($self, $cmd, $pfx) = @_;
 631         my $ucmd = $cmd;
 632         $ucmd =~ tr/-/_/;
 633         my $cb;
 634         $cb = $self->can($pfx.$ucmd) and return $cb;
 635         my $base = $ucmd;
 636         $base =~ s/_([a-z])/\u$1/g;
 637         my $pkg = "PublicInbox::Lei\u$base";
 638         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 639                 $pkg->can($pfx.$ucmd) : undef;
 640 }
 641
 642 sub dispatch {
 643         my ($self, $cmd, @argv) = @_;
 644         local $current_lei = $self; # for __WARN__
 645         dump_and_clear_log("from previous run\n");
 646         return _help($self, 'no command given') unless defined($cmd);
 647         # do not support Getopt bundling for this
 648         while ($cmd eq '-C' || $cmd eq '-c') {
 649                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 650                                         '-C DIRECTORY' : '-c <name>=<value>');
 651                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 652                 $cmd = shift(@argv) // return _help($self, 'no command given');
 653         }
 654         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 655                 optparse($self, $cmd, \@argv) or return;
 656                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 657                 if (my $chdir = $self->{opt}->{C}) {
 658                         for my $d (@$chdir) {
 659                                 next if $d eq ''; # same as git(1)
 660                                 chdir $d or return fail($self, "cd $d: $!");
 661                         }
 662                         if (delete $self->{3}) { # update cwd for rel2abs
 663                                 opendir my $dh, '.' or
 664                                         return fail($self, "opendir . $!");
 665                                 $self->{3} = $dh;
 666                         }
 667                 }
 668                 $cb->($self, @argv);
 669         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 670                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 671                         or return _help($self, 'bad arguments or options');
 672                 _help($self);
 673         } else {
 674                 fail($self, "`$cmd' is not an lei command");
 675         }
 676 }
 677
 678 sub _lei_cfg ($;$) {
 679         my ($self, $creat) = @_;
 680         return $self->{cfg} if $self->{cfg};
 681         my $f = _config_path($self);
 682         my @st = stat($f);
 683         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 684         my ($sto, $sto_dir);
 685         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 686                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 687                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 688         }
 689         if (!@st) {
 690                 unless ($creat) {
 691                         delete $self->{cfg};
 692                         return bless {}, 'PublicInbox::Config';
 693                 }
 694                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 695                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 696                 open my $fh, '>>', $f or die "open($f): $!\n";
 697                 @st = stat($fh) or die "fstat($f): $!\n";
 698                 $cur_st = pack('dd', $st[10], $st[7]);
 699                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 700         }
 701         my $cfg = PublicInbox::Config::git_config_dump($f);
 702         bless $cfg, 'PublicInbox::Config';
 703         $cfg->{-st} = $cur_st;
 704         $cfg->{'-f'} = $f;
 705         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 706                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 707                                                 store_path($self))) {
 708                 $cfg->{-lei_store} = $sto;
 709         }
 710         if (scalar(keys %PATH2CFG) > 5) {
 711                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 712                 for my $k (keys %PATH2CFG) {
 713                         delete($PATH2CFG{$k}) unless -f $k
 714                 }
 715         }
 716         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 717 }
 718
 719 sub _lei_store ($;$) {
 720         my ($self, $creat) = @_;
 721         my $cfg = _lei_cfg($self, $creat);
 722         $cfg->{-lei_store} //= do {
 723                 require PublicInbox::LeiStore;
 724                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 725                 return unless $creat || -d $dir;
 726                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 727         };
 728 }
 729
 730 sub _config {
 731         my ($self, @argv) = @_;
 732         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 733         my $cfg = _lei_cfg($self, 1);
 734         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 735         my %rdr = map { $_ => $self->{$_} } (0..2);
 736         waitpid(spawn($cmd, \%env, \%rdr), 0);
 737 }
 738
 739 sub lei_config {
 740         my ($self, @argv) = @_;
 741         $self->{opt}->{'config-file'} and return fail $self,
 742                 "config file switches not supported by `lei config'";
 743         _config(@_);
 744         x_it($self, $?) if $?;
 745 }
 746
 747 sub lei_daemon_pid { puts shift, $$ }
 748
 749 sub lei_daemon_kill {
 750         my ($self) = @_;
 751         my $sig = $self->{opt}->{signal} // 'TERM';
 752         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 753 }
 754
 755 # Shell completion helper.  Used by lei-completion.bash and hopefully
 756 # other shells.  Try to do as much here as possible to avoid redundancy
 757 # and improve maintainability.
 758 sub lei__complete {
 759         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 760         shift @argv; # ignore "lei", the entire command is sent
 761         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 762         my $cmd = shift @argv;
 763         my $info = $CMD{$cmd} // do { # filter matching commands
 764                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 765                 return;
 766         };
 767         my ($proto, undef, @spec) = @$info;
 768         my $cur = pop @argv;
 769         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 770         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 771                 # gross special case since the only git-config options
 772                 # Consider moving to a table if we need more special cases
 773                 # we use Getopt::Long for are the ones we reject, so these
 774                 # are the ones we don't reject:
 775                 if ($cmd eq 'config') {
 776                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 777                         @spec = qw(add z|null get get-all unset unset-all
 778                                 replace-all get-urlmatch
 779                                 remove-section rename-section
 780                                 name-only list|l edit|e
 781                                 get-color-name get-colorbool);
 782                         # fall-through
 783                 }
 784                 # generate short/long names from Getopt::Long specs
 785                 puts $self, grep(/$re/, qw(--help -h -C), map {
 786                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 787                         } elsif (s/\+\z//) { # verbose|v+
 788                         } elsif (s/!\z//) {
 789                                 # negation: solve! => no-solve|solve
 790                                 s/([\w\-]+)/$1|no-$1/g
 791                         }
 792                         map {
 793                                 my $x = length > 1 ? "--$_" : "-$_";
 794                                 $x eq $_cur ? () : $x;
 795                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 796                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 797         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 798                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 799         }
 800
 801         # switch args (e.g. lei q -f mbox<TAB>)
 802         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 803                 my $opt = quotemeta $1;
 804                 puts $self, map {
 805                         my $v = $OPTDESC{$_};
 806                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 807                         # get rid of ALL CAPS placeholder (e.g "OUT")
 808                         # (TODO: completion for external paths)
 809                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 810                         @v;
 811                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 812         }
 813         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 814                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 815         }
 816         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 817         # proto parsing.
 818 }
 819
 820 sub exec_buf ($$) {
 821         my ($argv, $env) = @_;
 822         my $argc = scalar @$argv;
 823         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 824         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 825         $buf;
 826 }
 827
 828 sub start_mua {
 829         my ($self) = @_;
 830         my $mua = $self->{opt}->{mua} // return;
 831         my $mfolder = $self->{ovv}->{dst};
 832         my (@cmd, $replaced);
 833         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 834                 @cmd = ($mua, '-f');
 835         # TODO: help wanted: other common FOSS MUAs
 836         } else {
 837                 require Text::ParseWords;
 838                 @cmd = Text::ParseWords::shellwords($mua);
 839                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 840                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 841         }
 842         push @cmd, $mfolder unless defined($replaced);
 843         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 844                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 845         } elsif ($self->{oneshot}) {
 846                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 847         }
 848         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 849                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 850         }
 851         $self->{opt}->{quiet} = 1;
 852         delete $self->{-progress};
 853         delete $self->{opt}->{verbose};
 854 }
 855
 856 sub send_exec_cmd { # tell script/lei to execute a command
 857         my ($self, $io, $cmd, $env) = @_;
 858         my $sock = $self->{sock} // die 'lei client gone';
 859         my $fds = [ map { fileno($_) } @$io ];
 860         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 861 }
 862
 863 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 864         my ($self) = @_;
 865         my $alerts = $self->{opt}->{alert} // return;
 866         while (my $op = shift(@$alerts)) {
 867                 if ($op eq ':WINCH') {
 868                         # hit the process group that started the MUA
 869                         if ($self->{sock}) {
 870                                 send($self->{sock}, '-WINCH', MSG_EOR);
 871                         } elsif ($self->{oneshot}) {
 872                                 kill('-WINCH', $$);
 873                         }
 874                 } elsif ($op eq ':bell') {
 875                         out($self, "\a");
 876                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 877                         push @$alerts, split(/(?<!\\),/, $op);
 878                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 879                         my $cmd = $1; # run an arbitrary command
 880                         require Text::ParseWords;
 881                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 882                         if (my $s = $self->{sock}) {
 883                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 884                         } elsif ($self->{oneshot}) {
 885                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 886                         }
 887                 } else {
 888                         err($self, "W: unsupported --alert=$op"); # non-fatal
 889                 }
 890         }
 891 }
 892
 893 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 894 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 895
 896 # this also normalizes the path
 897 sub path_to_fd {
 898         my ($self, $path) = @_;
 899         $path = rel2abs($self, $path);
 900         $path =~ tr!/!/!s;
 901         $path_to_fd{$path} // (
 902                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 903                         fail($self, "cannot open $path from daemon") : -1
 904         );
 905 }
 906
 907 # caller needs to "-t $self->{1}" to check if tty
 908 sub start_pager {
 909         my ($self) = @_;
 910         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 911         chomp(my $pager = <$fh> // '');
 912         close($fh) or warn "`git var PAGER' error: \$?=$?";
 913         return if $pager eq 'cat' || $pager eq '';
 914         my $new_env = { LESS => 'FRX', LV => '-c' };
 915         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 916         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 917         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 918         my $pgr = [ undef, @$rdr{1, 2} ];
 919         my $env = $self->{env};
 920         if ($self->{sock}) { # lei(1) process runs it
 921                 delete @$new_env{keys %$env}; # only set iff unset
 922                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 923         } elsif ($self->{oneshot}) {
 924                 my $cmd = [$pager];
 925                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 926         } else {
 927                 die 'BUG: start_pager w/o socket';
 928         }
 929         $self->{1} = $wpager;
 930         $self->{2} = $wpager if -t $self->{2};
 931         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 932         $self->{pgr} = $pgr;
 933 }
 934
 935 sub stop_pager {
 936         my ($self) = @_;
 937         my $pgr = delete($self->{pgr}) or return;
 938         $self->{2} = $pgr->[2];
 939         # do not restore original stdout, just close it so we error out
 940         close(delete($self->{1})) if $self->{1};
 941 }
 942
 943 sub accept_dispatch { # Listener {post_accept} callback
 944         my ($sock) = @_; # ignore other
 945         $sock->autoflush(1);
 946         my $self = bless { sock => $sock }, __PACKAGE__;
 947         vec(my $rvec = '', fileno($sock), 1) = 1;
 948         select($rvec, undef, undef, 60) or
 949                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 950         # (4096 * 33) >MAX_ARG_STRLEN
 951         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 952         if (!defined($fds[0])) {
 953                 warn(my $msg = "recv_cmd failed: $!");
 954                 return send($sock, $msg, MSG_EOR);
 955         } else {
 956                 my $i = 0;
 957                 for my $fd (@fds) {
 958                         open($self->{$i++}, '+<&=', $fd) and next;
 959                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 960                 }
 961                 return if scalar(@fds) != 4;
 962         }
 963         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 964         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 965         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 966         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 967                 return send($sock, 'request command truncated', MSG_EOR);
 968         my ($argc, @argv) = split(/\0/, $buf, -1);
 969         undef $buf;
 970         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 971         if (chdir($self->{3})) {
 972                 local %ENV = %env;
 973                 $self->{env} = \%env;
 974                 eval { dispatch($self, @argv) };
 975                 send($sock, $@, MSG_EOR) if $@;
 976         } else {
 977                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 978         }
 979 }
 980
 981 sub dclose {
 982         my ($self) = @_;
 983         delete $self->{-progress};
 984         for my $f (@WQ_KEYS) {
 985                 my $wq = delete $self->{$f} or next;
 986                 if ($wq->wq_kill) {
 987                         $wq->wq_close(0, undef, $self);
 988                 } elsif ($wq->wq_kill_old) {
 989                         $wq->wq_wait_old(undef, $self);
 990                 }
 991         }
 992         close(delete $self->{1}) if $self->{1}; # may reap_compress
 993         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 994 }
 995
 996 # for long-running results
 997 sub event_step {
 998         my ($self) = @_;
 999         local %ENV = %{$self->{env}};
1000         my $sock = $self->{sock};
1001         local $current_lei = $self;
1002         eval {
1003                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1004                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1005                                 return if $! == EAGAIN;
1006                                 next if $! == EINTR;
1007                                 last if $! == ECONNRESET;
1008                                 die "recvmsg: $!";
1009                         }
1010                         for my $fd (@fds) {
1011                                 open my $rfh, '+<&=', $fd;
1012                         }
1013                         die "unrecognized client signal: $buf";
1014                 }
1015                 dclose($self);
1016         };
1017         if (my $err = $@) {
1018                 eval { $self->fail($err) };
1019                 dclose($self);
1020         }
1021 }
1022
1023 sub event_step_init {
1024         my ($self) = @_;
1025         return if $self->{-event_init_done}++;
1026         if (my $sock = $self->{sock}) { # using DS->EventLoop
1027                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1028         }
1029 }
1030
1031 sub noop {}
1032
1033 sub oldset { $oldset }
1034
1035 sub dump_and_clear_log {
1036         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1037                 my @pfx = @_;
1038                 unshift(@pfx, "$errors_log ") if @pfx;
1039                 warn @pfx, do { local $/; <STDIN> };
1040                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1041         }
1042 }
1043
1044 # lei(1) calls this when it can't connect
1045 sub lazy_start {
1046         my ($path, $errno, $narg) = @_;
1047         local ($errors_log, $listener);
1048         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1049         $errors_log .= 'errors.log';
1050         my $addr = pack_sockaddr_un($path);
1051         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1052         $lk->lock_acquire;
1053         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1054         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1055                 return if connect($listener, $addr); # another process won
1056                 if ($errno == ECONNREFUSED && -S $path) {
1057                         unlink($path) or die "unlink($path): $!";
1058                 }
1059         } else {
1060                 $! = $errno; # allow interpolation to stringify in die
1061                 die "connect($path): $!";
1062         }
1063         umask(077) // die("umask(077): $!");
1064         bind($listener, $addr) or die "bind($path): $!";
1065         listen($listener, 1024) or die "listen: $!";
1066         $lk->lock_release;
1067         undef $lk;
1068         my @st = stat($path) or die "stat($path): $!";
1069         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1070         local $oldset = PublicInbox::DS::block_signals();
1071         if ($narg == 5) {
1072                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1073                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1074                         require PublicInbox::CmdIPC4;
1075                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1076                         PublicInbox::CmdIPC4->can('recv_cmd4');
1077                 };
1078         }
1079         $recv_cmd or die <<"";
1080 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1081
1082         require PublicInbox::Listener;
1083         require PublicInbox::EOFpipe;
1084         (-p STDOUT) or die "E: stdout must be a pipe\n";
1085         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1086         STDIN->autoflush(1);
1087         dump_and_clear_log("from previous daemon process:\n");
1088         POSIX::setsid() > 0 or die "setsid: $!";
1089         my $pid = fork // die "fork: $!";
1090         return if $pid;
1091         $0 = "lei-daemon $path";
1092         local %PATH2CFG;
1093         $listener->blocking(0);
1094         my $exit_code;
1095         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1096         local $quit = do {
1097                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1098                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1099                 sub {
1100                         $exit_code //= shift;
1101                         my $lis = $pil or exit($exit_code);
1102                         # closing eof_w triggers \&noop wakeup
1103                         $listener = $eof_w = $pil = $path = undef;
1104                         $lis->close; # DS::close
1105                         PublicInbox::DS->SetLoopTimeout(1000);
1106                 };
1107         };
1108         my $sig = {
1109                 CHLD => \&PublicInbox::DS::enqueue_reap,
1110                 QUIT => $quit,
1111                 INT => $quit,
1112                 TERM => $quit,
1113                 HUP => \&noop,
1114                 USR1 => \&noop,
1115                 USR2 => \&noop,
1116         };
1117         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1118         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1119         undef $sig;
1120         local $SIG{PIPE} = 'IGNORE';
1121         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1122                 undef $sigfd;
1123                 PublicInbox::DS->SetLoopTimeout(5000);
1124         } else {
1125                 # wake up every second to accept signals if we don't
1126                 # have signalfd or IO::KQueue:
1127                 PublicInbox::DS::sig_setmask($oldset);
1128                 PublicInbox::DS->SetLoopTimeout(1000);
1129         }
1130         PublicInbox::DS->SetPostLoopCallback(sub {
1131                 my ($dmap, undef) = @_;
1132                 if (@st = defined($path) ? stat($path) : ()) {
1133                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1134                                 warn "$path dev/ino changed, quitting\n";
1135                                 $path = undef;
1136                         }
1137                 } elsif (defined($path)) { # ENOENT is common
1138                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1139                         undef $path;
1140                         $quit->();
1141                 }
1142                 return 1 if defined($path);
1143                 my $now = now();
1144                 my $n = 0;
1145                 for my $s (values %$dmap) {
1146                         $s->can('busy') or next;
1147                         if ($s->busy($now)) {
1148                                 ++$n;
1149                         } else {
1150                                 $s->close;
1151                         }
1152                 }
1153                 $n; # true: continue, false: stop
1154         });
1155
1156         # STDIN was redirected to /dev/null above, closing STDERR and
1157         # STDOUT will cause the calling `lei' client process to finish
1158         # reading the <$daemon> pipe.
1159         local $SIG{__WARN__} = sub {
1160                 $current_lei ? err($current_lei, @_) : warn(
1161                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1162         };
1163         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1164         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1165         # $daemon pipe to `lei' closed, main loop begins:
1166         PublicInbox::DS->EventLoop;
1167         exit($exit_code // 0);
1168 }
1169
1170 sub busy { 1 } # prevent daemon-shutdown if client is connected
1171
1172 # for users w/o Socket::Msghdr installed or Inline::C enabled
1173 sub oneshot {
1174         my ($main_pkg) = @_;
1175         my $exit = $main_pkg->can('exit'); # caller may override exit()
1176         local $quit = $exit if $exit;
1177         local %PATH2CFG;
1178         umask(077) // die("umask(077): $!");
1179         my $self = bless {
1180                 oneshot => 1,
1181                 0 => *STDIN{GLOB},
1182                 1 => *STDOUT{GLOB},
1183                 2 => *STDERR{GLOB},
1184                 env => \%ENV
1185         }, __PACKAGE__;
1186         dispatch($self, @ARGV);
1187         x_it($self, $self->{child_error}) if $self->{child_error};
1188 }
1189
1190 # ensures stdout hits the FS before sock disconnects so a client
1191 # can immediately reread it
1192 sub DESTROY {
1193         my ($self) = @_;
1194         $self->{1}->autoflush(1) if $self->{1};
1195         stop_pager($self);
1196         my $err = $?;
1197         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1198         waitpid($_, 0) for keys %$oneshot_pids;
1199         $? = $err if $err; # preserve ->fail or ->x_it code
1200 }
1201
1202 1;