lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw($SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now);
  22 use PublicInbox::Spawn qw(spawn);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $GLP = Getopt::Long::Parser->new;
  29 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  30 my $GLP_PASS = Getopt::Long::Parser->new;
  31 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  32
  33 our %PATH2CFG; # persistent for socket daemon
  34
  35 # TBD: this is a documentation mechanism to show a subcommand
  36 # (may) pass options through to another command:
  37 sub pass_through { $GLP_PASS }
  38
  39 my $OPT;
  40 sub opt_dash {
  41         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  42         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  43         my $cb = sub { # Getopt::Long "<>" catch-all handler
  44                 my ($arg) = @_;
  45                 if ($arg =~ /\A-($re_str)\z/) {
  46                         $OPT->{$key} = $1;
  47                 } else {
  48                         die "bad argument for --$key: $arg\n";
  49                 }
  50         };
  51         ($spec, '<>' => $cb, $GLP_PASS)
  52 }
  53
  54 sub _store_path ($) {
  55         my ($env) = @_;
  56         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  57                 ($env->{HOME} // '/nonexistent').'/.local/share')
  58                 .'/lei/store', $env->{PWD});
  59 }
  60
  61 sub _config_path ($) {
  62         my ($env) = @_;
  63         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  64                 ($env->{HOME} // '/nonexistent').'/.config')
  65                 .'/lei/config', $env->{PWD});
  66 }
  67
  68 # TODO: generate shell completion + help using %CMD and %OPTDESC
  69 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  70 our %CMD = ( # sorted in order of importance/use:
  71 'query' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  72         save-as=s output|o=s format|f=s dedupe|d=s thread|t augment|a
  73         sort|s=s@ reverse|r offset=i remote local! extinbox!
  74         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  75
  76 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  77         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  78         pass_through('git show') ],
  79
  80 'add-extinbox' => [ 'URL_OR_PATHNAME',
  81         'add/set priority of a publicinbox|extindex for extra matches',
  82         qw(prio=i) ],
  83 'ls-extinbox' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  84         qw(format|f=s z local remote) ],
  85 'forget-extinbox' => [ '{URL_OR_PATHNAME|--prune}',
  86         'exclude further results from a publicinbox|extindex',
  87         qw(prune) ],
  88
  89 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  90                 qw(name-only format|f=s z) ],
  91 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  92 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  93
  94 'plonk' => [ '--thread|--from=IDENT',
  95         'exclude mail matching From: or thread from non-Message-ID searches',
  96         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  97 'mark' => [ 'MESSAGE_FLAGS...',
  98         'set/unset flags on message(s) from stdin',
  99         qw(stdin| oid=s exact by-mid|mid:s) ],
 100 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 101         'exclude message(s) on stdin from query results',
 102         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 103
 104 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 105         'remove imported messages from IMAP, Maildirs, and MH',
 106         qw(exact! all jobs:i indexed) ],
 107
 108 # code repos are used for `show' to solve blobs from patch mails
 109 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 110         qw(prio=i) ],
 111 'ls-coderepo' => [ '[FILTER_TERMS...]',
 112                 'list known code repos', qw(format|f=s z) ],
 113 'forget-coderepo' => [ 'PATHNAME',
 114         'stop using repo to solve blobs from patches',
 115         qw(prune) ],
 116
 117 'add-watch' => [ '[URL_OR_PATHNAME]',
 118                 'watch for new messages and flag changes',
 119         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 120 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 121                 qw(format|f=s z) ],
 122 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 123 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 124 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 125         qw(prune) ],
 126
 127 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 128         'one-shot import/update from URL or filesystem',
 129         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 130         ],
 131
 132 'config' => [ '[...]', sub {
 133                 'git-config(1) wrapper for '._config_path($_[0]);
 134         }, qw(config-file|system|global|file|f=s), # for conflict detection
 135         pass_through('git config') ],
 136 'init' => [ '[PATHNAME]', sub {
 137                 'initialize storage, default: '._store_path($_[0]);
 138         }, qw(quiet|q) ],
 139 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 140         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 141 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 142 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 143         qw(clear| unset|u=s@ z|0) ],
 144 'help' => [ '[SUBCOMMAND]', 'show help' ],
 145
 146 # XXX do we need this?
 147 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 148
 149 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 150         'rewrite git history in an attempt to improve compression',
 151         'gc!' ],
 152
 153 # internal commands are prefixed with '_'
 154 '_complete' => [ '[...]', 'internal shell completion helper',
 155                 pass_through('everything') ],
 156 ); # @CMD
 157
 158 # switch descriptions, try to keep consistent across commands
 159 # $spec: Getopt::Long option specification
 160 # $spec => [@ALLOWED_VALUES (default is first), $description],
 161 # $spec => $description
 162 # "$SUB_COMMAND TAB $spec" => as above
 163 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 164                 'specify message input format' ];
 165 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 166
 167 my %OPTDESC = (
 168 'help|h' => 'show this built-in help',
 169 'quiet|q' => 'be quiet',
 170 'solve!' => 'do not attempt to reconstruct blobs from emails',
 171 'save-as=s' => ['NAME', 'save a search terms by given name'],
 172
 173 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 174
 175 'dedupe|d=s' => ['STRAT|content|oid|mid',
 176                 'deduplication strategy'],
 177 'show   thread|t' => 'display entire thread a message belongs to',
 178 'query  thread|t' =>
 179         'return all messages in the same thread as the actual match(es)',
 180 'augment|a' => 'augment --output destination instead of clobbering',
 181
 182 'output|o=s' => [ 'DEST',
 183         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 184
 185 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 186                         'message/object output format' ],
 187 'mark   format|f=s' => $stdin_formats,
 188 'forget format|f=s' => $stdin_formats,
 189 'query  format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid',
 190                 'specify output format, default depends on --output'],
 191 'ls-query       format|f=s' => $ls_format,
 192 'ls-extinbox    format|f=s' => $ls_format,
 193
 194 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 195 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 196
 197 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 198                 "order of results `--output'-dependent"],
 199
 200 'prio=i' => 'priority of query source',
 201
 202 'local' => 'limit operations to the local filesystem',
 203 'local!' => 'exclude results from the local filesystem',
 204 'remote' => 'limit operations to those requiring network access',
 205 'remote!' => 'prevent operations requiring network access',
 206
 207 'mid=s' => 'specify the Message-ID of a message',
 208 'oid=s' => 'specify the git object ID of a message',
 209
 210 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 211 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 212 'include=s' => 'include mailboxes/newsgroups based on pattern',
 213
 214 'exact' => 'operate on exact header matches only',
 215 'exact!' => 'rely on content match instead of exact header matches',
 216
 217 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 218 'jobs:i' => 'set parallelism level',
 219
 220 # xargs, env, use "-0", git(1) uses "-z".  Should we support z|0 everywhere?
 221 'z' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 222 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 223
 224 # note: no "--ignore-environment" / "-i" support like env(1) since that
 225 # is one-shot and this is for a persistent daemon:
 226 'clear|' => 'clear the daemon environment',
 227 'unset|u=s@' => ['NAME',
 228         'unset matching NAME, may be specified multiple times'],
 229
 230 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 231 ); # %OPTDESC
 232
 233 my %CONFIG_KEYS = (
 234         'leistore.dir' => 'top-level storage location',
 235 );
 236
 237 sub x_it ($$) { # pronounced "exit"
 238         my ($self, $code) = @_;
 239         if (my $sig = ($code & 127)) {
 240                 kill($sig, $self->{pid} // $$);
 241         } else {
 242                 $code >>= 8;
 243                 if (my $sock = $self->{sock}) {
 244                         say $sock "exit=$code";
 245                 } else { # for oneshot
 246                         $quit->($code);
 247                 }
 248         }
 249 }
 250
 251 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 252
 253 sub emit {
 254         my ($self, $channel) = @_; # $buf = $_[2]
 255         print { $self->{$channel} } $_[2] or die "print FD[$channel]: $!";
 256 }
 257
 258 sub err {
 259         my ($self, $buf) = @_;
 260         $buf .= "\n" unless $buf =~ /\n\z/s;
 261         emit($self, 2, $buf);
 262 }
 263
 264 sub qerr { $_[0]->{opt}->{quiet} or err(@_) }
 265
 266 sub fail ($$;$) {
 267         my ($self, $buf, $exit_code) = @_;
 268         err($self, $buf);
 269         x_it($self, ($exit_code // 1) << 8);
 270         undef;
 271 }
 272
 273 sub _help ($;$) {
 274         my ($self, $errmsg) = @_;
 275         my $cmd = $self->{cmd} // 'COMMAND';
 276         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 277         my @top = ($cmd, shift(@info) // ());
 278         my $cmd_desc = shift(@info);
 279         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 280         my @opt_desc;
 281         my $lpad = 2;
 282         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 283                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 284                 my $arg_vals = '';
 285                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 286
 287                 # lower-case is a keyword (e.g. `content', `oid'),
 288                 # ALL_CAPS is a string description (e.g. `PATH')
 289                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 290                         $desc .= "\ndefault: `$1'";
 291                 }
 292                 my (@vals, @s, @l);
 293                 my $x = $sw;
 294                 if ($x =~ s/!\z//) { # solve! => --no-solve
 295                         $x = "no-$x";
 296                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 297                         @vals = (' [', undef, ']');
 298                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 299                         @vals = (' ', undef);
 300                 } # else: no args $x = 'thread|t'
 301                 for (split(/\|/, $x)) { # help|h
 302                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 303                 }
 304                 if (!scalar(@vals)) { # no args 'thread|t'
 305                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 306                         $vals[1] = $1;
 307                 } else {
 308                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 309                 }
 310                 if ($arg_vals =~ /([,\|])/) {
 311                         my $sep = $1;
 312                         my @allow = split(/\Q$sep\E/, $arg_vals);
 313                         my $must = $sep eq '|' ? 'Must' : 'Can';
 314                         @allow = map { "`$_'" } @allow;
 315                         my $last = pop @allow;
 316                         $desc .= "\n$must be one of: " .
 317                                 join(', ', @allow) . " or $last";
 318                 }
 319                 my $lhs = join(', ', @s, @l) . join('', @vals);
 320                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 321                         $lhs =~ s/\A--/- , --/;
 322                 } else {
 323                         $lhs =~ s/\A--/    --/; # pad if no short options
 324                 }
 325                 $lpad = length($lhs) if length($lhs) > $lpad;
 326                 push @opt_desc, $lhs, $desc;
 327         }
 328         my $msg = $errmsg ? "E: $errmsg\n" : '';
 329         $msg .= <<EOF;
 330 usage: lei @top
 331   $cmd_desc
 332
 333 EOF
 334         $lpad += 2;
 335         local $Text::Wrap::columns = 78 - $lpad;
 336         my $padding = ' ' x ($lpad + 2);
 337         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 338                 $msg .= '  '.pack("A$lpad", $lhs);
 339                 $rhs = wrap('', '', $rhs);
 340                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 341                 $msg .= $rhs;
 342                 $msg .= "\n";
 343         }
 344         my $channel = $errmsg ? 2 : 1;
 345         emit($self, $channel, $msg);
 346         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 347         undef;
 348 }
 349
 350 sub optparse ($$$) {
 351         my ($self, $cmd, $argv) = @_;
 352         $self->{cmd} = $cmd;
 353         $OPT = $self->{opt} = {};
 354         my $info = $CMD{$cmd} // [ '[...]' ];
 355         my ($proto, undef, @spec) = @$info;
 356         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 357         push @spec, qw(help|h);
 358         my $lone_dash;
 359         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 360                 $lone_dash = $spec[0];
 361                 $OPT->{$spec[0]} = \(my $var);
 362                 push @spec, '' => \$var;
 363         }
 364         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 365                 return _help($self, "bad arguments or options for $cmd");
 366         return _help($self) if $OPT->{help};
 367
 368         # "-" aliases "stdin" or "clear"
 369         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 370
 371         my $i = 0;
 372         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 373         my ($err, $inf);
 374         my @args = split(/ /, $proto);
 375         for my $var (@args) {
 376                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 377                         $inf = defined($argv->[$i]) and last;
 378                         $var =~ s/\.\.\.\z//;
 379                         $err = "$var not supplied";
 380                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 381                         $argv->[$i++] // ($err = "$var not supplied");
 382                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 383                         $inf = 1;
 384                         last;
 385                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 386                         $i++;
 387                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 388                         my @or = split(/\|/, $var);
 389                         my $ok;
 390                         for my $o (@or) {
 391                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 392                                         $ok = defined($OPT->{$1});
 393                                         last;
 394                                 } elsif (defined($argv->[$i])) {
 395                                         $ok = 1;
 396                                         $i++;
 397                                         last;
 398                                 } # else continue looping
 399                         }
 400                         my $last = pop @or;
 401                         $err = join(', ', @or) . " or $last must be set";
 402                 } else {
 403                         warn "BUG: can't parse `$var' in $proto";
 404                 }
 405                 last if $err;
 406         }
 407         # warn "inf=$inf ".scalar(@$argv). ' '.scalar(@args)."\n";
 408         if (!$inf && scalar(@$argv) > scalar(@args)) {
 409                 $err //= 'too many arguments';
 410         }
 411         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 412 }
 413
 414 sub dispatch {
 415         my ($self, $cmd, @argv) = @_;
 416         local $SIG{__WARN__} = sub { err($self, "@_") };
 417         return _help($self, 'no command given') unless defined($cmd);
 418         my $func = "lei_$cmd";
 419         $func =~ tr/-/_/;
 420         if (my $cb = __PACKAGE__->can($func)) {
 421                 optparse($self, $cmd, \@argv) or return;
 422                 $cb->($self, @argv);
 423         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 424                 my $opt = {};
 425                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 426                         return _help($self, 'bad arguments or options');
 427                 _help($self);
 428         } else {
 429                 fail($self, "`$cmd' is not an lei command");
 430         }
 431 }
 432
 433 sub _lei_cfg ($;$) {
 434         my ($self, $creat) = @_;
 435         my $f = _config_path($self->{env});
 436         my @st = stat($f);
 437         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 438         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 439                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 440         }
 441         if (!@st) {
 442                 unless ($creat) {
 443                         delete $self->{cfg};
 444                         return;
 445                 }
 446                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 447                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 448                 open my $fh, '>>', $f or die "open($f): $!\n";
 449                 @st = stat($fh) or die "fstat($f): $!\n";
 450                 $cur_st = pack('dd', $st[10], $st[7]);
 451                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 452         }
 453         my $cfg = PublicInbox::Config::git_config_dump($f);
 454         $cfg->{-st} = $cur_st;
 455         $cfg->{'-f'} = $f;
 456         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 457 }
 458
 459 sub _lei_store ($;$) {
 460         my ($self, $creat) = @_;
 461         my $cfg = _lei_cfg($self, $creat);
 462         $cfg->{-lei_store} //= do {
 463                 require PublicInbox::LeiStore;
 464                 PublicInbox::SearchIdx::load_xapian_writable();
 465                 defined(my $dir = $cfg->{'leistore.dir'}) or return;
 466                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 467         };
 468 }
 469
 470 sub lei_show {
 471         my ($self, @argv) = @_;
 472 }
 473
 474 sub lei_query {
 475         my ($self, @argv) = @_;
 476 }
 477
 478 sub lei_mark {
 479         my ($self, @argv) = @_;
 480 }
 481
 482 sub lei_config {
 483         my ($self, @argv) = @_;
 484         $self->{opt}->{'config-file'} and return fail $self,
 485                 "config file switches not supported by `lei config'";
 486         my $env = $self->{env};
 487         delete local $env->{GIT_CONFIG};
 488         my $cfg = _lei_cfg($self, 1);
 489         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 490         my %rdr = map { $_ => $self->{$_} } (0..2);
 491         require PublicInbox::Import;
 492         PublicInbox::Import::run_die($cmd, $env, \%rdr);
 493 }
 494
 495 sub lei_init {
 496         my ($self, $dir) = @_;
 497         my $cfg = _lei_cfg($self, 1);
 498         my $cur = $cfg->{'leistore.dir'};
 499         my $env = $self->{env};
 500         $dir //= _store_path($env);
 501         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 502         my @cur = stat($cur) if defined($cur);
 503         $cur = File::Spec->canonpath($cur) if $cur;
 504         my @dir = stat($dir);
 505         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 506         if (@cur) {
 507                 if ($cur eq $dir) {
 508                         _lei_store($self, 1)->done;
 509                         return qerr($self, $exists);
 510                 }
 511
 512                 # some folks like symlinks and bind mounts :P
 513                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 514                         lei_config($self, 'leistore.dir', $dir);
 515                         _lei_store($self, 1)->done;
 516                         return qerr($self, "$exists (as $cur)");
 517                 }
 518                 return fail($self, <<"");
 519 E: leistore.dir=$cur already initialized and it is not $dir
 520
 521         }
 522         lei_config($self, 'leistore.dir', $dir);
 523         _lei_store($self, 1)->done;
 524         $exists //= "I: leistore.dir=$dir newly initialized";
 525         return qerr($self, $exists);
 526 }
 527
 528 sub lei_daemon_pid { emit($_[0], 1, "$$\n") }
 529
 530 sub lei_daemon_kill {
 531         my ($self) = @_;
 532         my $sig = $self->{opt}->{signal} // 'TERM';
 533         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 534 }
 535
 536 sub lei_daemon_env {
 537         my ($self, @argv) = @_;
 538         my $opt = $self->{opt};
 539         if (defined $opt->{clear}) {
 540                 %ENV = ();
 541         } elsif (my $u = $opt->{unset}) {
 542                 delete @ENV{@$u};
 543         }
 544         if (@argv) {
 545                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 546         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 547                 my $eor = $opt->{z} ? "\0" : "\n";
 548                 my $buf = '';
 549                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 550                 emit($self, 1, $buf)
 551         }
 552 }
 553
 554 sub lei_help { _help($_[0]) }
 555
 556 # Shell completion helper.  Used by lei-completion.bash and hopefully
 557 # other shells.  Try to do as much here as possible to avoid redundancy
 558 # and improve maintainability.
 559 sub lei__complete {
 560         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 561         shift @argv; # ignore "lei", the entire command is sent
 562         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 563         my $cmd = shift @argv;
 564         my $info = $CMD{$cmd} // do { # filter matching commands
 565                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 566                 return;
 567         };
 568         my ($proto, undef, @spec) = @$info;
 569         my $cur = pop @argv;
 570         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 571         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 572                 # gross special case since the only git-config options
 573                 # Consider moving to a table if we need more special cases
 574                 # we use Getopt::Long for are the ones we reject, so these
 575                 # are the ones we don't reject:
 576                 if ($cmd eq 'config') {
 577                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 578                         @spec = qw(add z|null get get-all unset unset-all
 579                                 replace-all get-urlmatch
 580                                 remove-section rename-section
 581                                 name-only list|l edit|e
 582                                 get-color-name get-colorbool);
 583                         # fall-through
 584                 }
 585                 # TODO: arg support
 586                 puts $self, grep(/$re/, map { # generate short/long names
 587                         my $eq = '';
 588                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 589                                 $eq = '=';
 590                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 591                         } else { # negation: solve! => no-solve|solve
 592                                 s/\A(.+)!\z/no-$1|$1/;
 593                         }
 594                         map {
 595                                 length > 1 ? "--$_$eq" : "-$_"
 596                         } split(/\|/, $_, -1) # help|h
 597                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 598         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 599                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 600         }
 601         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 602         # proto parsing.
 603 }
 604
 605 sub reap_exec { # dwaitpid callback
 606         my ($self, $pid) = @_;
 607         x_it($self, $?);
 608 }
 609
 610 sub lei_git { # support passing through random git commands
 611         my ($self, @argv) = @_;
 612         my %rdr = map { $_ => $self->{$_} } (0..2);
 613         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 614         PublicInbox::DS::dwaitpid($pid, \&reap_exec, $self);
 615 }
 616
 617 sub accept_dispatch { # Listener {post_accept} callback
 618         my ($sock) = @_; # ignore other
 619         $sock->blocking(1);
 620         $sock->autoflush(1);
 621         my $self = bless { sock => $sock }, __PACKAGE__;
 622         vec(my $rin = '', fileno($sock), 1) = 1;
 623         # `say $sock' triggers "die" in lei(1)
 624         for my $i (0..2) {
 625                 if (select(my $rout = $rin, undef, undef, 1)) {
 626                         my $fd = IO::FDPass::recv(fileno($sock));
 627                         if ($fd >= 0) {
 628                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 629                                 if (open(my $fh, $rdr, $fd)) {
 630                                         $self->{$i} = $fh;
 631                                 } else {
 632                                         say $sock "open($rdr$fd) (FD=$i): $!";
 633                                         return;
 634                                 }
 635                         } else {
 636                                 say $sock "recv FD=$i: $!";
 637                                 return;
 638                         }
 639                 } else {
 640                         say $sock "timed out waiting to recv FD=$i";
 641                         return;
 642                 }
 643         }
 644         # $ARGV_STR = join("]\0[", @ARGV);
 645         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 646         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 647         my ($client_pid, $argv, $env) = do {
 648                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 649                 chomp(my $line = <$sock>);
 650                 split(/\0\0>/, $line, 3);
 651         };
 652         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 653         if (chdir($env{PWD})) {
 654                 $self->{env} = \%env;
 655                 $self->{pid} = $client_pid;
 656                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 657                 say $sock $@ if $@;
 658         } else {
 659                 say $sock "chdir($env{PWD}): $!"; # implicit close
 660         }
 661 }
 662
 663 sub noop {}
 664
 665 # lei(1) calls this when it can't connect
 666 sub lazy_start {
 667         my ($path, $errno) = @_;
 668         if ($errno == ECONNREFUSED) {
 669                 unlink($path) or die "unlink($path): $!";
 670         } elsif ($errno != ENOENT) {
 671                 $! = $errno; # allow interpolation to stringify in die
 672                 die "connect($path): $!";
 673         }
 674         umask(077) // die("umask(077): $!");
 675         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 676         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 677         listen($l, 1024) or die "listen: $!";
 678         my @st = stat($path) or die "stat($path): $!";
 679         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 680         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 681         my $oldset = PublicInbox::Sigfd::block_signals();
 682         require IO::FDPass;
 683         require PublicInbox::Listener;
 684         require PublicInbox::EOFpipe;
 685         (-p STDOUT && -p STDERR) or die "E: stdout+stderr must be pipes\n";
 686         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 687         POSIX::setsid() > 0 or die "setsid: $!";
 688         my $pid = fork // die "fork: $!";
 689         return if $pid;
 690         $0 = "lei-daemon $path";
 691         local %PATH2CFG;
 692         $_->blocking(0) for ($l, $eof_r, $eof_w);
 693         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 694         my $exit_code;
 695         local $quit = sub {
 696                 $exit_code //= shift;
 697                 my $listener = $l or exit($exit_code);
 698                 unlink($path) if defined($path);
 699                 # closing eof_w triggers \&noop wakeup
 700                 $eof_w = $l = $path = undef;
 701                 $listener->close; # DS::close
 702                 PublicInbox::DS->SetLoopTimeout(1000);
 703         };
 704         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 705         my $sig = {
 706                 CHLD => \&PublicInbox::DS::enqueue_reap,
 707                 QUIT => $quit,
 708                 INT => $quit,
 709                 TERM => $quit,
 710                 HUP => \&noop,
 711                 USR1 => \&noop,
 712                 USR2 => \&noop,
 713         };
 714         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 715         local %SIG = (%SIG, %$sig) if !$sigfd;
 716         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 717                 PublicInbox::DS->SetLoopTimeout(5000);
 718         } else {
 719                 # wake up every second to accept signals if we don't
 720                 # have signalfd or IO::KQueue:
 721                 PublicInbox::Sigfd::sig_setmask($oldset);
 722                 PublicInbox::DS->SetLoopTimeout(1000);
 723         }
 724         PublicInbox::DS->SetPostLoopCallback(sub {
 725                 my ($dmap, undef) = @_;
 726                 if (@st = defined($path) ? stat($path) : ()) {
 727                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 728                                 warn "$path dev/ino changed, quitting\n";
 729                                 $path = undef;
 730                         }
 731                 } elsif (defined($path)) {
 732                         warn "stat($path): $!, quitting ...\n";
 733                         undef $path; # don't unlink
 734                         $quit->();
 735                 }
 736                 return 1 if defined($path);
 737                 my $now = now();
 738                 my $n = 0;
 739                 for my $s (values %$dmap) {
 740                         $s->can('busy') or next;
 741                         if ($s->busy($now)) {
 742                                 ++$n;
 743                         } else {
 744                                 $s->close;
 745                         }
 746                 }
 747                 $n; # true: continue, false: stop
 748         });
 749
 750         # STDIN was redirected to /dev/null above, closing STDOUT and
 751         # STDERR will cause the calling `lei' client process to finish
 752         # reading <$daemon> pipe.
 753         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 754         openlog($path, 'pid', 'user');
 755         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 756         my $owner_pid = $$;
 757         my $on_destroy = PublicInbox::OnDestroy->new(sub {
 758                 syslog('crit', "$@") if $@ && $$ == $owner_pid;
 759         });
 760         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 761         # $daemon pipe to `lei' closed, main loop begins:
 762         PublicInbox::DS->EventLoop;
 763         @$on_destroy = (); # cancel on_destroy if we get here
 764         exit($exit_code // 0);
 765 }
 766
 767 # for users w/o IO::FDPass
 768 sub oneshot {
 769         my ($main_pkg) = @_;
 770         my $exit = $main_pkg->can('exit'); # caller may override exit()
 771         local $quit = $exit if $exit;
 772         local %PATH2CFG;
 773         umask(077) // die("umask(077): $!");
 774         dispatch((bless {
 775                 0 => *STDIN{IO},
 776                 1 => *STDOUT{IO},
 777                 2 => *STDERR{IO},
 778                 env => \%ENV
 779         }, __PACKAGE__), @ARGV);
 780 }
 781
 782 1;