lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 233                 'exclude specified external(s) from search' ],
 234 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 235                 'include specified external(s) in search' ],
 236 'q      only=s@' => [ 'URL_OR_PATHNAME',
 237                 'only use specified external(s) for search' ],
 238
 239 'ls-query       format|f=s' => $ls_format,
 240 'ls-external    format|f=s' => $ls_format,
 241
 242 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 243 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 244
 245 'sort|s=s' => [ 'VAL|received,relevance,docid',
 246                 "order of results `--output'-dependent"],
 247 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 248
 249 'boost=i' => 'increase/decrease priority of results (default: 0)',
 250
 251 'local' => 'limit operations to the local filesystem',
 252 'local!' => 'exclude results from the local filesystem',
 253 'remote' => 'limit operations to those requiring network access',
 254 'remote!' => 'prevent operations requiring network access',
 255
 256 'mid=s' => 'specify the Message-ID of a message',
 257 'oid=s' => 'specify the git object ID of a message',
 258
 259 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 260 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 261 'include=s' => 'include mailboxes/newsgroups based on pattern',
 262
 263 'exact' => 'operate on exact header matches only',
 264 'exact!' => 'rely on content match instead of exact header matches',
 265
 266 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 267 'jobs:i' => 'set parallelism level',
 268
 269 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 270 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 271
 272 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 273 ); # %OPTDESC
 274
 275 my %CONFIG_KEYS = (
 276         'leistore.dir' => 'top-level storage location',
 277 );
 278
 279 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 280 sub x_it ($$) {
 281         my ($self, $code) = @_;
 282         # make sure client sees stdout before exit
 283         $self->{1}->autoflush(1) if $self->{1};
 284         dump_and_clear_log();
 285         if (my $sock = $self->{sock}) {
 286                 send($sock, "x_it $code", MSG_EOR);
 287         } elsif ($self->{oneshot}) {
 288                 # don't want to end up using $? from child processes
 289                 for my $f (qw(lxs l2m)) {
 290                         my $wq = delete $self->{$f} or next;
 291                         $wq->DESTROY;
 292                 }
 293                 # cleanup anything that has tempfiles
 294                 delete @$self{qw(ovv dedupe)};
 295                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 296                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 297                         kill $signum, $$;
 298                         sleep; # wait for signal
 299                 } else {
 300                         $quit->($code >> 8);
 301                 }
 302         } # else ignore if client disconnected
 303 }
 304
 305 sub err ($;@) {
 306         my $self = shift;
 307         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 308         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 309         print $err @_, $eor and return;
 310         my $old_err = delete $self->{2};
 311         close($old_err) if $! == EPIPE && $old_err;;
 312         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 313         print $err @_, $eor or print STDERR @_, $eor;
 314 }
 315
 316 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 317
 318 sub fail ($$;$) {
 319         my ($self, $buf, $exit_code) = @_;
 320         err($self, $buf) if defined $buf;
 321         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 322         x_it($self, ($exit_code // 1) << 8);
 323         undef;
 324 }
 325
 326 sub out ($;@) {
 327         my $self = shift;
 328         return if print { $self->{1} // return } @_; # likely
 329         return note_sigpipe($self, 1) if $! == EPIPE;
 330         my $err = "error writing to stdout: $!";
 331         delete $self->{1};
 332         fail($self, $err);
 333 }
 334
 335 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 336
 337 sub child_error { # passes non-fatal curl exit codes to user
 338         my ($self, $child_error) = @_; # child_error is $?
 339         if (my $sock = $self->{sock}) { # send to lei(1) client
 340                 send($sock, "child_error $child_error", MSG_EOR);
 341         } elsif ($self->{oneshot}) {
 342                 $self->{child_error} = $child_error;
 343         } # else noop if client disconnected
 344 }
 345
 346 sub atfork_prepare_wq {
 347         my ($self, $wq) = @_;
 348         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 349         if (my $sock = $self->{sock}) {
 350                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 351         }
 352         if (my $pgr = $self->{pgr}) {
 353                 push @$tcafc, @$pgr[1,2];
 354         }
 355         if (my $old_1 = $self->{old_1}) {
 356                 push @$tcafc, $old_1;
 357         }
 358         for my $f (qw(lxs l2m)) {
 359                 my $ipc = $self->{$f} or next;
 360                 push @$tcafc, grep { defined }
 361                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 362         }
 363 }
 364
 365 sub io_restore ($$) {
 366         my ($dst, $src) = @_;
 367         for my $i (0..2) { # standard FDs
 368                 my $io = delete $src->{$i} or next;
 369                 $dst->{$i} = $io;
 370         }
 371         for my $i (3..9) { # named (non-standard) FDs
 372                 my $io = $src->{$i} or next;
 373                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 374                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 375                 $dst->{$f} = $io;
 376                 delete $src->{$i};
 377         }
 378 }
 379
 380 sub note_sigpipe { # triggers sigpipe_handler
 381         my ($self, $fd) = @_;
 382         close(delete($self->{$fd})); # explicit close silences Perl warning
 383         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 384         x_it($self, 13);
 385 }
 386
 387 sub atfork_child_wq {
 388         my ($self, $wq) = @_;
 389         io_restore($self, $wq);
 390         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 391         io_restore($self->{l2m}, $wq);
 392         %PATH2CFG = ();
 393         undef $errors_log;
 394         $quit = \&CORE::exit;
 395         $current_lei = $self; # for SIG{__WARN__}
 396 }
 397
 398 sub io_extract ($;@) {
 399         my ($obj, @fields) = @_;
 400         my @io;
 401         for my $f (@fields) {
 402                 my $io = delete $obj->{$f} or next;
 403                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 404                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 405                 push @io, $io;
 406         }
 407         @io
 408 }
 409
 410 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 411 sub atfork_parent_wq {
 412         my ($self, $wq) = @_;
 413         my $env = delete $self->{env}; # env is inherited at fork
 414         my $lei = bless { %$self }, ref($self);
 415         for my $f (qw(dedupe ovv)) {
 416                 my $tmp = delete($lei->{$f}) or next;
 417                 $lei->{$f} = $wq->deep_clone($tmp);
 418         }
 419         $self->{env} = $env;
 420         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 421         my @io = (delete(@$lei{qw(0 1 2)}),
 422                         io_extract($lei, qw(sock pkt_op startq)));
 423         my $l2m = $lei->{l2m};
 424         if ($l2m && $l2m != $wq) { # $wq == lxs
 425                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 426                         push @io, io_extract($l2m, '-wq_s1');
 427                         $l2m->{-wq_s1} = $wq_s1;
 428                 }
 429                 $l2m->wq_close(1);
 430         }
 431         ($lei, @io);
 432 }
 433
 434 sub _help ($;$) {
 435         my ($self, $errmsg) = @_;
 436         my $cmd = $self->{cmd} // 'COMMAND';
 437         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 438         my @top = ($cmd, shift(@info) // ());
 439         my $cmd_desc = shift(@info);
 440         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 441         my @opt_desc;
 442         my $lpad = 2;
 443         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 444                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 445                 my $arg_vals = '';
 446                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 447
 448                 # lower-case is a keyword (e.g. `content', `oid'),
 449                 # ALL_CAPS is a string description (e.g. `PATH')
 450                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 451                         $desc .= "\ndefault: `$1'";
 452                 }
 453                 my (@vals, @s, @l);
 454                 my $x = $sw;
 455                 if ($x =~ s/!\z//) { # solve! => --no-solve
 456                         $x = "no-$x";
 457                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 458                         @vals = (' [', undef, ']');
 459                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 460                         @vals = (' ', undef);
 461                 } # else: no args $x = 'thread|t'
 462                 for (split(/\|/, $x)) { # help|h
 463                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 464                 }
 465                 if (!scalar(@vals)) { # no args 'thread|t'
 466                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 467                         $vals[1] = $1;
 468                 } else {
 469                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 470                 }
 471                 if ($arg_vals =~ /([,\|])/) {
 472                         my $sep = $1;
 473                         my @allow = split(/\Q$sep\E/, $arg_vals);
 474                         my $must = $sep eq '|' ? 'Must' : 'Can';
 475                         @allow = map { "`$_'" } @allow;
 476                         my $last = pop @allow;
 477                         $desc .= "\n$must be one of: " .
 478                                 join(', ', @allow) . " or $last";
 479                 }
 480                 my $lhs = join(', ', @s, @l) . join('', @vals);
 481                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 482                         $lhs =~ s/\A--/- , --/;
 483                 } else {
 484                         $lhs =~ s/\A--/    --/; # pad if no short options
 485                 }
 486                 $lpad = length($lhs) if length($lhs) > $lpad;
 487                 push @opt_desc, $lhs, $desc;
 488         }
 489         my $msg = $errmsg ? "E: $errmsg\n" : '';
 490         $msg .= <<EOF;
 491 usage: lei @top
 492   $cmd_desc
 493
 494 EOF
 495         $lpad += 2;
 496         local $Text::Wrap::columns = 78 - $lpad;
 497         my $padding = ' ' x ($lpad + 2);
 498         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 499                 $msg .= '  '.pack("A$lpad", $lhs);
 500                 $rhs = wrap('', '', $rhs);
 501                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 502                 $msg .= $rhs;
 503                 $msg .= "\n";
 504         }
 505         print { $self->{$errmsg ? 2 : 1} } $msg;
 506         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 507         undef;
 508 }
 509
 510 sub optparse ($$$) {
 511         my ($self, $cmd, $argv) = @_;
 512         $self->{cmd} = $cmd;
 513         $OPT = $self->{opt} = {};
 514         my $info = $CMD{$cmd} // [ '[...]' ];
 515         my ($proto, undef, @spec) = @$info;
 516         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 517         push @spec, qw(help|h);
 518         my $lone_dash;
 519         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 520                 $lone_dash = $spec[0];
 521                 $OPT->{$spec[0]} = \(my $var);
 522                 push @spec, '' => \$var;
 523         }
 524         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 525                 return _help($self, "bad arguments or options for $cmd");
 526         return _help($self) if $OPT->{help};
 527
 528         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 529
 530         # "-" aliases "stdin" or "clear"
 531         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 532
 533         my $i = 0;
 534         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 535         my ($err, $inf);
 536         my @args = split(/ /, $proto);
 537         for my $var (@args) {
 538                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 539                         $inf = defined($argv->[$i]) and last;
 540                         $var =~ s/\.\.\.\z//;
 541                         $err = "$var not supplied";
 542                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 543                         $argv->[$i++] // ($err = "$var not supplied");
 544                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 545                         $inf = 1;
 546                         last;
 547                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 548                         $i++;
 549                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 550                         my @or = split(/\|/, $var);
 551                         my $ok;
 552                         for my $o (@or) {
 553                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 554                                         $ok = defined($OPT->{$1});
 555                                         last;
 556                                 } elsif (defined($argv->[$i])) {
 557                                         $ok = 1;
 558                                         $i++;
 559                                         last;
 560                                 } # else continue looping
 561                         }
 562                         last if $ok;
 563                         my $last = pop @or;
 564                         $err = join(', ', @or) . " or $last must be set";
 565                 } else {
 566                         warn "BUG: can't parse `$var' in $proto";
 567                 }
 568                 last if $err;
 569         }
 570         if (!$inf && scalar(@$argv) > scalar(@args)) {
 571                 $err //= 'too many arguments';
 572         }
 573         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 574 }
 575
 576 sub dispatch {
 577         my ($self, $cmd, @argv) = @_;
 578         local $current_lei = $self; # for __WARN__
 579         dump_and_clear_log("from previous run\n");
 580         return _help($self, 'no command given') unless defined($cmd);
 581         my $func = "lei_$cmd";
 582         $func =~ tr/-/_/;
 583         if (my $cb = __PACKAGE__->can($func)) {
 584                 optparse($self, $cmd, \@argv) or return;
 585                 $cb->($self, @argv);
 586         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 587                 my $opt = {};
 588                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 589                         return _help($self, 'bad arguments or options');
 590                 _help($self);
 591         } else {
 592                 fail($self, "`$cmd' is not an lei command");
 593         }
 594 }
 595
 596 sub _lei_cfg ($;$) {
 597         my ($self, $creat) = @_;
 598         my $f = _config_path($self);
 599         my @st = stat($f);
 600         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 601         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 602                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 603         }
 604         if (!@st) {
 605                 unless ($creat) {
 606                         delete $self->{cfg};
 607                         return;
 608                 }
 609                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 610                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 611                 open my $fh, '>>', $f or die "open($f): $!\n";
 612                 @st = stat($fh) or die "fstat($f): $!\n";
 613                 $cur_st = pack('dd', $st[10], $st[7]);
 614                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 615         }
 616         my $cfg = PublicInbox::Config::git_config_dump($f);
 617         $cfg->{-st} = $cur_st;
 618         $cfg->{'-f'} = $f;
 619         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 620 }
 621
 622 sub _lei_store ($;$) {
 623         my ($self, $creat) = @_;
 624         my $cfg = _lei_cfg($self, $creat);
 625         $cfg->{-lei_store} //= do {
 626                 require PublicInbox::LeiStore;
 627                 my $dir = $cfg->{'leistore.dir'};
 628                 $dir //= $creat ? _store_path($self) : return;
 629                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 630         };
 631 }
 632
 633 sub lei_show {
 634         my ($self, @argv) = @_;
 635 }
 636
 637 sub lei_mark {
 638         my ($self, @argv) = @_;
 639 }
 640
 641 sub _config {
 642         my ($self, @argv) = @_;
 643         my $env = $self->{env};
 644         delete local $env->{GIT_CONFIG};
 645         delete local $ENV{GIT_CONFIG};
 646         my $cfg = _lei_cfg($self, 1);
 647         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 648         my %rdr = map { $_ => $self->{$_} } (0..2);
 649         waitpid(spawn($cmd, $env, \%rdr), 0);
 650 }
 651
 652 sub lei_config {
 653         my ($self, @argv) = @_;
 654         $self->{opt}->{'config-file'} and return fail $self,
 655                 "config file switches not supported by `lei config'";
 656         _config(@_);
 657         x_it($self, $?) if $?;
 658 }
 659
 660 sub lei_init {
 661         my ($self, $dir) = @_;
 662         my $cfg = _lei_cfg($self, 1);
 663         my $cur = $cfg->{'leistore.dir'};
 664         $dir //= _store_path($self);
 665         $dir = rel2abs($self, $dir);
 666         my @cur = stat($cur) if defined($cur);
 667         $cur = File::Spec->canonpath($cur // $dir);
 668         my @dir = stat($dir);
 669         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 670         if (@cur) {
 671                 if ($cur eq $dir) {
 672                         _lei_store($self, 1)->done;
 673                         return qerr($self, $exists);
 674                 }
 675
 676                 # some folks like symlinks and bind mounts :P
 677                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 678                         lei_config($self, 'leistore.dir', $dir);
 679                         _lei_store($self, 1)->done;
 680                         return qerr($self, "$exists (as $cur)");
 681                 }
 682                 return fail($self, <<"");
 683 E: leistore.dir=$cur already initialized and it is not $dir
 684
 685         }
 686         lei_config($self, 'leistore.dir', $dir);
 687         _lei_store($self, 1)->done;
 688         $exists //= "I: leistore.dir=$dir newly initialized";
 689         return qerr($self, $exists);
 690 }
 691
 692 sub lei_daemon_pid { puts shift, $$ }
 693
 694 sub lei_daemon_kill {
 695         my ($self) = @_;
 696         my $sig = $self->{opt}->{signal} // 'TERM';
 697         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 698 }
 699
 700 sub lei_help { _help($_[0]) }
 701
 702 # Shell completion helper.  Used by lei-completion.bash and hopefully
 703 # other shells.  Try to do as much here as possible to avoid redundancy
 704 # and improve maintainability.
 705 sub lei__complete {
 706         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 707         shift @argv; # ignore "lei", the entire command is sent
 708         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 709         my $cmd = shift @argv;
 710         my $info = $CMD{$cmd} // do { # filter matching commands
 711                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 712                 return;
 713         };
 714         my ($proto, undef, @spec) = @$info;
 715         my $cur = pop @argv;
 716         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 717         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 718                 # gross special case since the only git-config options
 719                 # Consider moving to a table if we need more special cases
 720                 # we use Getopt::Long for are the ones we reject, so these
 721                 # are the ones we don't reject:
 722                 if ($cmd eq 'config') {
 723                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 724                         @spec = qw(add z|null get get-all unset unset-all
 725                                 replace-all get-urlmatch
 726                                 remove-section rename-section
 727                                 name-only list|l edit|e
 728                                 get-color-name get-colorbool);
 729                         # fall-through
 730                 }
 731                 puts $self, grep(/$re/, map { # generate short/long names
 732                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 733                         } else { # negation: solve! => no-solve|solve
 734                                 s/\A(.+)!\z/no-$1|$1/;
 735                         }
 736                         map {
 737                                 my $x = length > 1 ? "--$_" : "-$_";
 738                                 $x eq $cur ? () : $x;
 739                         } split(/\|/, $_, -1) # help|h
 740                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 741         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 742                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 743         }
 744
 745         # switch args (e.g. lei q -f mbox<TAB>)
 746         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 747                 my $opt = quotemeta $1;
 748                 puts $self, map {
 749                         my $v = $OPTDESC{$_};
 750                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 751                         # get rid of ALL CAPS placeholder (e.g "OUT")
 752                         # (TODO: completion for external paths)
 753                         shift(@v) if uc($v[0]) eq $v[0];
 754                         @v;
 755                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 756         }
 757         $cmd =~ tr/-/_/;
 758         if (my $sub = $self->can("_complete_$cmd")) {
 759                 puts $self, $sub->($self, @argv, $cur);
 760         }
 761         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 762         # proto parsing.
 763 }
 764
 765 sub exec_buf ($$) {
 766         my ($argv, $env) = @_;
 767         my $argc = scalar @$argv;
 768         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 769         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 770         $buf;
 771 }
 772
 773 sub start_mua {
 774         my ($self) = @_;
 775         my $mua = $self->{opt}->{'mua-cmd'} // return;
 776         my $mfolder = $self->{ovv}->{dst};
 777         my (@cmd, $replaced);
 778         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 779                 @cmd = ($mua, '-f');
 780         # TODO: help wanted: other common FOSS MUAs
 781         } else {
 782                 require Text::ParseWords;
 783                 my @cmd = Text::ParseWords::shellwords($mua);
 784                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 785                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 786         }
 787         push @cmd, $mfolder unless defined($replaced);
 788         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 789                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 790         } elsif ($self->{oneshot}) {
 791                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 792         }
 793 }
 794
 795 # caller needs to "-t $self->{1}" to check if tty
 796 sub start_pager {
 797         my ($self) = @_;
 798         my $env = $self->{env};
 799         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 800         chomp(my $pager = <$fh> // '');
 801         close($fh) or warn "`git var PAGER' error: \$?=$?";
 802         return if $pager eq 'cat' || $pager eq '';
 803         # TODO TIOCGWINSZ
 804         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 805         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 806         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 807         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 808         my $pgr = [ undef, @$rdr{1, 2} ];
 809         if (my $sock = $self->{sock}) { # lei(1) process runs it
 810                 delete @$new_env{keys %$env}; # only set iff unset
 811                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 812                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 813         } elsif ($self->{oneshot}) {
 814                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 815                 $pgr->[3] = $$; # ew'll reap it
 816         } else {
 817                 die 'BUG: start_pager w/o socket';
 818         }
 819         $self->{1} = $wpager;
 820         $self->{2} = $wpager if -t $self->{2};
 821         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 822         $self->{pgr} = $pgr;
 823 }
 824
 825 sub stop_pager {
 826         my ($self) = @_;
 827         my $pgr = delete($self->{pgr}) or return;
 828         $self->{2} = $pgr->[2];
 829         # do not restore original stdout, just close it so we error out
 830         close(delete($self->{1})) if $self->{1};
 831         my $pid = $pgr->[0];
 832         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 833 }
 834
 835 sub accept_dispatch { # Listener {post_accept} callback
 836         my ($sock) = @_; # ignore other
 837         $sock->autoflush(1);
 838         my $self = bless { sock => $sock }, __PACKAGE__;
 839         vec(my $rvec = '', fileno($sock), 1) = 1;
 840         select($rvec, undef, undef, 60) or
 841                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 842         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 843         if (scalar(@fds) == 4) {
 844                 for my $i (0..3) {
 845                         my $fd = shift(@fds);
 846                         open($self->{$i}, '+<&=', $fd) and next;
 847                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 848                 }
 849         } else {
 850                 my $msg = "recv_cmd failed: $!";
 851                 warn $msg;
 852                 return send($sock, $msg, MSG_EOR);
 853         }
 854         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 855         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 856         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 857         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 858                 return send($sock, 'request command truncated', MSG_EOR);
 859         my ($argc, @argv) = split(/\0/, $buf, -1);
 860         undef $buf;
 861         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 862         if (chdir($self->{3})) {
 863                 local %ENV = %env;
 864                 $self->{env} = \%env;
 865                 eval { dispatch($self, @argv) };
 866                 send($sock, $@, MSG_EOR) if $@;
 867         } else {
 868                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 869         }
 870 }
 871
 872 sub dclose {
 873         my ($self) = @_;
 874         delete $self->{-progress};
 875         for my $f (qw(lxs l2m)) {
 876                 my $wq = delete $self->{$f} or next;
 877                 if ($wq->wq_kill) {
 878                         $wq->wq_close
 879                 } elsif ($wq->wq_kill_old) {
 880                         $wq->wq_wait_old($self);
 881                 }
 882         }
 883         close(delete $self->{1}) if $self->{1}; # may reap_compress
 884         $self->close if $self->{sock}; # PublicInbox::DS::close
 885 }
 886
 887 # for long-running results
 888 sub event_step {
 889         my ($self) = @_;
 890         local %ENV = %{$self->{env}};
 891         my $sock = $self->{sock};
 892         local $current_lei = $self;
 893         eval {
 894                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 895                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 896                                 return if $! == EAGAIN;
 897                                 next if $! == EINTR;
 898                                 last if $! == ECONNRESET;
 899                                 die "recvmsg: $!";
 900                         }
 901                         for my $fd (@fds) {
 902                                 open my $rfh, '+<&=', $fd;
 903                         }
 904                         die "unrecognized client signal: $buf";
 905                 }
 906                 dclose($self);
 907         };
 908         if (my $err = $@) {
 909                 eval { $self->fail($err) };
 910                 dclose($self);
 911         }
 912 }
 913
 914 sub event_step_init {
 915         my ($self) = @_;
 916         if (my $sock = $self->{sock}) { # using DS->EventLoop
 917                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 918         }
 919 }
 920
 921 sub noop {}
 922
 923 our $oldset; sub oldset { $oldset }
 924
 925 sub dump_and_clear_log {
 926         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 927                 my @pfx = @_;
 928                 unshift(@pfx, "$errors_log ") if @pfx;
 929                 warn @pfx, do { local $/; <STDIN> };
 930                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 931         }
 932 }
 933
 934 # lei(1) calls this when it can't connect
 935 sub lazy_start {
 936         my ($path, $errno, $narg) = @_;
 937         if ($errno == ECONNREFUSED) {
 938                 unlink($path) or die "unlink($path): $!";
 939         } elsif ($errno != ENOENT) {
 940                 $! = $errno; # allow interpolation to stringify in die
 941                 die "connect($path): $!";
 942         }
 943         if (eval { require BSD::Resource }) {
 944                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 945                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 946                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 947         }
 948         umask(077) // die("umask(077): $!");
 949         local $listener;
 950         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 951         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 952         listen($listener, 1024) or die "listen: $!";
 953         my @st = stat($path) or die "stat($path): $!";
 954         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 955         local $oldset = PublicInbox::DS::block_signals();
 956         if ($narg == 5) {
 957                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 958                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 959                         require PublicInbox::CmdIPC4;
 960                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 961                         PublicInbox::CmdIPC4->can('recv_cmd4');
 962                 };
 963         }
 964         $recv_cmd or die <<"";
 965 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 966
 967         require PublicInbox::Listener;
 968         require PublicInbox::EOFpipe;
 969         (-p STDOUT) or die "E: stdout must be a pipe\n";
 970         local $errors_log;
 971         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 972         $errors_log .= 'errors.log';
 973         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 974         STDIN->autoflush(1);
 975         dump_and_clear_log("from previous daemon process:\n");
 976         POSIX::setsid() > 0 or die "setsid: $!";
 977         my $pid = fork // die "fork: $!";
 978         return if $pid;
 979         $0 = "lei-daemon $path";
 980         local %PATH2CFG;
 981         $listener->blocking(0);
 982         my $exit_code;
 983         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 984         local $quit = do {
 985                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 986                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 987                 sub {
 988                         $exit_code //= shift;
 989                         my $lis = $pil or exit($exit_code);
 990                         # closing eof_w triggers \&noop wakeup
 991                         $listener = $eof_w = $pil = $path = undef;
 992                         $lis->close; # DS::close
 993                         PublicInbox::DS->SetLoopTimeout(1000);
 994                 };
 995         };
 996         my $sig = {
 997                 CHLD => \&PublicInbox::DS::enqueue_reap,
 998                 QUIT => $quit,
 999                 INT => $quit,
1000                 TERM => $quit,
1001                 HUP => \&noop,
1002                 USR1 => \&noop,
1003                 USR2 => \&noop,
1004         };
1005         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1006         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1007         undef $sig;
1008         local $SIG{PIPE} = 'IGNORE';
1009         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1010                 undef $sigfd;
1011                 PublicInbox::DS->SetLoopTimeout(5000);
1012         } else {
1013                 # wake up every second to accept signals if we don't
1014                 # have signalfd or IO::KQueue:
1015                 PublicInbox::DS::sig_setmask($oldset);
1016                 PublicInbox::DS->SetLoopTimeout(1000);
1017         }
1018         PublicInbox::DS->SetPostLoopCallback(sub {
1019                 my ($dmap, undef) = @_;
1020                 if (@st = defined($path) ? stat($path) : ()) {
1021                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1022                                 warn "$path dev/ino changed, quitting\n";
1023                                 $path = undef;
1024                         }
1025                 } elsif (defined($path)) { # ENOENT is common
1026                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1027                         undef $path;
1028                         $quit->();
1029                 }
1030                 return 1 if defined($path);
1031                 my $now = now();
1032                 my $n = 0;
1033                 for my $s (values %$dmap) {
1034                         $s->can('busy') or next;
1035                         if ($s->busy($now)) {
1036                                 ++$n;
1037                         } else {
1038                                 $s->close;
1039                         }
1040                 }
1041                 $n; # true: continue, false: stop
1042         });
1043
1044         # STDIN was redirected to /dev/null above, closing STDERR and
1045         # STDOUT will cause the calling `lei' client process to finish
1046         # reading the <$daemon> pipe.
1047         local $SIG{__WARN__} = sub {
1048                 $current_lei ? err($current_lei, @_) : warn(
1049                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1050         };
1051         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1052         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1053         # $daemon pipe to `lei' closed, main loop begins:
1054         PublicInbox::DS->EventLoop;
1055         exit($exit_code // 0);
1056 }
1057
1058 # for users w/o Socket::Msghdr installed or Inline::C enabled
1059 sub oneshot {
1060         my ($main_pkg) = @_;
1061         my $exit = $main_pkg->can('exit'); # caller may override exit()
1062         local $quit = $exit if $exit;
1063         local %PATH2CFG;
1064         umask(077) // die("umask(077): $!");
1065         my $self = bless {
1066                 oneshot => 1,
1067                 0 => *STDIN{GLOB},
1068                 1 => *STDOUT{GLOB},
1069                 2 => *STDERR{GLOB},
1070                 env => \%ENV
1071         }, __PACKAGE__;
1072         dispatch($self, @ARGV);
1073         x_it($self, $self->{child_error}) if $self->{child_error};
1074 }
1075
1076 # ensures stdout hits the FS before sock disconnects so a client
1077 # can immediately reread it
1078 sub DESTROY {
1079         my ($self) = @_;
1080         $self->{1}->autoflush(1) if $self->{1};
1081         stop_pager($self);
1082         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1083                 waitpid($mua_pid, 0);
1084         }
1085 }
1086
1087 1;