lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use Sys::Syslog qw(syslog openlog);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  87         verbose|v
  88         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  89
  90 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  91         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  92         pass_through('git show') ],
  93
  94 'add-external' => [ 'URL_OR_PATHNAME',
  95         'add/set priority of a publicinbox|extindex for extra matches',
  96         qw(boost=i quiet|q) ],
  97 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  98         qw(format|f=s z|0 local remote quiet|q) ],
  99 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 100         'exclude further results from a publicinbox|extindex',
 101         qw(prune quiet|q) ],
 102
 103 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 104                 qw(name-only format|f=s z) ],
 105 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 106 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 107
 108 'plonk' => [ '--thread|--from=IDENT',
 109         'exclude mail matching From: or thread from non-Message-ID searches',
 110         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 111 'mark' => [ 'MESSAGE_FLAGS...',
 112         'set/unset flags on message(s) from stdin',
 113         qw(stdin| oid=s exact by-mid|mid:s) ],
 114 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 115         "exclude message(s) on stdin from `q' search results",
 116         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 117
 118 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 119         'remove imported messages from IMAP, Maildirs, and MH',
 120         qw(exact! all jobs:i indexed) ],
 121
 122 # code repos are used for `show' to solve blobs from patch mails
 123 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 124         qw(boost=i) ],
 125 'ls-coderepo' => [ '[FILTER_TERMS...]',
 126                 'list known code repos', qw(format|f=s z) ],
 127 'forget-coderepo' => [ 'PATHNAME',
 128         'stop using repo to solve blobs from patches',
 129         qw(prune) ],
 130
 131 'add-watch' => [ '[URL_OR_PATHNAME]',
 132                 'watch for new messages and flag changes',
 133         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 134 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 135                 qw(format|f=s z) ],
 136 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 138 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 139         qw(prune) ],
 140
 141 'import' => [ 'URL_OR_PATHNAME|--stdin',
 142         'one-shot import/update from URL or filesystem',
 143         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 144         ],
 145
 146 'config' => [ '[...]', sub {
 147                 'git-config(1) wrapper for '._config_path($_[0]);
 148         }, qw(config-file|system|global|file|f=s), # for conflict detection
 149         pass_through('git config') ],
 150 'init' => [ '[PATHNAME]', sub {
 151                 'initialize storage, default: '._store_path($_[0]);
 152         }, qw(quiet|q) ],
 153 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 154         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 155 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 156 'help' => [ '[SUBCOMMAND]', 'show help' ],
 157
 158 # XXX do we need this?
 159 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 160
 161 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 162         'rewrite git history in an attempt to improve compression',
 163         'gc!' ],
 164
 165 # internal commands are prefixed with '_'
 166 '_complete' => [ '[...]', 'internal shell completion helper',
 167                 pass_through('everything') ],
 168 ); # @CMD
 169
 170 # switch descriptions, try to keep consistent across commands
 171 # $spec: Getopt::Long option specification
 172 # $spec => [@ALLOWED_VALUES (default is first), $description],
 173 # $spec => $description
 174 # "$SUB_COMMAND TAB $spec" => as above
 175 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 176                 'specify message input format' ];
 177 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 178
 179 my %OPTDESC = (
 180 'help|h' => 'show this built-in help',
 181 'quiet|q' => 'be quiet',
 182 'solve!' => 'do not attempt to reconstruct blobs from emails',
 183 'save-as=s' => ['NAME', 'save a search terms by given name'],
 184
 185 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 186
 187 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 188                 'deduplication strategy'],
 189 'show   thread|t' => 'display entire thread a message belongs to',
 190 'q      thread|t' =>
 191         'return all messages in the same thread as the actual match(es)',
 192 'augment|a' => 'augment --output destination instead of clobbering',
 193
 194 'output|o=s' => [ 'DEST',
 195         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 196 'mua-cmd|mua=s' => [ 'COMMAND',
 197         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 198
 199 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 200                         'message/object output format' ],
 201 'mark   format|f=s' => $stdin_formats,
 202 'forget format|f=s' => $stdin_formats,
 203 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 204                 'specify output format, default depends on --output'],
 205 'ls-query       format|f=s' => $ls_format,
 206 'ls-external    format|f=s' => $ls_format,
 207
 208 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 209 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 210
 211 'sort|s=s' => [ 'VAL|received,relevance,docid',
 212                 "order of results `--output'-dependent"],
 213 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 214
 215 'boost=i' => 'increase/decrease priority of results (default: 0)',
 216
 217 'local' => 'limit operations to the local filesystem',
 218 'local!' => 'exclude results from the local filesystem',
 219 'remote' => 'limit operations to those requiring network access',
 220 'remote!' => 'prevent operations requiring network access',
 221
 222 'mid=s' => 'specify the Message-ID of a message',
 223 'oid=s' => 'specify the git object ID of a message',
 224
 225 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 226 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 227 'include=s' => 'include mailboxes/newsgroups based on pattern',
 228
 229 'exact' => 'operate on exact header matches only',
 230 'exact!' => 'rely on content match instead of exact header matches',
 231
 232 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 233 'jobs:i' => 'set parallelism level',
 234
 235 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 236 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 237
 238 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 239 ); # %OPTDESC
 240
 241 my %CONFIG_KEYS = (
 242         'leistore.dir' => 'top-level storage location',
 243 );
 244
 245 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 246 sub x_it ($$) {
 247         my ($self, $code) = @_;
 248         # make sure client sees stdout before exit
 249         $self->{1}->autoflush(1) if $self->{1};
 250         dump_and_clear_log();
 251         if (my $sock = $self->{sock}) {
 252                 send($sock, "x_it $code", MSG_EOR);
 253         } elsif (!($code & 127)) { # oneshot, ignore signals
 254                 # don't want to end up using $? from child processes
 255                 for my $f (qw(lxs l2m)) {
 256                         my $wq = delete $self->{$f} or next;
 257                         $wq->DESTROY;
 258                 }
 259                 $quit->($code >> 8);
 260         }
 261 }
 262
 263 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 264
 265 sub out ($;@) { print { shift->{1} } @_ }
 266
 267 sub err ($;@) {
 268         my $self = shift;
 269         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 270         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 271 }
 272
 273 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 274
 275 sub fail ($$;$) {
 276         my ($self, $buf, $exit_code) = @_;
 277         err($self, $buf);
 278         x_it($self, ($exit_code // 1) << 8);
 279         undef;
 280 }
 281
 282 sub child_error { # passes non-fatal curl exit codes to user
 283         my ($self, $child_error) = @_; # child_error is $?
 284         if (my $sock = $self->{sock}) { # send to lei(1) client
 285                 send($sock, "child_error $child_error", MSG_EOR);
 286         } else { # oneshot
 287                 $self->{child_error} = $child_error;
 288         }
 289         undef;
 290 }
 291
 292 sub atfork_prepare_wq {
 293         my ($self, $wq) = @_;
 294         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 295         if (my $sock = $self->{sock}) {
 296                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 297         }
 298         if (my $pgr = $self->{pgr}) {
 299                 push @$tcafc, @$pgr[1,2];
 300         }
 301         if (my $old_1 = $self->{old_1}) {
 302                 push @$tcafc, $old_1;
 303         }
 304         for my $f (qw(lxs l2m)) {
 305                 my $ipc = $self->{$f} or next;
 306                 push @$tcafc, grep { defined }
 307                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 308         }
 309 }
 310
 311 # usage: my %sig = $lei->atfork_child_wq($wq);
 312 #        local @SIG{keys %sig} = values %sig;
 313 sub atfork_child_wq {
 314         my ($self, $wq) = @_;
 315         my ($sock, $l2m_wq_s1);
 316         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 317         $self->{sock} = $sock if -S $sock;
 318         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 319         %PATH2CFG = ();
 320         undef $errors_log;
 321         $quit = \&CORE::exit;
 322         (__WARN__ => sub { err($self, @_) },
 323         PIPE => sub {
 324                 $self->x_it(13); # SIGPIPE = 13
 325                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 326                 for my $i (1, 2) {
 327                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 328                         close(delete $self->{$i});
 329                 }
 330                 # trigger the LeiXSearch $done OpPipe:
 331                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 332                 $SIG{PIPE} = 'DEFAULT';
 333                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 334         });
 335 }
 336
 337 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 338 sub atfork_parent_wq {
 339         my ($self, $wq) = @_;
 340         my $env = delete $self->{env}; # env is inherited at fork
 341         my $ret = bless { %$self }, ref($self);
 342         if (my $dedupe = delete $ret->{dedupe}) {
 343                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 344         }
 345         $self->{env} = $env;
 346         delete @$ret{qw(-lei_store cfg old_1 pgr lxs)}; # keep l2m
 347         my @io = delete @$ret{0..2};
 348         $io[3] = delete($ret->{sock}) // $io[2];
 349         my $l2m = $ret->{l2m};
 350         if ($l2m && $l2m != $wq) { # $wq == lxs
 351                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 352                 $l2m->wq_close(1);
 353         }
 354         ($ret, @io);
 355 }
 356
 357 sub _help ($;$) {
 358         my ($self, $errmsg) = @_;
 359         my $cmd = $self->{cmd} // 'COMMAND';
 360         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 361         my @top = ($cmd, shift(@info) // ());
 362         my $cmd_desc = shift(@info);
 363         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 364         my @opt_desc;
 365         my $lpad = 2;
 366         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 367                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 368                 my $arg_vals = '';
 369                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 370
 371                 # lower-case is a keyword (e.g. `content', `oid'),
 372                 # ALL_CAPS is a string description (e.g. `PATH')
 373                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 374                         $desc .= "\ndefault: `$1'";
 375                 }
 376                 my (@vals, @s, @l);
 377                 my $x = $sw;
 378                 if ($x =~ s/!\z//) { # solve! => --no-solve
 379                         $x = "no-$x";
 380                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 381                         @vals = (' [', undef, ']');
 382                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 383                         @vals = (' ', undef);
 384                 } # else: no args $x = 'thread|t'
 385                 for (split(/\|/, $x)) { # help|h
 386                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 387                 }
 388                 if (!scalar(@vals)) { # no args 'thread|t'
 389                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 390                         $vals[1] = $1;
 391                 } else {
 392                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 393                 }
 394                 if ($arg_vals =~ /([,\|])/) {
 395                         my $sep = $1;
 396                         my @allow = split(/\Q$sep\E/, $arg_vals);
 397                         my $must = $sep eq '|' ? 'Must' : 'Can';
 398                         @allow = map { "`$_'" } @allow;
 399                         my $last = pop @allow;
 400                         $desc .= "\n$must be one of: " .
 401                                 join(', ', @allow) . " or $last";
 402                 }
 403                 my $lhs = join(', ', @s, @l) . join('', @vals);
 404                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 405                         $lhs =~ s/\A--/- , --/;
 406                 } else {
 407                         $lhs =~ s/\A--/    --/; # pad if no short options
 408                 }
 409                 $lpad = length($lhs) if length($lhs) > $lpad;
 410                 push @opt_desc, $lhs, $desc;
 411         }
 412         my $msg = $errmsg ? "E: $errmsg\n" : '';
 413         $msg .= <<EOF;
 414 usage: lei @top
 415   $cmd_desc
 416
 417 EOF
 418         $lpad += 2;
 419         local $Text::Wrap::columns = 78 - $lpad;
 420         my $padding = ' ' x ($lpad + 2);
 421         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 422                 $msg .= '  '.pack("A$lpad", $lhs);
 423                 $rhs = wrap('', '', $rhs);
 424                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 425                 $msg .= $rhs;
 426                 $msg .= "\n";
 427         }
 428         print { $self->{$errmsg ? 2 : 1} } $msg;
 429         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 430         undef;
 431 }
 432
 433 sub optparse ($$$) {
 434         my ($self, $cmd, $argv) = @_;
 435         $self->{cmd} = $cmd;
 436         $OPT = $self->{opt} = {};
 437         my $info = $CMD{$cmd} // [ '[...]' ];
 438         my ($proto, undef, @spec) = @$info;
 439         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 440         push @spec, qw(help|h);
 441         my $lone_dash;
 442         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 443                 $lone_dash = $spec[0];
 444                 $OPT->{$spec[0]} = \(my $var);
 445                 push @spec, '' => \$var;
 446         }
 447         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 448                 return _help($self, "bad arguments or options for $cmd");
 449         return _help($self) if $OPT->{help};
 450
 451         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 452
 453         # "-" aliases "stdin" or "clear"
 454         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 455
 456         my $i = 0;
 457         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 458         my ($err, $inf);
 459         my @args = split(/ /, $proto);
 460         for my $var (@args) {
 461                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 462                         $inf = defined($argv->[$i]) and last;
 463                         $var =~ s/\.\.\.\z//;
 464                         $err = "$var not supplied";
 465                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 466                         $argv->[$i++] // ($err = "$var not supplied");
 467                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 468                         $inf = 1;
 469                         last;
 470                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 471                         $i++;
 472                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 473                         my @or = split(/\|/, $var);
 474                         my $ok;
 475                         for my $o (@or) {
 476                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 477                                         $ok = defined($OPT->{$1});
 478                                         last;
 479                                 } elsif (defined($argv->[$i])) {
 480                                         $ok = 1;
 481                                         $i++;
 482                                         last;
 483                                 } # else continue looping
 484                         }
 485                         last if $ok;
 486                         my $last = pop @or;
 487                         $err = join(', ', @or) . " or $last must be set";
 488                 } else {
 489                         warn "BUG: can't parse `$var' in $proto";
 490                 }
 491                 last if $err;
 492         }
 493         if (!$inf && scalar(@$argv) > scalar(@args)) {
 494                 $err //= 'too many arguments';
 495         }
 496         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 497 }
 498
 499 sub dispatch {
 500         my ($self, $cmd, @argv) = @_;
 501         local $current_lei = $self; # for __WARN__
 502         dump_and_clear_log("from previous run\n");
 503         return _help($self, 'no command given') unless defined($cmd);
 504         my $func = "lei_$cmd";
 505         $func =~ tr/-/_/;
 506         if (my $cb = __PACKAGE__->can($func)) {
 507                 optparse($self, $cmd, \@argv) or return;
 508                 $cb->($self, @argv);
 509         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 510                 my $opt = {};
 511                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 512                         return _help($self, 'bad arguments or options');
 513                 _help($self);
 514         } else {
 515                 fail($self, "`$cmd' is not an lei command");
 516         }
 517 }
 518
 519 sub _lei_cfg ($;$) {
 520         my ($self, $creat) = @_;
 521         my $f = _config_path($self->{env});
 522         my @st = stat($f);
 523         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 524         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 525                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 526         }
 527         if (!@st) {
 528                 unless ($creat) {
 529                         delete $self->{cfg};
 530                         return;
 531                 }
 532                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 533                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 534                 open my $fh, '>>', $f or die "open($f): $!\n";
 535                 @st = stat($fh) or die "fstat($f): $!\n";
 536                 $cur_st = pack('dd', $st[10], $st[7]);
 537                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 538         }
 539         my $cfg = PublicInbox::Config::git_config_dump($f);
 540         $cfg->{-st} = $cur_st;
 541         $cfg->{'-f'} = $f;
 542         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 543 }
 544
 545 sub _lei_store ($;$) {
 546         my ($self, $creat) = @_;
 547         my $cfg = _lei_cfg($self, $creat);
 548         $cfg->{-lei_store} //= do {
 549                 require PublicInbox::LeiStore;
 550                 my $dir = $cfg->{'leistore.dir'};
 551                 $dir //= _store_path($self->{env}) if $creat;
 552                 return unless $dir;
 553                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 554         };
 555 }
 556
 557 sub lei_show {
 558         my ($self, @argv) = @_;
 559 }
 560
 561 sub lei_mark {
 562         my ($self, @argv) = @_;
 563 }
 564
 565 sub _config {
 566         my ($self, @argv) = @_;
 567         my $env = $self->{env};
 568         delete local $env->{GIT_CONFIG};
 569         delete local $ENV{GIT_CONFIG};
 570         my $cfg = _lei_cfg($self, 1);
 571         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 572         my %rdr = map { $_ => $self->{$_} } (0..2);
 573         waitpid(spawn($cmd, $env, \%rdr), 0);
 574 }
 575
 576 sub lei_config {
 577         my ($self, @argv) = @_;
 578         $self->{opt}->{'config-file'} and return fail $self,
 579                 "config file switches not supported by `lei config'";
 580         _config(@_);
 581         x_it($self, $?) if $?;
 582 }
 583
 584 sub lei_init {
 585         my ($self, $dir) = @_;
 586         my $cfg = _lei_cfg($self, 1);
 587         my $cur = $cfg->{'leistore.dir'};
 588         my $env = $self->{env};
 589         $dir //= _store_path($env);
 590         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 591         my @cur = stat($cur) if defined($cur);
 592         $cur = File::Spec->canonpath($cur // $dir);
 593         my @dir = stat($dir);
 594         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 595         if (@cur) {
 596                 if ($cur eq $dir) {
 597                         _lei_store($self, 1)->done;
 598                         return qerr($self, $exists);
 599                 }
 600
 601                 # some folks like symlinks and bind mounts :P
 602                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 603                         lei_config($self, 'leistore.dir', $dir);
 604                         _lei_store($self, 1)->done;
 605                         return qerr($self, "$exists (as $cur)");
 606                 }
 607                 return fail($self, <<"");
 608 E: leistore.dir=$cur already initialized and it is not $dir
 609
 610         }
 611         lei_config($self, 'leistore.dir', $dir);
 612         _lei_store($self, 1)->done;
 613         $exists //= "I: leistore.dir=$dir newly initialized";
 614         return qerr($self, $exists);
 615 }
 616
 617 sub lei_daemon_pid { puts shift, $$ }
 618
 619 sub lei_daemon_kill {
 620         my ($self) = @_;
 621         my $sig = $self->{opt}->{signal} // 'TERM';
 622         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 623 }
 624
 625 sub lei_help { _help($_[0]) }
 626
 627 # Shell completion helper.  Used by lei-completion.bash and hopefully
 628 # other shells.  Try to do as much here as possible to avoid redundancy
 629 # and improve maintainability.
 630 sub lei__complete {
 631         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 632         shift @argv; # ignore "lei", the entire command is sent
 633         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 634         my $cmd = shift @argv;
 635         my $info = $CMD{$cmd} // do { # filter matching commands
 636                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 637                 return;
 638         };
 639         my ($proto, undef, @spec) = @$info;
 640         my $cur = pop @argv;
 641         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 642         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 643                 # gross special case since the only git-config options
 644                 # Consider moving to a table if we need more special cases
 645                 # we use Getopt::Long for are the ones we reject, so these
 646                 # are the ones we don't reject:
 647                 if ($cmd eq 'config') {
 648                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 649                         @spec = qw(add z|null get get-all unset unset-all
 650                                 replace-all get-urlmatch
 651                                 remove-section rename-section
 652                                 name-only list|l edit|e
 653                                 get-color-name get-colorbool);
 654                         # fall-through
 655                 }
 656                 # TODO: arg support
 657                 puts $self, grep(/$re/, map { # generate short/long names
 658                         my $eq = '';
 659                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 660                                 $eq = '=';
 661                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 662                         } else { # negation: solve! => no-solve|solve
 663                                 s/\A(.+)!\z/no-$1|$1/;
 664                         }
 665                         map {
 666                                 length > 1 ? "--$_$eq" : "-$_"
 667                         } split(/\|/, $_, -1) # help|h
 668                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 669         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 670                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 671         }
 672         $cmd =~ tr/-/_/;
 673         if (my $sub = $self->can("_complete_$cmd")) {
 674                 puts $self, $sub->($self, @argv, $cur);
 675         }
 676         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 677         # proto parsing.
 678 }
 679
 680 sub reap_exec { # dwaitpid callback
 681         my ($self, $pid) = @_;
 682         x_it($self, $?);
 683 }
 684
 685 sub lei_git { # support passing through random git commands
 686         my ($self, @argv) = @_;
 687         my %rdr = map { $_ => $self->{$_} } (0..2);
 688         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 689         dwaitpid($pid, \&reap_exec, $self);
 690 }
 691
 692 sub exec_buf ($$) {
 693         my ($argv, $env) = @_;
 694         my $argc = scalar @$argv;
 695         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 696         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 697         $buf;
 698 }
 699
 700 sub start_mua {
 701         my ($self, $sock) = @_;
 702         my $mua = $self->{opt}->{'mua-cmd'} // return;
 703         my $mfolder = $self->{ovv}->{dst};
 704         require Text::ParseWords;
 705         my $replaced;
 706         my @cmd = Text::ParseWords::shellwords($mua);
 707         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 708         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 709         push @cmd, $mfolder unless defined($replaced);
 710         $sock //= $self->{sock};
 711         if ($sock) { # lei(1) client process runs it
 712                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 713         } else { # oneshot
 714                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 715         }
 716 }
 717
 718 # caller needs to "-t $self->{1}" to check if tty
 719 sub start_pager {
 720         my ($self) = @_;
 721         my $env = $self->{env};
 722         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 723         chomp(my $pager = <$fh> // '');
 724         close($fh) or warn "`git var PAGER' error: \$?=$?";
 725         return if $pager eq 'cat' || $pager eq '';
 726         # TODO TIOCGWINSZ
 727         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 728         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 729         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 730         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 731         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 732         if (my $sock = $self->{sock}) { # lei(1) process runs it
 733                 delete @$new_env{keys %$env}; # only set iff unset
 734                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 735                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 736         } else {
 737                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 738         }
 739         $self->{1} = $wpager;
 740         $self->{2} = $wpager if -t $self->{2};
 741         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 742         $self->{pgr} = $pgr;
 743 }
 744
 745 sub stop_pager {
 746         my ($self) = @_;
 747         my $pgr = delete($self->{pgr}) or return;
 748         $self->{2} = $pgr->[2];
 749         # do not restore original stdout, just close it so we error out
 750         close(delete($self->{1})) if $self->{1};
 751         my $pid = $pgr->[0];
 752         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 753 }
 754
 755 sub accept_dispatch { # Listener {post_accept} callback
 756         my ($sock) = @_; # ignore other
 757         $sock->autoflush(1);
 758         my $self = bless { sock => $sock }, __PACKAGE__;
 759         vec(my $rvec = '', fileno($sock), 1) = 1;
 760         select($rvec, undef, undef, 1) or
 761                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 762         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 763         if (scalar(@fds) == 4) {
 764                 my $i = 0;
 765                 for my $rdr (qw(<&= >&= >&= <&=)) {
 766                         my $fd = shift(@fds);
 767                         open($self->{$i++}, $rdr, $fd) and next;
 768                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 769                 }
 770         } else {
 771                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 772         }
 773         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 774         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 775         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 776         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 777                 return send($sock, 'request command truncated', MSG_EOR);
 778         my ($argc, @argv) = split(/\0/, $buf, -1);
 779         undef $buf;
 780         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 781         if (chdir(delete($self->{3}))) {
 782                 local %ENV = %env;
 783                 $self->{env} = \%env;
 784                 eval { dispatch($self, @argv) };
 785                 send($sock, $@, MSG_EOR) if $@;
 786         } else {
 787                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 788         }
 789 }
 790
 791 sub dclose {
 792         my ($self) = @_;
 793         for my $f (qw(lxs l2m)) {
 794                 my $wq = delete $self->{$f} or next;
 795                 if ($wq->wq_kill) {
 796                         $self->wq_close
 797                 } elsif ($wq->wq_kill_old) {
 798                         $wq->wq_wait_old;
 799                 }
 800         }
 801         close(delete $self->{1}) if $self->{1}; # may reap_compress
 802         $self->close if $self->{sock}; # PublicInbox::DS::close
 803 }
 804
 805 # for long-running results
 806 sub event_step {
 807         my ($self) = @_;
 808         local %ENV = %{$self->{env}};
 809         my $sock = $self->{sock};
 810         local $current_lei = $self;
 811         eval {
 812                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 813                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 814                                 return if $! == EAGAIN;
 815                                 next if $! == EINTR;
 816                                 last if $! == ECONNRESET;
 817                                 die "recvmsg: $!";
 818                         }
 819                         for my $fd (@fds) {
 820                                 open my $rfh, '+<&=', $fd;
 821                         }
 822                         die "unrecognized client signal: $buf";
 823                 }
 824                 dclose($self);
 825         };
 826         if (my $err = $@) {
 827                 eval { $self->fail($err) };
 828                 dclose($self);
 829         }
 830 }
 831
 832 sub event_step_init {
 833         my ($self) = @_;
 834         if (my $sock = $self->{sock}) { # using DS->EventLoop
 835                 $sock->blocking(0);
 836                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 837         }
 838 }
 839
 840 sub noop {}
 841
 842 our $oldset; sub oldset { $oldset }
 843
 844 sub dump_and_clear_log {
 845         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 846                 my @pfx = @_;
 847                 unshift(@pfx, "$errors_log ") if @pfx;
 848                 warn @pfx, do { local $/; <STDIN> };
 849                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 850         }
 851 }
 852
 853 # lei(1) calls this when it can't connect
 854 sub lazy_start {
 855         my ($path, $errno, $narg) = @_;
 856         if ($errno == ECONNREFUSED) {
 857                 unlink($path) or die "unlink($path): $!";
 858         } elsif ($errno != ENOENT) {
 859                 $! = $errno; # allow interpolation to stringify in die
 860                 die "connect($path): $!";
 861         }
 862         umask(077) // die("umask(077): $!");
 863         local $listener;
 864         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 865         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 866         listen($listener, 1024) or die "listen: $!";
 867         my @st = stat($path) or die "stat($path): $!";
 868         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 869         local $oldset = PublicInbox::DS::block_signals();
 870         if ($narg == 5) {
 871                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 872                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 873                         require PublicInbox::CmdIPC4;
 874                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 875                         PublicInbox::CmdIPC4->can('recv_cmd4');
 876                 };
 877         }
 878         $recv_cmd or die <<"";
 879 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 880
 881         require PublicInbox::Listener;
 882         require PublicInbox::EOFpipe;
 883         (-p STDOUT) or die "E: stdout must be a pipe\n";
 884         local $errors_log;
 885         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 886         $errors_log .= 'errors.log';
 887         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 888         STDIN->autoflush(1);
 889         dump_and_clear_log("from previous daemon process:\n");
 890         POSIX::setsid() > 0 or die "setsid: $!";
 891         my $pid = fork // die "fork: $!";
 892         return if $pid;
 893         $0 = "lei-daemon $path";
 894         local %PATH2CFG;
 895         $listener->blocking(0);
 896         my $exit_code;
 897         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 898         local $quit = do {
 899                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 900                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 901                 sub {
 902                         $exit_code //= shift;
 903                         my $lis = $pil or exit($exit_code);
 904                         # closing eof_w triggers \&noop wakeup
 905                         $listener = $eof_w = $pil = $path = undef;
 906                         $lis->close; # DS::close
 907                         PublicInbox::DS->SetLoopTimeout(1000);
 908                 };
 909         };
 910         my $sig = {
 911                 CHLD => \&PublicInbox::DS::enqueue_reap,
 912                 QUIT => $quit,
 913                 INT => $quit,
 914                 TERM => $quit,
 915                 HUP => \&noop,
 916                 USR1 => \&noop,
 917                 USR2 => \&noop,
 918         };
 919         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 920         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 921         undef $sig;
 922         local $SIG{PIPE} = 'IGNORE';
 923         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 924                 undef $sigfd;
 925                 PublicInbox::DS->SetLoopTimeout(5000);
 926         } else {
 927                 # wake up every second to accept signals if we don't
 928                 # have signalfd or IO::KQueue:
 929                 PublicInbox::DS::sig_setmask($oldset);
 930                 PublicInbox::DS->SetLoopTimeout(1000);
 931         }
 932         PublicInbox::DS->SetPostLoopCallback(sub {
 933                 my ($dmap, undef) = @_;
 934                 if (@st = defined($path) ? stat($path) : ()) {
 935                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 936                                 warn "$path dev/ino changed, quitting\n";
 937                                 $path = undef;
 938                         }
 939                 } elsif (defined($path)) {
 940                         warn "stat($path): $!, quitting ...\n";
 941                         undef $path; # don't unlink
 942                         $quit->();
 943                 }
 944                 return 1 if defined($path);
 945                 my $now = now();
 946                 my $n = 0;
 947                 for my $s (values %$dmap) {
 948                         $s->can('busy') or next;
 949                         if ($s->busy($now)) {
 950                                 ++$n;
 951                         } else {
 952                                 $s->close;
 953                         }
 954                 }
 955                 $n; # true: continue, false: stop
 956         });
 957
 958         # STDIN was redirected to /dev/null above, closing STDERR and
 959         # STDOUT will cause the calling `lei' client process to finish
 960         # reading the <$daemon> pipe.
 961         openlog($path, 'pid', 'user');
 962         local $SIG{__WARN__} = sub {
 963                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 964         };
 965         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 966                 syslog('crit', "$@") if $@;
 967         });
 968         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 969         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 970         # $daemon pipe to `lei' closed, main loop begins:
 971         PublicInbox::DS->EventLoop;
 972         @$on_destroy = (); # cancel on_destroy if we get here
 973         exit($exit_code // 0);
 974 }
 975
 976 # for users w/o Socket::Msghdr installed or Inline::C enabled
 977 sub oneshot {
 978         my ($main_pkg) = @_;
 979         my $exit = $main_pkg->can('exit'); # caller may override exit()
 980         local $quit = $exit if $exit;
 981         local %PATH2CFG;
 982         umask(077) // die("umask(077): $!");
 983         my $self = bless {
 984                 0 => *STDIN{GLOB},
 985                 1 => *STDOUT{GLOB},
 986                 2 => *STDERR{GLOB},
 987                 env => \%ENV
 988         }, __PACKAGE__;
 989         dispatch($self, @ARGV);
 990         x_it($self, $self->{child_error}) if $self->{child_error};
 991 }
 992
 993 # ensures stdout hits the FS before sock disconnects so a client
 994 # can immediately reread it
 995 sub DESTROY {
 996         my ($self) = @_;
 997         $self->{1}->autoflush(1) if $self->{1};
 998         stop_pager($self);
 999         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1000                 waitpid($mua_pid, 0);
1001         }
1002 }
1003
1004 1;