lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  32         $recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  40 our %LIVE_SOCK; # "GLOB(0x....)" => $lei->{sock}
  41
  42 # TBD: this is a documentation mechanism to show a subcommand
  43 # (may) pass options through to another command:
  44 sub pass_through { $GLP_PASS }
  45
  46 my $OPT;
  47 sub opt_dash ($$) {
  48         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  49         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  50         my $cb = sub { # Getopt::Long "<>" catch-all handler
  51                 my ($arg) = @_;
  52                 if ($arg =~ /\A-($re_str)\z/) {
  53                         $OPT->{$key} = $1;
  54                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  55                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  56                 # lone (single) dash is handled elsewhere
  57                 } elsif (substr($arg, 0, 1) eq '-') {
  58                         if ($OPT->{'--'}) {
  59                                 push @{$OPT->{-argv}}, $arg;
  60                         } else {
  61                                 die "bad argument: $arg\n";
  62                         }
  63                 } else {
  64                         push @{$OPT->{-argv}}, $arg;
  65                 }
  66         };
  67         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  68 }
  69
  70 # rel2abs preserves symlinks in parent, unlike abs_path
  71 sub rel2abs {
  72         my ($self, $p) = @_;
  73         if (index($p, '/') == 0) { # already absolute
  74                 $p =~ tr!/!/!s; # squeeze redundant slashes
  75                 chop($p) if substr($p, -1, 1) eq '/';
  76                 return $p;
  77         }
  78         my $pwd = $self->{env}->{PWD};
  79         my $cwd;
  80         if (defined $pwd) {
  81                 my $xcwd = $self->{3} //
  82                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  83                 if (my @st_pwd = stat($pwd)) {
  84                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  85                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  86                                 $self->{env}->{PWD} = $pwd = undef;
  87                 } else { # PWD was invalid
  88                         $self->{env}->{PWD} = $pwd = undef;
  89                 }
  90         }
  91         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  92         File::Spec->rel2abs($p, $pwd);
  93 }
  94
  95 # abs_path resolves symlinks in parent iff all parents exist
  96 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  97
  98 sub canonpath_harder {
  99         my $p = $_[-1]; # $_[0] may be self
 100         $p = File::Spec->canonpath($p);
 101         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 102 }
 103
 104 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 108                 .'/lei');
 109 }
 110
 111 sub store_path ($) { share_path($_[0]) . '/store' }
 112
 113 sub _config_path ($) {
 114         my ($self) = @_;
 115         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 116                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 117                 .'/lei/config');
 118 }
 119
 120 sub cache_dir ($) {
 121         my ($self) = @_;
 122         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 123                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 124                 .'/lei');
 125 }
 126
 127 sub url_folder_cache {
 128         my ($self) = @_;
 129         require PublicInbox::SharedKV; # URI => updated_at_sec_
 130         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 131 }
 132
 133 sub ale {
 134         my ($self) = @_;
 135         $self->{ale} //= do {
 136                 require PublicInbox::LeiALE;
 137                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 138         };
 139 }
 140
 141 sub index_opt {
 142         # TODO: drop underscore variants everywhere, they're undocumented
 143         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 144         max_size|max-size=s sequential-shard
 145         batch_size|batch-size=s skip-docdata)
 146 }
 147
 148 my @c_opt = qw(c=s@ C=s@ quiet|q);
 149 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 150         import-remote! no-torsocks torsocks=s),
 151         PublicInbox::LeiQuery::curl_opt());
 152
 153 # we don't support -C as an alias for --find-copies since it's already
 154 # used for chdir
 155 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 156         output-indicator-context=s indent-heuristic!
 157         minimal patience histogram anchored=s@ diff-algorithm=s
 158         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 159         word-diff:s word-diff-regex=s color-words:s no-renames
 160         rename-empty! check ws-error-highlight=s full-index binary
 161         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 162         find-copies-harder irreversible-delete|D l=i diff-filter=s
 163         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 164         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 165         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 166         inter-hunk-context=i function-context|W exit-code ext-diff
 167         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 168         line-prefix=s);
 169
 170 # we generate shell completion + help using %CMD and %OPTDESC,
 171 # see lei__complete() and PublicInbox::LeiHelp
 172 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 173 our %CMD = ( # sorted in order of importance/use:
 174 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 175         'stdin|', # /|\z/ must be first for lone dash
 176         @lxs_opt,
 177         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 178         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 179         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 180         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 181
 182 'up' => [ 'OUTPUT...|--all', 'update saved search',
 183         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 184
 185 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 186         'stdin|', # /|\z/ must be first for lone dash
 187         # some of these options are ridiculous for lcat
 188         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 189         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 190         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 191         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 192
 193 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 194         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 195         @lxs_opt, @c_opt ],
 196
 197 'rediff' => [ '--stdin|LOCATION...',
 198                 'regenerate a diff with different options',
 199         'stdin|', # /|\z/ must be first for lone dash
 200         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 201         @diff_opt, @lxs_opt, @c_opt ],
 202
 203 'add-external' => [ 'LOCATION',
 204         'add/set priority of a publicinbox|extindex for extra matches',
 205         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 206         verbose|v+), @c_opt, index_opt(),
 207         PublicInbox::LeiQuery::curl_opt() ],
 208 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 209         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 210 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 211 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 212                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 213 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 214                 qw(z|0 ascii l url), @c_opt ],
 215 'forget-external' => [ 'LOCATION...|--prune',
 216         'exclude further results from a publicinbox|extindex',
 217         qw(prune), @c_opt ],
 218
 219 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 220                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 221 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 222                 qw(verbose|v+), @c_opt ],
 223 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 224                         @c_opt ],
 225 'rm' => [ '--stdin|LOCATION...',
 226         'remove a message from the index and prevent reindexing',
 227         'stdin|', # /|\z/ must be first for lone dash
 228         @c_opt ],
 229 'plonk' => [ '--threads|--from=IDENT',
 230         'exclude mail matching From: or threads from non-Message-ID searches',
 231         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 232 'tag' => [ 'KEYWORDS...',
 233         'set/unset keywords and/or labels on message(s)',
 234         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 235         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 236         pass_through('-kw:foo for delete') ],
 237
 238 'purge-mailsource' => [ 'LOCATION|--all',
 239         'remove imported messages from IMAP, Maildirs, and MH',
 240         qw(exact! all jobs:i indexed), @c_opt ],
 241
 242 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 243         qw(poll-interval=s state=s recursive|r), @c_opt ],
 244 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 245         qw(recursive|r), @c_opt ],
 246 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 247                 qw(l z|0), @c_opt ],
 248 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 249 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 250 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 251         qw(prune), @c_opt ],
 252
 253 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 254         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 255         verbose|v+ incremental!),
 256          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 257          @c_opt ],
 258 'import' => [ 'LOCATION...|--stdin',
 259         'one-time import/update from URL or filesystem',
 260         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 261         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 262         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 263 'forget-mail-sync' => [ 'LOCATION...',
 264         'forget sync information for a mail folder', @c_opt ],
 265 'prune-mail-sync' => [ 'LOCATION...|--all',
 266         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 267 'export-kw' => [ 'LOCATION...|--all',
 268         'one-time export of keywords of sync sources',
 269         qw(all:s mode=s), @c_opt ],
 270 'convert' => [ 'LOCATION...|--stdin',
 271         'one-time conversion from URL or filesystem to another format',
 272         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 273         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 274 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 275         "use a patch to generate a query for `lei q --stdin'",
 276         qw(stdin| want|w=s@ uri debug), @c_opt ],
 277 'config' => [ '[...]', sub {
 278                 'git-config(1) wrapper for '._config_path($_[0]);
 279         }, qw(config-file|system|global|file|f=s), # for conflict detection
 280          qw(c=s@ C=s@), pass_through('git config') ],
 281 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 282         qw(pretty ascii dir=s), @c_opt ],
 283
 284 'init' => [ '[DIRNAME]', sub {
 285         "initialize storage, default: ".store_path($_[0]);
 286         }, @c_opt ],
 287 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 288         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 289         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 290 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 291 'help' => [ '[SUBCOMMAND]', 'show help' ],
 292
 293 # TODO
 294 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 295 #       'rewrite git history in an attempt to improve compression',
 296 #       qw(gc!), @c_opt ],
 297 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 298 #
 299 # internal commands are prefixed with '_'
 300 '_complete' => [ '[...]', 'internal shell completion helper',
 301                 pass_through('everything') ],
 302 ); # @CMD
 303
 304 # switch descriptions, try to keep consistent across commands
 305 # $spec: Getopt::Long option specification
 306 # $spec => [@ALLOWED_VALUES (default is first), $description],
 307 # $spec => $description
 308 # "$SUB_COMMAND TAB $spec" => as above
 309 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 310                         'specify message input format' ];
 311 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 312
 313 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 314 my %OPTDESC = (
 315 'help|h' => 'show this built-in help',
 316 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 317 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 318 'quiet|q' => 'be quiet',
 319 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 320         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 321
 322 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 323 'globoff|g' => "do not match locations using '*?' wildcards ".
 324                 "and\xa0'[]'\x{a0}ranges",
 325 'invert-match|v' => 'select non-matching lines',
 326 'color!' => 'disable color (for --format=text)',
 327 'verbose|v+' => 'be more verbose',
 328 'external!' => 'do not use externals',
 329 'mail!' => 'do not look in mail storage for OID',
 330 'cwd!' => 'do not look in git repo of current working directory',
 331 'oid-a|A=s' => 'pre-image OID',
 332 'path-a|a=s' => 'pre-image pathname associated with OID',
 333 'path-b|b=s' => 'post-image pathname associated with OID',
 334 'git-dir=s@' => 'additional git repository to scan',
 335 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 336 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 337         "proxy for (e.g. `socks5h://0:9050')" ],
 338 'torsocks=s' => ['VAL|auto|no|yes',
 339                 'whether or not to wrap git and curl commands with torsocks'],
 340 'no-torsocks' => 'alias for --torsocks=no',
 341 'save!' =>  "do not save a search for `lei up'",
 342 'import-remote!' => 'do not memoize remote messages into local store',
 343
 344 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 345
 346 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 347                 'deduplication strategy'],
 348 'threads|t+' =>
 349         'return all messages in the same threads as the actual match(es)',
 350
 351 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 352                 'search prefixes to extract (default: dfpost7)' ],
 353
 354 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 355         'run command(s) or perform ops when done writing to output ' .
 356         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 357         'nothing otherwise)' ],
 358
 359 'augment|a' => 'augment --output destination instead of clobbering',
 360
 361 'output|mfolder|o=s' => [ 'MFOLDER',
 362         "destination (e.g.\xa0`/path/to/Maildir', ".
 363         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 364 'mua=s' => [ 'CMD',
 365         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 366 'new-only       import' => 'only import new messages from IMAP source',
 367
 368 'inbox-version=i' => [ 'NUM|1|2',
 369                 'force a public-inbox version with --mirror'],
 370 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 371
 372 # public-inbox-index options
 373 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 374 'compact' => 'run compact index after mirroring',
 375 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 376         "indexlevel with --mirror (default: full)" ],
 377 'max_size|max-size=s' => [ 'SIZE',
 378         'do not index messages larger than SIZE (default: infinity)' ],
 379 'batch_size|batch-size=s' => [ 'SIZE',
 380         'flush changes to OS after given number of bytes (default: 1m)' ],
 381 'sequential-shard' =>
 382         'index Xapian shards sequentially for slow storage',
 383 'skip-docdata' =>
 384         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 385
 386 'format|f=s     q' => [
 387         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 388                 'specify output format, default depends on --output'],
 389 'exclude=s@     q' => [ 'LOCATION',
 390                 'exclude specified external(s) from search' ],
 391 'include|I=s@   q' => [ 'LOCATION',
 392                 'include specified external(s) in search' ],
 393 'only=s@        q' => [ 'LOCATION',
 394                 'only use specified external(s) for search' ],
 395 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 396                 'control number of search and writer jobs' ],
 397 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 398
 399 'in-format|F=s' => $stdin_formats,
 400 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 401                         'listing output format' ],
 402 'l      ls-search' => 'long listing format',
 403 'l      ls-watch' => 'long listing format',
 404 'l      ls-mail-source' => 'long listing format',
 405 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 406 'format|f=s     ls-external' => $ls_format,
 407
 408 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 409 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 410
 411 'sort|s=s' => [ 'VAL|received|relevance|docid',
 412                 "order of results is `--output'-dependent"],
 413 'reverse|r' => 'reverse search results', # like sort(1)
 414
 415 'boost=i' => 'increase/decrease priority of results (default: 0)',
 416
 417 'local' => 'limit operations to the local filesystem',
 418 'local!' => 'exclude results from the local filesystem',
 419 'remote' => 'limit operations to those requiring network access',
 420 'remote!' => 'prevent operations requiring network access',
 421
 422 'all:s  up' => ['local', 'update all (local) saved searches' ],
 423
 424 'mid=s' => 'specify the Message-ID of a message',
 425 'oid=s' => 'specify the git object ID of a message',
 426
 427 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 428 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 429 'include=s' => 'include mailboxes/newsgroups based on pattern',
 430
 431 'exact' => 'operate on exact header matches only',
 432 'exact!' => 'rely on content match instead of exact header matches',
 433
 434 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 435
 436 'kw!' => 'disable/enable importing keywords (aka "flags")',
 437
 438 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 439 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 440
 441 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 442 ); # %OPTDESC
 443
 444 my %CONFIG_KEYS = (
 445         'leistore.dir' => 'top-level storage location',
 446 );
 447
 448 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 449
 450 sub _drop_wq {
 451         my ($self) = @_;
 452         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 453                 if ($wq->wq_kill) {
 454                         $wq->wq_close(0, undef, $self);
 455                 } elsif ($wq->wq_kill_old) {
 456                         $wq->wq_wait_old(undef, $self);
 457                 }
 458                 $wq->DESTROY;
 459         }
 460 }
 461
 462 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 463 sub x_it ($$) {
 464         my ($self, $code) = @_;
 465         # make sure client sees stdout before exit
 466         $self->{1}->autoflush(1) if $self->{1};
 467         dump_and_clear_log();
 468         stop_pager($self);
 469         if ($self->{pkt_op_p}) { # to top lei-daemon
 470                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 471         } elsif ($self->{sock}) { # to lei(1) client
 472                 send($self->{sock}, "x_it $code", MSG_EOR);
 473         } # else ignore if client disconnected
 474 }
 475
 476 sub err ($;@) {
 477         my $self = shift;
 478         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 479         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 480         print $err @_, @eor and return;
 481         my $old_err = delete $self->{2};
 482         close($old_err) if $! == EPIPE && $old_err;
 483         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 484         print $err @_, @eor or print STDERR @_, @eor;
 485 }
 486
 487 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 488
 489 sub qfin { # show message on finalization (LeiFinmsg)
 490         my ($lei, $msg) = @_;
 491         return if $lei->{opt}->{quiet};
 492         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 493 }
 494
 495 sub fail_handler ($;$$) {
 496         my ($lei, $code, $io) = @_;
 497         close($io) if $io; # needed to avoid warnings on SIGPIPE
 498         _drop_wq($lei);
 499         x_it($lei, $code // (1 << 8));
 500 }
 501
 502 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 503         fail_handler($_[0], 13, delete $_[0]->{1});
 504 }
 505
 506 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 507 sub sigint_reap {
 508         my ($pgid) = @_;
 509         dwaitpid($pgid) if kill('-INT', $pgid);
 510 }
 511
 512 sub fail ($$;$) {
 513         my ($self, $buf, $exit_code) = @_;
 514         $self->{failed}++;
 515         err($self, $buf) if defined $buf;
 516         # calls fail_handler:
 517         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 518         x_it($self, ($exit_code // 1) << 8);
 519         undef;
 520 }
 521
 522 sub out ($;@) {
 523         my $self = shift;
 524         return if print { $self->{1} // return } @_; # likely
 525         return note_sigpipe($self, 1) if $! == EPIPE;
 526         my $err = "error writing to output: $!";
 527         delete $self->{1};
 528         fail($self, $err);
 529 }
 530
 531 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 532
 533 sub child_error { # passes non-fatal curl exit codes to user
 534         my ($self, $child_error, $msg) = @_; # child_error is $?
 535         $self->err($msg) if $msg;
 536         if ($self->{pkt_op_p}) { # to top lei-daemon
 537                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 538         } elsif ($self->{sock}) { # to lei(1) client
 539                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 540         } # else noop if client disconnected
 541 }
 542
 543 sub note_sigpipe { # triggers sigpipe_handler
 544         my ($self, $fd) = @_;
 545         close(delete($self->{$fd})); # explicit close silences Perl warning
 546         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 547         x_it($self, 13);
 548 }
 549
 550 sub _lei_atfork_child {
 551         my ($self, $persist) = @_;
 552         # we need to explicitly close things which are on stack
 553         if ($persist) {
 554                 chdir '/' or die "chdir(/): $!";
 555                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 556                 if (my $cfg = $self->{cfg}) {
 557                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 558                 }
 559         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 560                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 561                 STDERR->autoflush(1);
 562         }
 563         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 564         if (my $op_c = delete $self->{pkt_op_c}) {
 565                 close(delete $op_c->{sock});
 566         }
 567         if (my $pgr = delete $self->{pgr}) {
 568                 close($_) for (@$pgr[1,2]);
 569         }
 570         close $listener if $listener;
 571         undef $listener;
 572         $dir_idle->force_close if $dir_idle;
 573         %PATH2CFG = ();
 574         $MDIR2CFGPATH = {};
 575         %LIVE_SOCK = ();
 576         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 577         undef $errors_log;
 578         $quit = \&CORE::exit;
 579         $self->{-eml_noisy} or # only "lei import" sets this atm
 580                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 581         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 582 }
 583
 584 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 585         my ($self) = @_;
 586         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 587                 $op->close; # PublicInbox::PktOp::close
 588         }
 589         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 590         close $pkt_op_p->{op_p};
 591 }
 592
 593 sub pkt_op_pair {
 594         my ($self) = @_;
 595         require PublicInbox::OnDestroy;
 596         require PublicInbox::PktOp;
 597         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 598         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 599         $end;
 600 }
 601
 602 sub incr {
 603         my ($self, $field, $nr) = @_;
 604         $self->{counters}->{$field} += $nr;
 605 }
 606
 607 sub workers_start {
 608         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 609         $ops = {
 610                 '!' => [ \&fail_handler, $lei ],
 611                 '|' => [ \&sigpipe_handler, $lei ],
 612                 'x_it' => [ \&x_it, $lei ],
 613                 'child_error' => [ \&child_error, $lei ],
 614                 'incr' => [ \&incr, $lei ],
 615                 ($ops ? %$ops : ()),
 616         };
 617         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 618         my $end = $lei->pkt_op_pair;
 619         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 620         $flds->{lei} = $lei;
 621         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 622         delete $lei->{pkt_op_p};
 623         my $op_c = delete $lei->{pkt_op_c};
 624         @$end = ();
 625         $lei->event_step_init;
 626         ($op_c, $ops);
 627 }
 628
 629 # call this when we're ready to wait on events and yield to other clients
 630 sub wait_wq_events {
 631         my ($lei, $op_c, $ops) = @_;
 632         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 633                 $wq->wq_close(1);
 634         }
 635         $op_c->{ops} = $ops;
 636 }
 637
 638 sub _help {
 639         require PublicInbox::LeiHelp;
 640         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 641 }
 642
 643 sub optparse ($$$) {
 644         my ($self, $cmd, $argv) = @_;
 645         # allow _complete --help to complete, not show help
 646         return 1 if substr($cmd, 0, 1) eq '_';
 647         $self->{cmd} = $cmd;
 648         $OPT = $self->{opt} //= {};
 649         my $info = $CMD{$cmd} // [ '[...]' ];
 650         my ($proto, undef, @spec) = @$info;
 651         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 652         push @spec, qw(help|h);
 653         my $lone_dash;
 654         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 655                 $lone_dash = $spec[0];
 656                 $OPT->{$spec[0]} = \(my $var);
 657                 push @spec, '' => \$var;
 658         }
 659         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 660                 return _help($self, "bad arguments or options for $cmd");
 661         return _help($self) if $OPT->{help};
 662
 663         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 664
 665         # "-" aliases "stdin" or "clear"
 666         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 667
 668         my $i = 0;
 669         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 670         my ($err, $inf);
 671         my @args = split(/ /, $proto);
 672         for my $var (@args) {
 673                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 674                         $inf = defined($argv->[$i]) and last;
 675                         $var =~ s/\.\.\.\z//;
 676                         $err = "$var not supplied";
 677                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 678                         $argv->[$i++] // ($err = "$var not supplied");
 679                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 680                         $inf = 1;
 681                         last;
 682                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 683                         $i++;
 684                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 685                         $inf = 1 if index($var, '...') > 0;
 686                         my @or = split(/\|/, $var);
 687                         my $ok;
 688                         for my $o (@or) {
 689                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 690                                         my $sw = $1;
 691                                         # assume pipe/regular file on stdin
 692                                         # w/o args means stdin
 693                                         if ($sw eq 'stdin' && !@$argv &&
 694                                                         (-p $self->{0} ||
 695                                                          -f _) && -r _) {
 696                                                 $OPT->{stdin} //= 1;
 697                                         }
 698                                         $ok = defined($OPT->{$sw});
 699                                         last if $ok;
 700                                 } elsif (defined($argv->[$i])) {
 701                                         $ok = 1;
 702                                         $i++;
 703                                         last;
 704                                 } # else continue looping
 705                         }
 706                         last if $ok;
 707                         my $last = pop @or;
 708                         $err = join(', ', @or) . " or $last must be set";
 709                 } else {
 710                         warn "BUG: can't parse `$var' in $proto";
 711                 }
 712                 last if $err;
 713         }
 714         if (!$inf && scalar(@$argv) > scalar(@args)) {
 715                 $err //= 'too many arguments';
 716         }
 717         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 718 }
 719
 720 sub _tmp_cfg { # for lei -c <name>=<value> ...
 721         my ($self) = @_;
 722         my $cfg = _lei_cfg($self, 1);
 723         require File::Temp;
 724         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 725         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 726         $ft->autoflush(1);
 727         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 728 [include]
 729         path = $cfg->{-f}
 730 EOM
 731         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 732         for (@{$self->{opt}->{c}}) {
 733                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 734 `-c $_' is not of the form -c <name>=<value>'
 735 EOM
 736                 my $name = $1;
 737                 my $value = $2 // 1;
 738                 _config($self, '--add', $name, $value);
 739                 if (defined(my $v = $tmp->{$name})) {
 740                         if (ref($v) eq 'ARRAY') {
 741                                 push @$v, $value;
 742                         } else {
 743                                 $tmp->{$name} = [ $v, $value ];
 744                         }
 745                 } else {
 746                         $tmp->{$name} = $value;
 747                 }
 748         }
 749 }
 750
 751 sub lazy_cb ($$$) {
 752         my ($self, $cmd, $pfx) = @_;
 753         my $ucmd = $cmd;
 754         $ucmd =~ tr/-/_/;
 755         my $cb;
 756         $cb = $self->can($pfx.$ucmd) and return $cb;
 757         my $base = $ucmd;
 758         $base =~ s/_([a-z])/\u$1/g;
 759         my $pkg = "PublicInbox::Lei\u$base";
 760         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 761                 $pkg->can($pfx.$ucmd) : undef;
 762 }
 763
 764 sub dispatch {
 765         my ($self, $cmd, @argv) = @_;
 766         local $current_lei = $self; # for __WARN__
 767         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 768         dump_and_clear_log("from previous run\n");
 769         return _help($self, 'no command given') unless defined($cmd);
 770         # do not support Getopt bundling for this
 771         while ($cmd eq '-C' || $cmd eq '-c') {
 772                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 773                                         '-C DIRECTORY' : '-c <name>=<value>');
 774                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 775                 $cmd = shift(@argv) // return _help($self, 'no command given');
 776         }
 777         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 778                 optparse($self, $cmd, \@argv) or return;
 779                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 780                 if (my $chdir = $self->{opt}->{C}) {
 781                         for my $d (@$chdir) {
 782                                 next if $d eq ''; # same as git(1)
 783                                 chdir $d or return fail($self, "cd $d: $!");
 784                         }
 785                         open $self->{3}, '.' or return fail($self, "open . $!");
 786                 }
 787                 $cb->($self, @argv);
 788         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 789                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 790                         or return _help($self, 'bad arguments or options');
 791                 _help($self);
 792         } else {
 793                 fail($self, "`$cmd' is not an lei command");
 794         }
 795 }
 796
 797 sub _lei_cfg ($;$) {
 798         my ($self, $creat) = @_;
 799         return $self->{cfg} if $self->{cfg};
 800         my $f = _config_path($self);
 801         my @st = stat($f);
 802         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 803         my ($sto, $sto_dir, $watches, $lne);
 804         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 805                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 806                 ($sto, $sto_dir, $watches, $lne) =
 807                                 @$cfg{qw(-lei_store leistore.dir -watches
 808                                         -lei_note_event)};
 809         }
 810         if (!@st) {
 811                 unless ($creat) {
 812                         delete $self->{cfg};
 813                         return bless {}, 'PublicInbox::Config';
 814                 }
 815                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 816                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 817                 open my $fh, '>>', $f or die "open($f): $!\n";
 818                 @st = stat($fh) or die "fstat($f): $!\n";
 819                 $cur_st = pack('dd', $st[10], $st[7]);
 820                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 821         }
 822         my $cfg = PublicInbox::Config->git_config_dump($f);
 823         $cfg->{-st} = $cur_st;
 824         $cfg->{'-f'} = $f;
 825         if ($sto && canonpath_harder($sto_dir // store_path($self))
 826                         eq canonpath_harder($cfg->{'leistore.dir'} //
 827                                                 store_path($self))) {
 828                 $cfg->{-lei_store} = $sto;
 829                 $cfg->{-lei_note_event} = $lne;
 830                 $cfg->{-watches} = $watches if $watches;
 831         }
 832         if (scalar(keys %PATH2CFG) > 5) {
 833                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 834                 for my $k (keys %PATH2CFG) {
 835                         delete($PATH2CFG{$k}) unless -f $k
 836                 }
 837         }
 838         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 839         refresh_watches($self);
 840         $cfg;
 841 }
 842
 843 sub _lei_store ($;$) {
 844         my ($self, $creat) = @_;
 845         my $cfg = _lei_cfg($self, $creat) // return;
 846         $cfg->{-lei_store} //= do {
 847                 require PublicInbox::LeiStore;
 848                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 849                 return unless $creat || -d $dir;
 850                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 851         };
 852 }
 853
 854 sub _config {
 855         my ($self, @argv) = @_;
 856         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 857         my $cfg = _lei_cfg($self, 1);
 858         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 859         my %rdr = map { $_ => $self->{$_} } (0..2);
 860         waitpid(spawn($cmd, \%env, \%rdr), 0);
 861 }
 862
 863 sub lei_config {
 864         my ($self, @argv) = @_;
 865         $self->{opt}->{'config-file'} and return fail $self,
 866                 "config file switches not supported by `lei config'";
 867         _config(@_);
 868         x_it($self, $?) if $?;
 869 }
 870
 871 sub lei_daemon_pid { puts shift, $$ }
 872
 873 sub lei_daemon_kill {
 874         my ($self) = @_;
 875         my $sig = $self->{opt}->{signal} // 'TERM';
 876         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 877 }
 878
 879 # Shell completion helper.  Used by lei-completion.bash and hopefully
 880 # other shells.  Try to do as much here as possible to avoid redundancy
 881 # and improve maintainability.
 882 sub lei__complete {
 883         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 884         shift @argv; # ignore "lei", the entire command is sent
 885         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 886         my $cmd = shift @argv;
 887         my $info = $CMD{$cmd} // do { # filter matching commands
 888                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 889                 return;
 890         };
 891         my ($proto, undef, @spec) = @$info;
 892         my $cur = pop @argv;
 893         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 894         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 895                 # gross special case since the only git-config options
 896                 # Consider moving to a table if we need more special cases
 897                 # we use Getopt::Long for are the ones we reject, so these
 898                 # are the ones we don't reject:
 899                 if ($cmd eq 'config') {
 900                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 901                         @spec = qw(add z|null get get-all unset unset-all
 902                                 replace-all get-urlmatch
 903                                 remove-section rename-section
 904                                 name-only list|l edit|e
 905                                 get-color-name get-colorbool);
 906                         # fall-through
 907                 }
 908                 # generate short/long names from Getopt::Long specs
 909                 puts $self, grep(/$re/, qw(--help -h -C), map {
 910                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 911                         } elsif (s/\+\z//) { # verbose|v+
 912                         } elsif (s/!\z//) {
 913                                 # negation: mail! => no-mail|mail
 914                                 s/([\w\-]+)/$1|no-$1/g
 915                         }
 916                         map {
 917                                 my $x = length > 1 ? "--$_" : "-$_";
 918                                 $x eq $_cur ? () : $x;
 919                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 920                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 921         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 922                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 923         }
 924
 925         # switch args (e.g. lei q -f mbox<TAB>)
 926         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 927                 my $opt = quotemeta $1;
 928                 puts $self, map {
 929                         my $v = $OPTDESC{$_};
 930                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 931                         # get rid of ALL CAPS placeholder (e.g "OUT")
 932                         # (TODO: completion for external paths)
 933                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 934                         @v;
 935                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 936         }
 937         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 938                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 939         }
 940         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 941         # proto parsing.
 942 }
 943
 944 sub exec_buf ($$) {
 945         my ($argv, $env) = @_;
 946         my $argc = scalar @$argv;
 947         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 948         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 949         $buf;
 950 }
 951
 952 sub start_mua {
 953         my ($self) = @_;
 954         my $mua = $self->{opt}->{mua} // return;
 955         my $mfolder = $self->{ovv}->{dst};
 956         my (@cmd, $replaced);
 957         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 958                 @cmd = ($mua, '-f');
 959         # TODO: help wanted: other common FOSS MUAs
 960         } else {
 961                 require Text::ParseWords;
 962                 @cmd = Text::ParseWords::shellwords($mua);
 963                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 964                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 965         }
 966         push @cmd, $mfolder unless defined($replaced);
 967         if ($self->{sock}) { # lei(1) client process runs it
 968                 # restore terminal: echo $query | lei q --stdin --mua=...
 969                 my $io = [];
 970                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 971                 send_exec_cmd($self, $io, \@cmd, {});
 972         }
 973         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 974                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 975         }
 976         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 977         $self->{opt}->{quiet} = 1;
 978         delete $self->{-progress};
 979         delete $self->{opt}->{verbose};
 980 }
 981
 982 sub send_exec_cmd { # tell script/lei to execute a command
 983         my ($self, $io, $cmd, $env) = @_;
 984         my $sock = $self->{sock} // die 'lei client gone';
 985         my $fds = [ map { fileno($_) } @$io ];
 986         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 987 }
 988
 989 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 990         my ($self) = @_;
 991         my $alerts = $self->{opt}->{alert} // return;
 992         my $sock = $self->{sock};
 993         while (my $op = shift(@$alerts)) {
 994                 if ($op eq ':WINCH') {
 995                         # hit the process group that started the MUA
 996                         send($sock, '-WINCH', MSG_EOR) if $sock;
 997                 } elsif ($op eq ':bell') {
 998                         out($self, "\a");
 999                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1000                         push @$alerts, split(/(?<!\\),/, $op);
1001                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1002                         my $cmd = $1; # run an arbitrary command
1003                         require Text::ParseWords;
1004                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1005                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1006                 } else {
1007                         err($self, "W: unsupported --alert=$op"); # non-fatal
1008                 }
1009         }
1010 }
1011
1012 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1013 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1014
1015 # this also normalizes the path
1016 sub path_to_fd {
1017         my ($self, $path) = @_;
1018         $path = rel2abs($self, $path);
1019         $path =~ tr!/!/!s;
1020         $path_to_fd{$path} // (
1021                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1022                         fail($self, "cannot open $path from daemon") : -1
1023         );
1024 }
1025
1026 # caller needs to "-t $self->{1}" to check if tty
1027 sub start_pager {
1028         my ($self) = @_;
1029         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1030         chomp(my $pager = <$fh> // '');
1031         close($fh) or warn "`git var PAGER' error: \$?=$?";
1032         return if $pager eq 'cat' || $pager eq '';
1033         my $new_env = { LESS => 'FRX', LV => '-c' };
1034         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1035         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1036         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1037         my $pgr = [ undef, @$rdr{1, 2} ];
1038         my $env = $self->{env};
1039         if ($self->{sock}) { # lei(1) process runs it
1040                 delete @$new_env{keys %$env}; # only set iff unset
1041                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1042         } else {
1043                 die 'BUG: start_pager w/o socket';
1044         }
1045         $self->{1} = $wpager;
1046         $self->{2} = $wpager if -t $self->{2};
1047         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1048         $self->{pgr} = $pgr;
1049 }
1050
1051 sub stop_pager {
1052         my ($self) = @_;
1053         my $pgr = delete($self->{pgr}) or return;
1054         $self->{2} = $pgr->[2];
1055         # do not restore original stdout, just close it so we error out
1056         close(delete($self->{1})) if $self->{1};
1057 }
1058
1059 sub accept_dispatch { # Listener {post_accept} callback
1060         my ($sock) = @_; # ignore other
1061         $sock->autoflush(1);
1062         my $self = bless { sock => $sock }, __PACKAGE__;
1063         vec(my $rvec = '', fileno($sock), 1) = 1;
1064         select($rvec, undef, undef, 60) or
1065                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1066         # (4096 * 33) >MAX_ARG_STRLEN
1067         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1068         if (!defined($fds[0])) {
1069                 warn(my $msg = "recv_cmd failed: $!");
1070                 return send($sock, $msg, MSG_EOR);
1071         } else {
1072                 my $i = 0;
1073                 for my $fd (@fds) {
1074                         open($self->{$i++}, '+<&=', $fd) and next;
1075                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1076                 }
1077                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1078         }
1079         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1080         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1081         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1082                 return send($sock, 'request command truncated', MSG_EOR);
1083         my ($argc, @argv) = split(/\0/, $buf, -1);
1084         undef $buf;
1085         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1086         if (chdir($self->{3})) {
1087                 local %ENV = %env;
1088                 $self->{env} = \%env;
1089                 eval { dispatch($self, @argv) };
1090                 send($sock, $@, MSG_EOR) if $@;
1091         } else {
1092                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1093         }
1094 }
1095
1096 sub dclose {
1097         my ($self) = @_;
1098         delete $self->{-progress};
1099         _drop_wq($self) if $self->{failed};
1100         close(delete $self->{1}) if $self->{1}; # may reap_compress
1101         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1102 }
1103
1104 # for long-running results
1105 sub event_step {
1106         my ($self) = @_;
1107         local %ENV = %{$self->{env}};
1108         my $sock = $self->{sock};
1109         local $current_lei = $self;
1110         eval {
1111                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1112                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1113                                 return if $! == EAGAIN;
1114                                 next if $! == EINTR;
1115                                 last if $! == ECONNRESET;
1116                                 die "recvmsg: $!";
1117                         }
1118                         for my $fd (@fds) {
1119                                 open my $rfh, '+<&=', $fd;
1120                         }
1121                         die "unrecognized client signal: $buf";
1122                 }
1123                 _drop_wq($self); # EOF, client disconnected
1124                 dclose($self);
1125         };
1126         if (my $err = $@) {
1127                 eval { $self->fail($err) };
1128                 dclose($self);
1129         }
1130 }
1131
1132 sub event_step_init {
1133         my ($self) = @_;
1134         my $sock = $self->{sock} or return;
1135         $self->{-event_init_done} //= do { # persist til $ops done
1136                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1137                 $sock;
1138         };
1139 }
1140
1141 sub noop {}
1142
1143 sub oldset { $oldset }
1144
1145 sub dump_and_clear_log {
1146         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1147                 my @pfx = @_;
1148                 unshift(@pfx, "$errors_log ") if @pfx;
1149                 warn @pfx, do { local $/; <STDIN> };
1150                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1151         }
1152 }
1153
1154 sub cfg2lei ($) {
1155         my ($cfg) = @_;
1156         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1157         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1158         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1159         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1160         open($lei->{3}, '/') or die "open /: $!";
1161         chdir($lei->{3}) or die "chdir /': $!";
1162         my ($x, $y);
1163         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1164         $lei->{sock} = $x;
1165         require PublicInbox::LeiSelfSocket;
1166         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1167         $lei;
1168 }
1169
1170 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1171         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1172         my $fn = $ev->fullname;
1173         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1174                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1175                 $nc = '' if $ev->IN_DELETE;
1176                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1177                         my $cfg = $PATH2CFG{$f} // next;
1178                         eval {
1179                                 local %ENV = %{$cfg->{-env}};
1180                                 my $lei = cfg2lei($cfg);
1181                                 $lei->dispatch('note-event',
1182                                                 "maildir:$mdir", $nc, $bn, $fn);
1183                         };
1184                         warn "E note-event $f: $@\n" if $@;
1185                 }
1186         }
1187         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1188                 $ev->cancel;
1189         }
1190         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1191                 delete $MDIR2CFGPATH->{$1};
1192         }
1193         if (!-e $fn) { # config file or Maildir gone
1194                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1195                         delete $cfgpaths->{$fn};
1196                 }
1197                 delete $PATH2CFG{$fn};
1198         }
1199 }
1200
1201 # lei(1) calls this when it can't connect
1202 sub lazy_start {
1203         my ($path, $errno, $narg) = @_;
1204         local ($errors_log, $listener);
1205         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1206         $errors_log = "$sock_dir/errors.log";
1207         my $addr = pack_sockaddr_un($path);
1208         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1209         $lk->lock_acquire;
1210         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1211         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1212                 return if connect($listener, $addr); # another process won
1213                 if ($errno == ECONNREFUSED && -S $path) {
1214                         unlink($path) or die "unlink($path): $!";
1215                 }
1216         } else {
1217                 $! = $errno; # allow interpolation to stringify in die
1218                 die "connect($path): $!";
1219         }
1220         umask(077) // die("umask(077): $!");
1221         bind($listener, $addr) or die "bind($path): $!";
1222         $lk->lock_release;
1223         undef $lk;
1224         my @st = stat($path) or die "stat($path): $!";
1225         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1226         local $oldset = PublicInbox::DS::block_signals();
1227         if ($narg == 5) {
1228                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1229                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1230                         require PublicInbox::CmdIPC4;
1231                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1232                         PublicInbox::CmdIPC4->can('recv_cmd4');
1233                 };
1234         }
1235         $recv_cmd or die <<"";
1236 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1237
1238         require PublicInbox::Listener;
1239         require PublicInbox::PktOp;
1240         (-p STDOUT) or die "E: stdout must be a pipe\n";
1241         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1242         STDIN->autoflush(1);
1243         dump_and_clear_log("from previous daemon process:\n");
1244         POSIX::setsid() > 0 or die "setsid: $!";
1245         my $pid = fork // die "fork: $!";
1246         return if $pid;
1247         $0 = "lei-daemon $path";
1248         local %PATH2CFG;
1249         local $MDIR2CFGPATH;
1250         $listener->blocking(0);
1251         my $exit_code;
1252         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1253         local $quit = do {
1254                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1255                 sub {
1256                         $exit_code //= shift;
1257                         my $lis = $pil or exit($exit_code);
1258                         # closing eof_p triggers \&noop wakeup
1259                         $listener = $eof_p = $pil = $path = undef;
1260                         $lis->close; # DS::close
1261                         PublicInbox::DS->SetLoopTimeout(1000);
1262                 };
1263         };
1264         my $sig = {
1265                 CHLD => \&PublicInbox::DS::enqueue_reap,
1266                 QUIT => $quit,
1267                 INT => $quit,
1268                 TERM => $quit,
1269                 HUP => \&noop,
1270                 USR1 => \&noop,
1271                 USR2 => \&noop,
1272         };
1273         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1274         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1275         undef $sig;
1276         local $SIG{PIPE} = 'IGNORE';
1277         require PublicInbox::DirIdle;
1278         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1279                 # just rely on wakeup to hit PostLoopCallback set below
1280                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1281         }, 1);
1282         if ($sigfd) {
1283                 undef $sigfd; # unref, already in DS::DescriptorMap
1284         } else {
1285                 # wake up every second to accept signals if we don't
1286                 # have signalfd or IO::KQueue:
1287                 PublicInbox::DS::sig_setmask($oldset);
1288                 PublicInbox::DS->SetLoopTimeout(1000);
1289         }
1290         PublicInbox::DS->SetPostLoopCallback(sub {
1291                 my ($dmap, undef) = @_;
1292                 if (@st = defined($path) ? stat($path) : ()) {
1293                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1294                                 warn "$path dev/ino changed, quitting\n";
1295                                 $path = undef;
1296                         }
1297                 } elsif (defined($path)) { # ENOENT is common
1298                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1299                         undef $path;
1300                         $quit->();
1301                 }
1302                 return 1 if defined($path);
1303                 my $now = now();
1304                 my $n = 0;
1305                 for my $s (values %$dmap) {
1306                         $s->can('busy') or next;
1307                         if ($s->busy($now)) {
1308                                 ++$n;
1309                         } else {
1310                                 $s->close;
1311                         }
1312                 }
1313                 $n; # true: continue, false: stop
1314         });
1315
1316         # STDIN was redirected to /dev/null above, closing STDERR and
1317         # STDOUT will cause the calling `lei' client process to finish
1318         # reading the <$daemon> pipe.
1319         local $SIG{__WARN__} = sub {
1320                 $current_lei ? err($current_lei, @_) : warn(
1321                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1322         };
1323         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1324         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1325         # $daemon pipe to `lei' closed, main loop begins:
1326         PublicInbox::DS->EventLoop;
1327         exit($exit_code // 0);
1328 }
1329
1330 sub busy { 1 } # prevent daemon-shutdown if client is connected
1331
1332 # ensures stdout hits the FS before sock disconnects so a client
1333 # can immediately reread it
1334 sub DESTROY {
1335         my ($self) = @_;
1336         if (my $counters = delete $self->{counters}) {
1337                 for my $k (sort keys %$counters) {
1338                         my $nr = $counters->{$k};
1339                         $self->child_error(1 << 8, "$nr $k messages");
1340                 }
1341         }
1342         $self->{1}->autoflush(1) if $self->{1};
1343         stop_pager($self);
1344         # preserve $? for ->fail or ->x_it code
1345 }
1346
1347 sub wq_done_wait { # dwaitpid callback
1348         my ($arg, $pid) = @_;
1349         my ($wq, $lei) = @$arg;
1350         my $err_type = $lei->{-err_type};
1351         $? and $lei->child_error($?,
1352                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1353         $lei->dclose;
1354 }
1355
1356 sub fchdir {
1357         my ($lei) = @_;
1358         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1359         chdir($dh) || $lei->fail("fchdir: $!");
1360 }
1361
1362 sub wq_eof { # EOF callback for main daemon
1363         my ($lei) = @_;
1364         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1365         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1366 }
1367
1368 sub watch_state_ok ($) {
1369         my ($state) = $_[-1]; # $_[0] may be $self
1370         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1371 }
1372
1373 sub cancel_maildir_watch ($$) {
1374         my ($d, $cfg_f) = @_;
1375         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1376         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1377                 delete $MDIR2CFGPATH->{$d};
1378         for my $x (@{$w // []}) { $x->cancel }
1379 }
1380
1381 sub add_maildir_watch ($$) {
1382         my ($d, $cfg_f) = @_;
1383         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1384                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1385                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1386         }
1387 }
1388
1389 sub refresh_watches {
1390         my ($lei) = @_;
1391         my $cfg = _lei_cfg($lei) or return;
1392         my $old = $cfg->{-watches};
1393         my $watches = $cfg->{-watches} //= {};
1394         my %seen;
1395         my $cfg_f = $cfg->{'-f'};
1396         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1397                 my $url = substr($w, length('watch.'), -length('.state'));
1398                 require PublicInbox::LeiWatch;
1399                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1400                 $seen{$url} = undef;
1401                 my $state = $cfg->get_1("watch.$url", 'state');
1402                 if (!watch_state_ok($state)) {
1403                         $lei->err("watch.$url.state=$state not supported");
1404                         next;
1405                 }
1406                 if ($url =~ /\Amaildir:(.+)/i) {
1407                         my $d = canonpath_harder($1);
1408                         if ($state eq 'pause') {
1409                                 cancel_maildir_watch($d, $cfg_f);
1410                         } else {
1411                                 add_maildir_watch($d, $cfg_f);
1412                         }
1413                 } else { # TODO: imap/nntp/jmap
1414                         $lei->child_error(1, "E: watch $url not supported, yet")
1415                 }
1416         }
1417
1418         # add all known Maildir folders as implicit watches
1419         my $sto = $lei->_lei_store;
1420         my $renames = 0;
1421         if (my $lms = $sto ? $sto->search->lms : undef) {
1422                 for my $d ($lms->folders('maildir:')) {
1423                         substr($d, 0, length('maildir:')) = '';
1424                         my $cd = canonpath_harder($d);
1425                         my $f = "maildir:$cd";
1426
1427                         # fixup old bugs while we're iterating:
1428                         if ($d ne $cd) {
1429                                 $sto->ipc_do('lms_rename_folder',
1430                                                 "maildir:$d", $f);
1431                                 ++$renames;
1432                         }
1433                         next if $watches->{$f}; # may be set to pause
1434                         require PublicInbox::LeiWatch;
1435                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1436                         $seen{$f} = undef;
1437                         add_maildir_watch($cd, $cfg_f);
1438                 }
1439         }
1440         $lei->sto_done_request if $renames;
1441         if ($old) { # cull old non-existent entries
1442                 for my $url (keys %$old) {
1443                         next if exists $seen{$url};
1444                         delete $old->{$url};
1445                         if ($url =~ /\Amaildir:(.+)/i) {
1446                                 my $d = canonpath_harder($1);
1447                                 cancel_maildir_watch($d, $cfg_f);
1448                         } else { # TODO: imap/nntp/jmap
1449                                 $lei->child_error(1, "E: watch $url TODO");
1450                         }
1451                 }
1452         }
1453         if (scalar keys %$watches) {
1454                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1455         } else {
1456                 delete $cfg->{-watches};
1457         }
1458 }
1459
1460 sub git_blob_id {
1461         my ($lei, $eml) = @_;
1462         ($lei->{sto} // _lei_store($lei, 1))->git_blob_id($eml);
1463 }
1464
1465 sub lms { # read-only LeiMailSync
1466         my ($lei) = @_;
1467         my $lse = $lei->{lse} // do {
1468                 my $sto = $lei->{sto} // _lei_store($lei);
1469                 $sto ? $sto->search : undef
1470         };
1471         $lse ? $lse->lms : undef;
1472 }
1473
1474 sub sto_done_request { # only call this from lei-daemon process (not workers)
1475         my ($lei, $sock) = @_;
1476         if ($sock //= $lei->{sock}) {
1477                 $LIVE_SOCK{"$sock"} = $sock;
1478                 $lei->{sto}->ipc_do('done', "$sock"); # issue, async wait
1479         } else { # forcibly wait
1480                 my $wait = $lei->{sto}->ipc_do('done');
1481         }
1482 }
1483
1484 sub sto_done_complete { # called in lei-daemon when LeiStore->done is complete
1485         my ($sock_str) = @_;
1486         delete $LIVE_SOCK{$sock_str}; # frees {sock} for waiting lei clients
1487 }
1488
1489 1;