lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 my ($recv_cmd, $send_cmd);
  30 my $GLP = Getopt::Long::Parser->new;
  31 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  32 my $GLP_PASS = Getopt::Long::Parser->new;
  33 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  34
  35 our %PATH2CFG; # persistent for socket daemon
  36 our @TO_CLOSE_ATFORK_CHILD;
  37
  38 # TBD: this is a documentation mechanism to show a subcommand
  39 # (may) pass options through to another command:
  40 sub pass_through { $GLP_PASS }
  41
  42 my $OPT;
  43 sub opt_dash ($$) {
  44         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  45         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  46         my $cb = sub { # Getopt::Long "<>" catch-all handler
  47                 my ($arg) = @_;
  48                 if ($arg =~ /\A-($re_str)\z/) {
  49                         $OPT->{$key} = $1;
  50                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  51                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  52                 # lone (single) dash is handled elsewhere
  53                 } elsif (substr($arg, 0, 1) eq '-') {
  54                         if ($OPT->{'--'}) {
  55                                 push @{$OPT->{-argv}}, $arg;
  56                         } else {
  57                                 die "bad argument: $arg\n";
  58                         }
  59                 } else {
  60                         push @{$OPT->{-argv}}, $arg;
  61                 }
  62         };
  63         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  64 }
  65
  66 sub _store_path ($) {
  67         my ($env) = @_;
  68         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  69                 ($env->{HOME} // '/nonexistent').'/.local/share')
  70                 .'/lei/store', $env->{PWD});
  71 }
  72
  73 sub _config_path ($) {
  74         my ($env) = @_;
  75         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  76                 ($env->{HOME} // '/nonexistent').'/.config')
  77                 .'/lei/config', $env->{PWD});
  78 }
  79
  80 # TODO: generate shell completion + help using %CMD and %OPTDESC
  81 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  82 our %CMD = ( # sorted in order of importance/use:
  83 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  84         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  85         sort|s=s reverse|r offset=i remote local! external! pretty
  86         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  87
  88 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  89         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  90         pass_through('git show') ],
  91
  92 'add-external' => [ 'URL_OR_PATHNAME',
  93         'add/set priority of a publicinbox|extindex for extra matches',
  94         qw(boost=i quiet|q) ],
  95 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  96         qw(format|f=s z|0 local remote quiet|q) ],
  97 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  98         'exclude further results from a publicinbox|extindex',
  99         qw(prune quiet|q) ],
 100
 101 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 102                 qw(name-only format|f=s z) ],
 103 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 104 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 105
 106 'plonk' => [ '--thread|--from=IDENT',
 107         'exclude mail matching From: or thread from non-Message-ID searches',
 108         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 109 'mark' => [ 'MESSAGE_FLAGS...',
 110         'set/unset flags on message(s) from stdin',
 111         qw(stdin| oid=s exact by-mid|mid:s) ],
 112 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 113         "exclude message(s) on stdin from `q' search results",
 114         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 115
 116 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 117         'remove imported messages from IMAP, Maildirs, and MH',
 118         qw(exact! all jobs:i indexed) ],
 119
 120 # code repos are used for `show' to solve blobs from patch mails
 121 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 122         qw(boost=i) ],
 123 'ls-coderepo' => [ '[FILTER_TERMS...]',
 124                 'list known code repos', qw(format|f=s z) ],
 125 'forget-coderepo' => [ 'PATHNAME',
 126         'stop using repo to solve blobs from patches',
 127         qw(prune) ],
 128
 129 'add-watch' => [ '[URL_OR_PATHNAME]',
 130                 'watch for new messages and flag changes',
 131         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 132 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 133                 qw(format|f=s z) ],
 134 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 135 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 137         qw(prune) ],
 138
 139 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 140         'one-shot import/update from URL or filesystem',
 141         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 142         ],
 143
 144 'config' => [ '[...]', sub {
 145                 'git-config(1) wrapper for '._config_path($_[0]);
 146         }, qw(config-file|system|global|file|f=s), # for conflict detection
 147         pass_through('git config') ],
 148 'init' => [ '[PATHNAME]', sub {
 149                 'initialize storage, default: '._store_path($_[0]);
 150         }, qw(quiet|q) ],
 151 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 152         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 153 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 154 'help' => [ '[SUBCOMMAND]', 'show help' ],
 155
 156 # XXX do we need this?
 157 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 158
 159 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 160         'rewrite git history in an attempt to improve compression',
 161         'gc!' ],
 162
 163 # internal commands are prefixed with '_'
 164 '_complete' => [ '[...]', 'internal shell completion helper',
 165                 pass_through('everything') ],
 166 ); # @CMD
 167
 168 # switch descriptions, try to keep consistent across commands
 169 # $spec: Getopt::Long option specification
 170 # $spec => [@ALLOWED_VALUES (default is first), $description],
 171 # $spec => $description
 172 # "$SUB_COMMAND TAB $spec" => as above
 173 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 174                 'specify message input format' ];
 175 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 176
 177 my %OPTDESC = (
 178 'help|h' => 'show this built-in help',
 179 'quiet|q' => 'be quiet',
 180 'solve!' => 'do not attempt to reconstruct blobs from emails',
 181 'save-as=s' => ['NAME', 'save a search terms by given name'],
 182
 183 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 184
 185 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 186                 'deduplication strategy'],
 187 'show   thread|t' => 'display entire thread a message belongs to',
 188 'q      thread|t' =>
 189         'return all messages in the same thread as the actual match(es)',
 190 'augment|a' => 'augment --output destination instead of clobbering',
 191
 192 'output|o=s' => [ 'DEST',
 193         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 194
 195 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 196                         'message/object output format' ],
 197 'mark   format|f=s' => $stdin_formats,
 198 'forget format|f=s' => $stdin_formats,
 199 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 200                 'specify output format, default depends on --output'],
 201 'ls-query       format|f=s' => $ls_format,
 202 'ls-external    format|f=s' => $ls_format,
 203
 204 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 205 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 206
 207 'sort|s=s' => [ 'VAL|received,relevance,docid',
 208                 "order of results `--output'-dependent"],
 209 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 210
 211 'boost=i' => 'increase/decrease priority of results (default: 0)',
 212
 213 'local' => 'limit operations to the local filesystem',
 214 'local!' => 'exclude results from the local filesystem',
 215 'remote' => 'limit operations to those requiring network access',
 216 'remote!' => 'prevent operations requiring network access',
 217
 218 'mid=s' => 'specify the Message-ID of a message',
 219 'oid=s' => 'specify the git object ID of a message',
 220
 221 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 222 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 223 'include=s' => 'include mailboxes/newsgroups based on pattern',
 224
 225 'exact' => 'operate on exact header matches only',
 226 'exact!' => 'rely on content match instead of exact header matches',
 227
 228 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 229 'jobs:i' => 'set parallelism level',
 230
 231 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 232 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 233
 234 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 235 ); # %OPTDESC
 236
 237 my %CONFIG_KEYS = (
 238         'leistore.dir' => 'top-level storage location',
 239 );
 240
 241 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 242 sub x_it ($$) {
 243         my ($self, $code) = @_;
 244         # make sure client sees stdout before exit
 245         $self->{1}->autoflush(1) if $self->{1};
 246         if (my $sock = $self->{sock}) {
 247                 send($sock, "x_it $code", MSG_EOR);
 248         } elsif (!($code & 127)) { # oneshot, ignore signals
 249                 $quit->($code >> 8);
 250         }
 251 }
 252
 253 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 254
 255 sub out ($;@) { print { shift->{1} } @_ }
 256
 257 sub err ($;@) {
 258         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 259 }
 260
 261 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 262
 263 sub fail ($$;$) {
 264         my ($self, $buf, $exit_code) = @_;
 265         err($self, $buf);
 266         x_it($self, ($exit_code // 1) << 8);
 267         undef;
 268 }
 269
 270 sub atfork_prepare_wq {
 271         my ($self, $wq) = @_;
 272         push @{$wq->{-ipc_atfork_child_close}}, @TO_CLOSE_ATFORK_CHILD,
 273                                 grep { defined } @$self{qw(0 1 2 sock)}
 274 }
 275
 276 # usage: my %sig = $lei->atfork_child_wq($wq);
 277 #        local @SIG{keys %sig} = values %sig;
 278 sub atfork_child_wq {
 279         my ($self, $wq) = @_;
 280         @$self{qw(0 1 2 sock)} = delete(@$wq{0..3});
 281         %PATH2CFG = ();
 282         @TO_CLOSE_ATFORK_CHILD = ();
 283         (__WARN__ => sub { err($self, @_) },
 284         PIPE => sub {
 285                 $self->x_it(13); # SIGPIPE = 13
 286                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 287                 close($_) for (delete @$self{1..2});
 288                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 289         });
 290 }
 291
 292 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 293 sub atfork_parent_wq {
 294         my ($self, $wq) = @_;
 295         if ($wq->wq_workers) {
 296                 my $env = delete $self->{env}; # env is inherited at fork
 297                 my $ret = bless { %$self }, ref($self);
 298                 $self->{env} = $env;
 299                 delete @$ret{qw(-lei_store cfg pgr)};
 300                 ($ret, delete @$ret{0..2}, delete($ret->{sock}) // ());
 301         } else {
 302                 ($self, @$self{0..2}, $self->{sock} // ());
 303         }
 304 }
 305
 306 sub _help ($;$) {
 307         my ($self, $errmsg) = @_;
 308         my $cmd = $self->{cmd} // 'COMMAND';
 309         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 310         my @top = ($cmd, shift(@info) // ());
 311         my $cmd_desc = shift(@info);
 312         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 313         my @opt_desc;
 314         my $lpad = 2;
 315         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 316                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 317                 my $arg_vals = '';
 318                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 319
 320                 # lower-case is a keyword (e.g. `content', `oid'),
 321                 # ALL_CAPS is a string description (e.g. `PATH')
 322                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 323                         $desc .= "\ndefault: `$1'";
 324                 }
 325                 my (@vals, @s, @l);
 326                 my $x = $sw;
 327                 if ($x =~ s/!\z//) { # solve! => --no-solve
 328                         $x = "no-$x";
 329                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 330                         @vals = (' [', undef, ']');
 331                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 332                         @vals = (' ', undef);
 333                 } # else: no args $x = 'thread|t'
 334                 for (split(/\|/, $x)) { # help|h
 335                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 336                 }
 337                 if (!scalar(@vals)) { # no args 'thread|t'
 338                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 339                         $vals[1] = $1;
 340                 } else {
 341                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 342                 }
 343                 if ($arg_vals =~ /([,\|])/) {
 344                         my $sep = $1;
 345                         my @allow = split(/\Q$sep\E/, $arg_vals);
 346                         my $must = $sep eq '|' ? 'Must' : 'Can';
 347                         @allow = map { "`$_'" } @allow;
 348                         my $last = pop @allow;
 349                         $desc .= "\n$must be one of: " .
 350                                 join(', ', @allow) . " or $last";
 351                 }
 352                 my $lhs = join(', ', @s, @l) . join('', @vals);
 353                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 354                         $lhs =~ s/\A--/- , --/;
 355                 } else {
 356                         $lhs =~ s/\A--/    --/; # pad if no short options
 357                 }
 358                 $lpad = length($lhs) if length($lhs) > $lpad;
 359                 push @opt_desc, $lhs, $desc;
 360         }
 361         my $msg = $errmsg ? "E: $errmsg\n" : '';
 362         $msg .= <<EOF;
 363 usage: lei @top
 364   $cmd_desc
 365
 366 EOF
 367         $lpad += 2;
 368         local $Text::Wrap::columns = 78 - $lpad;
 369         my $padding = ' ' x ($lpad + 2);
 370         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 371                 $msg .= '  '.pack("A$lpad", $lhs);
 372                 $rhs = wrap('', '', $rhs);
 373                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 374                 $msg .= $rhs;
 375                 $msg .= "\n";
 376         }
 377         print { $self->{$errmsg ? 2 : 1} } $msg;
 378         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 379         undef;
 380 }
 381
 382 sub optparse ($$$) {
 383         my ($self, $cmd, $argv) = @_;
 384         $self->{cmd} = $cmd;
 385         $OPT = $self->{opt} = {};
 386         my $info = $CMD{$cmd} // [ '[...]' ];
 387         my ($proto, undef, @spec) = @$info;
 388         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 389         push @spec, qw(help|h);
 390         my $lone_dash;
 391         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 392                 $lone_dash = $spec[0];
 393                 $OPT->{$spec[0]} = \(my $var);
 394                 push @spec, '' => \$var;
 395         }
 396         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 397                 return _help($self, "bad arguments or options for $cmd");
 398         return _help($self) if $OPT->{help};
 399
 400         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 401
 402         # "-" aliases "stdin" or "clear"
 403         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 404
 405         my $i = 0;
 406         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 407         my ($err, $inf);
 408         my @args = split(/ /, $proto);
 409         for my $var (@args) {
 410                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 411                         $inf = defined($argv->[$i]) and last;
 412                         $var =~ s/\.\.\.\z//;
 413                         $err = "$var not supplied";
 414                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 415                         $argv->[$i++] // ($err = "$var not supplied");
 416                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 417                         $inf = 1;
 418                         last;
 419                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 420                         $i++;
 421                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 422                         my @or = split(/\|/, $var);
 423                         my $ok;
 424                         for my $o (@or) {
 425                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 426                                         $ok = defined($OPT->{$1});
 427                                         last;
 428                                 } elsif (defined($argv->[$i])) {
 429                                         $ok = 1;
 430                                         $i++;
 431                                         last;
 432                                 } # else continue looping
 433                         }
 434                         my $last = pop @or;
 435                         $err = join(', ', @or) . " or $last must be set";
 436                 } else {
 437                         warn "BUG: can't parse `$var' in $proto";
 438                 }
 439                 last if $err;
 440         }
 441         if (!$inf && scalar(@$argv) > scalar(@args)) {
 442                 $err //= 'too many arguments';
 443         }
 444         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 445 }
 446
 447 sub dispatch {
 448         my ($self, $cmd, @argv) = @_;
 449         local $SIG{__WARN__} = sub { err($self, @_) };
 450         return _help($self, 'no command given') unless defined($cmd);
 451         my $func = "lei_$cmd";
 452         $func =~ tr/-/_/;
 453         if (my $cb = __PACKAGE__->can($func)) {
 454                 optparse($self, $cmd, \@argv) or return;
 455                 $cb->($self, @argv);
 456         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 457                 my $opt = {};
 458                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 459                         return _help($self, 'bad arguments or options');
 460                 _help($self);
 461         } else {
 462                 fail($self, "`$cmd' is not an lei command");
 463         }
 464 }
 465
 466 sub _lei_cfg ($;$) {
 467         my ($self, $creat) = @_;
 468         my $f = _config_path($self->{env});
 469         my @st = stat($f);
 470         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 471         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 472                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 473         }
 474         if (!@st) {
 475                 unless ($creat) {
 476                         delete $self->{cfg};
 477                         return;
 478                 }
 479                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 480                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 481                 open my $fh, '>>', $f or die "open($f): $!\n";
 482                 @st = stat($fh) or die "fstat($f): $!\n";
 483                 $cur_st = pack('dd', $st[10], $st[7]);
 484                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 485         }
 486         my $cfg = PublicInbox::Config::git_config_dump($f);
 487         $cfg->{-st} = $cur_st;
 488         $cfg->{'-f'} = $f;
 489         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 490 }
 491
 492 sub _lei_store ($;$) {
 493         my ($self, $creat) = @_;
 494         my $cfg = _lei_cfg($self, $creat);
 495         $cfg->{-lei_store} //= do {
 496                 require PublicInbox::LeiStore;
 497                 my $dir = $cfg->{'leistore.dir'};
 498                 $dir //= _store_path($self->{env}) if $creat;
 499                 return unless $dir;
 500                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 501         };
 502 }
 503
 504 sub lei_show {
 505         my ($self, @argv) = @_;
 506 }
 507
 508 sub lei_mark {
 509         my ($self, @argv) = @_;
 510 }
 511
 512 sub lei_config {
 513         my ($self, @argv) = @_;
 514         $self->{opt}->{'config-file'} and return fail $self,
 515                 "config file switches not supported by `lei config'";
 516         my $env = $self->{env};
 517         delete local $env->{GIT_CONFIG};
 518         my $cfg = _lei_cfg($self, 1);
 519         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 520         my %rdr = map { $_ => $self->{$_} } (0..2);
 521         run_die($cmd, $env, \%rdr);
 522 }
 523
 524 sub lei_init {
 525         my ($self, $dir) = @_;
 526         my $cfg = _lei_cfg($self, 1);
 527         my $cur = $cfg->{'leistore.dir'};
 528         my $env = $self->{env};
 529         $dir //= _store_path($env);
 530         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 531         my @cur = stat($cur) if defined($cur);
 532         $cur = File::Spec->canonpath($cur // $dir);
 533         my @dir = stat($dir);
 534         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 535         if (@cur) {
 536                 if ($cur eq $dir) {
 537                         _lei_store($self, 1)->done;
 538                         return qerr($self, $exists);
 539                 }
 540
 541                 # some folks like symlinks and bind mounts :P
 542                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 543                         lei_config($self, 'leistore.dir', $dir);
 544                         _lei_store($self, 1)->done;
 545                         return qerr($self, "$exists (as $cur)");
 546                 }
 547                 return fail($self, <<"");
 548 E: leistore.dir=$cur already initialized and it is not $dir
 549
 550         }
 551         lei_config($self, 'leistore.dir', $dir);
 552         _lei_store($self, 1)->done;
 553         $exists //= "I: leistore.dir=$dir newly initialized";
 554         return qerr($self, $exists);
 555 }
 556
 557 sub lei_daemon_pid { puts shift, $$ }
 558
 559 sub lei_daemon_kill {
 560         my ($self) = @_;
 561         my $sig = $self->{opt}->{signal} // 'TERM';
 562         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 563 }
 564
 565 sub lei_help { _help($_[0]) }
 566
 567 # Shell completion helper.  Used by lei-completion.bash and hopefully
 568 # other shells.  Try to do as much here as possible to avoid redundancy
 569 # and improve maintainability.
 570 sub lei__complete {
 571         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 572         shift @argv; # ignore "lei", the entire command is sent
 573         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 574         my $cmd = shift @argv;
 575         my $info = $CMD{$cmd} // do { # filter matching commands
 576                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 577                 return;
 578         };
 579         my ($proto, undef, @spec) = @$info;
 580         my $cur = pop @argv;
 581         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 582         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 583                 # gross special case since the only git-config options
 584                 # Consider moving to a table if we need more special cases
 585                 # we use Getopt::Long for are the ones we reject, so these
 586                 # are the ones we don't reject:
 587                 if ($cmd eq 'config') {
 588                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 589                         @spec = qw(add z|null get get-all unset unset-all
 590                                 replace-all get-urlmatch
 591                                 remove-section rename-section
 592                                 name-only list|l edit|e
 593                                 get-color-name get-colorbool);
 594                         # fall-through
 595                 }
 596                 # TODO: arg support
 597                 puts $self, grep(/$re/, map { # generate short/long names
 598                         my $eq = '';
 599                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 600                                 $eq = '=';
 601                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 602                         } else { # negation: solve! => no-solve|solve
 603                                 s/\A(.+)!\z/no-$1|$1/;
 604                         }
 605                         map {
 606                                 length > 1 ? "--$_$eq" : "-$_"
 607                         } split(/\|/, $_, -1) # help|h
 608                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 609         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 610                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 611         }
 612         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 613         # proto parsing.
 614 }
 615
 616 sub reap_exec { # dwaitpid callback
 617         my ($self, $pid) = @_;
 618         x_it($self, $?);
 619 }
 620
 621 sub lei_git { # support passing through random git commands
 622         my ($self, @argv) = @_;
 623         my %rdr = map { $_ => $self->{$_} } (0..2);
 624         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 625         dwaitpid($pid, \&reap_exec, $self);
 626 }
 627
 628 # caller needs to "-t $self->{1}" to check if tty
 629 sub start_pager {
 630         my ($self) = @_;
 631         my $env = $self->{env};
 632         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 633         chomp(my $pager = <$fh> // '');
 634         close($fh) or warn "`git var PAGER' error: \$?=$?";
 635         return if $pager eq 'cat' || $pager eq '';
 636         # TODO TIOCGWINSZ
 637         my %new_env = (LESS => 'FRX', LV => '-c', COLUMNS => 80);
 638         $new_env{MORE} = 'FRX' if $^O eq 'freebsd';
 639         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 640         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 641         my $pgr = [ undef, @$rdr{1, 2} ];
 642         if (my $sock = $self->{sock}) { # lei(1) process runs it
 643                 delete @new_env{keys %$env}; # only set iff unset
 644                 my $buf = "exec 1\0".$pager;
 645                 while (my ($k, $v) = each %new_env) { $buf .= "\0$k=$v" };
 646                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 647                 $send_cmd->($sock, $fds, $buf, MSG_EOR);
 648         } else {
 649                 $pgr->[0] = spawn([$pager], $env, $rdr);
 650         }
 651         $self->{1} = $wpager;
 652         $self->{2} = $wpager if -t $self->{2};
 653         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 654         $self->{pgr} = $pgr;
 655 }
 656
 657 sub stop_pager {
 658         my ($self) = @_;
 659         my $pgr = delete($self->{pgr}) or return;
 660         $self->{2} = $pgr->[2];
 661         # do not restore original stdout, just close it so we error out
 662         close(delete($self->{1})) if $self->{1};
 663         my $pid = $pgr->[0];
 664         dwaitpid($pid, undef, $self->{sock}) if $pid;
 665 }
 666
 667 sub accept_dispatch { # Listener {post_accept} callback
 668         my ($sock) = @_; # ignore other
 669         $sock->autoflush(1);
 670         my $self = bless { sock => $sock }, __PACKAGE__;
 671         vec(my $rvec, fileno($sock), 1) = 1;
 672         select($rvec, undef, undef, 1) or
 673                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 674         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 675         if (scalar(@fds) == 3) {
 676                 my $i = 0;
 677                 for my $rdr (qw(<&= >&= >&=)) {
 678                         my $fd = shift(@fds);
 679                         if (open(my $fh, $rdr, $fd)) {
 680                                 $self->{$i++} = $fh;
 681                                 next;
 682                         }
 683                         return send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 684                 }
 685         } else {
 686                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 687         }
 688         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 689         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 690         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 691         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 692                 return send($sock, 'request command truncated', MSG_EOR);
 693         my ($argc, @argv) = split(/\0/, $buf, -1);
 694         undef $buf;
 695         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 696         if (chdir($env{PWD})) {
 697                 local %ENV = %env;
 698                 $self->{env} = \%env;
 699                 eval { dispatch($self, @argv) };
 700                 send($sock, $@, MSG_EOR) if $@;
 701         } else {
 702                 send($sock, "chdir($env{PWD}): $!", MSG_EOR); # implicit close
 703         }
 704 }
 705
 706 sub dclose {
 707         my ($self) = @_;
 708         delete $self->{lxs}; # stops LeiXSearch queries
 709         $self->close; # PublicInbox::DS::close
 710 }
 711
 712 # for long-running results
 713 sub event_step {
 714         my ($self) = @_;
 715         local %ENV = %{$self->{env}};
 716         my $sock = $self->{sock};
 717         eval {
 718                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 719                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 720                                 return if $! == EAGAIN;
 721                                 next if $! == EINTR;
 722                                 last if $! == ECONNRESET;
 723                                 die "recvmsg: $!";
 724                         }
 725                         for my $fd (@fds) {
 726                                 open my $rfh, '+<&=', $fd;
 727                         }
 728                         die "unrecognized client signal: $buf";
 729                 }
 730                 dclose($self);
 731         };
 732         if (my $err = $@) {
 733                 eval { $self->fail($err) };
 734                 dclose($self);
 735         }
 736 }
 737
 738 sub event_step_init {
 739         my ($self) = @_;
 740         $self->{sock}->blocking(0);
 741         $self->SUPER::new($self->{sock}, EPOLLIN|EPOLLET);
 742 }
 743
 744 sub noop {}
 745
 746 our $oldset; sub oldset { $oldset }
 747
 748 # lei(1) calls this when it can't connect
 749 sub lazy_start {
 750         my ($path, $errno, $nfd) = @_;
 751         if ($errno == ECONNREFUSED) {
 752                 unlink($path) or die "unlink($path): $!";
 753         } elsif ($errno != ENOENT) {
 754                 $! = $errno; # allow interpolation to stringify in die
 755                 die "connect($path): $!";
 756         }
 757         umask(077) // die("umask(077): $!");
 758         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 759         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 760         listen($l, 1024) or die "listen: $!";
 761         my @st = stat($path) or die "stat($path): $!";
 762         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 763         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 764         local $oldset = PublicInbox::DS::block_signals();
 765         if ($nfd == 4) {
 766                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 767                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 768                         require PublicInbox::CmdIPC4;
 769                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 770                         PublicInbox::CmdIPC4->can('recv_cmd4');
 771                 };
 772         }
 773         $recv_cmd or die <<"";
 774 (Socket::MsgHdr || Inline::C) missing/unconfigured (nfd=$nfd);
 775
 776         require PublicInbox::Listener;
 777         require PublicInbox::EOFpipe;
 778         (-p STDOUT) or die "E: stdout must be a pipe\n";
 779         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 780         POSIX::setsid() > 0 or die "setsid: $!";
 781         my $pid = fork // die "fork: $!";
 782         return if $pid;
 783         $0 = "lei-daemon $path";
 784         local %PATH2CFG;
 785         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_r, $eof_w);
 786         $_->blocking(0) for ($l, $eof_r, $eof_w);
 787         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 788         my $exit_code;
 789         local $quit = sub {
 790                 $exit_code //= shift;
 791                 my $listener = $l or exit($exit_code);
 792                 # closing eof_w triggers \&noop wakeup
 793                 $eof_w = $l = $path = undef;
 794                 $listener->close; # DS::close
 795                 PublicInbox::DS->SetLoopTimeout(1000);
 796         };
 797         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 798         my $sig = {
 799                 CHLD => \&PublicInbox::DS::enqueue_reap,
 800                 QUIT => $quit,
 801                 INT => $quit,
 802                 TERM => $quit,
 803                 HUP => \&noop,
 804                 USR1 => \&noop,
 805                 USR2 => \&noop,
 806         };
 807         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 808         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 809         local $SIG{PIPE} = 'IGNORE';
 810         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 811                 push @TO_CLOSE_ATFORK_CHILD, $sigfd->{sock};
 812                 PublicInbox::DS->SetLoopTimeout(5000);
 813         } else {
 814                 # wake up every second to accept signals if we don't
 815                 # have signalfd or IO::KQueue:
 816                 PublicInbox::DS::sig_setmask($oldset);
 817                 PublicInbox::DS->SetLoopTimeout(1000);
 818         }
 819         PublicInbox::DS->SetPostLoopCallback(sub {
 820                 my ($dmap, undef) = @_;
 821                 if (@st = defined($path) ? stat($path) : ()) {
 822                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 823                                 warn "$path dev/ino changed, quitting\n";
 824                                 $path = undef;
 825                         }
 826                 } elsif (defined($path)) {
 827                         warn "stat($path): $!, quitting ...\n";
 828                         undef $path; # don't unlink
 829                         $quit->();
 830                 }
 831                 return 1 if defined($path);
 832                 my $now = now();
 833                 my $n = 0;
 834                 for my $s (values %$dmap) {
 835                         $s->can('busy') or next;
 836                         if ($s->busy($now)) {
 837                                 ++$n;
 838                         } else {
 839                                 $s->close;
 840                         }
 841                 }
 842                 $n; # true: continue, false: stop
 843         });
 844
 845         # STDIN was redirected to /dev/null above, closing STDERR and
 846         # STDOUT will cause the calling `lei' client process to finish
 847         # reading the <$daemon> pipe.
 848         openlog($path, 'pid', 'user');
 849         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 850         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 851                 syslog('crit', "$@") if $@;
 852         });
 853         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 854         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 855         # $daemon pipe to `lei' closed, main loop begins:
 856         PublicInbox::DS->EventLoop;
 857         @$on_destroy = (); # cancel on_destroy if we get here
 858         exit($exit_code // 0);
 859 }
 860
 861 # for users w/o Socket::Msghdr
 862 sub oneshot {
 863         my ($main_pkg) = @_;
 864         my $exit = $main_pkg->can('exit'); # caller may override exit()
 865         local $quit = $exit if $exit;
 866         local %PATH2CFG;
 867         umask(077) // die("umask(077): $!");
 868         dispatch((bless {
 869                 0 => *STDIN{GLOB},
 870                 1 => *STDOUT{GLOB},
 871                 2 => *STDERR{GLOB},
 872                 env => \%ENV
 873         }, __PACKAGE__), @ARGV);
 874 }
 875
 876 # ensures stdout hits the FS before sock disconnects so a client
 877 # can immediately reread it
 878 sub DESTROY {
 879         my ($self) = @_;
 880         $self->{1}->autoflush(1) if $self->{1};
 881         stop_pager($self);
 882 }
 883
 884 1;