lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 233                 'exclude specified external(s) from search' ],
 234 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 235                 'include specified external(s) in search' ],
 236 'q      only=s@' => [ 'URL_OR_PATHNAME',
 237                 'only use specified external(s) for search' ],
 238
 239 'ls-query       format|f=s' => $ls_format,
 240 'ls-external    format|f=s' => $ls_format,
 241
 242 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 243 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 244
 245 'sort|s=s' => [ 'VAL|received,relevance,docid',
 246                 "order of results `--output'-dependent"],
 247 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 248
 249 'boost=i' => 'increase/decrease priority of results (default: 0)',
 250
 251 'local' => 'limit operations to the local filesystem',
 252 'local!' => 'exclude results from the local filesystem',
 253 'remote' => 'limit operations to those requiring network access',
 254 'remote!' => 'prevent operations requiring network access',
 255
 256 'mid=s' => 'specify the Message-ID of a message',
 257 'oid=s' => 'specify the git object ID of a message',
 258
 259 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 260 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 261 'include=s' => 'include mailboxes/newsgroups based on pattern',
 262
 263 'exact' => 'operate on exact header matches only',
 264 'exact!' => 'rely on content match instead of exact header matches',
 265
 266 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 267 'jobs:i' => 'set parallelism level',
 268
 269 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 270 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 271
 272 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 273 ); # %OPTDESC
 274
 275 my %CONFIG_KEYS = (
 276         'leistore.dir' => 'top-level storage location',
 277 );
 278
 279 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 280 sub x_it ($$) {
 281         my ($self, $code) = @_;
 282         # make sure client sees stdout before exit
 283         $self->{1}->autoflush(1) if $self->{1};
 284         dump_and_clear_log();
 285         if (my $sock = $self->{sock}) {
 286                 send($sock, "x_it $code", MSG_EOR);
 287         } elsif (!$self->{oneshot}) {
 288                 return; # client disconnected, noop
 289         } elsif (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 290                 $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 291                 kill $signum, $$;
 292                 sleep; # wait for signal
 293         } else {
 294                 # don't want to end up using $? from child processes
 295                 for my $f (qw(lxs l2m)) {
 296                         my $wq = delete $self->{$f} or next;
 297                         $wq->DESTROY;
 298                 }
 299                 $quit->($code >> 8);
 300         }
 301 }
 302
 303 sub err ($;@) {
 304         my $self = shift;
 305         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 306         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 307         print $err @_, $eor and return;
 308         my $old_err = delete $self->{2};
 309         close($old_err) if $! == EPIPE && $old_err;;
 310         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 311         print $err @_, $eor or print STDERR @_, $eor;
 312 }
 313
 314 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 315
 316 sub fail ($$;$) {
 317         my ($self, $buf, $exit_code) = @_;
 318         err($self, $buf) if defined $buf;
 319         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 320         x_it($self, ($exit_code // 1) << 8);
 321         undef;
 322 }
 323
 324 sub out ($;@) {
 325         my $self = shift;
 326         return if print { $self->{1} // return } @_; # likely
 327         return note_sigpipe($self, 1) if $! == EPIPE;
 328         my $err = "error writing to stdout: $!";
 329         delete $self->{1};
 330         fail($self, $err);
 331 }
 332
 333 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 334
 335 sub child_error { # passes non-fatal curl exit codes to user
 336         my ($self, $child_error) = @_; # child_error is $?
 337         if (my $sock = $self->{sock}) { # send to lei(1) client
 338                 send($sock, "child_error $child_error", MSG_EOR);
 339         } elsif ($self->{oneshot}) {
 340                 $self->{child_error} = $child_error;
 341         } # else noop if client disconnected
 342 }
 343
 344 sub atfork_prepare_wq {
 345         my ($self, $wq) = @_;
 346         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 347         if (my $sock = $self->{sock}) {
 348                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 349         }
 350         if (my $pgr = $self->{pgr}) {
 351                 push @$tcafc, @$pgr[1,2];
 352         }
 353         if (my $old_1 = $self->{old_1}) {
 354                 push @$tcafc, $old_1;
 355         }
 356         for my $f (qw(lxs l2m)) {
 357                 my $ipc = $self->{$f} or next;
 358                 push @$tcafc, grep { defined }
 359                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 360         }
 361 }
 362
 363 sub io_restore ($$) {
 364         my ($dst, $src) = @_;
 365         for my $i (0..2) { # standard FDs
 366                 my $io = delete $src->{$i} or next;
 367                 $dst->{$i} = $io;
 368         }
 369         for my $i (3..9) { # named (non-standard) FDs
 370                 my $io = $src->{$i} or next;
 371                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 372                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 373                 $dst->{$f} = $io;
 374                 delete $src->{$i};
 375         }
 376 }
 377
 378 sub note_sigpipe { # triggers sigpipe_handler
 379         my ($self, $fd) = @_;
 380         close(delete($self->{$fd})); # explicit close silences Perl warning
 381         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 382         x_it($self, 13);
 383 }
 384
 385 sub atfork_child_wq {
 386         my ($self, $wq) = @_;
 387         io_restore($self, $wq);
 388         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 389         io_restore($self->{l2m}, $wq);
 390         %PATH2CFG = ();
 391         undef $errors_log;
 392         $quit = \&CORE::exit;
 393         $current_lei = $self; # for SIG{__WARN__}
 394 }
 395
 396 sub io_extract ($;@) {
 397         my ($obj, @fields) = @_;
 398         my @io;
 399         for my $f (@fields) {
 400                 my $io = delete $obj->{$f} or next;
 401                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 402                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 403                 push @io, $io;
 404         }
 405         @io
 406 }
 407
 408 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 409 sub atfork_parent_wq {
 410         my ($self, $wq) = @_;
 411         my $env = delete $self->{env}; # env is inherited at fork
 412         my $lei = bless { %$self }, ref($self);
 413         for my $f (qw(dedupe ovv)) {
 414                 my $tmp = delete($lei->{$f}) or next;
 415                 $lei->{$f} = $wq->deep_clone($tmp);
 416         }
 417         $self->{env} = $env;
 418         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 419         my @io = (delete(@$lei{qw(0 1 2)}),
 420                         io_extract($lei, qw(sock pkt_op startq)));
 421         my $l2m = $lei->{l2m};
 422         if ($l2m && $l2m != $wq) { # $wq == lxs
 423                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 424                         push @io, io_extract($l2m, '-wq_s1');
 425                         $l2m->{-wq_s1} = $wq_s1;
 426                 }
 427                 $l2m->wq_close(1);
 428         }
 429         ($lei, @io);
 430 }
 431
 432 sub _help ($;$) {
 433         my ($self, $errmsg) = @_;
 434         my $cmd = $self->{cmd} // 'COMMAND';
 435         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 436         my @top = ($cmd, shift(@info) // ());
 437         my $cmd_desc = shift(@info);
 438         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 439         my @opt_desc;
 440         my $lpad = 2;
 441         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 442                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 443                 my $arg_vals = '';
 444                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 445
 446                 # lower-case is a keyword (e.g. `content', `oid'),
 447                 # ALL_CAPS is a string description (e.g. `PATH')
 448                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 449                         $desc .= "\ndefault: `$1'";
 450                 }
 451                 my (@vals, @s, @l);
 452                 my $x = $sw;
 453                 if ($x =~ s/!\z//) { # solve! => --no-solve
 454                         $x = "no-$x";
 455                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 456                         @vals = (' [', undef, ']');
 457                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 458                         @vals = (' ', undef);
 459                 } # else: no args $x = 'thread|t'
 460                 for (split(/\|/, $x)) { # help|h
 461                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 462                 }
 463                 if (!scalar(@vals)) { # no args 'thread|t'
 464                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 465                         $vals[1] = $1;
 466                 } else {
 467                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 468                 }
 469                 if ($arg_vals =~ /([,\|])/) {
 470                         my $sep = $1;
 471                         my @allow = split(/\Q$sep\E/, $arg_vals);
 472                         my $must = $sep eq '|' ? 'Must' : 'Can';
 473                         @allow = map { "`$_'" } @allow;
 474                         my $last = pop @allow;
 475                         $desc .= "\n$must be one of: " .
 476                                 join(', ', @allow) . " or $last";
 477                 }
 478                 my $lhs = join(', ', @s, @l) . join('', @vals);
 479                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 480                         $lhs =~ s/\A--/- , --/;
 481                 } else {
 482                         $lhs =~ s/\A--/    --/; # pad if no short options
 483                 }
 484                 $lpad = length($lhs) if length($lhs) > $lpad;
 485                 push @opt_desc, $lhs, $desc;
 486         }
 487         my $msg = $errmsg ? "E: $errmsg\n" : '';
 488         $msg .= <<EOF;
 489 usage: lei @top
 490   $cmd_desc
 491
 492 EOF
 493         $lpad += 2;
 494         local $Text::Wrap::columns = 78 - $lpad;
 495         my $padding = ' ' x ($lpad + 2);
 496         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 497                 $msg .= '  '.pack("A$lpad", $lhs);
 498                 $rhs = wrap('', '', $rhs);
 499                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 500                 $msg .= $rhs;
 501                 $msg .= "\n";
 502         }
 503         print { $self->{$errmsg ? 2 : 1} } $msg;
 504         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 505         undef;
 506 }
 507
 508 sub optparse ($$$) {
 509         my ($self, $cmd, $argv) = @_;
 510         $self->{cmd} = $cmd;
 511         $OPT = $self->{opt} = {};
 512         my $info = $CMD{$cmd} // [ '[...]' ];
 513         my ($proto, undef, @spec) = @$info;
 514         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 515         push @spec, qw(help|h);
 516         my $lone_dash;
 517         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 518                 $lone_dash = $spec[0];
 519                 $OPT->{$spec[0]} = \(my $var);
 520                 push @spec, '' => \$var;
 521         }
 522         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 523                 return _help($self, "bad arguments or options for $cmd");
 524         return _help($self) if $OPT->{help};
 525
 526         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 527
 528         # "-" aliases "stdin" or "clear"
 529         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 530
 531         my $i = 0;
 532         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 533         my ($err, $inf);
 534         my @args = split(/ /, $proto);
 535         for my $var (@args) {
 536                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 537                         $inf = defined($argv->[$i]) and last;
 538                         $var =~ s/\.\.\.\z//;
 539                         $err = "$var not supplied";
 540                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 541                         $argv->[$i++] // ($err = "$var not supplied");
 542                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 543                         $inf = 1;
 544                         last;
 545                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 546                         $i++;
 547                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 548                         my @or = split(/\|/, $var);
 549                         my $ok;
 550                         for my $o (@or) {
 551                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 552                                         $ok = defined($OPT->{$1});
 553                                         last;
 554                                 } elsif (defined($argv->[$i])) {
 555                                         $ok = 1;
 556                                         $i++;
 557                                         last;
 558                                 } # else continue looping
 559                         }
 560                         last if $ok;
 561                         my $last = pop @or;
 562                         $err = join(', ', @or) . " or $last must be set";
 563                 } else {
 564                         warn "BUG: can't parse `$var' in $proto";
 565                 }
 566                 last if $err;
 567         }
 568         if (!$inf && scalar(@$argv) > scalar(@args)) {
 569                 $err //= 'too many arguments';
 570         }
 571         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 572 }
 573
 574 sub dispatch {
 575         my ($self, $cmd, @argv) = @_;
 576         local $current_lei = $self; # for __WARN__
 577         dump_and_clear_log("from previous run\n");
 578         return _help($self, 'no command given') unless defined($cmd);
 579         my $func = "lei_$cmd";
 580         $func =~ tr/-/_/;
 581         if (my $cb = __PACKAGE__->can($func)) {
 582                 optparse($self, $cmd, \@argv) or return;
 583                 $cb->($self, @argv);
 584         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 585                 my $opt = {};
 586                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 587                         return _help($self, 'bad arguments or options');
 588                 _help($self);
 589         } else {
 590                 fail($self, "`$cmd' is not an lei command");
 591         }
 592 }
 593
 594 sub _lei_cfg ($;$) {
 595         my ($self, $creat) = @_;
 596         my $f = _config_path($self);
 597         my @st = stat($f);
 598         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 599         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 600                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 601         }
 602         if (!@st) {
 603                 unless ($creat) {
 604                         delete $self->{cfg};
 605                         return;
 606                 }
 607                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 608                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 609                 open my $fh, '>>', $f or die "open($f): $!\n";
 610                 @st = stat($fh) or die "fstat($f): $!\n";
 611                 $cur_st = pack('dd', $st[10], $st[7]);
 612                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 613         }
 614         my $cfg = PublicInbox::Config::git_config_dump($f);
 615         $cfg->{-st} = $cur_st;
 616         $cfg->{'-f'} = $f;
 617         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 618 }
 619
 620 sub _lei_store ($;$) {
 621         my ($self, $creat) = @_;
 622         my $cfg = _lei_cfg($self, $creat);
 623         $cfg->{-lei_store} //= do {
 624                 require PublicInbox::LeiStore;
 625                 my $dir = $cfg->{'leistore.dir'};
 626                 $dir //= $creat ? _store_path($self) : return;
 627                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 628         };
 629 }
 630
 631 sub lei_show {
 632         my ($self, @argv) = @_;
 633 }
 634
 635 sub lei_mark {
 636         my ($self, @argv) = @_;
 637 }
 638
 639 sub _config {
 640         my ($self, @argv) = @_;
 641         my $env = $self->{env};
 642         delete local $env->{GIT_CONFIG};
 643         delete local $ENV{GIT_CONFIG};
 644         my $cfg = _lei_cfg($self, 1);
 645         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 646         my %rdr = map { $_ => $self->{$_} } (0..2);
 647         waitpid(spawn($cmd, $env, \%rdr), 0);
 648 }
 649
 650 sub lei_config {
 651         my ($self, @argv) = @_;
 652         $self->{opt}->{'config-file'} and return fail $self,
 653                 "config file switches not supported by `lei config'";
 654         _config(@_);
 655         x_it($self, $?) if $?;
 656 }
 657
 658 sub lei_init {
 659         my ($self, $dir) = @_;
 660         my $cfg = _lei_cfg($self, 1);
 661         my $cur = $cfg->{'leistore.dir'};
 662         $dir //= _store_path($self);
 663         $dir = rel2abs($self, $dir);
 664         my @cur = stat($cur) if defined($cur);
 665         $cur = File::Spec->canonpath($cur // $dir);
 666         my @dir = stat($dir);
 667         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 668         if (@cur) {
 669                 if ($cur eq $dir) {
 670                         _lei_store($self, 1)->done;
 671                         return qerr($self, $exists);
 672                 }
 673
 674                 # some folks like symlinks and bind mounts :P
 675                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 676                         lei_config($self, 'leistore.dir', $dir);
 677                         _lei_store($self, 1)->done;
 678                         return qerr($self, "$exists (as $cur)");
 679                 }
 680                 return fail($self, <<"");
 681 E: leistore.dir=$cur already initialized and it is not $dir
 682
 683         }
 684         lei_config($self, 'leistore.dir', $dir);
 685         _lei_store($self, 1)->done;
 686         $exists //= "I: leistore.dir=$dir newly initialized";
 687         return qerr($self, $exists);
 688 }
 689
 690 sub lei_daemon_pid { puts shift, $$ }
 691
 692 sub lei_daemon_kill {
 693         my ($self) = @_;
 694         my $sig = $self->{opt}->{signal} // 'TERM';
 695         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 696 }
 697
 698 sub lei_help { _help($_[0]) }
 699
 700 # Shell completion helper.  Used by lei-completion.bash and hopefully
 701 # other shells.  Try to do as much here as possible to avoid redundancy
 702 # and improve maintainability.
 703 sub lei__complete {
 704         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 705         shift @argv; # ignore "lei", the entire command is sent
 706         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 707         my $cmd = shift @argv;
 708         my $info = $CMD{$cmd} // do { # filter matching commands
 709                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 710                 return;
 711         };
 712         my ($proto, undef, @spec) = @$info;
 713         my $cur = pop @argv;
 714         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 715         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 716                 # gross special case since the only git-config options
 717                 # Consider moving to a table if we need more special cases
 718                 # we use Getopt::Long for are the ones we reject, so these
 719                 # are the ones we don't reject:
 720                 if ($cmd eq 'config') {
 721                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 722                         @spec = qw(add z|null get get-all unset unset-all
 723                                 replace-all get-urlmatch
 724                                 remove-section rename-section
 725                                 name-only list|l edit|e
 726                                 get-color-name get-colorbool);
 727                         # fall-through
 728                 }
 729                 puts $self, grep(/$re/, map { # generate short/long names
 730                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 731                         } else { # negation: solve! => no-solve|solve
 732                                 s/\A(.+)!\z/no-$1|$1/;
 733                         }
 734                         map {
 735                                 my $x = length > 1 ? "--$_" : "-$_";
 736                                 $x eq $cur ? () : $x;
 737                         } split(/\|/, $_, -1) # help|h
 738                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 739         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 740                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 741         }
 742
 743         # switch args (e.g. lei q -f mbox<TAB>)
 744         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 745                 my $opt = quotemeta $1;
 746                 puts $self, map {
 747                         my $v = $OPTDESC{$_};
 748                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 749                         # get rid of ALL CAPS placeholder (e.g "OUT")
 750                         # (TODO: completion for external paths)
 751                         shift(@v) if uc($v[0]) eq $v[0];
 752                         @v;
 753                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 754         }
 755         $cmd =~ tr/-/_/;
 756         if (my $sub = $self->can("_complete_$cmd")) {
 757                 puts $self, $sub->($self, @argv, $cur);
 758         }
 759         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 760         # proto parsing.
 761 }
 762
 763 sub exec_buf ($$) {
 764         my ($argv, $env) = @_;
 765         my $argc = scalar @$argv;
 766         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 767         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 768         $buf;
 769 }
 770
 771 sub start_mua {
 772         my ($self) = @_;
 773         my $mua = $self->{opt}->{'mua-cmd'} // return;
 774         my $mfolder = $self->{ovv}->{dst};
 775         my (@cmd, $replaced);
 776         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 777                 @cmd = ($mua, '-f');
 778         # TODO: help wanted: other common FOSS MUAs
 779         } else {
 780                 require Text::ParseWords;
 781                 my @cmd = Text::ParseWords::shellwords($mua);
 782                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 783                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 784         }
 785         push @cmd, $mfolder unless defined($replaced);
 786         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 787                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 788         } elsif ($self->{oneshot}) {
 789                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 790         }
 791 }
 792
 793 # caller needs to "-t $self->{1}" to check if tty
 794 sub start_pager {
 795         my ($self) = @_;
 796         my $env = $self->{env};
 797         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 798         chomp(my $pager = <$fh> // '');
 799         close($fh) or warn "`git var PAGER' error: \$?=$?";
 800         return if $pager eq 'cat' || $pager eq '';
 801         # TODO TIOCGWINSZ
 802         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 803         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 804         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 805         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 806         my $pgr = [ undef, @$rdr{1, 2} ];
 807         if (my $sock = $self->{sock}) { # lei(1) process runs it
 808                 delete @$new_env{keys %$env}; # only set iff unset
 809                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 810                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 811         } elsif ($self->{oneshot}) {
 812                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 813                 $pgr->[3] = $$; # ew'll reap it
 814         } else {
 815                 die 'BUG: start_pager w/o socket';
 816         }
 817         $self->{1} = $wpager;
 818         $self->{2} = $wpager if -t $self->{2};
 819         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 820         $self->{pgr} = $pgr;
 821 }
 822
 823 sub stop_pager {
 824         my ($self) = @_;
 825         my $pgr = delete($self->{pgr}) or return;
 826         $self->{2} = $pgr->[2];
 827         # do not restore original stdout, just close it so we error out
 828         close(delete($self->{1})) if $self->{1};
 829         my $pid = $pgr->[0];
 830         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 831 }
 832
 833 sub accept_dispatch { # Listener {post_accept} callback
 834         my ($sock) = @_; # ignore other
 835         $sock->autoflush(1);
 836         my $self = bless { sock => $sock }, __PACKAGE__;
 837         vec(my $rvec = '', fileno($sock), 1) = 1;
 838         select($rvec, undef, undef, 60) or
 839                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 840         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 841         if (scalar(@fds) == 4) {
 842                 for my $i (0..3) {
 843                         my $fd = shift(@fds);
 844                         open($self->{$i}, '+<&=', $fd) and next;
 845                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 846                 }
 847         } else {
 848                 my $msg = "recv_cmd failed: $!";
 849                 warn $msg;
 850                 return send($sock, $msg, MSG_EOR);
 851         }
 852         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 853         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 854         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 855         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 856                 return send($sock, 'request command truncated', MSG_EOR);
 857         my ($argc, @argv) = split(/\0/, $buf, -1);
 858         undef $buf;
 859         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 860         if (chdir($self->{3})) {
 861                 local %ENV = %env;
 862                 $self->{env} = \%env;
 863                 eval { dispatch($self, @argv) };
 864                 send($sock, $@, MSG_EOR) if $@;
 865         } else {
 866                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 867         }
 868 }
 869
 870 sub dclose {
 871         my ($self) = @_;
 872         for my $f (qw(lxs l2m)) {
 873                 my $wq = delete $self->{$f} or next;
 874                 if ($wq->wq_kill) {
 875                         $wq->wq_close
 876                 } elsif ($wq->wq_kill_old) {
 877                         $wq->wq_wait_old($self);
 878                 }
 879         }
 880         close(delete $self->{1}) if $self->{1}; # may reap_compress
 881         $self->close if $self->{sock}; # PublicInbox::DS::close
 882 }
 883
 884 # for long-running results
 885 sub event_step {
 886         my ($self) = @_;
 887         local %ENV = %{$self->{env}};
 888         my $sock = $self->{sock};
 889         local $current_lei = $self;
 890         eval {
 891                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 892                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 893                                 return if $! == EAGAIN;
 894                                 next if $! == EINTR;
 895                                 last if $! == ECONNRESET;
 896                                 die "recvmsg: $!";
 897                         }
 898                         for my $fd (@fds) {
 899                                 open my $rfh, '+<&=', $fd;
 900                         }
 901                         die "unrecognized client signal: $buf";
 902                 }
 903                 dclose($self);
 904         };
 905         if (my $err = $@) {
 906                 eval { $self->fail($err) };
 907                 dclose($self);
 908         }
 909 }
 910
 911 sub event_step_init {
 912         my ($self) = @_;
 913         if (my $sock = $self->{sock}) { # using DS->EventLoop
 914                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 915         }
 916 }
 917
 918 sub noop {}
 919
 920 our $oldset; sub oldset { $oldset }
 921
 922 sub dump_and_clear_log {
 923         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 924                 my @pfx = @_;
 925                 unshift(@pfx, "$errors_log ") if @pfx;
 926                 warn @pfx, do { local $/; <STDIN> };
 927                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 928         }
 929 }
 930
 931 # lei(1) calls this when it can't connect
 932 sub lazy_start {
 933         my ($path, $errno, $narg) = @_;
 934         if ($errno == ECONNREFUSED) {
 935                 unlink($path) or die "unlink($path): $!";
 936         } elsif ($errno != ENOENT) {
 937                 $! = $errno; # allow interpolation to stringify in die
 938                 die "connect($path): $!";
 939         }
 940         if (eval { require BSD::Resource }) {
 941                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 942                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 943                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 944         }
 945         umask(077) // die("umask(077): $!");
 946         local $listener;
 947         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 948         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 949         listen($listener, 1024) or die "listen: $!";
 950         my @st = stat($path) or die "stat($path): $!";
 951         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 952         local $oldset = PublicInbox::DS::block_signals();
 953         if ($narg == 5) {
 954                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 955                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 956                         require PublicInbox::CmdIPC4;
 957                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 958                         PublicInbox::CmdIPC4->can('recv_cmd4');
 959                 };
 960         }
 961         $recv_cmd or die <<"";
 962 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 963
 964         require PublicInbox::Listener;
 965         require PublicInbox::EOFpipe;
 966         (-p STDOUT) or die "E: stdout must be a pipe\n";
 967         local $errors_log;
 968         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 969         $errors_log .= 'errors.log';
 970         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 971         STDIN->autoflush(1);
 972         dump_and_clear_log("from previous daemon process:\n");
 973         POSIX::setsid() > 0 or die "setsid: $!";
 974         my $pid = fork // die "fork: $!";
 975         return if $pid;
 976         $0 = "lei-daemon $path";
 977         local %PATH2CFG;
 978         $listener->blocking(0);
 979         my $exit_code;
 980         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 981         local $quit = do {
 982                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 983                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 984                 sub {
 985                         $exit_code //= shift;
 986                         my $lis = $pil or exit($exit_code);
 987                         # closing eof_w triggers \&noop wakeup
 988                         $listener = $eof_w = $pil = $path = undef;
 989                         $lis->close; # DS::close
 990                         PublicInbox::DS->SetLoopTimeout(1000);
 991                 };
 992         };
 993         my $sig = {
 994                 CHLD => \&PublicInbox::DS::enqueue_reap,
 995                 QUIT => $quit,
 996                 INT => $quit,
 997                 TERM => $quit,
 998                 HUP => \&noop,
 999                 USR1 => \&noop,
1000                 USR2 => \&noop,
1001         };
1002         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1003         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1004         undef $sig;
1005         local $SIG{PIPE} = 'IGNORE';
1006         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1007                 undef $sigfd;
1008                 PublicInbox::DS->SetLoopTimeout(5000);
1009         } else {
1010                 # wake up every second to accept signals if we don't
1011                 # have signalfd or IO::KQueue:
1012                 PublicInbox::DS::sig_setmask($oldset);
1013                 PublicInbox::DS->SetLoopTimeout(1000);
1014         }
1015         PublicInbox::DS->SetPostLoopCallback(sub {
1016                 my ($dmap, undef) = @_;
1017                 if (@st = defined($path) ? stat($path) : ()) {
1018                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1019                                 warn "$path dev/ino changed, quitting\n";
1020                                 $path = undef;
1021                         }
1022                 } elsif (defined($path)) { # ENOENT is common
1023                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1024                         undef $path;
1025                         $quit->();
1026                 }
1027                 return 1 if defined($path);
1028                 my $now = now();
1029                 my $n = 0;
1030                 for my $s (values %$dmap) {
1031                         $s->can('busy') or next;
1032                         if ($s->busy($now)) {
1033                                 ++$n;
1034                         } else {
1035                                 $s->close;
1036                         }
1037                 }
1038                 $n; # true: continue, false: stop
1039         });
1040
1041         # STDIN was redirected to /dev/null above, closing STDERR and
1042         # STDOUT will cause the calling `lei' client process to finish
1043         # reading the <$daemon> pipe.
1044         local $SIG{__WARN__} = sub {
1045                 $current_lei ? err($current_lei, @_) : warn(
1046                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1047         };
1048         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1049         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1050         # $daemon pipe to `lei' closed, main loop begins:
1051         PublicInbox::DS->EventLoop;
1052         exit($exit_code // 0);
1053 }
1054
1055 # for users w/o Socket::Msghdr installed or Inline::C enabled
1056 sub oneshot {
1057         my ($main_pkg) = @_;
1058         my $exit = $main_pkg->can('exit'); # caller may override exit()
1059         local $quit = $exit if $exit;
1060         local %PATH2CFG;
1061         umask(077) // die("umask(077): $!");
1062         my $self = bless {
1063                 oneshot => 1,
1064                 0 => *STDIN{GLOB},
1065                 1 => *STDOUT{GLOB},
1066                 2 => *STDERR{GLOB},
1067                 env => \%ENV
1068         }, __PACKAGE__;
1069         dispatch($self, @ARGV);
1070         x_it($self, $self->{child_error}) if $self->{child_error};
1071 }
1072
1073 # ensures stdout hits the FS before sock disconnects so a client
1074 # can immediately reread it
1075 sub DESTROY {
1076         my ($self) = @_;
1077         $self->{1}->autoflush(1) if $self->{1};
1078         stop_pager($self);
1079         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1080                 waitpid($mua_pid, 0);
1081         }
1082 }
1083
1084 1;