lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 205 'verbose|v' => 'be more verbose',
 206 'solve!' => 'do not attempt to reconstruct blobs from emails',
 207 'torsocks=s' => ['auto|no|yes',
 208                 'whether or not to wrap git and curl commands with torsocks'],
 209 'no-torsocks' => 'alias for --torsocks=no',
 210 'save-as=s' => ['NAME', 'save a search terms by given name'],
 211
 212 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 213
 214 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 215                 'deduplication strategy'],
 216 'show   thread|t' => 'display entire thread a message belongs to',
 217 'q      thread|t' =>
 218         'return all messages in the same thread as the actual match(es)',
 219 'augment|a' => 'augment --output destination instead of clobbering',
 220
 221 'output|mfolder|o=s' => [ 'DEST',
 222         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 223 'mua-cmd|mua=s' => [ 'COMMAND',
 224         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 225
 226 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 227                         'message/object output format' ],
 228 'mark   format|f=s' => $stdin_formats,
 229 'forget format|f=s' => $stdin_formats,
 230 'q      format|f=s' => [
 231         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 232                 'specify output format, default depends on --output'],
 233 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 234                 'exclude specified external(s) from search' ],
 235 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 236                 'include specified external(s) in search' ],
 237 'q      only=s@' => [ 'URL_OR_PATHNAME',
 238                 'only use specified external(s) for search' ],
 239
 240 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 241                 'control number of search and writer jobs' ],
 242
 243 'ls-query       format|f=s' => $ls_format,
 244 'ls-external    format|f=s' => $ls_format,
 245
 246 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 247 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 248
 249 'sort|s=s' => [ 'VAL|received,relevance,docid',
 250                 "order of results `--output'-dependent"],
 251 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 252
 253 'boost=i' => 'increase/decrease priority of results (default: 0)',
 254
 255 'local' => 'limit operations to the local filesystem',
 256 'local!' => 'exclude results from the local filesystem',
 257 'remote' => 'limit operations to those requiring network access',
 258 'remote!' => 'prevent operations requiring network access',
 259
 260 'mid=s' => 'specify the Message-ID of a message',
 261 'oid=s' => 'specify the git object ID of a message',
 262
 263 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 264 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 265 'include=s' => 'include mailboxes/newsgroups based on pattern',
 266
 267 'exact' => 'operate on exact header matches only',
 268 'exact!' => 'rely on content match instead of exact header matches',
 269
 270 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 271 'jobs:i' => 'set parallelism level',
 272
 273 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 274 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 275
 276 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 277 ); # %OPTDESC
 278
 279 my %CONFIG_KEYS = (
 280         'leistore.dir' => 'top-level storage location',
 281 );
 282
 283 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 284 sub x_it ($$) {
 285         my ($self, $code) = @_;
 286         # make sure client sees stdout before exit
 287         $self->{1}->autoflush(1) if $self->{1};
 288         dump_and_clear_log();
 289         if (my $s = $self->{pkt_op} // $self->{sock}) {
 290                 send($s, "x_it $code", MSG_EOR);
 291         } elsif ($self->{oneshot}) {
 292                 # don't want to end up using $? from child processes
 293                 for my $f (qw(lxs l2m)) {
 294                         my $wq = delete $self->{$f} or next;
 295                         $wq->DESTROY;
 296                 }
 297                 # cleanup anything that has tempfiles
 298                 delete @$self{qw(ovv dedupe)};
 299                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 300                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 301                         kill $signum, $$;
 302                         sleep; # wait for signal
 303                 } else {
 304                         $quit->($code >> 8);
 305                 }
 306         } # else ignore if client disconnected
 307 }
 308
 309 sub err ($;@) {
 310         my $self = shift;
 311         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 312         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 313         print $err @_, @eor and return;
 314         my $old_err = delete $self->{2};
 315         close($old_err) if $! == EPIPE && $old_err;
 316         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 317         print $err @_, @eor or print STDERR @_, @eor;
 318 }
 319
 320 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 321
 322 sub fail ($$;$) {
 323         my ($self, $buf, $exit_code) = @_;
 324         err($self, $buf) if defined $buf;
 325         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 326         x_it($self, ($exit_code // 1) << 8);
 327         undef;
 328 }
 329
 330 sub out ($;@) {
 331         my $self = shift;
 332         return if print { $self->{1} // return } @_; # likely
 333         return note_sigpipe($self, 1) if $! == EPIPE;
 334         my $err = "error writing to stdout: $!";
 335         delete $self->{1};
 336         fail($self, $err);
 337 }
 338
 339 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 340
 341 sub child_error { # passes non-fatal curl exit codes to user
 342         my ($self, $child_error) = @_; # child_error is $?
 343         if (my $s = $self->{pkt_op} // $self->{sock}) {
 344                 # send to the parent lei-daemon or to lei(1) client
 345                 send($s, "child_error $child_error", MSG_EOR);
 346         } elsif (!$PublicInbox::DS::in_loop) {
 347                 $self->{child_error} = $child_error;
 348         } # else noop if client disconnected
 349 }
 350
 351 sub atfork_prepare_wq {
 352         my ($self, $wq) = @_;
 353         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 354         if (my $sock = $self->{sock}) {
 355                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 356         }
 357         if (my $pgr = $self->{pgr}) {
 358                 push @$tcafc, @$pgr[1,2];
 359         }
 360         if (my $old_1 = $self->{old_1}) {
 361                 push @$tcafc, $old_1;
 362         }
 363         for my $f (qw(lxs l2m)) {
 364                 my $ipc = $self->{$f} or next;
 365                 push @$tcafc, grep { defined }
 366                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 367         }
 368 }
 369
 370 sub io_restore ($$) {
 371         my ($dst, $src) = @_;
 372         for my $i (0..2) { # standard FDs
 373                 my $io = delete $src->{$i} or next;
 374                 $dst->{$i} = $io;
 375         }
 376         for my $i (3..9) { # named (non-standard) FDs
 377                 my $io = $src->{$i} or next;
 378                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 379                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 380                 $dst->{$f} = $io;
 381                 delete $src->{$i};
 382         }
 383 }
 384
 385 sub note_sigpipe { # triggers sigpipe_handler
 386         my ($self, $fd) = @_;
 387         close(delete($self->{$fd})); # explicit close silences Perl warning
 388         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 389         x_it($self, 13);
 390 }
 391
 392 sub atfork_child_wq {
 393         my ($self, $wq) = @_;
 394         io_restore($self, $wq);
 395         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 396         io_restore($self->{l2m}, $wq);
 397         %PATH2CFG = ();
 398         undef $errors_log;
 399         $quit = \&CORE::exit;
 400         $current_lei = $self; # for SIG{__WARN__}
 401 }
 402
 403 sub io_extract ($;@) {
 404         my ($obj, @fields) = @_;
 405         my @io;
 406         for my $f (@fields) {
 407                 my $io = delete $obj->{$f} or next;
 408                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 409                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 410                 push @io, $io;
 411         }
 412         @io
 413 }
 414
 415 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 416 sub atfork_parent_wq {
 417         my ($self, $wq) = @_;
 418         my $env = delete $self->{env}; # env is inherited at fork
 419         my $lei = bless { %$self }, ref($self);
 420         for my $f (qw(dedupe ovv)) {
 421                 my $tmp = delete($lei->{$f}) or next;
 422                 $lei->{$f} = $wq->deep_clone($tmp);
 423         }
 424         $self->{env} = $env;
 425         delete @$lei{qw(sock 3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 426         my @io = (delete(@$lei{qw(0 1 2)}),
 427                         io_extract($lei, qw(pkt_op startq)));
 428         my $l2m = $lei->{l2m};
 429         if ($l2m && $l2m != $wq) { # $wq == lxs
 430                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 431                         push @io, io_extract($l2m, '-wq_s1');
 432                         $l2m->{-wq_s1} = $wq_s1;
 433                 }
 434                 $l2m->wq_close(1);
 435         }
 436         ($lei, @io);
 437 }
 438
 439 sub _help ($;$) {
 440         my ($self, $errmsg) = @_;
 441         my $cmd = $self->{cmd} // 'COMMAND';
 442         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 443         my @top = ($cmd, shift(@info) // ());
 444         my $cmd_desc = shift(@info);
 445         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 446         my @opt_desc;
 447         my $lpad = 2;
 448         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 449                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 450                 my $arg_vals = '';
 451                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 452
 453                 # lower-case is a keyword (e.g. `content', `oid'),
 454                 # ALL_CAPS is a string description (e.g. `PATH')
 455                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 456                         $desc .= "\ndefault: `$1'";
 457                 }
 458                 my (@vals, @s, @l);
 459                 my $x = $sw;
 460                 if ($x =~ s/!\z//) { # solve! => --no-solve
 461                         $x = "no-$x";
 462                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 463                         @vals = (' [', undef, ']');
 464                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 465                         @vals = (' ', undef);
 466                 } # else: no args $x = 'thread|t'
 467                 for (split(/\|/, $x)) { # help|h
 468                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 469                 }
 470                 if (!scalar(@vals)) { # no args 'thread|t'
 471                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 472                         $vals[1] = $1;
 473                 } else {
 474                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 475                 }
 476                 if ($arg_vals =~ /([,\|])/) {
 477                         my $sep = $1;
 478                         my @allow = split(/\Q$sep\E/, $arg_vals);
 479                         my $must = $sep eq '|' ? 'Must' : 'Can';
 480                         @allow = map { "`$_'" } @allow;
 481                         my $last = pop @allow;
 482                         $desc .= "\n$must be one of: " .
 483                                 join(', ', @allow) . " or $last";
 484                 }
 485                 my $lhs = join(', ', @s, @l) . join('', @vals);
 486                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 487                         $lhs =~ s/\A--/- , --/;
 488                 } else {
 489                         $lhs =~ s/\A--/    --/; # pad if no short options
 490                 }
 491                 $lpad = length($lhs) if length($lhs) > $lpad;
 492                 push @opt_desc, $lhs, $desc;
 493         }
 494         my $msg = $errmsg ? "E: $errmsg\n" : '';
 495         $msg .= <<EOF;
 496 usage: lei @top
 497   $cmd_desc
 498
 499 EOF
 500         $lpad += 2;
 501         local $Text::Wrap::columns = 78 - $lpad;
 502         my $padding = ' ' x ($lpad + 2);
 503         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 504                 $msg .= '  '.pack("A$lpad", $lhs);
 505                 $rhs = wrap('', '', $rhs);
 506                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 507                 $msg .= $rhs;
 508                 $msg .= "\n";
 509         }
 510         print { $self->{$errmsg ? 2 : 1} } $msg;
 511         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 512         undef;
 513 }
 514
 515 sub optparse ($$$) {
 516         my ($self, $cmd, $argv) = @_;
 517         $self->{cmd} = $cmd;
 518         $OPT = $self->{opt} = {};
 519         my $info = $CMD{$cmd} // [ '[...]' ];
 520         my ($proto, undef, @spec) = @$info;
 521         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 522         push @spec, qw(help|h);
 523         my $lone_dash;
 524         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 525                 $lone_dash = $spec[0];
 526                 $OPT->{$spec[0]} = \(my $var);
 527                 push @spec, '' => \$var;
 528         }
 529         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 530                 return _help($self, "bad arguments or options for $cmd");
 531         return _help($self) if $OPT->{help};
 532
 533         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 534
 535         # "-" aliases "stdin" or "clear"
 536         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 537
 538         my $i = 0;
 539         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 540         my ($err, $inf);
 541         my @args = split(/ /, $proto);
 542         for my $var (@args) {
 543                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 544                         $inf = defined($argv->[$i]) and last;
 545                         $var =~ s/\.\.\.\z//;
 546                         $err = "$var not supplied";
 547                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 548                         $argv->[$i++] // ($err = "$var not supplied");
 549                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 550                         $inf = 1;
 551                         last;
 552                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 553                         $i++;
 554                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 555                         my @or = split(/\|/, $var);
 556                         my $ok;
 557                         for my $o (@or) {
 558                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 559                                         $ok = defined($OPT->{$1});
 560                                         last;
 561                                 } elsif (defined($argv->[$i])) {
 562                                         $ok = 1;
 563                                         $i++;
 564                                         last;
 565                                 } # else continue looping
 566                         }
 567                         last if $ok;
 568                         my $last = pop @or;
 569                         $err = join(', ', @or) . " or $last must be set";
 570                 } else {
 571                         warn "BUG: can't parse `$var' in $proto";
 572                 }
 573                 last if $err;
 574         }
 575         if (!$inf && scalar(@$argv) > scalar(@args)) {
 576                 $err //= 'too many arguments';
 577         }
 578         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 579 }
 580
 581 sub dispatch {
 582         my ($self, $cmd, @argv) = @_;
 583         local $current_lei = $self; # for __WARN__
 584         dump_and_clear_log("from previous run\n");
 585         return _help($self, 'no command given') unless defined($cmd);
 586         my $func = "lei_$cmd";
 587         $func =~ tr/-/_/;
 588         if (my $cb = __PACKAGE__->can($func)) {
 589                 optparse($self, $cmd, \@argv) or return;
 590                 $cb->($self, @argv);
 591         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 592                 my $opt = {};
 593                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 594                         return _help($self, 'bad arguments or options');
 595                 _help($self);
 596         } else {
 597                 fail($self, "`$cmd' is not an lei command");
 598         }
 599 }
 600
 601 sub _lei_cfg ($;$) {
 602         my ($self, $creat) = @_;
 603         my $f = _config_path($self);
 604         my @st = stat($f);
 605         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 606         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 607                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 608         }
 609         if (!@st) {
 610                 unless ($creat) {
 611                         delete $self->{cfg};
 612                         return;
 613                 }
 614                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 615                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 616                 open my $fh, '>>', $f or die "open($f): $!\n";
 617                 @st = stat($fh) or die "fstat($f): $!\n";
 618                 $cur_st = pack('dd', $st[10], $st[7]);
 619                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 620         }
 621         my $cfg = PublicInbox::Config::git_config_dump($f);
 622         $cfg->{-st} = $cur_st;
 623         $cfg->{'-f'} = $f;
 624         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 625 }
 626
 627 sub _lei_store ($;$) {
 628         my ($self, $creat) = @_;
 629         my $cfg = _lei_cfg($self, $creat);
 630         $cfg->{-lei_store} //= do {
 631                 require PublicInbox::LeiStore;
 632                 my $dir = $cfg->{'leistore.dir'};
 633                 $dir //= $creat ? _store_path($self) : return;
 634                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 635         };
 636 }
 637
 638 sub lei_show {
 639         my ($self, @argv) = @_;
 640 }
 641
 642 sub lei_mark {
 643         my ($self, @argv) = @_;
 644 }
 645
 646 sub _config {
 647         my ($self, @argv) = @_;
 648         my $env = $self->{env};
 649         delete local $env->{GIT_CONFIG};
 650         delete local $ENV{GIT_CONFIG};
 651         my $cfg = _lei_cfg($self, 1);
 652         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 653         my %rdr = map { $_ => $self->{$_} } (0..2);
 654         waitpid(spawn($cmd, $env, \%rdr), 0);
 655 }
 656
 657 sub lei_config {
 658         my ($self, @argv) = @_;
 659         $self->{opt}->{'config-file'} and return fail $self,
 660                 "config file switches not supported by `lei config'";
 661         _config(@_);
 662         x_it($self, $?) if $?;
 663 }
 664
 665 sub lei_init {
 666         my ($self, $dir) = @_;
 667         my $cfg = _lei_cfg($self, 1);
 668         my $cur = $cfg->{'leistore.dir'};
 669         $dir //= _store_path($self);
 670         $dir = rel2abs($self, $dir);
 671         my @cur = stat($cur) if defined($cur);
 672         $cur = File::Spec->canonpath($cur // $dir);
 673         my @dir = stat($dir);
 674         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 675         if (@cur) {
 676                 if ($cur eq $dir) {
 677                         _lei_store($self, 1)->done;
 678                         return qerr($self, $exists);
 679                 }
 680
 681                 # some folks like symlinks and bind mounts :P
 682                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 683                         lei_config($self, 'leistore.dir', $dir);
 684                         _lei_store($self, 1)->done;
 685                         return qerr($self, "$exists (as $cur)");
 686                 }
 687                 return fail($self, <<"");
 688 E: leistore.dir=$cur already initialized and it is not $dir
 689
 690         }
 691         lei_config($self, 'leistore.dir', $dir);
 692         _lei_store($self, 1)->done;
 693         $exists //= "I: leistore.dir=$dir newly initialized";
 694         return qerr($self, $exists);
 695 }
 696
 697 sub lei_daemon_pid { puts shift, $$ }
 698
 699 sub lei_daemon_kill {
 700         my ($self) = @_;
 701         my $sig = $self->{opt}->{signal} // 'TERM';
 702         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 703 }
 704
 705 sub lei_help { _help($_[0]) }
 706
 707 # Shell completion helper.  Used by lei-completion.bash and hopefully
 708 # other shells.  Try to do as much here as possible to avoid redundancy
 709 # and improve maintainability.
 710 sub lei__complete {
 711         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 712         shift @argv; # ignore "lei", the entire command is sent
 713         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 714         my $cmd = shift @argv;
 715         my $info = $CMD{$cmd} // do { # filter matching commands
 716                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 717                 return;
 718         };
 719         my ($proto, undef, @spec) = @$info;
 720         my $cur = pop @argv;
 721         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 722         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 723                 # gross special case since the only git-config options
 724                 # Consider moving to a table if we need more special cases
 725                 # we use Getopt::Long for are the ones we reject, so these
 726                 # are the ones we don't reject:
 727                 if ($cmd eq 'config') {
 728                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 729                         @spec = qw(add z|null get get-all unset unset-all
 730                                 replace-all get-urlmatch
 731                                 remove-section rename-section
 732                                 name-only list|l edit|e
 733                                 get-color-name get-colorbool);
 734                         # fall-through
 735                 }
 736                 puts $self, grep(/$re/, map { # generate short/long names
 737                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 738                         } else { # negation: solve! => no-solve|solve
 739                                 s/\A(.+)!\z/no-$1|$1/;
 740                         }
 741                         map {
 742                                 my $x = length > 1 ? "--$_" : "-$_";
 743                                 $x eq $cur ? () : $x;
 744                         } split(/\|/, $_, -1) # help|h
 745                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 746         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 747                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 748         }
 749
 750         # switch args (e.g. lei q -f mbox<TAB>)
 751         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 752                 my $opt = quotemeta $1;
 753                 puts $self, map {
 754                         my $v = $OPTDESC{$_};
 755                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 756                         # get rid of ALL CAPS placeholder (e.g "OUT")
 757                         # (TODO: completion for external paths)
 758                         shift(@v) if uc($v[0]) eq $v[0];
 759                         @v;
 760                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 761         }
 762         $cmd =~ tr/-/_/;
 763         if (my $sub = $self->can("_complete_$cmd")) {
 764                 puts $self, $sub->($self, @argv, $cur);
 765         }
 766         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 767         # proto parsing.
 768 }
 769
 770 sub exec_buf ($$) {
 771         my ($argv, $env) = @_;
 772         my $argc = scalar @$argv;
 773         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 774         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 775         $buf;
 776 }
 777
 778 sub start_mua {
 779         my ($self) = @_;
 780         my $mua = $self->{opt}->{'mua-cmd'} // return;
 781         my $mfolder = $self->{ovv}->{dst};
 782         my (@cmd, $replaced);
 783         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 784                 @cmd = ($mua, '-f');
 785         # TODO: help wanted: other common FOSS MUAs
 786         } else {
 787                 require Text::ParseWords;
 788                 my @cmd = Text::ParseWords::shellwords($mua);
 789                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 790                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 791         }
 792         push @cmd, $mfolder unless defined($replaced);
 793         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 794                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 795         } elsif ($self->{oneshot}) {
 796                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 797         }
 798 }
 799
 800 # caller needs to "-t $self->{1}" to check if tty
 801 sub start_pager {
 802         my ($self) = @_;
 803         my $env = $self->{env};
 804         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 805         chomp(my $pager = <$fh> // '');
 806         close($fh) or warn "`git var PAGER' error: \$?=$?";
 807         return if $pager eq 'cat' || $pager eq '';
 808         # TODO TIOCGWINSZ
 809         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 810         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 811         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 812         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 813         my $pgr = [ undef, @$rdr{1, 2} ];
 814         if (my $sock = $self->{sock}) { # lei(1) process runs it
 815                 delete @$new_env{keys %$env}; # only set iff unset
 816                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 817                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 818         } elsif ($self->{oneshot}) {
 819                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 820                 $pgr->[3] = $$; # ew'll reap it
 821         } else {
 822                 die 'BUG: start_pager w/o socket';
 823         }
 824         $self->{1} = $wpager;
 825         $self->{2} = $wpager if -t $self->{2};
 826         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 827         $self->{pgr} = $pgr;
 828 }
 829
 830 sub stop_pager {
 831         my ($self) = @_;
 832         my $pgr = delete($self->{pgr}) or return;
 833         $self->{2} = $pgr->[2];
 834         # do not restore original stdout, just close it so we error out
 835         close(delete($self->{1})) if $self->{1};
 836         my $pid = $pgr->[0];
 837         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 838 }
 839
 840 sub accept_dispatch { # Listener {post_accept} callback
 841         my ($sock) = @_; # ignore other
 842         $sock->autoflush(1);
 843         my $self = bless { sock => $sock }, __PACKAGE__;
 844         vec(my $rvec = '', fileno($sock), 1) = 1;
 845         select($rvec, undef, undef, 60) or
 846                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 847         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 848         if (scalar(@fds) == 4) {
 849                 for my $i (0..3) {
 850                         my $fd = shift(@fds);
 851                         open($self->{$i}, '+<&=', $fd) and next;
 852                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 853                 }
 854         } else {
 855                 my $msg = "recv_cmd failed: $!";
 856                 warn $msg;
 857                 return send($sock, $msg, MSG_EOR);
 858         }
 859         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 860         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 861         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 862         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 863                 return send($sock, 'request command truncated', MSG_EOR);
 864         my ($argc, @argv) = split(/\0/, $buf, -1);
 865         undef $buf;
 866         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 867         if (chdir($self->{3})) {
 868                 local %ENV = %env;
 869                 $self->{env} = \%env;
 870                 eval { dispatch($self, @argv) };
 871                 send($sock, $@, MSG_EOR) if $@;
 872         } else {
 873                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 874         }
 875 }
 876
 877 sub dclose {
 878         my ($self) = @_;
 879         delete $self->{-progress};
 880         for my $f (qw(lxs l2m)) {
 881                 my $wq = delete $self->{$f} or next;
 882                 if ($wq->wq_kill) {
 883                         $wq->wq_close
 884                 } elsif ($wq->wq_kill_old) {
 885                         $wq->wq_wait_old($self);
 886                 }
 887         }
 888         close(delete $self->{1}) if $self->{1}; # may reap_compress
 889         $self->close if $self->{sock}; # PublicInbox::DS::close
 890 }
 891
 892 # for long-running results
 893 sub event_step {
 894         my ($self) = @_;
 895         local %ENV = %{$self->{env}};
 896         my $sock = $self->{sock};
 897         local $current_lei = $self;
 898         eval {
 899                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 900                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 901                                 return if $! == EAGAIN;
 902                                 next if $! == EINTR;
 903                                 last if $! == ECONNRESET;
 904                                 die "recvmsg: $!";
 905                         }
 906                         for my $fd (@fds) {
 907                                 open my $rfh, '+<&=', $fd;
 908                         }
 909                         die "unrecognized client signal: $buf";
 910                 }
 911                 dclose($self);
 912         };
 913         if (my $err = $@) {
 914                 eval { $self->fail($err) };
 915                 dclose($self);
 916         }
 917 }
 918
 919 sub event_step_init {
 920         my ($self) = @_;
 921         if (my $sock = $self->{sock}) { # using DS->EventLoop
 922                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 923         }
 924 }
 925
 926 sub noop {}
 927
 928 our $oldset; sub oldset { $oldset }
 929
 930 sub dump_and_clear_log {
 931         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 932                 my @pfx = @_;
 933                 unshift(@pfx, "$errors_log ") if @pfx;
 934                 warn @pfx, do { local $/; <STDIN> };
 935                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 936         }
 937 }
 938
 939 # lei(1) calls this when it can't connect
 940 sub lazy_start {
 941         my ($path, $errno, $narg) = @_;
 942         if ($errno == ECONNREFUSED) {
 943                 unlink($path) or die "unlink($path): $!";
 944         } elsif ($errno != ENOENT) {
 945                 $! = $errno; # allow interpolation to stringify in die
 946                 die "connect($path): $!";
 947         }
 948         if (eval { require BSD::Resource }) {
 949                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 950                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 951                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 952         }
 953         umask(077) // die("umask(077): $!");
 954         local $listener;
 955         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 956         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 957         listen($listener, 1024) or die "listen: $!";
 958         my @st = stat($path) or die "stat($path): $!";
 959         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 960         local $oldset = PublicInbox::DS::block_signals();
 961         if ($narg == 5) {
 962                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 963                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 964                         require PublicInbox::CmdIPC4;
 965                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 966                         PublicInbox::CmdIPC4->can('recv_cmd4');
 967                 };
 968         }
 969         $recv_cmd or die <<"";
 970 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 971
 972         require PublicInbox::Listener;
 973         require PublicInbox::EOFpipe;
 974         (-p STDOUT) or die "E: stdout must be a pipe\n";
 975         local $errors_log;
 976         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 977         $errors_log .= 'errors.log';
 978         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 979         STDIN->autoflush(1);
 980         dump_and_clear_log("from previous daemon process:\n");
 981         POSIX::setsid() > 0 or die "setsid: $!";
 982         my $pid = fork // die "fork: $!";
 983         return if $pid;
 984         $0 = "lei-daemon $path";
 985         local %PATH2CFG;
 986         $listener->blocking(0);
 987         my $exit_code;
 988         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 989         local $quit = do {
 990                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 991                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 992                 sub {
 993                         $exit_code //= shift;
 994                         my $lis = $pil or exit($exit_code);
 995                         # closing eof_w triggers \&noop wakeup
 996                         $listener = $eof_w = $pil = $path = undef;
 997                         $lis->close; # DS::close
 998                         PublicInbox::DS->SetLoopTimeout(1000);
 999                 };
1000         };
1001         my $sig = {
1002                 CHLD => \&PublicInbox::DS::enqueue_reap,
1003                 QUIT => $quit,
1004                 INT => $quit,
1005                 TERM => $quit,
1006                 HUP => \&noop,
1007                 USR1 => \&noop,
1008                 USR2 => \&noop,
1009         };
1010         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1011         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1012         undef $sig;
1013         local $SIG{PIPE} = 'IGNORE';
1014         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1015                 undef $sigfd;
1016                 PublicInbox::DS->SetLoopTimeout(5000);
1017         } else {
1018                 # wake up every second to accept signals if we don't
1019                 # have signalfd or IO::KQueue:
1020                 PublicInbox::DS::sig_setmask($oldset);
1021                 PublicInbox::DS->SetLoopTimeout(1000);
1022         }
1023         PublicInbox::DS->SetPostLoopCallback(sub {
1024                 my ($dmap, undef) = @_;
1025                 if (@st = defined($path) ? stat($path) : ()) {
1026                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1027                                 warn "$path dev/ino changed, quitting\n";
1028                                 $path = undef;
1029                         }
1030                 } elsif (defined($path)) { # ENOENT is common
1031                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1032                         undef $path;
1033                         $quit->();
1034                 }
1035                 return 1 if defined($path);
1036                 my $now = now();
1037                 my $n = 0;
1038                 for my $s (values %$dmap) {
1039                         $s->can('busy') or next;
1040                         if ($s->busy($now)) {
1041                                 ++$n;
1042                         } else {
1043                                 $s->close;
1044                         }
1045                 }
1046                 $n; # true: continue, false: stop
1047         });
1048
1049         # STDIN was redirected to /dev/null above, closing STDERR and
1050         # STDOUT will cause the calling `lei' client process to finish
1051         # reading the <$daemon> pipe.
1052         local $SIG{__WARN__} = sub {
1053                 $current_lei ? err($current_lei, @_) : warn(
1054                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1055         };
1056         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1057         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1058         # $daemon pipe to `lei' closed, main loop begins:
1059         PublicInbox::DS->EventLoop;
1060         exit($exit_code // 0);
1061 }
1062
1063 # for users w/o Socket::Msghdr installed or Inline::C enabled
1064 sub oneshot {
1065         my ($main_pkg) = @_;
1066         my $exit = $main_pkg->can('exit'); # caller may override exit()
1067         local $quit = $exit if $exit;
1068         local %PATH2CFG;
1069         umask(077) // die("umask(077): $!");
1070         my $self = bless {
1071                 oneshot => 1,
1072                 0 => *STDIN{GLOB},
1073                 1 => *STDOUT{GLOB},
1074                 2 => *STDERR{GLOB},
1075                 env => \%ENV
1076         }, __PACKAGE__;
1077         dispatch($self, @ARGV);
1078         x_it($self, $self->{child_error}) if $self->{child_error};
1079 }
1080
1081 # ensures stdout hits the FS before sock disconnects so a client
1082 # can immediately reread it
1083 sub DESTROY {
1084         my ($self) = @_;
1085         $self->{1}->autoflush(1) if $self->{1};
1086         stop_pager($self);
1087         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1088                 waitpid($mua_pid, 0);
1089         }
1090 }
1091
1092 1;