lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use PublicInbox::Import;
  28 use PublicInbox::ContentHash qw(git_sha);
  29 use Time::HiRes qw(stat); # ctime comparisons for config cache
  30 use File::Path qw(mkpath);
  31 use File::Spec;
  32 use Sys::Syslog qw(openlog syslog closelog);
  33 our $quit = \&CORE::exit;
  34 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  35         $recv_cmd, $send_cmd);
  36 my $GLP = Getopt::Long::Parser->new;
  37 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  38 my $GLP_PASS = Getopt::Long::Parser->new;
  39 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  40
  41 our %PATH2CFG; # persistent for socket daemon
  42 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  43
  44 # TBD: this is a documentation mechanism to show a subcommand
  45 # (may) pass options through to another command:
  46 sub pass_through { $GLP_PASS }
  47
  48 my $OPT;
  49 sub opt_dash ($$) {
  50         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  51         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  52         my $cb = sub { # Getopt::Long "<>" catch-all handler
  53                 my ($arg) = @_;
  54                 if ($arg =~ /\A-($re_str)\z/) {
  55                         $OPT->{$key} = $1;
  56                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  57                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  58                 # lone (single) dash is handled elsewhere
  59                 } elsif (substr($arg, 0, 1) eq '-') {
  60                         if ($OPT->{'--'}) {
  61                                 push @{$OPT->{-argv}}, $arg;
  62                         } else {
  63                                 die "bad argument: $arg\n";
  64                         }
  65                 } else {
  66                         push @{$OPT->{-argv}}, $arg;
  67                 }
  68         };
  69         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  70 }
  71
  72 # rel2abs preserves symlinks in parent, unlike abs_path
  73 sub rel2abs {
  74         my ($self, $p) = @_;
  75         if (index($p, '/') == 0) { # already absolute
  76                 $p =~ tr!/!/!s; # squeeze redundant slashes
  77                 chop($p) if substr($p, -1, 1) eq '/';
  78                 return $p;
  79         }
  80         my $pwd = $self->{env}->{PWD};
  81         my $cwd;
  82         if (defined $pwd) {
  83                 my $xcwd = $self->{3} //
  84                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  85                 if (my @st_pwd = stat($pwd)) {
  86                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  87                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  88                                 $self->{env}->{PWD} = $pwd = undef;
  89                 } else { # PWD was invalid
  90                         $self->{env}->{PWD} = $pwd = undef;
  91                 }
  92         }
  93         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  94         File::Spec->rel2abs($p, $pwd);
  95 }
  96
  97 # abs_path resolves symlinks in parent iff all parents exist
  98 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  99
 100 sub canonpath_harder {
 101         my $p = $_[-1]; # $_[0] may be self
 102         $p = File::Spec->canonpath($p);
 103         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 104 }
 105
 106 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 107         my ($self) = @_;
 108         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 109                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 110                 .'/lei');
 111 }
 112
 113 sub store_path ($) { share_path($_[0]) . '/store' }
 114
 115 sub _config_path ($) {
 116         my ($self) = @_;
 117         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 118                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 119                 .'/lei/config');
 120 }
 121
 122 sub cache_dir ($) {
 123         my ($self) = @_;
 124         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 125                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 126                 .'/lei');
 127 }
 128
 129 sub url_folder_cache {
 130         my ($self) = @_;
 131         require PublicInbox::SharedKV; # URI => updated_at_sec_
 132         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 133 }
 134
 135 sub ale {
 136         my ($self) = @_;
 137         $self->{ale} //= do {
 138                 require PublicInbox::LeiALE;
 139                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 140         };
 141 }
 142
 143 sub index_opt {
 144         # TODO: drop underscore variants everywhere, they're undocumented
 145         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 146         max_size|max-size=s sequential-shard
 147         batch_size|batch-size=s skip-docdata)
 148 }
 149
 150 my @c_opt = qw(c=s@ C=s@ quiet|q);
 151 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 152 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 153         import-remote!);
 154
 155 # we don't support -C as an alias for --find-copies since it's already
 156 # used for chdir
 157 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 158         output-indicator-context=s indent-heuristic!
 159         minimal patience histogram anchored=s@ diff-algorithm=s
 160         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 161         word-diff:s word-diff-regex=s color-words:s no-renames
 162         rename-empty! check ws-error-highlight=s full-index binary
 163         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 164         find-copies-harder irreversible-delete|D l=i diff-filter=s
 165         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 166         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 167         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 168         inter-hunk-context=i function-context|W exit-code ext-diff
 169         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 170         line-prefix=s);
 171
 172 # we generate shell completion + help using %CMD and %OPTDESC,
 173 # see lei__complete() and PublicInbox::LeiHelp
 174 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 175 our %CMD = ( # sorted in order of importance/use:
 176 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 177         'stdin|', # /|\z/ must be first for lone dash
 178         @lxs_opt, @net_opt,
 179         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 180         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 181         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 182         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 183
 184 'up' => [ 'OUTPUT...|--all', 'update saved search',
 185         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+
 186         remote-fudge-time=s all:s), @c_opt ],
 187
 188 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 189         'stdin|', # /|\z/ must be first for lone dash
 190         # some of these options are ridiculous for lcat
 191         @lxs_opt, @net_opt,
 192         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 193         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 194         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 195         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 196
 197 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 198         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 199         @lxs_opt, @net_opt, @c_opt ],
 200
 201 'rediff' => [ '--stdin|LOCATION...',
 202                 'regenerate a diff with different options',
 203         'stdin|', # /|\z/ must be first for lone dash
 204         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 205         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 206
 207 'add-external' => [ 'LOCATION',
 208         'add/set priority of a publicinbox|extindex for extra matches',
 209         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 210         @c_opt, index_opt(), @net_opt ],
 211 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 212         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 213 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 214 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 215                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 216 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 217                 qw(z|0 ascii l pretty url), @c_opt ],
 218 'forget-external' => [ 'LOCATION...|--prune',
 219         'exclude further results from a publicinbox|extindex',
 220         qw(prune), @c_opt ],
 221
 222 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 223                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 224 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 225                 qw(verbose|v+), @c_opt ],
 226 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 227                         @c_opt ],
 228 'rm' => [ '--stdin|LOCATION...',
 229         'remove a message from the index and prevent reindexing',
 230         'stdin|', # /|\z/ must be first for lone dash
 231         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 232 'plonk' => [ '--threads|--from=IDENT',
 233         'exclude mail matching From: or threads from non-Message-ID searches',
 234         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 235 'tag' => [ 'KEYWORDS...',
 236         'set/unset keywords and/or labels on message(s)',
 237         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 238         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 239
 240 'purge-mailsource' => [ 'LOCATION|--all',
 241         'remove imported messages from IMAP, Maildirs, and MH',
 242         qw(exact! all jobs:i indexed), @c_opt ],
 243
 244 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 245         qw(poll-interval=s state=s recursive|r), @c_opt ],
 246 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 247         qw(recursive|r), @c_opt ],
 248 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 249                 qw(l z|0), @c_opt ],
 250 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 251 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 252 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 253         qw(prune), @c_opt ],
 254
 255 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 256         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 257         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 258          @c_opt ],
 259 'import' => [ 'LOCATION...|--stdin',
 260         'one-time import/update from URL or filesystem',
 261         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 262         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 263         @net_opt, @c_opt ],
 264 'forget-mail-sync' => [ 'LOCATION...',
 265         'forget sync information for a mail folder', @c_opt ],
 266 'refresh-mail-sync' => [ 'LOCATION...|--all',
 267         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 268 'export-kw' => [ 'LOCATION...|--all',
 269         'one-time export of keywords of sync sources',
 270         qw(all:s mode=s), @net_opt, @c_opt ],
 271 'convert' => [ 'LOCATION...|--stdin',
 272         'one-time conversion from URL or filesystem to another format',
 273         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 274         @net_opt, @c_opt ],
 275 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 276         "use a patch to generate a query for `lei q --stdin'",
 277         qw(stdin| want|w=s@ uri debug), @c_opt ],
 278 'config' => [ '[...]', sub {
 279                 'git-config(1) wrapper for '._config_path($_[0]);
 280         }, qw(config-file|system|global|file|f=s), # for conflict detection
 281          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 282 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 283         qw(stdin| pretty ascii dir=s), @c_opt ],
 284
 285 'init' => [ '[DIRNAME]', sub {
 286         "initialize storage, default: ".store_path($_[0]);
 287         }, @c_opt ],
 288 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 289         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 290         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 291 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 292 'help' => [ '[SUBCOMMAND]', 'show help' ],
 293
 294 # TODO
 295 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 296 #       'rewrite git history in an attempt to improve compression',
 297 #       qw(gc!), @c_opt ],
 298 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 299 #
 300 # internal commands are prefixed with '_'
 301 '_complete' => [ '[...]', 'internal shell completion helper',
 302                 pass_through('everything') ],
 303 ); # @CMD
 304
 305 # switch descriptions, try to keep consistent across commands
 306 # $spec: Getopt::Long option specification
 307 # $spec => [@ALLOWED_VALUES (default is first), $description],
 308 # $spec => $description
 309 # "$SUB_COMMAND TAB $spec" => as above
 310 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 311                         'specify message input format' ];
 312 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 313
 314 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 315 my %OPTDESC = (
 316 'help|h' => 'show this built-in help',
 317 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 318 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 319 'quiet|q' => 'be quiet',
 320 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 321         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 322
 323 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 324 'globoff|g' => "do not match locations using '*?' wildcards ".
 325                 "and\xa0'[]'\x{a0}ranges",
 326 'invert-match|v' => 'select non-matching lines',
 327 'color!' => 'disable color (for --format=text)',
 328 'verbose|v+' => 'be more verbose',
 329 'external!' => 'do not use externals',
 330 'mail!' => 'do not look in mail storage for OID',
 331 'cwd!' => 'do not look in git repo of current working directory',
 332 'oid-a|A=s' => 'pre-image OID',
 333 'path-a|a=s' => 'pre-image pathname associated with OID',
 334 'path-b|b=s' => 'post-image pathname associated with OID',
 335 'git-dir=s@' => 'additional git repository to scan',
 336 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 337 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 338         "proxy for (e.g. `socks5h://0:9050')" ],
 339 'torsocks=s' => ['VAL|auto|no|yes',
 340                 'whether or not to wrap git and curl commands with torsocks'],
 341 'no-torsocks' => 'alias for --torsocks=no',
 342 'save!' =>  "do not save a search for `lei up'",
 343 'import-remote!' => 'do not memoize remote messages into local store',
 344
 345 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 346
 347 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 348                 'deduplication strategy'],
 349 'threads|t+' =>
 350         'return all messages in the same threads as the actual match(es)',
 351
 352 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 353                 'search prefixes to extract (default: dfpost7)' ],
 354
 355 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 356         'run command(s) or perform ops when done writing to output ' .
 357         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 358         'nothing otherwise)' ],
 359
 360 'augment|a' => 'augment --output destination instead of clobbering',
 361
 362 'output|mfolder|o=s' => [ 'MFOLDER',
 363         "destination (e.g.\xa0`/path/to/Maildir', ".
 364         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 365 'mua=s' => [ 'CMD',
 366         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 367 'new-only       import' => 'only import new messages from IMAP source',
 368
 369 'inbox-version=i' => [ 'NUM|1|2',
 370                 'force a public-inbox version with --mirror'],
 371 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 372
 373 # public-inbox-index options
 374 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 375 'compact' => 'run compact index after mirroring',
 376 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 377         "indexlevel with --mirror (default: full)" ],
 378 'max_size|max-size=s' => [ 'SIZE',
 379         'do not index messages larger than SIZE (default: infinity)' ],
 380 'batch_size|batch-size=s' => [ 'SIZE',
 381         'flush changes to OS after given number of bytes (default: 1m)' ],
 382 'sequential-shard' =>
 383         'index Xapian shards sequentially for slow storage',
 384 'skip-docdata' =>
 385         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 386
 387 'format|f=s     q' => [
 388         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 389                 'specify output format, default depends on --output'],
 390 'exclude=s@     q' => [ 'LOCATION',
 391                 'exclude specified external(s) from search' ],
 392 'include|I=s@   q' => [ 'LOCATION',
 393                 'include specified external(s) in search' ],
 394 'only=s@        q' => [ 'LOCATION',
 395                 'only use specified external(s) for search' ],
 396 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 397                 'control number of search and writer jobs' ],
 398 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 399
 400 'in-format|F=s' => $stdin_formats,
 401 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 402                         'listing output format' ],
 403 'l      ls-search' => 'long listing format',
 404 'l      ls-watch' => 'long listing format',
 405 'l      ls-mail-source' => 'long listing format',
 406 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 407 'format|f=s     ls-external' => $ls_format,
 408
 409 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 410 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 411
 412 'sort|s=s' => [ 'VAL|received|relevance|docid',
 413                 "order of results is `--output'-dependent"],
 414 'reverse|r' => 'reverse search results', # like sort(1)
 415
 416 'boost=i' => 'increase/decrease priority of results (default: 0)',
 417
 418 'local' => 'limit operations to the local filesystem',
 419 'local!' => 'exclude results from the local filesystem',
 420 'remote' => 'limit operations to those requiring network access',
 421 'remote!' => 'prevent operations requiring network access',
 422
 423 # up, refresh-mail-sync, export-kw
 424 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 425
 426 'remote-fudge-time=s' => [ 'INTERVAL',
 427         'look for mail INTERVAL older than the last successful query' ],
 428
 429 'mid=s' => 'specify the Message-ID of a message',
 430 'oid=s' => 'specify the git object ID of a message',
 431
 432 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 433 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 434 'include=s' => 'include mailboxes/newsgroups based on pattern',
 435
 436 'exact' => 'operate on exact header matches only',
 437 'exact!' => 'rely on content match instead of exact header matches',
 438
 439 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 440
 441 'kw!' => 'disable/enable importing keywords (aka "flags")',
 442
 443 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 444 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 445
 446 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 447 ); # %OPTDESC
 448
 449 my %CONFIG_KEYS = (
 450         'leistore.dir' => 'top-level storage location',
 451 );
 452
 453 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 454
 455 sub _drop_wq {
 456         my ($self) = @_;
 457         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 458                 if ($wq->wq_kill) {
 459                         $wq->wq_close(0, undef, $self);
 460                 } elsif ($wq->wq_kill_old) {
 461                         $wq->wq_wait_old(undef, $self);
 462                 }
 463                 $wq->DESTROY;
 464         }
 465 }
 466
 467 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 468 sub x_it ($$) {
 469         my ($self, $code) = @_;
 470         # make sure client sees stdout before exit
 471         $self->{1}->autoflush(1) if $self->{1};
 472         stop_pager($self);
 473         if ($self->{pkt_op_p}) { # worker => lei-daemon
 474                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 475         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 476                 send($self->{sock}, "x_it $code", MSG_EOR);
 477         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 478                 exit($code >> 8);
 479         } # else ignore if client disconnected
 480 }
 481
 482 sub err ($;@) {
 483         my $self = shift;
 484         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 485         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 486         print $err @_, @eor and return;
 487         my $old_err = delete $self->{2};
 488         close($old_err) if $! == EPIPE && $old_err;
 489         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 490         print $err @_, @eor or print STDERR @_, @eor;
 491 }
 492
 493 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 494
 495 sub qfin { # show message on finalization (LeiFinmsg)
 496         my ($lei, $msg) = @_;
 497         return if $lei->{opt}->{quiet};
 498         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 499 }
 500
 501 sub fail_handler ($;$$) {
 502         my ($lei, $code, $io) = @_;
 503         close($io) if $io; # needed to avoid warnings on SIGPIPE
 504         _drop_wq($lei);
 505         x_it($lei, $code // (1 << 8));
 506 }
 507
 508 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 509         fail_handler($_[0], 13, delete $_[0]->{1});
 510 }
 511
 512 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 513 sub sigint_reap {
 514         my ($pgid) = @_;
 515         dwaitpid($pgid) if kill('-INT', $pgid);
 516 }
 517
 518 sub fail ($$;$) {
 519         my ($self, $buf, $exit_code) = @_;
 520         $self->{failed}++;
 521         err($self, $buf) if defined $buf;
 522         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 523         x_it($self, ($exit_code // 1) << 8);
 524         undef;
 525 }
 526
 527 sub out ($;@) {
 528         my $self = shift;
 529         return if print { $self->{1} // return } @_; # likely
 530         return note_sigpipe($self, 1) if $! == EPIPE;
 531         my $err = "error writing to output: $!";
 532         delete $self->{1};
 533         fail($self, $err);
 534 }
 535
 536 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 537
 538 sub child_error { # passes non-fatal curl exit codes to user
 539         my ($self, $child_error, $msg) = @_; # child_error is $?
 540         $child_error ||= 1 << 8;
 541         $self->err($msg) if $msg;
 542         if ($self->{pkt_op_p}) { # to top lei-daemon
 543                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 544         } elsif ($self->{sock}) { # to lei(1) client
 545                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 546         } else { # non-lei admin command
 547                 $self->{child_error} ||= $child_error;
 548         } # else noop if client disconnected
 549 }
 550
 551 sub note_sigpipe { # triggers sigpipe_handler
 552         my ($self, $fd) = @_;
 553         close(delete($self->{$fd})); # explicit close silences Perl warning
 554         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 555         x_it($self, 13);
 556 }
 557
 558 sub _lei_atfork_child {
 559         my ($self, $persist) = @_;
 560         # we need to explicitly close things which are on stack
 561         if ($persist) {
 562                 chdir '/' or die "chdir(/): $!";
 563                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 564                 if (my $cfg = $self->{cfg}) {
 565                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 566                 }
 567         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 568                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 569                 STDERR->autoflush(1);
 570         }
 571         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 572         if (my $op_c = delete $self->{pkt_op_c}) {
 573                 close(delete $op_c->{sock});
 574         }
 575         if (my $pgr = delete $self->{pgr}) {
 576                 close($_) for (@$pgr[1,2]);
 577         }
 578         close $listener if $listener;
 579         undef $listener;
 580         $dir_idle->force_close if $dir_idle;
 581         undef $dir_idle;
 582         %PATH2CFG = ();
 583         $MDIR2CFGPATH = {};
 584         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 585         undef $errors_log;
 586         $quit = \&CORE::exit;
 587         $self->{-eml_noisy} or # only "lei import" sets this atm
 588                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 589         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 590 }
 591
 592 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 593         my ($self) = @_;
 594         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 595                 $op->close; # PublicInbox::PktOp::close
 596         }
 597         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 598         close $pkt_op_p->{op_p};
 599 }
 600
 601 sub pkt_op_pair {
 602         my ($self) = @_;
 603         require PublicInbox::OnDestroy;
 604         require PublicInbox::PktOp;
 605         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 606         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 607         $end;
 608 }
 609
 610 sub incr {
 611         my ($self, $field, $nr) = @_;
 612         $self->{counters}->{$field} += $nr;
 613 }
 614
 615 sub pkt_ops {
 616         my ($lei, $ops) = @_;
 617         $ops->{fail_handler} = [ $lei ];
 618         $ops->{sigpipe_handler} = [ $lei ];
 619         $ops->{x_it} = [ $lei ];
 620         $ops->{child_error} = [ $lei ];
 621         $ops->{incr} = [ $lei ];
 622         $ops;
 623 }
 624
 625 sub workers_start {
 626         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 627         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 628         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 629         my $end = $lei->pkt_op_pair;
 630         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 631         $flds->{lei} = $lei;
 632         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 633         delete $lei->{pkt_op_p};
 634         my $op_c = delete $lei->{pkt_op_c};
 635         @$end = ();
 636         $lei->event_step_init;
 637         ($op_c, $ops);
 638 }
 639
 640 # call this when we're ready to wait on events and yield to other clients
 641 sub wait_wq_events {
 642         my ($lei, $op_c, $ops) = @_;
 643         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 644                 $wq->wq_close(1);
 645         }
 646         $op_c->{ops} = $ops;
 647 }
 648
 649 sub _help {
 650         require PublicInbox::LeiHelp;
 651         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 652 }
 653
 654 sub optparse ($$$) {
 655         my ($self, $cmd, $argv) = @_;
 656         # allow _complete --help to complete, not show help
 657         return 1 if substr($cmd, 0, 1) eq '_';
 658         $self->{cmd} = $cmd;
 659         $OPT = $self->{opt} //= {};
 660         my $info = $CMD{$cmd} // [ '[...]' ];
 661         my ($proto, undef, @spec) = @$info;
 662         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 663         push @spec, qw(help|h);
 664         my $lone_dash;
 665         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 666                 $lone_dash = $spec[0];
 667                 $OPT->{$spec[0]} = \(my $var);
 668                 push @spec, '' => \$var;
 669         }
 670         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 671                 return _help($self, "bad arguments or options for $cmd");
 672         return _help($self) if $OPT->{help};
 673
 674         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 675
 676         # "-" aliases "stdin" or "clear"
 677         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 678
 679         my $i = 0;
 680         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 681         my ($err, $inf);
 682         my @args = split(/ /, $proto);
 683         for my $var (@args) {
 684                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 685                         $inf = defined($argv->[$i]) and last;
 686                         $var =~ s/\.\.\.\z//;
 687                         $err = "$var not supplied";
 688                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 689                         $argv->[$i++] // ($err = "$var not supplied");
 690                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 691                         $inf = 1;
 692                         last;
 693                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 694                         $i++;
 695                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 696                         $inf = 1 if index($var, '...') > 0;
 697                         my @or = split(/\|/, $var);
 698                         my $ok;
 699                         for my $o (@or) {
 700                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 701                                         my $sw = $1;
 702                                         # assume pipe/regular file on stdin
 703                                         # w/o args means stdin
 704                                         if ($sw eq 'stdin' && !@$argv &&
 705                                                         (-p $self->{0} ||
 706                                                          -f _) && -r _) {
 707                                                 $OPT->{stdin} //= 1;
 708                                         }
 709                                         $ok = defined($OPT->{$sw});
 710                                         last if $ok;
 711                                 } elsif (defined($argv->[$i])) {
 712                                         $ok = 1;
 713                                         $i++;
 714                                         last;
 715                                 } # else continue looping
 716                         }
 717                         last if $ok;
 718                         my $last = pop @or;
 719                         $err = join(', ', @or) . " or $last must be set";
 720                 } else {
 721                         warn "BUG: can't parse `$var' in $proto";
 722                 }
 723                 last if $err;
 724         }
 725         if (!$inf && scalar(@$argv) > scalar(@args)) {
 726                 $err //= 'too many arguments';
 727         }
 728         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 729 }
 730
 731 sub _tmp_cfg { # for lei -c <name>=<value> ...
 732         my ($self) = @_;
 733         my $cfg = _lei_cfg($self, 1);
 734         require File::Temp;
 735         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 736         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 737         $ft->autoflush(1);
 738         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 739 [include]
 740         path = $cfg->{-f}
 741 EOM
 742         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 743         for (@{$self->{opt}->{c}}) {
 744                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 745 `-c $_' is not of the form -c <name>=<value>'
 746 EOM
 747                 my $name = $1;
 748                 my $value = $2 // 1;
 749                 _config($self, '--add', $name, $value);
 750                 if (defined(my $v = $tmp->{$name})) {
 751                         if (ref($v) eq 'ARRAY') {
 752                                 push @$v, $value;
 753                         } else {
 754                                 $tmp->{$name} = [ $v, $value ];
 755                         }
 756                 } else {
 757                         $tmp->{$name} = $value;
 758                 }
 759         }
 760 }
 761
 762 sub lazy_cb ($$$) {
 763         my ($self, $cmd, $pfx) = @_;
 764         my $ucmd = $cmd;
 765         $ucmd =~ tr/-/_/;
 766         my $cb;
 767         $cb = $self->can($pfx.$ucmd) and return $cb;
 768         my $base = $ucmd;
 769         $base =~ s/_([a-z])/\u$1/g;
 770         my $pkg = "PublicInbox::Lei\u$base";
 771         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 772                 $pkg->can($pfx.$ucmd) : undef;
 773 }
 774
 775 sub dispatch {
 776         my ($self, $cmd, @argv) = @_;
 777         fchdir($self) or return;
 778         local %ENV = %{$self->{env}};
 779         local $current_lei = $self; # for __WARN__
 780         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 781         return _help($self, 'no command given') unless defined($cmd);
 782         # do not support Getopt bundling for this
 783         while ($cmd eq '-C' || $cmd eq '-c') {
 784                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 785                                         '-C DIRECTORY' : '-c <name>=<value>');
 786                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 787                 $cmd = shift(@argv) // return _help($self, 'no command given');
 788         }
 789         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 790                 optparse($self, $cmd, \@argv) or return;
 791                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 792                 if (my $chdir = $self->{opt}->{C}) {
 793                         for my $d (@$chdir) {
 794                                 next if $d eq ''; # same as git(1)
 795                                 chdir $d or return fail($self, "cd $d: $!");
 796                         }
 797                         open $self->{3}, '.' or return fail($self, "open . $!");
 798                 }
 799                 $cb->($self, @argv);
 800         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 801                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 802                         or return _help($self, 'bad arguments or options');
 803                 _help($self);
 804         } else {
 805                 fail($self, "`$cmd' is not an lei command");
 806         }
 807 }
 808
 809 sub _lei_cfg ($;$) {
 810         my ($self, $creat) = @_;
 811         return $self->{cfg} if $self->{cfg};
 812         my $f = _config_path($self);
 813         my @st = stat($f);
 814         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 815         my ($sto, $sto_dir, $watches, $lne);
 816         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 817                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 818                 ($sto, $sto_dir, $watches, $lne) =
 819                                 @$cfg{qw(-lei_store leistore.dir -watches
 820                                         -lei_note_event)};
 821         }
 822         if (!@st) {
 823                 unless ($creat) {
 824                         delete $self->{cfg};
 825                         return bless {}, 'PublicInbox::Config';
 826                 }
 827                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 828                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 829                 open my $fh, '>>', $f or die "open($f): $!\n";
 830                 @st = stat($fh) or die "fstat($f): $!\n";
 831                 $cur_st = pack('dd', $st[10], $st[7]);
 832                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 833         }
 834         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 835         $cfg->{-st} = $cur_st;
 836         $cfg->{'-f'} = $f;
 837         if ($sto && canonpath_harder($sto_dir // store_path($self))
 838                         eq canonpath_harder($cfg->{'leistore.dir'} //
 839                                                 store_path($self))) {
 840                 $cfg->{-lei_store} = $sto;
 841                 $cfg->{-lei_note_event} = $lne;
 842                 $cfg->{-watches} = $watches if $watches;
 843         }
 844         if (scalar(keys %PATH2CFG) > 5) {
 845                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 846                 for my $k (keys %PATH2CFG) {
 847                         delete($PATH2CFG{$k}) unless -f $k
 848                 }
 849         }
 850         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 851         refresh_watches($self);
 852         $cfg;
 853 }
 854
 855 sub _lei_store ($;$) {
 856         my ($self, $creat) = @_;
 857         my $cfg = _lei_cfg($self, $creat) // return;
 858         $cfg->{-lei_store} //= do {
 859                 require PublicInbox::LeiStore;
 860                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 861                 return unless $creat || -d $dir;
 862                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 863         };
 864 }
 865
 866 sub _config {
 867         my ($self, @argv) = @_;
 868         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 869         my $cfg = _lei_cfg($self, 1);
 870         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 871         my %rdr = map { $_ => $self->{$_} } (0..2);
 872         waitpid(spawn($cmd, \%env, \%rdr), 0);
 873 }
 874
 875 sub lei_daemon_pid { puts shift, $$ }
 876
 877 sub lei_daemon_kill {
 878         my ($self) = @_;
 879         my $sig = $self->{opt}->{signal} // 'TERM';
 880         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 881 }
 882
 883 # Shell completion helper.  Used by lei-completion.bash and hopefully
 884 # other shells.  Try to do as much here as possible to avoid redundancy
 885 # and improve maintainability.
 886 sub lei__complete {
 887         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 888         shift @argv; # ignore "lei", the entire command is sent
 889         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 890         my $cmd = shift @argv;
 891         my $info = $CMD{$cmd} // do { # filter matching commands
 892                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 893                 return;
 894         };
 895         my ($proto, undef, @spec) = @$info;
 896         my $cur = pop @argv;
 897         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 898         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 899                 # gross special case since the only git-config options
 900                 # Consider moving to a table if we need more special cases
 901                 # we use Getopt::Long for are the ones we reject, so these
 902                 # are the ones we don't reject:
 903                 if ($cmd eq 'config') {
 904                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 905                         @spec = qw(add z|null get get-all unset unset-all
 906                                 replace-all get-urlmatch
 907                                 remove-section rename-section
 908                                 name-only list|l edit|e
 909                                 get-color-name get-colorbool);
 910                         # fall-through
 911                 }
 912                 # generate short/long names from Getopt::Long specs
 913                 puts $self, grep(/$re/, qw(--help -h -C), map {
 914                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 915                         } elsif (s/\+\z//) { # verbose|v+
 916                         } elsif (s/!\z//) {
 917                                 # negation: mail! => no-mail|mail
 918                                 s/([\w\-]+)/$1|no-$1/g
 919                         }
 920                         map {
 921                                 my $x = length > 1 ? "--$_" : "-$_";
 922                                 $x eq $_cur ? () : $x;
 923                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 924                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 925         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 926                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 927         }
 928
 929         # switch args (e.g. lei q -f mbox<TAB>)
 930         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 931                 my $opt = quotemeta $1;
 932                 puts $self, map {
 933                         my $v = $OPTDESC{$_};
 934                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 935                         # get rid of ALL CAPS placeholder (e.g "OUT")
 936                         # (TODO: completion for external paths)
 937                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 938                         @v;
 939                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 940         }
 941         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 942                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 943         }
 944         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 945         # proto parsing.
 946 }
 947
 948 sub exec_buf ($$) {
 949         my ($argv, $env) = @_;
 950         my $argc = scalar @$argv;
 951         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 952         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 953         $buf;
 954 }
 955
 956 sub start_mua {
 957         my ($self) = @_;
 958         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 959                 refresh_watches($self);
 960         }
 961         my $mua = $self->{opt}->{mua} // return;
 962         my $mfolder = $self->{ovv}->{dst};
 963         my (@cmd, $replaced);
 964         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 965                 @cmd = ($mua, '-f');
 966         # TODO: help wanted: other common FOSS MUAs
 967         } else {
 968                 require Text::ParseWords;
 969                 @cmd = Text::ParseWords::shellwords($mua);
 970                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 971                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 972         }
 973         push @cmd, $mfolder unless defined($replaced);
 974         if ($self->{sock}) { # lei(1) client process runs it
 975                 # restore terminal: echo $query | lei q --stdin --mua=...
 976                 my $io = [];
 977                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 978                 send_exec_cmd($self, $io, \@cmd, {});
 979         }
 980         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 981                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 982         }
 983         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 984         $self->{opt}->{quiet} = 1;
 985         delete $self->{-progress};
 986         delete $self->{opt}->{verbose};
 987 }
 988
 989 sub send_exec_cmd { # tell script/lei to execute a command
 990         my ($self, $io, $cmd, $env) = @_;
 991         my $sock = $self->{sock} // die 'lei client gone';
 992         my $fds = [ map { fileno($_) } @$io ];
 993         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 994 }
 995
 996 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 997         my ($self) = @_;
 998         my $alerts = $self->{opt}->{alert} // return;
 999         my $sock = $self->{sock};
1000         while (my $op = shift(@$alerts)) {
1001                 if ($op eq ':WINCH') {
1002                         # hit the process group that started the MUA
1003                         send($sock, '-WINCH', MSG_EOR) if $sock;
1004                 } elsif ($op eq ':bell') {
1005                         out($self, "\a");
1006                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1007                         push @$alerts, split(/(?<!\\),/, $op);
1008                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1009                         my $cmd = $1; # run an arbitrary command
1010                         require Text::ParseWords;
1011                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1012                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1013                 } else {
1014                         err($self, "W: unsupported --alert=$op"); # non-fatal
1015                 }
1016         }
1017 }
1018
1019 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1020 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1021
1022 # this also normalizes the path
1023 sub path_to_fd {
1024         my ($self, $path) = @_;
1025         $path = rel2abs($self, $path);
1026         $path =~ tr!/!/!s;
1027         $path_to_fd{$path} // (
1028                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1029                         fail($self, "cannot open $path from daemon") : -1
1030         );
1031 }
1032
1033 # caller needs to "-t $self->{1}" to check if tty
1034 sub start_pager {
1035         my ($self, $new_env) = @_;
1036         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1037         chomp(my $pager = <$fh> // '');
1038         close($fh) or warn "`git var PAGER' error: \$?=$?";
1039         return if $pager eq 'cat' || $pager eq '';
1040         $new_env //= {};
1041         $new_env->{LESS} //= 'FRX';
1042         $new_env->{LV} //= '-c';
1043         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1044         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1045         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1046         my $pgr = [ undef, @$rdr{1, 2} ];
1047         my $env = $self->{env};
1048         if ($self->{sock}) { # lei(1) process runs it
1049                 delete @$new_env{keys %$env}; # only set iff unset
1050                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1051         } else {
1052                 die 'BUG: start_pager w/o socket';
1053         }
1054         $self->{1} = $wpager;
1055         $self->{2} = $wpager if -t $self->{2};
1056         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1057         $self->{pgr} = $pgr;
1058 }
1059
1060 # display a message for user before spawning full-screen $VISUAL
1061 sub pgr_err {
1062         my ($self, @msg) = @_;
1063         return $self->err(@msg) unless $self->{sock} && -t $self->{2};
1064         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1065         print { $self->{2} } @msg;
1066         $self->{2}->autoflush(1);
1067         stop_pager($self);
1068         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1069 }
1070
1071 sub stop_pager {
1072         my ($self) = @_;
1073         my $pgr = delete($self->{pgr}) or return;
1074         $self->{2} = $pgr->[2];
1075         close(delete($self->{1})) if $self->{1};
1076         $self->{1} = $pgr->[1];
1077 }
1078
1079 sub accept_dispatch { # Listener {post_accept} callback
1080         my ($sock) = @_; # ignore other
1081         $sock->autoflush(1);
1082         my $self = bless { sock => $sock }, __PACKAGE__;
1083         vec(my $rvec = '', fileno($sock), 1) = 1;
1084         select($rvec, undef, undef, 60) or
1085                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1086         # (4096 * 33) >MAX_ARG_STRLEN
1087         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1088         if (!defined($fds[0])) {
1089                 warn(my $msg = "recv_cmd failed: $!");
1090                 return send($sock, $msg, MSG_EOR);
1091         } else {
1092                 my $i = 0;
1093                 for my $fd (@fds) {
1094                         open($self->{$i++}, '+<&=', $fd) and next;
1095                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1096                 }
1097                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1098         }
1099         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1100         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1101         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1102                 return send($sock, 'request command truncated', MSG_EOR);
1103         my ($argc, @argv) = split(/\0/, $buf, -1);
1104         undef $buf;
1105         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1106         $self->{env} = \%env;
1107         eval { dispatch($self, @argv) };
1108         send($sock, $@, MSG_EOR) if $@;
1109 }
1110
1111 sub dclose {
1112         my ($self) = @_;
1113         delete $self->{-progress};
1114         _drop_wq($self) if $self->{failed};
1115         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1116 }
1117
1118 # for long-running results
1119 sub event_step {
1120         my ($self) = @_;
1121         local %ENV = %{$self->{env}};
1122         local $current_lei = $self;
1123         eval {
1124                 my $buf;
1125                 while (my @fds = $recv_cmd->($self->{sock}, $buf, 4096)) {
1126                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1127                                 return if $! == EAGAIN;
1128                                 next if $! == EINTR;
1129                                 last if $! == ECONNRESET;
1130                                 die "recvmsg: $!";
1131                         }
1132                         for (@fds) { open my $rfh, '+<&=', $_ }
1133                 }
1134                 if ($buf eq '') {
1135                         _drop_wq($self); # EOF, client disconnected
1136                         dclose($self);
1137                 } elsif ($buf =~ /\A(STOP|CONT)\z/) {
1138                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1139                                 $wq->wq_kill($buf) or $wq->wq_kill_old($buf);
1140                         }
1141                 } else {
1142                         die "unrecognized client signal: $buf";
1143                 }
1144         };
1145         if (my $err = $@) {
1146                 eval { $self->fail($err) };
1147                 dclose($self);
1148         }
1149 }
1150
1151 sub event_step_init {
1152         my ($self) = @_;
1153         my $sock = $self->{sock} or return;
1154         $self->{-event_init_done} //= do { # persist til $ops done
1155                 $sock->blocking(0);
1156                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1157                 $sock;
1158         };
1159 }
1160
1161 sub noop {}
1162
1163 sub oldset { $oldset }
1164
1165 sub dump_and_clear_log {
1166         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1167                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1168                 chomp(my @lines = <STDIN>);
1169                 truncate(STDIN, 0) or
1170                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1171                 for my $l (@lines) { syslog('warning', '%s', $l) }
1172                 closelog(); # don't share across fork
1173         }
1174 }
1175
1176 sub cfg2lei ($) {
1177         my ($cfg) = @_;
1178         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1179         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1180         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1181         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1182         open($lei->{3}, '/') or die "open /: $!";
1183         my ($x, $y);
1184         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1185         $lei->{sock} = $x;
1186         require PublicInbox::LeiSelfSocket;
1187         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1188         $lei;
1189 }
1190
1191 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1192         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1193         my $fn = $ev->fullname;
1194         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1195                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1196                 $nc = '' if $ev->IN_DELETE;
1197                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1198                         my $cfg = $PATH2CFG{$f} // next;
1199                         eval {
1200                                 my $lei = cfg2lei($cfg);
1201                                 $lei->dispatch('note-event',
1202                                                 "maildir:$mdir", $nc, $bn, $fn);
1203                         };
1204                         warn "E: note-event $f: $@\n" if $@;
1205                 }
1206         }
1207         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1208                 $ev->cancel;
1209         }
1210         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1211                 delete $MDIR2CFGPATH->{$1};
1212         }
1213         if (!-e $fn) { # config file or Maildir gone
1214                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1215                         delete $cfgpaths->{$fn};
1216                 }
1217                 delete $PATH2CFG{$fn};
1218         }
1219 }
1220
1221 # lei(1) calls this when it can't connect
1222 sub lazy_start {
1223         my ($path, $errno, $narg) = @_;
1224         local ($errors_log, $listener);
1225         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1226         $errors_log = "$sock_dir/errors.log";
1227         my $addr = pack_sockaddr_un($path);
1228         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1229         umask(077) // die("umask(077): $!");
1230         $lk->lock_acquire;
1231         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1232         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1233                 return if connect($listener, $addr); # another process won
1234                 if ($errno == ECONNREFUSED && -S $path) {
1235                         unlink($path) or die "unlink($path): $!";
1236                 }
1237         } else {
1238                 $! = $errno; # allow interpolation to stringify in die
1239                 die "connect($path): $!";
1240         }
1241         bind($listener, $addr) or die "bind($path): $!";
1242         $lk->lock_release;
1243         undef $lk;
1244         my @st = stat($path) or die "stat($path): $!";
1245         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1246         local $oldset = PublicInbox::DS::block_signals();
1247         if ($narg == 5) {
1248                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1249                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1250                         require PublicInbox::CmdIPC4;
1251                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1252                         PublicInbox::CmdIPC4->can('recv_cmd4');
1253                 };
1254         }
1255         $recv_cmd or die <<"";
1256 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1257
1258         require PublicInbox::Listener;
1259         require PublicInbox::PktOp;
1260         (-p STDOUT) or die "E: stdout must be a pipe\n";
1261         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1262         STDIN->autoflush(1);
1263         dump_and_clear_log();
1264         POSIX::setsid() > 0 or die "setsid: $!";
1265         my $pid = fork // die "fork: $!";
1266         return if $pid;
1267         $0 = "lei-daemon $path";
1268         local %PATH2CFG;
1269         local $MDIR2CFGPATH;
1270         $listener->blocking(0);
1271         my $exit_code;
1272         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1273         local $quit = do {
1274                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1275                 sub {
1276                         $exit_code //= shift;
1277                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1278                         my $lis = $pil or exit($exit_code);
1279                         # closing eof_p triggers \&noop wakeup
1280                         $listener = $eof_p = $pil = $path = undef;
1281                         $lis->close; # DS::close
1282                         PublicInbox::DS->SetLoopTimeout(1000);
1283                 };
1284         };
1285         my $sig = {
1286                 CHLD => \&PublicInbox::DS::enqueue_reap,
1287                 QUIT => $quit,
1288                 INT => $quit,
1289                 TERM => $quit,
1290                 HUP => \&noop,
1291                 USR1 => \&noop,
1292                 USR2 => \&noop,
1293         };
1294         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1295         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1296         undef $sig;
1297         local $SIG{PIPE} = 'IGNORE';
1298         require PublicInbox::DirIdle;
1299         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1300                 # just rely on wakeup to hit PostLoopCallback set below
1301                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1302         }, 1);
1303         if ($sigfd) {
1304                 undef $sigfd; # unref, already in DS::DescriptorMap
1305         } else {
1306                 # wake up every second to accept signals if we don't
1307                 # have signalfd or IO::KQueue:
1308                 PublicInbox::DS::sig_setmask($oldset);
1309                 PublicInbox::DS->SetLoopTimeout(1000);
1310         }
1311         PublicInbox::DS->SetPostLoopCallback(sub {
1312                 my ($dmap, undef) = @_;
1313                 if (@st = defined($path) ? stat($path) : ()) {
1314                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1315                                 warn "$path dev/ino changed, quitting\n";
1316                                 $path = undef;
1317                         }
1318                 } elsif (defined($path)) { # ENOENT is common
1319                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1320                         undef $path;
1321                         $quit->();
1322                 }
1323                 return 1 if defined($path);
1324                 my $now = now();
1325                 my $n = 0;
1326                 for my $s (values %$dmap) {
1327                         $s->can('busy') or next;
1328                         if ($s->busy($now)) {
1329                                 ++$n;
1330                         } else {
1331                                 $s->close;
1332                         }
1333                 }
1334                 $n; # true: continue, false: stop
1335         });
1336
1337         # STDIN was redirected to /dev/null above, closing STDERR and
1338         # STDOUT will cause the calling `lei' client process to finish
1339         # reading the <$daemon> pipe.
1340         local $SIG{__WARN__} = sub {
1341                 $current_lei ? err($current_lei, @_) : warn(
1342                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1343         };
1344         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1345         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1346         # $daemon pipe to `lei' closed, main loop begins:
1347         eval { PublicInbox::DS->EventLoop };
1348         warn "event loop error: $@\n" if $@;
1349         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1350         PublicInbox::DS::sig_setmask($oldset);
1351         dump_and_clear_log();
1352         exit($exit_code // 0);
1353 }
1354
1355 sub busy { 1 } # prevent daemon-shutdown if client is connected
1356
1357 # ensures stdout hits the FS before sock disconnects so a client
1358 # can immediately reread it
1359 sub DESTROY {
1360         my ($self) = @_;
1361         if (my $counters = delete $self->{counters}) {
1362                 for my $k (sort keys %$counters) {
1363                         my $nr = $counters->{$k};
1364                         $self->child_error(0, "$nr $k messages");
1365                 }
1366         }
1367         $self->{1}->autoflush(1) if $self->{1};
1368         stop_pager($self);
1369         dump_and_clear_log();
1370         # preserve $? for ->fail or ->x_it code
1371 }
1372
1373 sub wq_done_wait { # dwaitpid callback
1374         my ($arg, $pid) = @_;
1375         my ($wq, $lei) = @$arg;
1376         my $err_type = $lei->{-err_type};
1377         $? and $lei->child_error($?,
1378                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1379         $lei->dclose;
1380 }
1381
1382 sub fchdir {
1383         my ($lei) = @_;
1384         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1385         chdir($dh) || $lei->fail("fchdir: $!");
1386 }
1387
1388 sub wq_eof { # EOF callback for main daemon
1389         my ($lei) = @_;
1390         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1391         $wq1->wq_wait_old($wq1->can('_wq_done_wait') // \&wq_done_wait, $lei);
1392 }
1393
1394 sub watch_state_ok ($) {
1395         my ($state) = $_[-1]; # $_[0] may be $self
1396         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1397 }
1398
1399 sub cancel_maildir_watch ($$) {
1400         my ($d, $cfg_f) = @_;
1401         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1402         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1403                 delete $MDIR2CFGPATH->{$d};
1404         for my $x (@{$w // []}) { $x->cancel }
1405 }
1406
1407 sub add_maildir_watch ($$) {
1408         my ($d, $cfg_f) = @_;
1409         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1410                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1411                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1412         }
1413 }
1414
1415 sub refresh_watches {
1416         my ($lei) = @_;
1417         $dir_idle or return;
1418         my $cfg = _lei_cfg($lei) or return;
1419         my $old = $cfg->{-watches};
1420         my $watches = $cfg->{-watches} //= {};
1421         my %seen;
1422         my $cfg_f = $cfg->{'-f'};
1423         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1424                 my $url = substr($w, length('watch.'), -length('.state'));
1425                 require PublicInbox::LeiWatch;
1426                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1427                 $seen{$url} = undef;
1428                 my $state = $cfg->get_1("watch.$url.state");
1429                 if (!watch_state_ok($state)) {
1430                         $lei->err("watch.$url.state=$state not supported");
1431                         next;
1432                 }
1433                 if ($url =~ /\Amaildir:(.+)/i) {
1434                         my $d = canonpath_harder($1);
1435                         if ($state eq 'pause') {
1436                                 cancel_maildir_watch($d, $cfg_f);
1437                         } else {
1438                                 add_maildir_watch($d, $cfg_f);
1439                         }
1440                 } else { # TODO: imap/nntp/jmap
1441                         $lei->child_error(0, "E: watch $url not supported, yet")
1442                 }
1443         }
1444
1445         # add all known Maildir folders as implicit watches
1446         my $lms = $lei->lms;
1447         if ($lms) {
1448                 $lms->lms_write_prepare;
1449                 for my $d ($lms->folders('maildir:')) {
1450                         substr($d, 0, length('maildir:')) = '';
1451
1452                         # fixup old bugs while we're iterating:
1453                         my $cd = canonpath_harder($d);
1454                         my $f = "maildir:$cd";
1455                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1456                         next if $watches->{$f}; # may be set to pause
1457                         require PublicInbox::LeiWatch;
1458                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1459                         $seen{$f} = undef;
1460                         add_maildir_watch($cd, $cfg_f);
1461                 }
1462         }
1463         if ($old) { # cull old non-existent entries
1464                 for my $url (keys %$old) {
1465                         next if exists $seen{$url};
1466                         delete $old->{$url};
1467                         if ($url =~ /\Amaildir:(.+)/i) {
1468                                 my $d = canonpath_harder($1);
1469                                 cancel_maildir_watch($d, $cfg_f);
1470                         } else { # TODO: imap/nntp/jmap
1471                                 $lei->child_error(0, "E: watch $url TODO");
1472                         }
1473                 }
1474         }
1475         if (scalar keys %$watches) {
1476                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1477         } else {
1478                 delete $cfg->{-watches};
1479         }
1480 }
1481
1482 # TODO: support SHA-256
1483 sub git_oid {
1484         my $eml = $_[-1];
1485         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1486         git_sha(1, $eml);
1487 }
1488
1489 sub lms {
1490         my ($lei, $rw) = @_;
1491         my $sto = $lei->{sto} // _lei_store($lei) // return;
1492         require PublicInbox::LeiMailSync;
1493         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1494         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1495 }
1496
1497 sub sto_done_request {
1498         my ($lei, $sock) = @_;
1499         eval {
1500                 if ($sock //= $lei->{sock}) { # issue, async wait
1501                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1502                 } else { # forcibly wait
1503                         my $wait = $lei->{sto}->wq_do('done');
1504                 }
1505         };
1506         $lei->err($@) if $@;
1507 }
1508
1509 sub cfg_dump ($$) {
1510         my ($lei, $f) = @_;
1511         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1512         return $ret if !$@;
1513         $lei->err($@);
1514         undef;
1515 }
1516
1517 1;