lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX ();
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use Sys::Syslog qw(syslog openlog);
  21 use PublicInbox::Config;
  22 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  23 use PublicInbox::Sigfd;
  24 use PublicInbox::DS qw(now dwaitpid);
  25 use PublicInbox::Spawn qw(spawn popen_rd);
  26 use PublicInbox::OnDestroy;
  27 use Text::Wrap qw(wrap);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener);
  33 my ($recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40
  41 # TBD: this is a documentation mechanism to show a subcommand
  42 # (may) pass options through to another command:
  43 sub pass_through { $GLP_PASS }
  44
  45 my $OPT;
  46 sub opt_dash ($$) {
  47         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  48         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  49         my $cb = sub { # Getopt::Long "<>" catch-all handler
  50                 my ($arg) = @_;
  51                 if ($arg =~ /\A-($re_str)\z/) {
  52                         $OPT->{$key} = $1;
  53                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  54                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  55                 # lone (single) dash is handled elsewhere
  56                 } elsif (substr($arg, 0, 1) eq '-') {
  57                         if ($OPT->{'--'}) {
  58                                 push @{$OPT->{-argv}}, $arg;
  59                         } else {
  60                                 die "bad argument: $arg\n";
  61                         }
  62                 } else {
  63                         push @{$OPT->{-argv}}, $arg;
  64                 }
  65         };
  66         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  67 }
  68
  69 sub rel2abs ($$) {
  70         my ($self, $p) = @_;
  71         return $p if index($p, '/') == 0; # already absolute
  72         my $pwd = $self->{env}->{PWD};
  73         if (defined $pwd) {
  74                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  75                 if (my @st_pwd = stat($pwd)) {
  76                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  77                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  78                                 $self->{env}->{PWD} = $pwd = $cwd;
  79                 } else { # PWD was invalid
  80                         delete $self->{env}->{PWD};
  81                         undef $pwd;
  82                 }
  83         }
  84         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  85         File::Spec->rel2abs($p, $pwd);
  86 }
  87
  88 sub _store_path ($) {
  89         my ($self) = @_;
  90         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  91                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  92                 .'/lei/store');
  93 }
  94
  95 sub _config_path ($) {
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  99                 .'/lei/config');
 100 }
 101
 102 # TODO: generate shell completion + help using %CMD and %OPTDESC
 103 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 104 our %CMD = ( # sorted in order of importance/use:
 105 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 106         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 107         sort|s=s reverse|r offset=i remote! local! external! pretty
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'ls-query       format|f=s' => $ls_format,
 233 'ls-external    format|f=s' => $ls_format,
 234
 235 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 236 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 237
 238 'sort|s=s' => [ 'VAL|received,relevance,docid',
 239                 "order of results `--output'-dependent"],
 240 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 241
 242 'boost=i' => 'increase/decrease priority of results (default: 0)',
 243
 244 'local' => 'limit operations to the local filesystem',
 245 'local!' => 'exclude results from the local filesystem',
 246 'remote' => 'limit operations to those requiring network access',
 247 'remote!' => 'prevent operations requiring network access',
 248
 249 'mid=s' => 'specify the Message-ID of a message',
 250 'oid=s' => 'specify the git object ID of a message',
 251
 252 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 253 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 254 'include=s' => 'include mailboxes/newsgroups based on pattern',
 255
 256 'exact' => 'operate on exact header matches only',
 257 'exact!' => 'rely on content match instead of exact header matches',
 258
 259 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 260 'jobs:i' => 'set parallelism level',
 261
 262 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 263 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 264
 265 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 266 ); # %OPTDESC
 267
 268 my %CONFIG_KEYS = (
 269         'leistore.dir' => 'top-level storage location',
 270 );
 271
 272 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 273 sub x_it ($$) {
 274         my ($self, $code) = @_;
 275         # make sure client sees stdout before exit
 276         $self->{1}->autoflush(1) if $self->{1};
 277         dump_and_clear_log();
 278         if (my $sock = $self->{sock}) {
 279                 send($sock, "x_it $code", MSG_EOR);
 280         } elsif (!($code & 127)) { # oneshot, ignore signals
 281                 # don't want to end up using $? from child processes
 282                 for my $f (qw(lxs l2m)) {
 283                         my $wq = delete $self->{$f} or next;
 284                         $wq->DESTROY;
 285                 }
 286                 $quit->($code >> 8);
 287         }
 288 }
 289
 290 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 291
 292 sub out ($;@) { print { shift->{1} } @_ }
 293
 294 sub err ($;@) {
 295         my $self = shift;
 296         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 297         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 298 }
 299
 300 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 301
 302 sub fail ($$;$) {
 303         my ($self, $buf, $exit_code) = @_;
 304         err($self, $buf);
 305         x_it($self, ($exit_code // 1) << 8);
 306         undef;
 307 }
 308
 309 sub child_error { # passes non-fatal curl exit codes to user
 310         my ($self, $child_error) = @_; # child_error is $?
 311         if (my $sock = $self->{sock}) { # send to lei(1) client
 312                 send($sock, "child_error $child_error", MSG_EOR);
 313         } else { # oneshot
 314                 $self->{child_error} = $child_error;
 315         }
 316         undef;
 317 }
 318
 319 sub atfork_prepare_wq {
 320         my ($self, $wq) = @_;
 321         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 322         if (my $sock = $self->{sock}) {
 323                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 324         }
 325         if (my $pgr = $self->{pgr}) {
 326                 push @$tcafc, @$pgr[1,2];
 327         }
 328         if (my $old_1 = $self->{old_1}) {
 329                 push @$tcafc, $old_1;
 330         }
 331         for my $f (qw(lxs l2m)) {
 332                 my $ipc = $self->{$f} or next;
 333                 push @$tcafc, grep { defined }
 334                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 335         }
 336 }
 337
 338 # usage: my %sig = $lei->atfork_child_wq($wq);
 339 #        local @SIG{keys %sig} = values %sig;
 340 sub atfork_child_wq {
 341         my ($self, $wq) = @_;
 342         my ($sock, $l2m_wq_s1);
 343         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 344         $self->{sock} = $sock if -S $sock;
 345         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 346         %PATH2CFG = ();
 347         undef $errors_log;
 348         $quit = \&CORE::exit;
 349         (__WARN__ => sub { err($self, @_) },
 350         PIPE => sub {
 351                 $self->x_it(13); # SIGPIPE = 13
 352                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 353                 for my $i (1, 2) {
 354                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 355                         close(delete $self->{$i});
 356                 }
 357                 # trigger the LeiXSearch $done OpPipe:
 358                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 359                 $SIG{PIPE} = 'DEFAULT';
 360                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 361         });
 362 }
 363
 364 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 365 sub atfork_parent_wq {
 366         my ($self, $wq) = @_;
 367         my $env = delete $self->{env}; # env is inherited at fork
 368         my $ret = bless { %$self }, ref($self);
 369         if (my $dedupe = delete $ret->{dedupe}) {
 370                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 371         }
 372         $self->{env} = $env;
 373         delete @$ret{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 374         my @io = delete @$ret{0..2};
 375         $io[3] = delete($ret->{sock}) // $io[2];
 376         my $l2m = $ret->{l2m};
 377         if ($l2m && $l2m != $wq) { # $wq == lxs
 378                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 379                 $l2m->wq_close(1);
 380         }
 381         ($ret, @io);
 382 }
 383
 384 sub _help ($;$) {
 385         my ($self, $errmsg) = @_;
 386         my $cmd = $self->{cmd} // 'COMMAND';
 387         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 388         my @top = ($cmd, shift(@info) // ());
 389         my $cmd_desc = shift(@info);
 390         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 391         my @opt_desc;
 392         my $lpad = 2;
 393         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 394                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 395                 my $arg_vals = '';
 396                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 397
 398                 # lower-case is a keyword (e.g. `content', `oid'),
 399                 # ALL_CAPS is a string description (e.g. `PATH')
 400                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 401                         $desc .= "\ndefault: `$1'";
 402                 }
 403                 my (@vals, @s, @l);
 404                 my $x = $sw;
 405                 if ($x =~ s/!\z//) { # solve! => --no-solve
 406                         $x = "no-$x";
 407                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 408                         @vals = (' [', undef, ']');
 409                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 410                         @vals = (' ', undef);
 411                 } # else: no args $x = 'thread|t'
 412                 for (split(/\|/, $x)) { # help|h
 413                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 414                 }
 415                 if (!scalar(@vals)) { # no args 'thread|t'
 416                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 417                         $vals[1] = $1;
 418                 } else {
 419                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 420                 }
 421                 if ($arg_vals =~ /([,\|])/) {
 422                         my $sep = $1;
 423                         my @allow = split(/\Q$sep\E/, $arg_vals);
 424                         my $must = $sep eq '|' ? 'Must' : 'Can';
 425                         @allow = map { "`$_'" } @allow;
 426                         my $last = pop @allow;
 427                         $desc .= "\n$must be one of: " .
 428                                 join(', ', @allow) . " or $last";
 429                 }
 430                 my $lhs = join(', ', @s, @l) . join('', @vals);
 431                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 432                         $lhs =~ s/\A--/- , --/;
 433                 } else {
 434                         $lhs =~ s/\A--/    --/; # pad if no short options
 435                 }
 436                 $lpad = length($lhs) if length($lhs) > $lpad;
 437                 push @opt_desc, $lhs, $desc;
 438         }
 439         my $msg = $errmsg ? "E: $errmsg\n" : '';
 440         $msg .= <<EOF;
 441 usage: lei @top
 442   $cmd_desc
 443
 444 EOF
 445         $lpad += 2;
 446         local $Text::Wrap::columns = 78 - $lpad;
 447         my $padding = ' ' x ($lpad + 2);
 448         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 449                 $msg .= '  '.pack("A$lpad", $lhs);
 450                 $rhs = wrap('', '', $rhs);
 451                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 452                 $msg .= $rhs;
 453                 $msg .= "\n";
 454         }
 455         print { $self->{$errmsg ? 2 : 1} } $msg;
 456         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 457         undef;
 458 }
 459
 460 sub optparse ($$$) {
 461         my ($self, $cmd, $argv) = @_;
 462         $self->{cmd} = $cmd;
 463         $OPT = $self->{opt} = {};
 464         my $info = $CMD{$cmd} // [ '[...]' ];
 465         my ($proto, undef, @spec) = @$info;
 466         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 467         push @spec, qw(help|h);
 468         my $lone_dash;
 469         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 470                 $lone_dash = $spec[0];
 471                 $OPT->{$spec[0]} = \(my $var);
 472                 push @spec, '' => \$var;
 473         }
 474         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 475                 return _help($self, "bad arguments or options for $cmd");
 476         return _help($self) if $OPT->{help};
 477
 478         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 479
 480         # "-" aliases "stdin" or "clear"
 481         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 482
 483         my $i = 0;
 484         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 485         my ($err, $inf);
 486         my @args = split(/ /, $proto);
 487         for my $var (@args) {
 488                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 489                         $inf = defined($argv->[$i]) and last;
 490                         $var =~ s/\.\.\.\z//;
 491                         $err = "$var not supplied";
 492                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 493                         $argv->[$i++] // ($err = "$var not supplied");
 494                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 495                         $inf = 1;
 496                         last;
 497                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 498                         $i++;
 499                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 500                         my @or = split(/\|/, $var);
 501                         my $ok;
 502                         for my $o (@or) {
 503                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 504                                         $ok = defined($OPT->{$1});
 505                                         last;
 506                                 } elsif (defined($argv->[$i])) {
 507                                         $ok = 1;
 508                                         $i++;
 509                                         last;
 510                                 } # else continue looping
 511                         }
 512                         last if $ok;
 513                         my $last = pop @or;
 514                         $err = join(', ', @or) . " or $last must be set";
 515                 } else {
 516                         warn "BUG: can't parse `$var' in $proto";
 517                 }
 518                 last if $err;
 519         }
 520         if (!$inf && scalar(@$argv) > scalar(@args)) {
 521                 $err //= 'too many arguments';
 522         }
 523         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 524 }
 525
 526 sub dispatch {
 527         my ($self, $cmd, @argv) = @_;
 528         local $current_lei = $self; # for __WARN__
 529         dump_and_clear_log("from previous run\n");
 530         return _help($self, 'no command given') unless defined($cmd);
 531         my $func = "lei_$cmd";
 532         $func =~ tr/-/_/;
 533         if (my $cb = __PACKAGE__->can($func)) {
 534                 optparse($self, $cmd, \@argv) or return;
 535                 $cb->($self, @argv);
 536         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 537                 my $opt = {};
 538                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 539                         return _help($self, 'bad arguments or options');
 540                 _help($self);
 541         } else {
 542                 fail($self, "`$cmd' is not an lei command");
 543         }
 544 }
 545
 546 sub _lei_cfg ($;$) {
 547         my ($self, $creat) = @_;
 548         my $f = _config_path($self);
 549         my @st = stat($f);
 550         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 551         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 552                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 553         }
 554         if (!@st) {
 555                 unless ($creat) {
 556                         delete $self->{cfg};
 557                         return;
 558                 }
 559                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 560                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 561                 open my $fh, '>>', $f or die "open($f): $!\n";
 562                 @st = stat($fh) or die "fstat($f): $!\n";
 563                 $cur_st = pack('dd', $st[10], $st[7]);
 564                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 565         }
 566         my $cfg = PublicInbox::Config::git_config_dump($f);
 567         $cfg->{-st} = $cur_st;
 568         $cfg->{'-f'} = $f;
 569         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 570 }
 571
 572 sub _lei_store ($;$) {
 573         my ($self, $creat) = @_;
 574         my $cfg = _lei_cfg($self, $creat);
 575         $cfg->{-lei_store} //= do {
 576                 require PublicInbox::LeiStore;
 577                 my $dir = $cfg->{'leistore.dir'};
 578                 $dir //= $creat ? _store_path($self) : return;
 579                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 580         };
 581 }
 582
 583 sub lei_show {
 584         my ($self, @argv) = @_;
 585 }
 586
 587 sub lei_mark {
 588         my ($self, @argv) = @_;
 589 }
 590
 591 sub _config {
 592         my ($self, @argv) = @_;
 593         my $env = $self->{env};
 594         delete local $env->{GIT_CONFIG};
 595         delete local $ENV{GIT_CONFIG};
 596         my $cfg = _lei_cfg($self, 1);
 597         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 598         my %rdr = map { $_ => $self->{$_} } (0..2);
 599         waitpid(spawn($cmd, $env, \%rdr), 0);
 600 }
 601
 602 sub lei_config {
 603         my ($self, @argv) = @_;
 604         $self->{opt}->{'config-file'} and return fail $self,
 605                 "config file switches not supported by `lei config'";
 606         _config(@_);
 607         x_it($self, $?) if $?;
 608 }
 609
 610 sub lei_init {
 611         my ($self, $dir) = @_;
 612         my $cfg = _lei_cfg($self, 1);
 613         my $cur = $cfg->{'leistore.dir'};
 614         $dir //= _store_path($self);
 615         $dir = rel2abs($self, $dir);
 616         my @cur = stat($cur) if defined($cur);
 617         $cur = File::Spec->canonpath($cur // $dir);
 618         my @dir = stat($dir);
 619         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 620         if (@cur) {
 621                 if ($cur eq $dir) {
 622                         _lei_store($self, 1)->done;
 623                         return qerr($self, $exists);
 624                 }
 625
 626                 # some folks like symlinks and bind mounts :P
 627                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 628                         lei_config($self, 'leistore.dir', $dir);
 629                         _lei_store($self, 1)->done;
 630                         return qerr($self, "$exists (as $cur)");
 631                 }
 632                 return fail($self, <<"");
 633 E: leistore.dir=$cur already initialized and it is not $dir
 634
 635         }
 636         lei_config($self, 'leistore.dir', $dir);
 637         _lei_store($self, 1)->done;
 638         $exists //= "I: leistore.dir=$dir newly initialized";
 639         return qerr($self, $exists);
 640 }
 641
 642 sub lei_daemon_pid { puts shift, $$ }
 643
 644 sub lei_daemon_kill {
 645         my ($self) = @_;
 646         my $sig = $self->{opt}->{signal} // 'TERM';
 647         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 648 }
 649
 650 sub lei_help { _help($_[0]) }
 651
 652 # Shell completion helper.  Used by lei-completion.bash and hopefully
 653 # other shells.  Try to do as much here as possible to avoid redundancy
 654 # and improve maintainability.
 655 sub lei__complete {
 656         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 657         shift @argv; # ignore "lei", the entire command is sent
 658         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 659         my $cmd = shift @argv;
 660         my $info = $CMD{$cmd} // do { # filter matching commands
 661                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 662                 return;
 663         };
 664         my ($proto, undef, @spec) = @$info;
 665         my $cur = pop @argv;
 666         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 667         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 668                 # gross special case since the only git-config options
 669                 # Consider moving to a table if we need more special cases
 670                 # we use Getopt::Long for are the ones we reject, so these
 671                 # are the ones we don't reject:
 672                 if ($cmd eq 'config') {
 673                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 674                         @spec = qw(add z|null get get-all unset unset-all
 675                                 replace-all get-urlmatch
 676                                 remove-section rename-section
 677                                 name-only list|l edit|e
 678                                 get-color-name get-colorbool);
 679                         # fall-through
 680                 }
 681                 puts $self, grep(/$re/, map { # generate short/long names
 682                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 683                         } else { # negation: solve! => no-solve|solve
 684                                 s/\A(.+)!\z/no-$1|$1/;
 685                         }
 686                         map {
 687                                 my $x = length > 1 ? "--$_" : "-$_";
 688                                 $x eq $cur ? () : $x;
 689                         } split(/\|/, $_, -1) # help|h
 690                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 691         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 692                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 693         }
 694
 695         # switch args (e.g. lei q -f mbox<TAB>)
 696         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 697                 my $opt = quotemeta $1;
 698                 puts $self, map {
 699                         my $v = $OPTDESC{$_};
 700                         $v = $v->[0] if ref($v);
 701                         my @v = split(/\|/, $v);
 702                         # get rid of ALL CAPS placeholder (e.g "OUT")
 703                         # (TODO: completion for external paths)
 704                         shift(@v) if uc($v[0]) eq $v[0];
 705                         @v;
 706                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 707         }
 708         $cmd =~ tr/-/_/;
 709         if (my $sub = $self->can("_complete_$cmd")) {
 710                 puts $self, $sub->($self, @argv, $cur);
 711         }
 712         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 713         # proto parsing.
 714 }
 715
 716 sub exec_buf ($$) {
 717         my ($argv, $env) = @_;
 718         my $argc = scalar @$argv;
 719         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 720         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 721         $buf;
 722 }
 723
 724 sub start_mua {
 725         my ($self) = @_;
 726         my $mua = $self->{opt}->{'mua-cmd'} // return;
 727         my $mfolder = $self->{ovv}->{dst};
 728         my (@cmd, $replaced);
 729         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 730                 @cmd = ($mua, '-f');
 731         # TODO: help wanted: other common FOSS MUAs
 732         } else {
 733                 require Text::ParseWords;
 734                 my @cmd = Text::ParseWords::shellwords($mua);
 735                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 736                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 737         }
 738         push @cmd, $mfolder unless defined($replaced);
 739         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 740                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 741         } else { # oneshot
 742                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 743         }
 744 }
 745
 746 # caller needs to "-t $self->{1}" to check if tty
 747 sub start_pager {
 748         my ($self) = @_;
 749         my $env = $self->{env};
 750         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 751         chomp(my $pager = <$fh> // '');
 752         close($fh) or warn "`git var PAGER' error: \$?=$?";
 753         return if $pager eq 'cat' || $pager eq '';
 754         # TODO TIOCGWINSZ
 755         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 756         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 757         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 758         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 759         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 760         if (my $sock = $self->{sock}) { # lei(1) process runs it
 761                 delete @$new_env{keys %$env}; # only set iff unset
 762                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 763                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 764         } else {
 765                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 766         }
 767         $self->{1} = $wpager;
 768         $self->{2} = $wpager if -t $self->{2};
 769         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 770         $self->{pgr} = $pgr;
 771 }
 772
 773 sub stop_pager {
 774         my ($self) = @_;
 775         my $pgr = delete($self->{pgr}) or return;
 776         $self->{2} = $pgr->[2];
 777         # do not restore original stdout, just close it so we error out
 778         close(delete($self->{1})) if $self->{1};
 779         my $pid = $pgr->[0];
 780         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 781 }
 782
 783 sub accept_dispatch { # Listener {post_accept} callback
 784         my ($sock) = @_; # ignore other
 785         $sock->autoflush(1);
 786         my $self = bless { sock => $sock }, __PACKAGE__;
 787         vec(my $rvec = '', fileno($sock), 1) = 1;
 788         select($rvec, undef, undef, 1) or
 789                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 790         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 791         if (scalar(@fds) == 4) {
 792                 for my $i (0..3) {
 793                         my $fd = shift(@fds);
 794                         open($self->{$i}, '+<&=', $fd) and next;
 795                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 796                 }
 797         } else {
 798                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 799         }
 800         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 801         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 802         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 803         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 804                 return send($sock, 'request command truncated', MSG_EOR);
 805         my ($argc, @argv) = split(/\0/, $buf, -1);
 806         undef $buf;
 807         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 808         if (chdir($self->{3})) {
 809                 local %ENV = %env;
 810                 $self->{env} = \%env;
 811                 eval { dispatch($self, @argv) };
 812                 send($sock, $@, MSG_EOR) if $@;
 813         } else {
 814                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 815         }
 816 }
 817
 818 sub dclose {
 819         my ($self) = @_;
 820         for my $f (qw(lxs l2m)) {
 821                 my $wq = delete $self->{$f} or next;
 822                 if ($wq->wq_kill) {
 823                         $wq->wq_close
 824                 } elsif ($wq->wq_kill_old) {
 825                         $wq->wq_wait_old;
 826                 }
 827         }
 828         close(delete $self->{1}) if $self->{1}; # may reap_compress
 829         $self->close if $self->{sock}; # PublicInbox::DS::close
 830 }
 831
 832 # for long-running results
 833 sub event_step {
 834         my ($self) = @_;
 835         local %ENV = %{$self->{env}};
 836         my $sock = $self->{sock};
 837         local $current_lei = $self;
 838         eval {
 839                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 840                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 841                                 return if $! == EAGAIN;
 842                                 next if $! == EINTR;
 843                                 last if $! == ECONNRESET;
 844                                 die "recvmsg: $!";
 845                         }
 846                         for my $fd (@fds) {
 847                                 open my $rfh, '+<&=', $fd;
 848                         }
 849                         die "unrecognized client signal: $buf";
 850                 }
 851                 dclose($self);
 852         };
 853         if (my $err = $@) {
 854                 eval { $self->fail($err) };
 855                 dclose($self);
 856         }
 857 }
 858
 859 sub event_step_init {
 860         my ($self) = @_;
 861         if (my $sock = $self->{sock}) { # using DS->EventLoop
 862                 $sock->blocking(0);
 863                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 864         }
 865 }
 866
 867 sub noop {}
 868
 869 our $oldset; sub oldset { $oldset }
 870
 871 sub dump_and_clear_log {
 872         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 873                 my @pfx = @_;
 874                 unshift(@pfx, "$errors_log ") if @pfx;
 875                 warn @pfx, do { local $/; <STDIN> };
 876                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 877         }
 878 }
 879
 880 # lei(1) calls this when it can't connect
 881 sub lazy_start {
 882         my ($path, $errno, $narg) = @_;
 883         if ($errno == ECONNREFUSED) {
 884                 unlink($path) or die "unlink($path): $!";
 885         } elsif ($errno != ENOENT) {
 886                 $! = $errno; # allow interpolation to stringify in die
 887                 die "connect($path): $!";
 888         }
 889         umask(077) // die("umask(077): $!");
 890         local $listener;
 891         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 892         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 893         listen($listener, 1024) or die "listen: $!";
 894         my @st = stat($path) or die "stat($path): $!";
 895         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 896         local $oldset = PublicInbox::DS::block_signals();
 897         if ($narg == 5) {
 898                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 899                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 900                         require PublicInbox::CmdIPC4;
 901                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 902                         PublicInbox::CmdIPC4->can('recv_cmd4');
 903                 };
 904         }
 905         $recv_cmd or die <<"";
 906 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 907
 908         require PublicInbox::Listener;
 909         require PublicInbox::EOFpipe;
 910         (-p STDOUT) or die "E: stdout must be a pipe\n";
 911         local $errors_log;
 912         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 913         $errors_log .= 'errors.log';
 914         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 915         STDIN->autoflush(1);
 916         dump_and_clear_log("from previous daemon process:\n");
 917         POSIX::setsid() > 0 or die "setsid: $!";
 918         my $pid = fork // die "fork: $!";
 919         return if $pid;
 920         $0 = "lei-daemon $path";
 921         local %PATH2CFG;
 922         $listener->blocking(0);
 923         my $exit_code;
 924         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 925         local $quit = do {
 926                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 927                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 928                 sub {
 929                         $exit_code //= shift;
 930                         my $lis = $pil or exit($exit_code);
 931                         # closing eof_w triggers \&noop wakeup
 932                         $listener = $eof_w = $pil = $path = undef;
 933                         $lis->close; # DS::close
 934                         PublicInbox::DS->SetLoopTimeout(1000);
 935                 };
 936         };
 937         my $sig = {
 938                 CHLD => \&PublicInbox::DS::enqueue_reap,
 939                 QUIT => $quit,
 940                 INT => $quit,
 941                 TERM => $quit,
 942                 HUP => \&noop,
 943                 USR1 => \&noop,
 944                 USR2 => \&noop,
 945         };
 946         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 947         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 948         undef $sig;
 949         local $SIG{PIPE} = 'IGNORE';
 950         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 951                 undef $sigfd;
 952                 PublicInbox::DS->SetLoopTimeout(5000);
 953         } else {
 954                 # wake up every second to accept signals if we don't
 955                 # have signalfd or IO::KQueue:
 956                 PublicInbox::DS::sig_setmask($oldset);
 957                 PublicInbox::DS->SetLoopTimeout(1000);
 958         }
 959         PublicInbox::DS->SetPostLoopCallback(sub {
 960                 my ($dmap, undef) = @_;
 961                 if (@st = defined($path) ? stat($path) : ()) {
 962                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 963                                 warn "$path dev/ino changed, quitting\n";
 964                                 $path = undef;
 965                         }
 966                 } elsif (defined($path)) {
 967                         warn "stat($path): $!, quitting ...\n";
 968                         undef $path; # don't unlink
 969                         $quit->();
 970                 }
 971                 return 1 if defined($path);
 972                 my $now = now();
 973                 my $n = 0;
 974                 for my $s (values %$dmap) {
 975                         $s->can('busy') or next;
 976                         if ($s->busy($now)) {
 977                                 ++$n;
 978                         } else {
 979                                 $s->close;
 980                         }
 981                 }
 982                 $n; # true: continue, false: stop
 983         });
 984
 985         # STDIN was redirected to /dev/null above, closing STDERR and
 986         # STDOUT will cause the calling `lei' client process to finish
 987         # reading the <$daemon> pipe.
 988         openlog($path, 'pid', 'user');
 989         local $SIG{__WARN__} = sub {
 990                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 991         };
 992         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 993                 syslog('crit', "$@") if $@;
 994         });
 995         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 996         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 997         # $daemon pipe to `lei' closed, main loop begins:
 998         PublicInbox::DS->EventLoop;
 999         @$on_destroy = (); # cancel on_destroy if we get here
1000         exit($exit_code // 0);
1001 }
1002
1003 # for users w/o Socket::Msghdr installed or Inline::C enabled
1004 sub oneshot {
1005         my ($main_pkg) = @_;
1006         my $exit = $main_pkg->can('exit'); # caller may override exit()
1007         local $quit = $exit if $exit;
1008         local %PATH2CFG;
1009         umask(077) // die("umask(077): $!");
1010         my $self = bless {
1011                 0 => *STDIN{GLOB},
1012                 1 => *STDOUT{GLOB},
1013                 2 => *STDERR{GLOB},
1014                 env => \%ENV
1015         }, __PACKAGE__;
1016         dispatch($self, @ARGV);
1017         x_it($self, $self->{child_error}) if $self->{child_error};
1018 }
1019
1020 # ensures stdout hits the FS before sock disconnects so a client
1021 # can immediately reread it
1022 sub DESTROY {
1023         my ($self) = @_;
1024         $self->{1}->autoflush(1) if $self->{1};
1025         stop_pager($self);
1026         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1027                 waitpid($mua_pid, 0);
1028         }
1029 }
1030
1031 1;