lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g stdin|
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 205 'verbose|v' => 'be more verbose',
 206 'solve!' => 'do not attempt to reconstruct blobs from emails',
 207 'torsocks=s' => ['auto|no|yes',
 208                 'whether or not to wrap git and curl commands with torsocks'],
 209 'no-torsocks' => 'alias for --torsocks=no',
 210 'save-as=s' => ['NAME', 'save a search terms by given name'],
 211
 212 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 213
 214 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 215                 'deduplication strategy'],
 216 'show   thread|t' => 'display entire thread a message belongs to',
 217 'q      thread|t' =>
 218         'return all messages in the same thread as the actual match(es)',
 219 'augment|a' => 'augment --output destination instead of clobbering',
 220
 221 'output|mfolder|o=s' => [ 'DEST',
 222         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 223 'mua-cmd|mua=s' => [ 'COMMAND',
 224         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 225
 226 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 227                         'message/object output format' ],
 228 'mark   format|f=s' => $stdin_formats,
 229 'forget format|f=s' => $stdin_formats,
 230 'q      format|f=s' => [
 231         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 232                 'specify output format, default depends on --output'],
 233 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 234                 'exclude specified external(s) from search' ],
 235 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 236                 'include specified external(s) in search' ],
 237 'q      only=s@' => [ 'URL_OR_PATHNAME',
 238                 'only use specified external(s) for search' ],
 239
 240 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 241                 'control number of search and writer jobs' ],
 242
 243 'ls-query       format|f=s' => $ls_format,
 244 'ls-external    format|f=s' => $ls_format,
 245
 246 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 247 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 248
 249 'sort|s=s' => [ 'VAL|received,relevance,docid',
 250                 "order of results `--output'-dependent"],
 251 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 252
 253 'boost=i' => 'increase/decrease priority of results (default: 0)',
 254
 255 'local' => 'limit operations to the local filesystem',
 256 'local!' => 'exclude results from the local filesystem',
 257 'remote' => 'limit operations to those requiring network access',
 258 'remote!' => 'prevent operations requiring network access',
 259
 260 'mid=s' => 'specify the Message-ID of a message',
 261 'oid=s' => 'specify the git object ID of a message',
 262
 263 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 264 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 265 'include=s' => 'include mailboxes/newsgroups based on pattern',
 266
 267 'exact' => 'operate on exact header matches only',
 268 'exact!' => 'rely on content match instead of exact header matches',
 269
 270 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 271 'jobs:i' => 'set parallelism level',
 272
 273 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 274 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 275
 276 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 277 ); # %OPTDESC
 278
 279 my %CONFIG_KEYS = (
 280         'leistore.dir' => 'top-level storage location',
 281 );
 282
 283 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 284 sub x_it ($$) {
 285         my ($self, $code) = @_;
 286         # make sure client sees stdout before exit
 287         $self->{1}->autoflush(1) if $self->{1};
 288         dump_and_clear_log();
 289         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 290                 send($s, "x_it $code", MSG_EOR);
 291         } elsif ($self->{oneshot}) {
 292                 # don't want to end up using $? from child processes
 293                 for my $f (qw(lxs l2m)) {
 294                         my $wq = delete $self->{$f} or next;
 295                         $wq->DESTROY;
 296                 }
 297                 # cleanup anything that has tempfiles
 298                 delete @$self{qw(ovv dedupe)};
 299                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 300                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 301                         kill $signum, $$;
 302                         sleep(1) while 1; # wait for signal
 303                 } else {
 304                         $quit->($code >> 8);
 305                 }
 306         } # else ignore if client disconnected
 307 }
 308
 309 sub err ($;@) {
 310         my $self = shift;
 311         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 312         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 313         print $err @_, @eor and return;
 314         my $old_err = delete $self->{2};
 315         close($old_err) if $! == EPIPE && $old_err;
 316         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 317         print $err @_, @eor or print STDERR @_, @eor;
 318 }
 319
 320 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 321
 322 sub fail ($$;$) {
 323         my ($self, $buf, $exit_code) = @_;
 324         err($self, $buf) if defined $buf;
 325         # calls fail_handler:
 326         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 327         x_it($self, ($exit_code // 1) << 8);
 328         undef;
 329 }
 330
 331 sub out ($;@) {
 332         my $self = shift;
 333         return if print { $self->{1} // return } @_; # likely
 334         return note_sigpipe($self, 1) if $! == EPIPE;
 335         my $err = "error writing to stdout: $!";
 336         delete $self->{1};
 337         fail($self, $err);
 338 }
 339
 340 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 341
 342 sub child_error { # passes non-fatal curl exit codes to user
 343         my ($self, $child_error) = @_; # child_error is $?
 344         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 345                 # send to the parent lei-daemon or to lei(1) client
 346                 send($s, "child_error $child_error", MSG_EOR);
 347         } elsif (!$PublicInbox::DS::in_loop) {
 348                 $self->{child_error} = $child_error;
 349         } # else noop if client disconnected
 350 }
 351
 352 sub note_sigpipe { # triggers sigpipe_handler
 353         my ($self, $fd) = @_;
 354         close(delete($self->{$fd})); # explicit close silences Perl warning
 355         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 356         x_it($self, 13);
 357 }
 358
 359 sub lei_atfork_child {
 360         my ($self) = @_;
 361         # we need to explicitly close things which are on stack
 362         delete $self->{0};
 363         for (delete @$self{qw(3 sock old_1 au_done)}) {
 364                 close($_) if defined($_);
 365         }
 366         if (my $op_c = delete $self->{pkt_op_c}) {
 367                 close(delete $op_c->{sock});
 368         }
 369         if (my $pgr = delete $self->{pgr}) {
 370                 close($_) for (@$pgr[1,2]);
 371         }
 372         close $listener if $listener;
 373         undef $listener;
 374         %PATH2CFG = ();
 375         undef $errors_log;
 376         $quit = \&CORE::exit;
 377         $current_lei = $self; # for SIG{__WARN__}
 378 }
 379
 380 sub _help ($;$) {
 381         my ($self, $errmsg) = @_;
 382         my $cmd = $self->{cmd} // 'COMMAND';
 383         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 384         my @top = ($cmd, shift(@info) // ());
 385         my $cmd_desc = shift(@info);
 386         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 387         my @opt_desc;
 388         my $lpad = 2;
 389         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 390                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 391                 my $arg_vals = '';
 392                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 393
 394                 # lower-case is a keyword (e.g. `content', `oid'),
 395                 # ALL_CAPS is a string description (e.g. `PATH')
 396                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 397                         $desc .= "\ndefault: `$1'";
 398                 }
 399                 my (@vals, @s, @l);
 400                 my $x = $sw;
 401                 if ($x =~ s/!\z//) { # solve! => --no-solve
 402                         $x = "no-$x";
 403                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 404                         @vals = (' [', undef, ']');
 405                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 406                         @vals = (' ', undef);
 407                 } # else: no args $x = 'thread|t'
 408                 for (split(/\|/, $x)) { # help|h
 409                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 410                 }
 411                 if (!scalar(@vals)) { # no args 'thread|t'
 412                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 413                         $vals[1] = $1;
 414                 } else {
 415                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 416                 }
 417                 if ($arg_vals =~ /([,\|])/) {
 418                         my $sep = $1;
 419                         my @allow = split(/\Q$sep\E/, $arg_vals);
 420                         my $must = $sep eq '|' ? 'Must' : 'Can';
 421                         @allow = map { "`$_'" } @allow;
 422                         my $last = pop @allow;
 423                         $desc .= "\n$must be one of: " .
 424                                 join(', ', @allow) . " or $last";
 425                 }
 426                 my $lhs = join(', ', @s, @l) . join('', @vals);
 427                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 428                         $lhs =~ s/\A--/- , --/;
 429                 } else {
 430                         $lhs =~ s/\A--/    --/; # pad if no short options
 431                 }
 432                 $lpad = length($lhs) if length($lhs) > $lpad;
 433                 push @opt_desc, $lhs, $desc;
 434         }
 435         my $msg = $errmsg ? "E: $errmsg\n" : '';
 436         $msg .= <<EOF;
 437 usage: lei @top
 438   $cmd_desc
 439
 440 EOF
 441         $lpad += 2;
 442         local $Text::Wrap::columns = 78 - $lpad;
 443         my $padding = ' ' x ($lpad + 2);
 444         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 445                 $msg .= '  '.pack("A$lpad", $lhs);
 446                 $rhs = wrap('', '', $rhs);
 447                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 448                 $msg .= $rhs;
 449                 $msg .= "\n";
 450         }
 451         my $out = $self->{$errmsg ? 2 : 1};
 452         start_pager($self) if -t $out;
 453         print $out $msg;
 454         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 455         undef;
 456 }
 457
 458 sub optparse ($$$) {
 459         my ($self, $cmd, $argv) = @_;
 460         $self->{cmd} = $cmd;
 461         $OPT = $self->{opt} = {};
 462         my $info = $CMD{$cmd} // [ '[...]' ];
 463         my ($proto, undef, @spec) = @$info;
 464         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 465         push @spec, qw(help|h);
 466         my $lone_dash;
 467         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 468                 $lone_dash = $spec[0];
 469                 $OPT->{$spec[0]} = \(my $var);
 470                 push @spec, '' => \$var;
 471         }
 472         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 473                 return _help($self, "bad arguments or options for $cmd");
 474         return _help($self) if $OPT->{help};
 475
 476         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 477
 478         # "-" aliases "stdin" or "clear"
 479         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 480
 481         my $i = 0;
 482         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 483         my ($err, $inf);
 484         my @args = split(/ /, $proto);
 485         for my $var (@args) {
 486                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 487                         $inf = defined($argv->[$i]) and last;
 488                         $var =~ s/\.\.\.\z//;
 489                         $err = "$var not supplied";
 490                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 491                         $argv->[$i++] // ($err = "$var not supplied");
 492                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 493                         $inf = 1;
 494                         last;
 495                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 496                         $i++;
 497                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 498                         $inf = 1 if index($var, '...') > 0;
 499                         my @or = split(/\|/, $var);
 500                         my $ok;
 501                         for my $o (@or) {
 502                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 503                                         $ok = defined($OPT->{$1});
 504                                         last if $ok;
 505                                 } elsif (defined($argv->[$i])) {
 506                                         $ok = 1;
 507                                         $i++;
 508                                         last;
 509                                 } # else continue looping
 510                         }
 511                         last if $ok;
 512                         my $last = pop @or;
 513                         $err = join(', ', @or) . " or $last must be set";
 514                 } else {
 515                         warn "BUG: can't parse `$var' in $proto";
 516                 }
 517                 last if $err;
 518         }
 519         if (!$inf && scalar(@$argv) > scalar(@args)) {
 520                 $err //= 'too many arguments';
 521         }
 522         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 523 }
 524
 525 sub dispatch {
 526         my ($self, $cmd, @argv) = @_;
 527         local $current_lei = $self; # for __WARN__
 528         dump_and_clear_log("from previous run\n");
 529         return _help($self, 'no command given') unless defined($cmd);
 530         my $func = "lei_$cmd";
 531         $func =~ tr/-/_/;
 532         if (my $cb = __PACKAGE__->can($func)) {
 533                 optparse($self, $cmd, \@argv) or return;
 534                 $cb->($self, @argv);
 535         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 536                 my $opt = {};
 537                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 538                         return _help($self, 'bad arguments or options');
 539                 _help($self);
 540         } else {
 541                 fail($self, "`$cmd' is not an lei command");
 542         }
 543 }
 544
 545 sub _lei_cfg ($;$) {
 546         my ($self, $creat) = @_;
 547         my $f = _config_path($self);
 548         my @st = stat($f);
 549         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 550         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 551                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 552         }
 553         if (!@st) {
 554                 unless ($creat) {
 555                         delete $self->{cfg};
 556                         return;
 557                 }
 558                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 559                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 560                 open my $fh, '>>', $f or die "open($f): $!\n";
 561                 @st = stat($fh) or die "fstat($f): $!\n";
 562                 $cur_st = pack('dd', $st[10], $st[7]);
 563                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 564         }
 565         my $cfg = PublicInbox::Config::git_config_dump($f);
 566         $cfg->{-st} = $cur_st;
 567         $cfg->{'-f'} = $f;
 568         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 569 }
 570
 571 sub _lei_store ($;$) {
 572         my ($self, $creat) = @_;
 573         my $cfg = _lei_cfg($self, $creat);
 574         $cfg->{-lei_store} //= do {
 575                 require PublicInbox::LeiStore;
 576                 my $dir = $cfg->{'leistore.dir'};
 577                 $dir //= $creat ? _store_path($self) : return;
 578                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 579         };
 580 }
 581
 582 sub lei_show {
 583         my ($self, @argv) = @_;
 584 }
 585
 586 sub lei_mark {
 587         my ($self, @argv) = @_;
 588 }
 589
 590 sub _config {
 591         my ($self, @argv) = @_;
 592         my $env = $self->{env};
 593         delete local $env->{GIT_CONFIG};
 594         delete local $ENV{GIT_CONFIG};
 595         my $cfg = _lei_cfg($self, 1);
 596         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 597         my %rdr = map { $_ => $self->{$_} } (0..2);
 598         waitpid(spawn($cmd, $env, \%rdr), 0);
 599 }
 600
 601 sub lei_config {
 602         my ($self, @argv) = @_;
 603         $self->{opt}->{'config-file'} and return fail $self,
 604                 "config file switches not supported by `lei config'";
 605         _config(@_);
 606         x_it($self, $?) if $?;
 607 }
 608
 609 sub lei_init {
 610         my ($self, $dir) = @_;
 611         my $cfg = _lei_cfg($self, 1);
 612         my $cur = $cfg->{'leistore.dir'};
 613         $dir //= _store_path($self);
 614         $dir = rel2abs($self, $dir);
 615         my @cur = stat($cur) if defined($cur);
 616         $cur = File::Spec->canonpath($cur // $dir);
 617         my @dir = stat($dir);
 618         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 619         if (@cur) {
 620                 if ($cur eq $dir) {
 621                         _lei_store($self, 1)->done;
 622                         return qerr($self, $exists);
 623                 }
 624
 625                 # some folks like symlinks and bind mounts :P
 626                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 627                         lei_config($self, 'leistore.dir', $dir);
 628                         _lei_store($self, 1)->done;
 629                         return qerr($self, "$exists (as $cur)");
 630                 }
 631                 return fail($self, <<"");
 632 E: leistore.dir=$cur already initialized and it is not $dir
 633
 634         }
 635         lei_config($self, 'leistore.dir', $dir);
 636         _lei_store($self, 1)->done;
 637         $exists //= "I: leistore.dir=$dir newly initialized";
 638         return qerr($self, $exists);
 639 }
 640
 641 sub lei_daemon_pid { puts shift, $$ }
 642
 643 sub lei_daemon_kill {
 644         my ($self) = @_;
 645         my $sig = $self->{opt}->{signal} // 'TERM';
 646         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 647 }
 648
 649 sub lei_help { _help($_[0]) }
 650
 651 # Shell completion helper.  Used by lei-completion.bash and hopefully
 652 # other shells.  Try to do as much here as possible to avoid redundancy
 653 # and improve maintainability.
 654 sub lei__complete {
 655         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 656         shift @argv; # ignore "lei", the entire command is sent
 657         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 658         my $cmd = shift @argv;
 659         my $info = $CMD{$cmd} // do { # filter matching commands
 660                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 661                 return;
 662         };
 663         my ($proto, undef, @spec) = @$info;
 664         my $cur = pop @argv;
 665         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 666         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 667                 # gross special case since the only git-config options
 668                 # Consider moving to a table if we need more special cases
 669                 # we use Getopt::Long for are the ones we reject, so these
 670                 # are the ones we don't reject:
 671                 if ($cmd eq 'config') {
 672                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 673                         @spec = qw(add z|null get get-all unset unset-all
 674                                 replace-all get-urlmatch
 675                                 remove-section rename-section
 676                                 name-only list|l edit|e
 677                                 get-color-name get-colorbool);
 678                         # fall-through
 679                 }
 680                 puts $self, grep(/$re/, map { # generate short/long names
 681                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 682                         } else { # negation: solve! => no-solve|solve
 683                                 s/\A(.+)!\z/no-$1|$1/;
 684                         }
 685                         map {
 686                                 my $x = length > 1 ? "--$_" : "-$_";
 687                                 $x eq $cur ? () : $x;
 688                         } split(/\|/, $_, -1) # help|h
 689                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 690         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 691                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 692         }
 693
 694         # switch args (e.g. lei q -f mbox<TAB>)
 695         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 696                 my $opt = quotemeta $1;
 697                 puts $self, map {
 698                         my $v = $OPTDESC{$_};
 699                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 700                         # get rid of ALL CAPS placeholder (e.g "OUT")
 701                         # (TODO: completion for external paths)
 702                         shift(@v) if uc($v[0]) eq $v[0];
 703                         @v;
 704                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 705         }
 706         $cmd =~ tr/-/_/;
 707         if (my $sub = $self->can("_complete_$cmd")) {
 708                 puts $self, $sub->($self, @argv, $cur);
 709         }
 710         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 711         # proto parsing.
 712 }
 713
 714 sub exec_buf ($$) {
 715         my ($argv, $env) = @_;
 716         my $argc = scalar @$argv;
 717         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 718         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 719         $buf;
 720 }
 721
 722 sub start_mua {
 723         my ($self) = @_;
 724         my $mua = $self->{opt}->{'mua-cmd'} // return;
 725         my $mfolder = $self->{ovv}->{dst};
 726         my (@cmd, $replaced);
 727         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 728                 @cmd = ($mua, '-f');
 729         # TODO: help wanted: other common FOSS MUAs
 730         } else {
 731                 require Text::ParseWords;
 732                 my @cmd = Text::ParseWords::shellwords($mua);
 733                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 734                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 735         }
 736         push @cmd, $mfolder unless defined($replaced);
 737         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 738                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 739         } elsif ($self->{oneshot}) {
 740                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 741         }
 742         delete $self->{-progress};
 743 }
 744
 745 # caller needs to "-t $self->{1}" to check if tty
 746 sub start_pager {
 747         my ($self) = @_;
 748         my $env = $self->{env};
 749         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 750         chomp(my $pager = <$fh> // '');
 751         close($fh) or warn "`git var PAGER' error: \$?=$?";
 752         return if $pager eq 'cat' || $pager eq '';
 753         # TODO TIOCGWINSZ
 754         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 755         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 756         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 757         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 758         my $pgr = [ undef, @$rdr{1, 2} ];
 759         if (my $sock = $self->{sock}) { # lei(1) process runs it
 760                 delete @$new_env{keys %$env}; # only set iff unset
 761                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 762                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 763         } elsif ($self->{oneshot}) {
 764                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 765                 $pgr->[3] = $$; # ew'll reap it
 766         } else {
 767                 die 'BUG: start_pager w/o socket';
 768         }
 769         $self->{1} = $wpager;
 770         $self->{2} = $wpager if -t $self->{2};
 771         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 772         $self->{pgr} = $pgr;
 773 }
 774
 775 sub stop_pager {
 776         my ($self) = @_;
 777         my $pgr = delete($self->{pgr}) or return;
 778         $self->{2} = $pgr->[2];
 779         # do not restore original stdout, just close it so we error out
 780         close(delete($self->{1})) if $self->{1};
 781         my $pid = $pgr->[0];
 782         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 783 }
 784
 785 sub accept_dispatch { # Listener {post_accept} callback
 786         my ($sock) = @_; # ignore other
 787         $sock->autoflush(1);
 788         my $self = bless { sock => $sock }, __PACKAGE__;
 789         vec(my $rvec = '', fileno($sock), 1) = 1;
 790         select($rvec, undef, undef, 60) or
 791                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 792         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 793         if (scalar(@fds) == 4) {
 794                 for my $i (0..3) {
 795                         my $fd = shift(@fds);
 796                         open($self->{$i}, '+<&=', $fd) and next;
 797                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 798                 }
 799         } else {
 800                 my $msg = "recv_cmd failed: $!";
 801                 warn $msg;
 802                 return send($sock, $msg, MSG_EOR);
 803         }
 804         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 805         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 806         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 807         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 808                 return send($sock, 'request command truncated', MSG_EOR);
 809         my ($argc, @argv) = split(/\0/, $buf, -1);
 810         undef $buf;
 811         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 812         if (chdir($self->{3})) {
 813                 local %ENV = %env;
 814                 $self->{env} = \%env;
 815                 eval { dispatch($self, @argv) };
 816                 send($sock, $@, MSG_EOR) if $@;
 817         } else {
 818                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 819         }
 820 }
 821
 822 sub dclose {
 823         my ($self) = @_;
 824         delete $self->{-progress};
 825         for my $f (qw(lxs l2m)) {
 826                 my $wq = delete $self->{$f} or next;
 827                 if ($wq->wq_kill) {
 828                         $wq->wq_close
 829                 } elsif ($wq->wq_kill_old) {
 830                         $wq->wq_wait_old($self);
 831                 }
 832         }
 833         close(delete $self->{1}) if $self->{1}; # may reap_compress
 834         $self->close if $self->{sock}; # PublicInbox::DS::close
 835 }
 836
 837 # for long-running results
 838 sub event_step {
 839         my ($self) = @_;
 840         local %ENV = %{$self->{env}};
 841         my $sock = $self->{sock};
 842         local $current_lei = $self;
 843         eval {
 844                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 845                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 846                                 return if $! == EAGAIN;
 847                                 next if $! == EINTR;
 848                                 last if $! == ECONNRESET;
 849                                 die "recvmsg: $!";
 850                         }
 851                         for my $fd (@fds) {
 852                                 open my $rfh, '+<&=', $fd;
 853                         }
 854                         die "unrecognized client signal: $buf";
 855                 }
 856                 dclose($self);
 857         };
 858         if (my $err = $@) {
 859                 eval { $self->fail($err) };
 860                 dclose($self);
 861         }
 862 }
 863
 864 sub event_step_init {
 865         my ($self) = @_;
 866         if (my $sock = $self->{sock}) { # using DS->EventLoop
 867                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 868         }
 869 }
 870
 871 sub noop {}
 872
 873 our $oldset; sub oldset { $oldset }
 874
 875 sub dump_and_clear_log {
 876         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 877                 my @pfx = @_;
 878                 unshift(@pfx, "$errors_log ") if @pfx;
 879                 warn @pfx, do { local $/; <STDIN> };
 880                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 881         }
 882 }
 883
 884 # lei(1) calls this when it can't connect
 885 sub lazy_start {
 886         my ($path, $errno, $narg) = @_;
 887         if ($errno == ECONNREFUSED) {
 888                 unlink($path) or die "unlink($path): $!";
 889         } elsif ($errno != ENOENT) {
 890                 $! = $errno; # allow interpolation to stringify in die
 891                 die "connect($path): $!";
 892         }
 893         if (eval { require BSD::Resource }) {
 894                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 895                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 896                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 897         }
 898         umask(077) // die("umask(077): $!");
 899         local $listener;
 900         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 901         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 902         listen($listener, 1024) or die "listen: $!";
 903         my @st = stat($path) or die "stat($path): $!";
 904         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 905         local $oldset = PublicInbox::DS::block_signals();
 906         if ($narg == 5) {
 907                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 908                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 909                         require PublicInbox::CmdIPC4;
 910                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 911                         PublicInbox::CmdIPC4->can('recv_cmd4');
 912                 };
 913         }
 914         $recv_cmd or die <<"";
 915 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 916
 917         require PublicInbox::Listener;
 918         require PublicInbox::EOFpipe;
 919         (-p STDOUT) or die "E: stdout must be a pipe\n";
 920         local $errors_log;
 921         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 922         $errors_log .= 'errors.log';
 923         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 924         STDIN->autoflush(1);
 925         dump_and_clear_log("from previous daemon process:\n");
 926         POSIX::setsid() > 0 or die "setsid: $!";
 927         my $pid = fork // die "fork: $!";
 928         return if $pid;
 929         $0 = "lei-daemon $path";
 930         local %PATH2CFG;
 931         $listener->blocking(0);
 932         my $exit_code;
 933         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 934         local $quit = do {
 935                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 936                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 937                 sub {
 938                         $exit_code //= shift;
 939                         my $lis = $pil or exit($exit_code);
 940                         # closing eof_w triggers \&noop wakeup
 941                         $listener = $eof_w = $pil = $path = undef;
 942                         $lis->close; # DS::close
 943                         PublicInbox::DS->SetLoopTimeout(1000);
 944                 };
 945         };
 946         my $sig = {
 947                 CHLD => \&PublicInbox::DS::enqueue_reap,
 948                 QUIT => $quit,
 949                 INT => $quit,
 950                 TERM => $quit,
 951                 HUP => \&noop,
 952                 USR1 => \&noop,
 953                 USR2 => \&noop,
 954         };
 955         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 956         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 957         undef $sig;
 958         local $SIG{PIPE} = 'IGNORE';
 959         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 960                 undef $sigfd;
 961                 PublicInbox::DS->SetLoopTimeout(5000);
 962         } else {
 963                 # wake up every second to accept signals if we don't
 964                 # have signalfd or IO::KQueue:
 965                 PublicInbox::DS::sig_setmask($oldset);
 966                 PublicInbox::DS->SetLoopTimeout(1000);
 967         }
 968         PublicInbox::DS->SetPostLoopCallback(sub {
 969                 my ($dmap, undef) = @_;
 970                 if (@st = defined($path) ? stat($path) : ()) {
 971                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 972                                 warn "$path dev/ino changed, quitting\n";
 973                                 $path = undef;
 974                         }
 975                 } elsif (defined($path)) { # ENOENT is common
 976                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
 977                         undef $path;
 978                         $quit->();
 979                 }
 980                 return 1 if defined($path);
 981                 my $now = now();
 982                 my $n = 0;
 983                 for my $s (values %$dmap) {
 984                         $s->can('busy') or next;
 985                         if ($s->busy($now)) {
 986                                 ++$n;
 987                         } else {
 988                                 $s->close;
 989                         }
 990                 }
 991                 $n; # true: continue, false: stop
 992         });
 993
 994         # STDIN was redirected to /dev/null above, closing STDERR and
 995         # STDOUT will cause the calling `lei' client process to finish
 996         # reading the <$daemon> pipe.
 997         local $SIG{__WARN__} = sub {
 998                 $current_lei ? err($current_lei, @_) : warn(
 999                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1000         };
1001         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1002         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1003         # $daemon pipe to `lei' closed, main loop begins:
1004         PublicInbox::DS->EventLoop;
1005         exit($exit_code // 0);
1006 }
1007
1008 # for users w/o Socket::Msghdr installed or Inline::C enabled
1009 sub oneshot {
1010         my ($main_pkg) = @_;
1011         my $exit = $main_pkg->can('exit'); # caller may override exit()
1012         local $quit = $exit if $exit;
1013         local %PATH2CFG;
1014         umask(077) // die("umask(077): $!");
1015         my $self = bless {
1016                 oneshot => 1,
1017                 0 => *STDIN{GLOB},
1018                 1 => *STDOUT{GLOB},
1019                 2 => *STDERR{GLOB},
1020                 env => \%ENV
1021         }, __PACKAGE__;
1022         dispatch($self, @ARGV);
1023         x_it($self, $self->{child_error}) if $self->{child_error};
1024 }
1025
1026 # ensures stdout hits the FS before sock disconnects so a client
1027 # can immediately reread it
1028 sub DESTROY {
1029         my ($self) = @_;
1030         $self->{1}->autoflush(1) if $self->{1};
1031         stop_pager($self);
1032         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1033                 waitpid($mua_pid, 0);
1034         }
1035 }
1036
1037 1;