lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we generate shell completion + help using %CMD and %OPTDESC,
 139 # see lei__complete() and PublicInbox::LeiHelp
 140 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 141 our %CMD = ( # sorted in order of importance/use:
 142 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 143         'stdin|', # /|\z/ must be first for lone dash
 144         @lxs_opt,
 145         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 146         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 147         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 148         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 149
 150 'up' => [ 'OUTPUT|--all', 'update saved search',
 151         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 152
 153 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 154         'stdin|', # /|\z/ must be first for lone dash
 155         # some of these options are ridiculous for lcat
 156         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 157         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 158         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 159         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 160
 161 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 162         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 163         @lxs_opt, @c_opt ],
 164
 165 'add-external' => [ 'LOCATION',
 166         'add/set priority of a publicinbox|extindex for extra matches',
 167         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 168         verbose|v+), @c_opt, index_opt(),
 169         PublicInbox::LeiQuery::curl_opt() ],
 170 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 171         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 172 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 173 'ls-sync' => [ '', 'list sync folders',
 174                 qw(z|0 z|0 globoff|g invert-match|v local remote), @c_opt ],
 175 'forget-external' => [ 'LOCATION...|--prune',
 176         'exclude further results from a publicinbox|extindex',
 177         qw(prune), @c_opt ],
 178
 179 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 180                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 181 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 182                 qw(verbose|v+), @c_opt ],
 183 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 184                         @c_opt ],
 185
 186 'plonk' => [ '--threads|--from=IDENT',
 187         'exclude mail matching From: or threads from non-Message-ID searches',
 188         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 189 'tag' => [ 'KEYWORDS...',
 190         'set/unset keywords and/or labels on message(s)',
 191         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 192         pass_through('-kw:foo for delete') ],
 193 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 194         "exclude message(s) on stdin from `q' search results",
 195         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 196
 197 'purge-mailsource' => [ 'LOCATION|--all',
 198         'remove imported messages from IMAP, Maildirs, and MH',
 199         qw(exact! all jobs:i indexed), @c_opt ],
 200
 201 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 202         qw(import! kw! interval=s recursive|r
 203         exclude=s include=s), @c_opt ],
 204 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 205                 qw(format|f=s z), @c_opt ],
 206 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 207 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 208 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 209         qw(prune), @c_opt ],
 210
 211 'import' => [ 'LOCATION...|--stdin',
 212         'one-time import/update from URL or filesystem',
 213         qw(stdin| offset=i recursive|r exclude=s include|I=s
 214         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!), @c_opt ],
 215 'convert' => [ 'LOCATION...|--stdin',
 216         'one-time conversion from URL or filesystem to another format',
 217         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 218         lock=s@ kw!), @c_opt ],
 219 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 220         "use a patch to generate a query for `lei q --stdin'",
 221         qw(stdin| want|w=s@ uri debug), @c_opt ],
 222 'config' => [ '[...]', sub {
 223                 'git-config(1) wrapper for '._config_path($_[0]);
 224         }, qw(config-file|system|global|file|f=s), # for conflict detection
 225          qw(c=s@ C=s@), pass_through('git config') ],
 226 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 227         qw(pretty ascii dir=s), @c_opt ],
 228
 229 'init' => [ '[DIRNAME]', sub {
 230         "initialize storage, default: ".store_path($_[0]);
 231         }, @c_opt ],
 232 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 233         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 234         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 235 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 236 'help' => [ '[SUBCOMMAND]', 'show help' ],
 237
 238 # XXX do we need this?
 239 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 240
 241 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 242         'rewrite git history in an attempt to improve compression',
 243         qw(gc!), @c_opt ],
 244
 245 # internal commands are prefixed with '_'
 246 '_complete' => [ '[...]', 'internal shell completion helper',
 247                 pass_through('everything') ],
 248 ); # @CMD
 249
 250 # switch descriptions, try to keep consistent across commands
 251 # $spec: Getopt::Long option specification
 252 # $spec => [@ALLOWED_VALUES (default is first), $description],
 253 # $spec => $description
 254 # "$SUB_COMMAND TAB $spec" => as above
 255 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 256                         'specify message input format' ];
 257 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 258
 259 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 260 my %OPTDESC = (
 261 'help|h' => 'show this built-in help',
 262 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 263 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 264 'quiet|q' => 'be quiet',
 265 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 266         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 267
 268 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 269 'globoff|g' => "do not match locations using '*?' wildcards ".
 270                 "and\xa0'[]'\x{a0}ranges",
 271 'color!' => 'disable color (for --format=text)',
 272 'verbose|v+' => 'be more verbose',
 273 'external!' => 'do not use externals',
 274 'mail!' => 'do not look in mail storage for OID',
 275 'cwd!' => 'do not look in git repo of current working directory',
 276 'oid-a|A=s' => 'pre-image OID',
 277 'path-a|a=s' => 'pre-image pathname associated with OID',
 278 'path-b|b=s' => 'post-image pathname associated with OID',
 279 'git-dir=s@' => 'additional git repository to scan',
 280 'torsocks=s' => ['VAL|auto|no|yes',
 281                 'whether or not to wrap git and curl commands with torsocks'],
 282 'no-torsocks' => 'alias for --torsocks=no',
 283 'save' =>  "save a search for `lei up'",
 284 'import-remote!' => 'do not memoize remote messages into local store',
 285
 286 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 287
 288 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 289                 'deduplication strategy'],
 290 'threads|t+' =>
 291         'return all messages in the same threads as the actual match(es)',
 292
 293 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 294                 'search prefixes to extract (default: dfpost7)' ],
 295
 296 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 297         'run command(s) or perform ops when done writing to output ' .
 298         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 299         'nothing otherwise)' ],
 300
 301 'augment|a' => 'augment --output destination instead of clobbering',
 302
 303 'output|mfolder|o=s' => [ 'MFOLDER',
 304         "destination (e.g.\xa0`/path/to/Maildir', ".
 305         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 306 'mua=s' => [ 'CMD',
 307         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 308
 309 'inbox-version=i' => [ 'NUM|1|2',
 310                 'force a public-inbox version with --mirror'],
 311 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 312
 313 # public-inbox-index options
 314 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 315 'compact' => 'run compact index after mirroring',
 316 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 317         "indexlevel with --mirror (default: full)" ],
 318 'max_size|max-size=s' => [ 'SIZE',
 319         'do not index messages larger than SIZE (default: infinity)' ],
 320 'batch_size|batch-size=s' => [ 'SIZE',
 321         'flush changes to OS after given number of bytes (default: 1m)' ],
 322 'sequential_shard|sequential-shard' =>
 323         'index Xapian shards sequentially for slow storage',
 324 'skip-docdata' =>
 325         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 326
 327 'format|f=s     q' => [
 328         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 329                 'specify output format, default depends on --output'],
 330 'exclude=s@     q' => [ 'LOCATION',
 331                 'exclude specified external(s) from search' ],
 332 'include|I=s@   q' => [ 'LOCATION',
 333                 'include specified external(s) in search' ],
 334 'only=s@        q' => [ 'LOCATION',
 335                 'only use specified external(s) for search' ],
 336 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 337                 'control number of search and writer jobs' ],
 338 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 339
 340 'in-format|F=s' => $stdin_formats,
 341 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 342                         'listing output format' ],
 343 'l      ls-search' => 'long listing format',
 344 'format|f=s     ls-external' => $ls_format,
 345
 346 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 347 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 348
 349 'sort|s=s' => [ 'VAL|received|relevance|docid',
 350                 "order of results is `--output'-dependent"],
 351 'reverse|r' => 'reverse search results', # like sort(1)
 352
 353 'boost=i' => 'increase/decrease priority of results (default: 0)',
 354
 355 'local' => 'limit operations to the local filesystem',
 356 'local!' => 'exclude results from the local filesystem',
 357 'remote' => 'limit operations to those requiring network access',
 358 'remote!' => 'prevent operations requiring network access',
 359
 360 'all:s  up' => ['local', 'update all (local) saved searches' ],
 361
 362 'mid=s' => 'specify the Message-ID of a message',
 363 'oid=s' => 'specify the git object ID of a message',
 364
 365 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 366 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 367 'include=s' => 'include mailboxes/newsgroups based on pattern',
 368
 369 'exact' => 'operate on exact header matches only',
 370 'exact!' => 'rely on content match instead of exact header matches',
 371
 372 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 373
 374 'kw!' => 'disable/enable importing keywords (aka "flags")',
 375
 376 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 377 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 378
 379 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 380 ); # %OPTDESC
 381
 382 my %CONFIG_KEYS = (
 383         'leistore.dir' => 'top-level storage location',
 384 );
 385
 386 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 387
 388 sub _drop_wq {
 389         my ($self) = @_;
 390         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 391                 if ($wq->wq_kill) {
 392                         $wq->wq_close(0, undef, $self);
 393                 } elsif ($wq->wq_kill_old) {
 394                         $wq->wq_wait_old(undef, $self);
 395                 }
 396                 $wq->DESTROY;
 397         }
 398 }
 399
 400 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 401 sub x_it ($$) {
 402         my ($self, $code) = @_;
 403         # make sure client sees stdout before exit
 404         $self->{1}->autoflush(1) if $self->{1};
 405         dump_and_clear_log();
 406         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 407                 send($s, "x_it $code", MSG_EOR);
 408         } elsif ($self->{oneshot}) {
 409                 # don't want to end up using $? from child processes
 410                 _drop_wq($self);
 411                 # cleanup anything that has tempfiles or open file handles
 412                 %PATH2CFG = ();
 413                 delete @$self{qw(ovv dedupe sto cfg)};
 414                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 415                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 416                         kill $signum, $$;
 417                         sleep(1) while 1; # wait for signal
 418                 } else {
 419                         $quit->($code >> 8);
 420                 }
 421         } # else ignore if client disconnected
 422 }
 423
 424 sub err ($;@) {
 425         my $self = shift;
 426         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 427         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 428         print $err @_, @eor and return;
 429         my $old_err = delete $self->{2};
 430         close($old_err) if $! == EPIPE && $old_err;
 431         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 432         print $err @_, @eor or print STDERR @_, @eor;
 433 }
 434
 435 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 436
 437 sub fail_handler ($;$$) {
 438         my ($lei, $code, $io) = @_;
 439         close($io) if $io; # needed to avoid warnings on SIGPIPE
 440         _drop_wq($lei);
 441         x_it($lei, $code // (1 << 8));
 442 }
 443
 444 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 445         fail_handler($_[0], 13, delete $_[0]->{1});
 446 }
 447
 448 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 449 sub sigint_reap {
 450         my ($pgid) = @_;
 451         dwaitpid($pgid) if kill('-INT', $pgid);
 452 }
 453
 454 sub fail ($$;$) {
 455         my ($self, $buf, $exit_code) = @_;
 456         err($self, $buf) if defined $buf;
 457         # calls fail_handler:
 458         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 459         x_it($self, ($exit_code // 1) << 8);
 460         undef;
 461 }
 462
 463 sub out ($;@) {
 464         my $self = shift;
 465         return if print { $self->{1} // return } @_; # likely
 466         return note_sigpipe($self, 1) if $! == EPIPE;
 467         my $err = "error writing to output: $!";
 468         delete $self->{1};
 469         fail($self, $err);
 470 }
 471
 472 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 473
 474 sub child_error { # passes non-fatal curl exit codes to user
 475         my ($self, $child_error, $msg) = @_; # child_error is $?
 476         $self->err($msg) if $msg;
 477         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 478                 # send to the parent lei-daemon or to lei(1) client
 479                 send($s, "child_error $child_error", MSG_EOR);
 480         } elsif (!$PublicInbox::DS::in_loop) {
 481                 $self->{child_error} = $child_error;
 482         } # else noop if client disconnected
 483 }
 484
 485 sub note_sigpipe { # triggers sigpipe_handler
 486         my ($self, $fd) = @_;
 487         close(delete($self->{$fd})); # explicit close silences Perl warning
 488         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 489         x_it($self, 13);
 490 }
 491
 492 sub _lei_atfork_child {
 493         my ($self, $persist) = @_;
 494         # we need to explicitly close things which are on stack
 495         if ($persist) {
 496                 chdir '/' or die "chdir(/): $!";
 497                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 498                 if (my $cfg = $self->{cfg}) {
 499                         delete $cfg->{-lei_store};
 500                 }
 501         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 502                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 503         }
 504         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 505         if (my $op_c = delete $self->{pkt_op_c}) {
 506                 close(delete $op_c->{sock});
 507         }
 508         if (my $pgr = delete $self->{pgr}) {
 509                 close($_) for (@$pgr[1,2]);
 510         }
 511         close $listener if $listener;
 512         undef $listener;
 513         %PATH2CFG = ();
 514         undef $errors_log;
 515         $quit = \&CORE::exit;
 516         $self->{-eml_noisy} or # only "lei import" sets this atm
 517                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 518         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 519 }
 520
 521 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 522         my ($self) = @_;
 523         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 524                 $op->close; # PublicInbox::PktOp::close
 525         }
 526         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 527         close $unclosed_after_die;
 528 }
 529
 530 sub pkt_op_pair {
 531         my ($self) = @_;
 532         require PublicInbox::OnDestroy;
 533         require PublicInbox::PktOp;
 534         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 535         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 536         $end;
 537 }
 538
 539 sub workers_start {
 540         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 541         $ops = {
 542                 '!' => [ \&fail_handler, $lei ],
 543                 '|' => [ \&sigpipe_handler, $lei ],
 544                 'x_it' => [ \&x_it, $lei ],
 545                 'child_error' => [ \&child_error, $lei ],
 546                 ($ops ? %$ops : ()),
 547         };
 548         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 549         my $end = $lei->pkt_op_pair;
 550         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 551         delete $lei->{pkt_op_p};
 552         my $op_c = delete $lei->{pkt_op_c};
 553         @$end = ();
 554         $lei->event_step_init;
 555         ($op_c, $ops);
 556 }
 557
 558 sub _help {
 559         require PublicInbox::LeiHelp;
 560         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 561 }
 562
 563 sub optparse ($$$) {
 564         my ($self, $cmd, $argv) = @_;
 565         # allow _complete --help to complete, not show help
 566         return 1 if substr($cmd, 0, 1) eq '_';
 567         $self->{cmd} = $cmd;
 568         $OPT = $self->{opt} //= {};
 569         my $info = $CMD{$cmd} // [ '[...]' ];
 570         my ($proto, undef, @spec) = @$info;
 571         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 572         push @spec, qw(help|h);
 573         my $lone_dash;
 574         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 575                 $lone_dash = $spec[0];
 576                 $OPT->{$spec[0]} = \(my $var);
 577                 push @spec, '' => \$var;
 578         }
 579         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 580                 return _help($self, "bad arguments or options for $cmd");
 581         return _help($self) if $OPT->{help};
 582
 583         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 584
 585         # "-" aliases "stdin" or "clear"
 586         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 587
 588         my $i = 0;
 589         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 590         my ($err, $inf);
 591         my @args = split(/ /, $proto);
 592         for my $var (@args) {
 593                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 594                         $inf = defined($argv->[$i]) and last;
 595                         $var =~ s/\.\.\.\z//;
 596                         $err = "$var not supplied";
 597                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 598                         $argv->[$i++] // ($err = "$var not supplied");
 599                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 600                         $inf = 1;
 601                         last;
 602                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 603                         $i++;
 604                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 605                         $inf = 1 if index($var, '...') > 0;
 606                         my @or = split(/\|/, $var);
 607                         my $ok;
 608                         for my $o (@or) {
 609                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 610                                         $ok = defined($OPT->{$1});
 611                                         last if $ok;
 612                                 } elsif (defined($argv->[$i])) {
 613                                         $ok = 1;
 614                                         $i++;
 615                                         last;
 616                                 } # else continue looping
 617                         }
 618                         last if $ok;
 619                         my $last = pop @or;
 620                         $err = join(', ', @or) . " or $last must be set";
 621                 } else {
 622                         warn "BUG: can't parse `$var' in $proto";
 623                 }
 624                 last if $err;
 625         }
 626         if (!$inf && scalar(@$argv) > scalar(@args)) {
 627                 $err //= 'too many arguments';
 628         }
 629         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 630 }
 631
 632 sub _tmp_cfg { # for lei -c <name>=<value> ...
 633         my ($self) = @_;
 634         my $cfg = _lei_cfg($self, 1);
 635         require File::Temp;
 636         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 637         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 638         $ft->autoflush(1);
 639         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 640 [include]
 641         path = $cfg->{-f}
 642 EOM
 643         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 644         for (@{$self->{opt}->{c}}) {
 645                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 646 `-c $_' is not of the form -c <name>=<value>'
 647 EOM
 648                 my $name = $1;
 649                 my $value = $2 // 1;
 650                 _config($self, '--add', $name, $value);
 651                 if (defined(my $v = $tmp->{$name})) {
 652                         if (ref($v) eq 'ARRAY') {
 653                                 push @$v, $value;
 654                         } else {
 655                                 $tmp->{$name} = [ $v, $value ];
 656                         }
 657                 } else {
 658                         $tmp->{$name} = $value;
 659                 }
 660         }
 661 }
 662
 663 sub lazy_cb ($$$) {
 664         my ($self, $cmd, $pfx) = @_;
 665         my $ucmd = $cmd;
 666         $ucmd =~ tr/-/_/;
 667         my $cb;
 668         $cb = $self->can($pfx.$ucmd) and return $cb;
 669         my $base = $ucmd;
 670         $base =~ s/_([a-z])/\u$1/g;
 671         my $pkg = "PublicInbox::Lei\u$base";
 672         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 673                 $pkg->can($pfx.$ucmd) : undef;
 674 }
 675
 676 sub dispatch {
 677         my ($self, $cmd, @argv) = @_;
 678         local $current_lei = $self; # for __WARN__
 679         dump_and_clear_log("from previous run\n");
 680         return _help($self, 'no command given') unless defined($cmd);
 681         # do not support Getopt bundling for this
 682         while ($cmd eq '-C' || $cmd eq '-c') {
 683                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 684                                         '-C DIRECTORY' : '-c <name>=<value>');
 685                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 686                 $cmd = shift(@argv) // return _help($self, 'no command given');
 687         }
 688         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 689                 optparse($self, $cmd, \@argv) or return;
 690                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 691                 if (my $chdir = $self->{opt}->{C}) {
 692                         for my $d (@$chdir) {
 693                                 next if $d eq ''; # same as git(1)
 694                                 chdir $d or return fail($self, "cd $d: $!");
 695                         }
 696                         if (delete $self->{3}) { # update cwd for rel2abs
 697                                 opendir my $dh, '.' or
 698                                         return fail($self, "opendir . $!");
 699                                 $self->{3} = $dh;
 700                         }
 701                 }
 702                 $cb->($self, @argv);
 703         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 704                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 705                         or return _help($self, 'bad arguments or options');
 706                 _help($self);
 707         } else {
 708                 fail($self, "`$cmd' is not an lei command");
 709         }
 710 }
 711
 712 sub _lei_cfg ($;$) {
 713         my ($self, $creat) = @_;
 714         return $self->{cfg} if $self->{cfg};
 715         my $f = _config_path($self);
 716         my @st = stat($f);
 717         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 718         my ($sto, $sto_dir);
 719         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 720                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 721                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 722         }
 723         if (!@st) {
 724                 unless ($creat) {
 725                         delete $self->{cfg};
 726                         return bless {}, 'PublicInbox::Config';
 727                 }
 728                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 729                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 730                 open my $fh, '>>', $f or die "open($f): $!\n";
 731                 @st = stat($fh) or die "fstat($f): $!\n";
 732                 $cur_st = pack('dd', $st[10], $st[7]);
 733                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 734         }
 735         my $cfg = PublicInbox::Config->git_config_dump($f);
 736         $cfg->{-st} = $cur_st;
 737         $cfg->{'-f'} = $f;
 738         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 739                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 740                                                 store_path($self))) {
 741                 $cfg->{-lei_store} = $sto;
 742         }
 743         if (scalar(keys %PATH2CFG) > 5) {
 744                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 745                 for my $k (keys %PATH2CFG) {
 746                         delete($PATH2CFG{$k}) unless -f $k
 747                 }
 748         }
 749         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 750 }
 751
 752 sub _lei_store ($;$) {
 753         my ($self, $creat) = @_;
 754         my $cfg = _lei_cfg($self, $creat);
 755         $cfg->{-lei_store} //= do {
 756                 require PublicInbox::LeiStore;
 757                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 758                 return unless $creat || -d $dir;
 759                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 760         };
 761 }
 762
 763 sub _config {
 764         my ($self, @argv) = @_;
 765         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 766         my $cfg = _lei_cfg($self, 1);
 767         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 768         my %rdr = map { $_ => $self->{$_} } (0..2);
 769         waitpid(spawn($cmd, \%env, \%rdr), 0);
 770 }
 771
 772 sub lei_config {
 773         my ($self, @argv) = @_;
 774         $self->{opt}->{'config-file'} and return fail $self,
 775                 "config file switches not supported by `lei config'";
 776         _config(@_);
 777         x_it($self, $?) if $?;
 778 }
 779
 780 sub lei_daemon_pid { puts shift, $$ }
 781
 782 sub lei_daemon_kill {
 783         my ($self) = @_;
 784         my $sig = $self->{opt}->{signal} // 'TERM';
 785         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 786 }
 787
 788 # Shell completion helper.  Used by lei-completion.bash and hopefully
 789 # other shells.  Try to do as much here as possible to avoid redundancy
 790 # and improve maintainability.
 791 sub lei__complete {
 792         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 793         shift @argv; # ignore "lei", the entire command is sent
 794         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 795         my $cmd = shift @argv;
 796         my $info = $CMD{$cmd} // do { # filter matching commands
 797                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 798                 return;
 799         };
 800         my ($proto, undef, @spec) = @$info;
 801         my $cur = pop @argv;
 802         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 803         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 804                 # gross special case since the only git-config options
 805                 # Consider moving to a table if we need more special cases
 806                 # we use Getopt::Long for are the ones we reject, so these
 807                 # are the ones we don't reject:
 808                 if ($cmd eq 'config') {
 809                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 810                         @spec = qw(add z|null get get-all unset unset-all
 811                                 replace-all get-urlmatch
 812                                 remove-section rename-section
 813                                 name-only list|l edit|e
 814                                 get-color-name get-colorbool);
 815                         # fall-through
 816                 }
 817                 # generate short/long names from Getopt::Long specs
 818                 puts $self, grep(/$re/, qw(--help -h -C), map {
 819                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 820                         } elsif (s/\+\z//) { # verbose|v+
 821                         } elsif (s/!\z//) {
 822                                 # negation: mail! => no-mail|mail
 823                                 s/([\w\-]+)/$1|no-$1/g
 824                         }
 825                         map {
 826                                 my $x = length > 1 ? "--$_" : "-$_";
 827                                 $x eq $_cur ? () : $x;
 828                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 829                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 830         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 831                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 832         }
 833
 834         # switch args (e.g. lei q -f mbox<TAB>)
 835         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 836                 my $opt = quotemeta $1;
 837                 puts $self, map {
 838                         my $v = $OPTDESC{$_};
 839                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 840                         # get rid of ALL CAPS placeholder (e.g "OUT")
 841                         # (TODO: completion for external paths)
 842                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 843                         @v;
 844                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 845         }
 846         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 847                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 848         }
 849         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 850         # proto parsing.
 851 }
 852
 853 sub exec_buf ($$) {
 854         my ($argv, $env) = @_;
 855         my $argc = scalar @$argv;
 856         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 857         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 858         $buf;
 859 }
 860
 861 sub start_mua {
 862         my ($self) = @_;
 863         my $mua = $self->{opt}->{mua} // return;
 864         my $mfolder = $self->{ovv}->{dst};
 865         my (@cmd, $replaced);
 866         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 867                 @cmd = ($mua, '-f');
 868         # TODO: help wanted: other common FOSS MUAs
 869         } else {
 870                 require Text::ParseWords;
 871                 @cmd = Text::ParseWords::shellwords($mua);
 872                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 873                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 874         }
 875         push @cmd, $mfolder unless defined($replaced);
 876         if ($self->{sock}) { # lei(1) client process runs it
 877                 # restore terminal: echo $query | lei q -stdin --mua=...
 878                 my $io = [];
 879                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 880                 send_exec_cmd($self, $io, \@cmd, {});
 881         } elsif ($self->{oneshot}) {
 882                 my $pid = fork // die "fork: $!";
 883                 if ($pid > 0) { # original process
 884                         if ($self->{opt}->{stdin} && -t STDOUT) {
 885                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 886                         }
 887                         exec(@cmd);
 888                         warn "exec @cmd: $!\n";
 889                         POSIX::_exit(1);
 890                 }
 891                 POSIX::setsid() > 0 or die "setsid: $!";
 892         }
 893         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 894                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 895         }
 896         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 897         $self->{opt}->{quiet} = 1;
 898         delete $self->{-progress};
 899         delete $self->{opt}->{verbose};
 900 }
 901
 902 sub send_exec_cmd { # tell script/lei to execute a command
 903         my ($self, $io, $cmd, $env) = @_;
 904         my $sock = $self->{sock} // die 'lei client gone';
 905         my $fds = [ map { fileno($_) } @$io ];
 906         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 907 }
 908
 909 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 910         my ($self) = @_;
 911         my $alerts = $self->{opt}->{alert} // return;
 912         while (my $op = shift(@$alerts)) {
 913                 if ($op eq ':WINCH') {
 914                         # hit the process group that started the MUA
 915                         if ($self->{sock}) {
 916                                 send($self->{sock}, '-WINCH', MSG_EOR);
 917                         } elsif ($self->{oneshot}) {
 918                                 kill('-WINCH', $$);
 919                         }
 920                 } elsif ($op eq ':bell') {
 921                         out($self, "\a");
 922                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 923                         push @$alerts, split(/(?<!\\),/, $op);
 924                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 925                         my $cmd = $1; # run an arbitrary command
 926                         require Text::ParseWords;
 927                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 928                         if (my $s = $self->{sock}) {
 929                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 930                         } elsif ($self->{oneshot}) {
 931                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 932                         }
 933                 } else {
 934                         err($self, "W: unsupported --alert=$op"); # non-fatal
 935                 }
 936         }
 937 }
 938
 939 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 940 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 941
 942 # this also normalizes the path
 943 sub path_to_fd {
 944         my ($self, $path) = @_;
 945         $path = rel2abs($self, $path);
 946         $path =~ tr!/!/!s;
 947         $path_to_fd{$path} // (
 948                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 949                         fail($self, "cannot open $path from daemon") : -1
 950         );
 951 }
 952
 953 # caller needs to "-t $self->{1}" to check if tty
 954 sub start_pager {
 955         my ($self) = @_;
 956         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 957         chomp(my $pager = <$fh> // '');
 958         close($fh) or warn "`git var PAGER' error: \$?=$?";
 959         return if $pager eq 'cat' || $pager eq '';
 960         my $new_env = { LESS => 'FRX', LV => '-c' };
 961         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 962         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 963         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 964         my $pgr = [ undef, @$rdr{1, 2} ];
 965         my $env = $self->{env};
 966         if ($self->{sock}) { # lei(1) process runs it
 967                 delete @$new_env{keys %$env}; # only set iff unset
 968                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 969         } elsif ($self->{oneshot}) {
 970                 my $cmd = [$pager];
 971                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 972         } else {
 973                 die 'BUG: start_pager w/o socket';
 974         }
 975         $self->{1} = $wpager;
 976         $self->{2} = $wpager if -t $self->{2};
 977         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 978         $self->{pgr} = $pgr;
 979 }
 980
 981 sub stop_pager {
 982         my ($self) = @_;
 983         my $pgr = delete($self->{pgr}) or return;
 984         $self->{2} = $pgr->[2];
 985         # do not restore original stdout, just close it so we error out
 986         close(delete($self->{1})) if $self->{1};
 987 }
 988
 989 sub accept_dispatch { # Listener {post_accept} callback
 990         my ($sock) = @_; # ignore other
 991         $sock->autoflush(1);
 992         my $self = bless { sock => $sock }, __PACKAGE__;
 993         vec(my $rvec = '', fileno($sock), 1) = 1;
 994         select($rvec, undef, undef, 60) or
 995                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 996         # (4096 * 33) >MAX_ARG_STRLEN
 997         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 998         if (!defined($fds[0])) {
 999                 warn(my $msg = "recv_cmd failed: $!");
1000                 return send($sock, $msg, MSG_EOR);
1001         } else {
1002                 my $i = 0;
1003                 for my $fd (@fds) {
1004                         open($self->{$i++}, '+<&=', $fd) and next;
1005                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1006                 }
1007                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1008         }
1009         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
1010         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1011         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1012         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1013                 return send($sock, 'request command truncated', MSG_EOR);
1014         my ($argc, @argv) = split(/\0/, $buf, -1);
1015         undef $buf;
1016         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1017         if (chdir($self->{3})) {
1018                 local %ENV = %env;
1019                 $self->{env} = \%env;
1020                 eval { dispatch($self, @argv) };
1021                 send($sock, $@, MSG_EOR) if $@;
1022         } else {
1023                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1024         }
1025 }
1026
1027 sub dclose {
1028         my ($self) = @_;
1029         delete $self->{-progress};
1030         _drop_wq($self);
1031         close(delete $self->{1}) if $self->{1}; # may reap_compress
1032         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1033 }
1034
1035 # for long-running results
1036 sub event_step {
1037         my ($self) = @_;
1038         local %ENV = %{$self->{env}};
1039         my $sock = $self->{sock};
1040         local $current_lei = $self;
1041         eval {
1042                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1043                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1044                                 return if $! == EAGAIN;
1045                                 next if $! == EINTR;
1046                                 last if $! == ECONNRESET;
1047                                 die "recvmsg: $!";
1048                         }
1049                         for my $fd (@fds) {
1050                                 open my $rfh, '+<&=', $fd;
1051                         }
1052                         die "unrecognized client signal: $buf";
1053                 }
1054                 dclose($self);
1055         };
1056         if (my $err = $@) {
1057                 eval { $self->fail($err) };
1058                 dclose($self);
1059         }
1060 }
1061
1062 sub event_step_init {
1063         my ($self) = @_;
1064         return if $self->{-event_init_done}++;
1065         if (my $sock = $self->{sock}) { # using DS->EventLoop
1066                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1067         }
1068 }
1069
1070 sub noop {}
1071
1072 sub oldset { $oldset }
1073
1074 sub dump_and_clear_log {
1075         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1076                 my @pfx = @_;
1077                 unshift(@pfx, "$errors_log ") if @pfx;
1078                 warn @pfx, do { local $/; <STDIN> };
1079                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1080         }
1081 }
1082
1083 # lei(1) calls this when it can't connect
1084 sub lazy_start {
1085         my ($path, $errno, $narg) = @_;
1086         local ($errors_log, $listener);
1087         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1088         $errors_log .= 'errors.log';
1089         my $addr = pack_sockaddr_un($path);
1090         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1091         $lk->lock_acquire;
1092         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1093         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1094                 return if connect($listener, $addr); # another process won
1095                 if ($errno == ECONNREFUSED && -S $path) {
1096                         unlink($path) or die "unlink($path): $!";
1097                 }
1098         } else {
1099                 $! = $errno; # allow interpolation to stringify in die
1100                 die "connect($path): $!";
1101         }
1102         umask(077) // die("umask(077): $!");
1103         bind($listener, $addr) or die "bind($path): $!";
1104         listen($listener, 1024) or die "listen: $!";
1105         $lk->lock_release;
1106         undef $lk;
1107         my @st = stat($path) or die "stat($path): $!";
1108         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1109         local $oldset = PublicInbox::DS::block_signals();
1110         if ($narg == 5) {
1111                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1112                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1113                         require PublicInbox::CmdIPC4;
1114                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1115                         PublicInbox::CmdIPC4->can('recv_cmd4');
1116                 };
1117         }
1118         $recv_cmd or die <<"";
1119 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1120
1121         require PublicInbox::Listener;
1122         require PublicInbox::EOFpipe;
1123         (-p STDOUT) or die "E: stdout must be a pipe\n";
1124         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1125         STDIN->autoflush(1);
1126         dump_and_clear_log("from previous daemon process:\n");
1127         POSIX::setsid() > 0 or die "setsid: $!";
1128         my $pid = fork // die "fork: $!";
1129         return if $pid;
1130         $0 = "lei-daemon $path";
1131         local %PATH2CFG;
1132         $listener->blocking(0);
1133         my $exit_code;
1134         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1135         local $quit = do {
1136                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1137                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1138                 sub {
1139                         $exit_code //= shift;
1140                         my $lis = $pil or exit($exit_code);
1141                         # closing eof_w triggers \&noop wakeup
1142                         $listener = $eof_w = $pil = $path = undef;
1143                         $lis->close; # DS::close
1144                         PublicInbox::DS->SetLoopTimeout(1000);
1145                 };
1146         };
1147         my $sig = {
1148                 CHLD => \&PublicInbox::DS::enqueue_reap,
1149                 QUIT => $quit,
1150                 INT => $quit,
1151                 TERM => $quit,
1152                 HUP => \&noop,
1153                 USR1 => \&noop,
1154                 USR2 => \&noop,
1155         };
1156         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1157         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1158         undef $sig;
1159         local $SIG{PIPE} = 'IGNORE';
1160         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1161                 undef $sigfd;
1162                 PublicInbox::DS->SetLoopTimeout(5000);
1163         } else {
1164                 # wake up every second to accept signals if we don't
1165                 # have signalfd or IO::KQueue:
1166                 PublicInbox::DS::sig_setmask($oldset);
1167                 PublicInbox::DS->SetLoopTimeout(1000);
1168         }
1169         PublicInbox::DS->SetPostLoopCallback(sub {
1170                 my ($dmap, undef) = @_;
1171                 if (@st = defined($path) ? stat($path) : ()) {
1172                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1173                                 warn "$path dev/ino changed, quitting\n";
1174                                 $path = undef;
1175                         }
1176                 } elsif (defined($path)) { # ENOENT is common
1177                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1178                         undef $path;
1179                         $quit->();
1180                 }
1181                 return 1 if defined($path);
1182                 my $now = now();
1183                 my $n = 0;
1184                 for my $s (values %$dmap) {
1185                         $s->can('busy') or next;
1186                         if ($s->busy($now)) {
1187                                 ++$n;
1188                         } else {
1189                                 $s->close;
1190                         }
1191                 }
1192                 $n; # true: continue, false: stop
1193         });
1194
1195         # STDIN was redirected to /dev/null above, closing STDERR and
1196         # STDOUT will cause the calling `lei' client process to finish
1197         # reading the <$daemon> pipe.
1198         local $SIG{__WARN__} = sub {
1199                 $current_lei ? err($current_lei, @_) : warn(
1200                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1201         };
1202         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1203         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1204         # $daemon pipe to `lei' closed, main loop begins:
1205         PublicInbox::DS->EventLoop;
1206         exit($exit_code // 0);
1207 }
1208
1209 sub busy { 1 } # prevent daemon-shutdown if client is connected
1210
1211 # for users w/o Socket::Msghdr installed or Inline::C enabled
1212 sub oneshot {
1213         my ($main_pkg) = @_;
1214         my $exit = $main_pkg->can('exit'); # caller may override exit()
1215         local $quit = $exit if $exit;
1216         local %PATH2CFG;
1217         umask(077) // die("umask(077): $!");
1218         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1219         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1220         dispatch($self, @ARGV);
1221         x_it($self, $self->{child_error}) if $self->{child_error};
1222 }
1223
1224 # ensures stdout hits the FS before sock disconnects so a client
1225 # can immediately reread it
1226 sub DESTROY {
1227         my ($self) = @_;
1228         $self->{1}->autoflush(1) if $self->{1};
1229         stop_pager($self);
1230         my $err = $?;
1231         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1232         waitpid($_, 0) for keys %$oneshot_pids;
1233         $? = $err if $err; # preserve ->fail or ->x_it code
1234 }
1235
1236 sub wq_done_wait { # dwaitpid callback
1237         my ($arg, $pid) = @_;
1238         my ($wq, $lei) = @$arg;
1239         my $err_type = $lei->{-err_type};
1240         $? and $lei->child_error($?,
1241                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1242         $lei->dclose;
1243 }
1244
1245 sub wq_eof { # EOF callback for main daemon
1246         my ($lei) = @_;
1247         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1248         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1249 }
1250
1251 1;