lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 200                 qw(z|0 ascii l), @c_opt ],
 201 'forget-external' => [ 'LOCATION...|--prune',
 202         'exclude further results from a publicinbox|extindex',
 203         qw(prune), @c_opt ],
 204
 205 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 206                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 207 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 208                 qw(verbose|v+), @c_opt ],
 209 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 210                         @c_opt ],
 211 'rm' => [ '--stdin|LOCATION...',
 212         'remove a message from the index and prevent reindexing',
 213         'stdin|', # /|\z/ must be first for lone dash
 214         @c_opt ],
 215 'plonk' => [ '--threads|--from=IDENT',
 216         'exclude mail matching From: or threads from non-Message-ID searches',
 217         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 218 'tag' => [ 'KEYWORDS...',
 219         'set/unset keywords and/or labels on message(s)',
 220         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 221         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 222         pass_through('-kw:foo for delete') ],
 223
 224 'purge-mailsource' => [ 'LOCATION|--all',
 225         'remove imported messages from IMAP, Maildirs, and MH',
 226         qw(exact! all jobs:i indexed), @c_opt ],
 227
 228 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 229         qw(import! kw! interval=s recursive|r
 230         exclude=s include=s), @c_opt ],
 231 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 232                 qw(format|f=s z), @c_opt ],
 233 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 234 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 235 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 236         qw(prune), @c_opt ],
 237
 238 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 239         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 240         verbose|v+ incremental!),
 241          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 242          @c_opt ],
 243 'import' => [ 'LOCATION...|--stdin',
 244         'one-time import/update from URL or filesystem',
 245         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 246         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 247         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 248 'forget-mail-sync' => [ 'LOCATION...',
 249         'forget sync information for a mail folder', @c_opt ],
 250 'prune-mail-sync' => [ 'LOCATION...|--all',
 251         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 252 'export-kw' => [ 'LOCATION...|--all',
 253         'one-time export of keywords of sync sources',
 254         qw(all:s mode=s), @c_opt ],
 255 'convert' => [ 'LOCATION...|--stdin',
 256         'one-time conversion from URL or filesystem to another format',
 257         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 258         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 259 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 260         "use a patch to generate a query for `lei q --stdin'",
 261         qw(stdin| want|w=s@ uri debug), @c_opt ],
 262 'config' => [ '[...]', sub {
 263                 'git-config(1) wrapper for '._config_path($_[0]);
 264         }, qw(config-file|system|global|file|f=s), # for conflict detection
 265          qw(c=s@ C=s@), pass_through('git config') ],
 266 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 267         qw(pretty ascii dir=s), @c_opt ],
 268
 269 'init' => [ '[DIRNAME]', sub {
 270         "initialize storage, default: ".store_path($_[0]);
 271         }, @c_opt ],
 272 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 273         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 274         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 275 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 276 'help' => [ '[SUBCOMMAND]', 'show help' ],
 277
 278 # TODO
 279 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 280 #       'rewrite git history in an attempt to improve compression',
 281 #       qw(gc!), @c_opt ],
 282 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 283 #
 284 # internal commands are prefixed with '_'
 285 '_complete' => [ '[...]', 'internal shell completion helper',
 286                 pass_through('everything') ],
 287 ); # @CMD
 288
 289 # switch descriptions, try to keep consistent across commands
 290 # $spec: Getopt::Long option specification
 291 # $spec => [@ALLOWED_VALUES (default is first), $description],
 292 # $spec => $description
 293 # "$SUB_COMMAND TAB $spec" => as above
 294 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 295                         'specify message input format' ];
 296 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 297
 298 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 299 my %OPTDESC = (
 300 'help|h' => 'show this built-in help',
 301 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 302 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 303 'quiet|q' => 'be quiet',
 304 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 305         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 306
 307 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 308 'globoff|g' => "do not match locations using '*?' wildcards ".
 309                 "and\xa0'[]'\x{a0}ranges",
 310 'invert-match|v' => 'select non-matching lines',
 311 'color!' => 'disable color (for --format=text)',
 312 'verbose|v+' => 'be more verbose',
 313 'external!' => 'do not use externals',
 314 'mail!' => 'do not look in mail storage for OID',
 315 'cwd!' => 'do not look in git repo of current working directory',
 316 'oid-a|A=s' => 'pre-image OID',
 317 'path-a|a=s' => 'pre-image pathname associated with OID',
 318 'path-b|b=s' => 'post-image pathname associated with OID',
 319 'git-dir=s@' => 'additional git repository to scan',
 320 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 321         "proxy for (e.g. `socks5h://0:9050')" ],
 322 'torsocks=s' => ['VAL|auto|no|yes',
 323                 'whether or not to wrap git and curl commands with torsocks'],
 324 'no-torsocks' => 'alias for --torsocks=no',
 325 'save' =>  "save a search for `lei up'",
 326 'import-remote!' => 'do not memoize remote messages into local store',
 327
 328 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 329
 330 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 331                 'deduplication strategy'],
 332 'threads|t+' =>
 333         'return all messages in the same threads as the actual match(es)',
 334
 335 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 336                 'search prefixes to extract (default: dfpost7)' ],
 337
 338 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 339         'run command(s) or perform ops when done writing to output ' .
 340         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 341         'nothing otherwise)' ],
 342
 343 'augment|a' => 'augment --output destination instead of clobbering',
 344
 345 'output|mfolder|o=s' => [ 'MFOLDER',
 346         "destination (e.g.\xa0`/path/to/Maildir', ".
 347         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 348 'mua=s' => [ 'CMD',
 349         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 350
 351 'inbox-version=i' => [ 'NUM|1|2',
 352                 'force a public-inbox version with --mirror'],
 353 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 354
 355 # public-inbox-index options
 356 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 357 'compact' => 'run compact index after mirroring',
 358 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 359         "indexlevel with --mirror (default: full)" ],
 360 'max_size|max-size=s' => [ 'SIZE',
 361         'do not index messages larger than SIZE (default: infinity)' ],
 362 'batch_size|batch-size=s' => [ 'SIZE',
 363         'flush changes to OS after given number of bytes (default: 1m)' ],
 364 'sequential_shard|sequential-shard' =>
 365         'index Xapian shards sequentially for slow storage',
 366 'skip-docdata' =>
 367         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 368
 369 'format|f=s     q' => [
 370         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 371                 'specify output format, default depends on --output'],
 372 'exclude=s@     q' => [ 'LOCATION',
 373                 'exclude specified external(s) from search' ],
 374 'include|I=s@   q' => [ 'LOCATION',
 375                 'include specified external(s) in search' ],
 376 'only=s@        q' => [ 'LOCATION',
 377                 'only use specified external(s) for search' ],
 378 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 379                 'control number of search and writer jobs' ],
 380 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 381
 382 'in-format|F=s' => $stdin_formats,
 383 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 384                         'listing output format' ],
 385 'l      ls-search' => 'long listing format',
 386 'l      ls-mail-source' => 'long listing format',
 387 'format|f=s     ls-external' => $ls_format,
 388
 389 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 390 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 391
 392 'sort|s=s' => [ 'VAL|received|relevance|docid',
 393                 "order of results is `--output'-dependent"],
 394 'reverse|r' => 'reverse search results', # like sort(1)
 395
 396 'boost=i' => 'increase/decrease priority of results (default: 0)',
 397
 398 'local' => 'limit operations to the local filesystem',
 399 'local!' => 'exclude results from the local filesystem',
 400 'remote' => 'limit operations to those requiring network access',
 401 'remote!' => 'prevent operations requiring network access',
 402
 403 'all:s  up' => ['local', 'update all (local) saved searches' ],
 404
 405 'mid=s' => 'specify the Message-ID of a message',
 406 'oid=s' => 'specify the git object ID of a message',
 407
 408 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 409 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 410 'include=s' => 'include mailboxes/newsgroups based on pattern',
 411
 412 'exact' => 'operate on exact header matches only',
 413 'exact!' => 'rely on content match instead of exact header matches',
 414
 415 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 416
 417 'kw!' => 'disable/enable importing keywords (aka "flags")',
 418
 419 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 420 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 421
 422 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 423 ); # %OPTDESC
 424
 425 my %CONFIG_KEYS = (
 426         'leistore.dir' => 'top-level storage location',
 427 );
 428
 429 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1); # internal workers
 430
 431 sub _drop_wq {
 432         my ($self) = @_;
 433         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 434                 if ($wq->wq_kill) {
 435                         $wq->wq_close(0, undef, $self);
 436                 } elsif ($wq->wq_kill_old) {
 437                         $wq->wq_wait_old(undef, $self);
 438                 }
 439                 $wq->DESTROY;
 440         }
 441 }
 442
 443 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 444 sub x_it ($$) {
 445         my ($self, $code) = @_;
 446         # make sure client sees stdout before exit
 447         $self->{1}->autoflush(1) if $self->{1};
 448         dump_and_clear_log();
 449         stop_pager($self);
 450         if ($self->{pkt_op_p}) { # to top lei-daemon
 451                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 452         } elsif ($self->{sock}) { # to lei(1) client
 453                 send($self->{sock}, "x_it $code", MSG_EOR);
 454         } # else ignore if client disconnected
 455 }
 456
 457 sub err ($;@) {
 458         my $self = shift;
 459         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 460         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 461         print $err @_, @eor and return;
 462         my $old_err = delete $self->{2};
 463         close($old_err) if $! == EPIPE && $old_err;
 464         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 465         print $err @_, @eor or print STDERR @_, @eor;
 466 }
 467
 468 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 469
 470 sub fail_handler ($;$$) {
 471         my ($lei, $code, $io) = @_;
 472         close($io) if $io; # needed to avoid warnings on SIGPIPE
 473         _drop_wq($lei);
 474         x_it($lei, $code // (1 << 8));
 475 }
 476
 477 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 478         fail_handler($_[0], 13, delete $_[0]->{1});
 479 }
 480
 481 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 482 sub sigint_reap {
 483         my ($pgid) = @_;
 484         dwaitpid($pgid) if kill('-INT', $pgid);
 485 }
 486
 487 sub fail ($$;$) {
 488         my ($self, $buf, $exit_code) = @_;
 489         $self->{failed}++;
 490         err($self, $buf) if defined $buf;
 491         # calls fail_handler:
 492         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 493         x_it($self, ($exit_code // 1) << 8);
 494         undef;
 495 }
 496
 497 sub out ($;@) {
 498         my $self = shift;
 499         return if print { $self->{1} // return } @_; # likely
 500         return note_sigpipe($self, 1) if $! == EPIPE;
 501         my $err = "error writing to output: $!";
 502         delete $self->{1};
 503         fail($self, $err);
 504 }
 505
 506 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 507
 508 sub child_error { # passes non-fatal curl exit codes to user
 509         my ($self, $child_error, $msg) = @_; # child_error is $?
 510         $self->err($msg) if $msg;
 511         if ($self->{pkt_op_p}) { # to top lei-daemon
 512                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 513         } elsif ($self->{sock}) { # to lei(1) client
 514                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 515         } # else noop if client disconnected
 516 }
 517
 518 sub note_sigpipe { # triggers sigpipe_handler
 519         my ($self, $fd) = @_;
 520         close(delete($self->{$fd})); # explicit close silences Perl warning
 521         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 522         x_it($self, 13);
 523 }
 524
 525 sub _lei_atfork_child {
 526         my ($self, $persist) = @_;
 527         # we need to explicitly close things which are on stack
 528         if ($persist) {
 529                 chdir '/' or die "chdir(/): $!";
 530                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 531                 if (my $cfg = $self->{cfg}) {
 532                         delete $cfg->{-lei_store};
 533                 }
 534         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 535                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 536                 STDERR->autoflush(1);
 537         }
 538         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 539         if (my $op_c = delete $self->{pkt_op_c}) {
 540                 close(delete $op_c->{sock});
 541         }
 542         if (my $pgr = delete $self->{pgr}) {
 543                 close($_) for (@$pgr[1,2]);
 544         }
 545         close $listener if $listener;
 546         undef $listener;
 547         undef $dir_idle;
 548         %PATH2CFG = ();
 549         undef $errors_log;
 550         $quit = \&CORE::exit;
 551         $self->{-eml_noisy} or # only "lei import" sets this atm
 552                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 553         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 554 }
 555
 556 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 557         my ($self) = @_;
 558         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 559                 $op->close; # PublicInbox::PktOp::close
 560         }
 561         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 562         close $pkt_op_p->{op_p};
 563 }
 564
 565 sub pkt_op_pair {
 566         my ($self) = @_;
 567         require PublicInbox::OnDestroy;
 568         require PublicInbox::PktOp;
 569         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 570         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 571         $end;
 572 }
 573
 574 sub incr {
 575         my ($self, $field, $nr) = @_;
 576         $self->{counters}->{$field} += $nr;
 577 }
 578
 579 sub workers_start {
 580         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 581         $ops = {
 582                 '!' => [ \&fail_handler, $lei ],
 583                 '|' => [ \&sigpipe_handler, $lei ],
 584                 'x_it' => [ \&x_it, $lei ],
 585                 'child_error' => [ \&child_error, $lei ],
 586                 'incr' => [ \&incr, $lei ],
 587                 ($ops ? %$ops : ()),
 588         };
 589         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 590         my $end = $lei->pkt_op_pair;
 591         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 592         $flds->{lei} = $lei;
 593         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 594         delete $lei->{pkt_op_p};
 595         my $op_c = delete $lei->{pkt_op_c};
 596         @$end = ();
 597         $lei->event_step_init;
 598         ($op_c, $ops);
 599 }
 600
 601 # call this when we're ready to wait on events and yield to other clients
 602 sub wait_wq_events {
 603         my ($lei, $op_c, $ops) = @_;
 604         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 605                 $wq->wq_close(1);
 606         }
 607         $op_c->{ops} = $ops;
 608 }
 609
 610 sub _help {
 611         require PublicInbox::LeiHelp;
 612         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 613 }
 614
 615 sub optparse ($$$) {
 616         my ($self, $cmd, $argv) = @_;
 617         # allow _complete --help to complete, not show help
 618         return 1 if substr($cmd, 0, 1) eq '_';
 619         $self->{cmd} = $cmd;
 620         $OPT = $self->{opt} //= {};
 621         my $info = $CMD{$cmd} // [ '[...]' ];
 622         my ($proto, undef, @spec) = @$info;
 623         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 624         push @spec, qw(help|h);
 625         my $lone_dash;
 626         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 627                 $lone_dash = $spec[0];
 628                 $OPT->{$spec[0]} = \(my $var);
 629                 push @spec, '' => \$var;
 630         }
 631         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 632                 return _help($self, "bad arguments or options for $cmd");
 633         return _help($self) if $OPT->{help};
 634
 635         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 636
 637         # "-" aliases "stdin" or "clear"
 638         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 639
 640         my $i = 0;
 641         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 642         my ($err, $inf);
 643         my @args = split(/ /, $proto);
 644         for my $var (@args) {
 645                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 646                         $inf = defined($argv->[$i]) and last;
 647                         $var =~ s/\.\.\.\z//;
 648                         $err = "$var not supplied";
 649                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 650                         $argv->[$i++] // ($err = "$var not supplied");
 651                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 652                         $inf = 1;
 653                         last;
 654                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 655                         $i++;
 656                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 657                         $inf = 1 if index($var, '...') > 0;
 658                         my @or = split(/\|/, $var);
 659                         my $ok;
 660                         for my $o (@or) {
 661                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 662                                         my $sw = $1;
 663                                         # assume pipe/regular file on stdin
 664                                         # w/o args means stdin
 665                                         if ($sw eq 'stdin' && !@$argv &&
 666                                                         (-p $self->{0} ||
 667                                                          -f _) && -r _) {
 668                                                 $OPT->{stdin} //= 1;
 669                                         }
 670                                         $ok = defined($OPT->{$sw});
 671                                         last if $ok;
 672                                 } elsif (defined($argv->[$i])) {
 673                                         $ok = 1;
 674                                         $i++;
 675                                         last;
 676                                 } # else continue looping
 677                         }
 678                         last if $ok;
 679                         my $last = pop @or;
 680                         $err = join(', ', @or) . " or $last must be set";
 681                 } else {
 682                         warn "BUG: can't parse `$var' in $proto";
 683                 }
 684                 last if $err;
 685         }
 686         if (!$inf && scalar(@$argv) > scalar(@args)) {
 687                 $err //= 'too many arguments';
 688         }
 689         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 690 }
 691
 692 sub _tmp_cfg { # for lei -c <name>=<value> ...
 693         my ($self) = @_;
 694         my $cfg = _lei_cfg($self, 1);
 695         require File::Temp;
 696         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 697         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 698         $ft->autoflush(1);
 699         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 700 [include]
 701         path = $cfg->{-f}
 702 EOM
 703         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 704         for (@{$self->{opt}->{c}}) {
 705                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 706 `-c $_' is not of the form -c <name>=<value>'
 707 EOM
 708                 my $name = $1;
 709                 my $value = $2 // 1;
 710                 _config($self, '--add', $name, $value);
 711                 if (defined(my $v = $tmp->{$name})) {
 712                         if (ref($v) eq 'ARRAY') {
 713                                 push @$v, $value;
 714                         } else {
 715                                 $tmp->{$name} = [ $v, $value ];
 716                         }
 717                 } else {
 718                         $tmp->{$name} = $value;
 719                 }
 720         }
 721 }
 722
 723 sub lazy_cb ($$$) {
 724         my ($self, $cmd, $pfx) = @_;
 725         my $ucmd = $cmd;
 726         $ucmd =~ tr/-/_/;
 727         my $cb;
 728         $cb = $self->can($pfx.$ucmd) and return $cb;
 729         my $base = $ucmd;
 730         $base =~ s/_([a-z])/\u$1/g;
 731         my $pkg = "PublicInbox::Lei\u$base";
 732         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 733                 $pkg->can($pfx.$ucmd) : undef;
 734 }
 735
 736 sub dispatch {
 737         my ($self, $cmd, @argv) = @_;
 738         local $current_lei = $self; # for __WARN__
 739         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 740         dump_and_clear_log("from previous run\n");
 741         return _help($self, 'no command given') unless defined($cmd);
 742         # do not support Getopt bundling for this
 743         while ($cmd eq '-C' || $cmd eq '-c') {
 744                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 745                                         '-C DIRECTORY' : '-c <name>=<value>');
 746                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 747                 $cmd = shift(@argv) // return _help($self, 'no command given');
 748         }
 749         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 750                 optparse($self, $cmd, \@argv) or return;
 751                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 752                 if (my $chdir = $self->{opt}->{C}) {
 753                         for my $d (@$chdir) {
 754                                 next if $d eq ''; # same as git(1)
 755                                 chdir $d or return fail($self, "cd $d: $!");
 756                         }
 757                         if (delete $self->{3}) { # update cwd for rel2abs
 758                                 opendir my $dh, '.' or
 759                                         return fail($self, "opendir . $!");
 760                                 $self->{3} = $dh;
 761                         }
 762                 }
 763                 $cb->($self, @argv);
 764         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 765                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 766                         or return _help($self, 'bad arguments or options');
 767                 _help($self);
 768         } else {
 769                 fail($self, "`$cmd' is not an lei command");
 770         }
 771 }
 772
 773 sub _lei_cfg ($;$) {
 774         my ($self, $creat) = @_;
 775         return $self->{cfg} if $self->{cfg};
 776         my $f = _config_path($self);
 777         my @st = stat($f);
 778         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 779         my ($sto, $sto_dir);
 780         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 781                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 782                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 783         }
 784         if (!@st) {
 785                 unless ($creat) {
 786                         delete $self->{cfg};
 787                         return bless {}, 'PublicInbox::Config';
 788                 }
 789                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 790                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 791                 open my $fh, '>>', $f or die "open($f): $!\n";
 792                 @st = stat($fh) or die "fstat($f): $!\n";
 793                 $cur_st = pack('dd', $st[10], $st[7]);
 794                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 795         }
 796         my $cfg = PublicInbox::Config->git_config_dump($f);
 797         $cfg->{-st} = $cur_st;
 798         $cfg->{'-f'} = $f;
 799         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 800                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 801                                                 store_path($self))) {
 802                 $cfg->{-lei_store} = $sto;
 803         }
 804         if (scalar(keys %PATH2CFG) > 5) {
 805                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 806                 for my $k (keys %PATH2CFG) {
 807                         delete($PATH2CFG{$k}) unless -f $k
 808                 }
 809         }
 810         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 811 }
 812
 813 sub _lei_store ($;$) {
 814         my ($self, $creat) = @_;
 815         my $cfg = _lei_cfg($self, $creat);
 816         $cfg->{-lei_store} //= do {
 817                 require PublicInbox::LeiStore;
 818                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 819                 return unless $creat || -d $dir;
 820                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 821         };
 822 }
 823
 824 sub _config {
 825         my ($self, @argv) = @_;
 826         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 827         my $cfg = _lei_cfg($self, 1);
 828         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 829         my %rdr = map { $_ => $self->{$_} } (0..2);
 830         waitpid(spawn($cmd, \%env, \%rdr), 0);
 831 }
 832
 833 sub lei_config {
 834         my ($self, @argv) = @_;
 835         $self->{opt}->{'config-file'} and return fail $self,
 836                 "config file switches not supported by `lei config'";
 837         _config(@_);
 838         x_it($self, $?) if $?;
 839 }
 840
 841 sub lei_daemon_pid { puts shift, $$ }
 842
 843 sub lei_daemon_kill {
 844         my ($self) = @_;
 845         my $sig = $self->{opt}->{signal} // 'TERM';
 846         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 847 }
 848
 849 # Shell completion helper.  Used by lei-completion.bash and hopefully
 850 # other shells.  Try to do as much here as possible to avoid redundancy
 851 # and improve maintainability.
 852 sub lei__complete {
 853         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 854         shift @argv; # ignore "lei", the entire command is sent
 855         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 856         my $cmd = shift @argv;
 857         my $info = $CMD{$cmd} // do { # filter matching commands
 858                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 859                 return;
 860         };
 861         my ($proto, undef, @spec) = @$info;
 862         my $cur = pop @argv;
 863         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 864         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 865                 # gross special case since the only git-config options
 866                 # Consider moving to a table if we need more special cases
 867                 # we use Getopt::Long for are the ones we reject, so these
 868                 # are the ones we don't reject:
 869                 if ($cmd eq 'config') {
 870                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 871                         @spec = qw(add z|null get get-all unset unset-all
 872                                 replace-all get-urlmatch
 873                                 remove-section rename-section
 874                                 name-only list|l edit|e
 875                                 get-color-name get-colorbool);
 876                         # fall-through
 877                 }
 878                 # generate short/long names from Getopt::Long specs
 879                 puts $self, grep(/$re/, qw(--help -h -C), map {
 880                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 881                         } elsif (s/\+\z//) { # verbose|v+
 882                         } elsif (s/!\z//) {
 883                                 # negation: mail! => no-mail|mail
 884                                 s/([\w\-]+)/$1|no-$1/g
 885                         }
 886                         map {
 887                                 my $x = length > 1 ? "--$_" : "-$_";
 888                                 $x eq $_cur ? () : $x;
 889                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 890                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 891         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 892                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 893         }
 894
 895         # switch args (e.g. lei q -f mbox<TAB>)
 896         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 897                 my $opt = quotemeta $1;
 898                 puts $self, map {
 899                         my $v = $OPTDESC{$_};
 900                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 901                         # get rid of ALL CAPS placeholder (e.g "OUT")
 902                         # (TODO: completion for external paths)
 903                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 904                         @v;
 905                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 906         }
 907         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 908                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 909         }
 910         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 911         # proto parsing.
 912 }
 913
 914 sub exec_buf ($$) {
 915         my ($argv, $env) = @_;
 916         my $argc = scalar @$argv;
 917         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 918         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 919         $buf;
 920 }
 921
 922 sub start_mua {
 923         my ($self) = @_;
 924         my $mua = $self->{opt}->{mua} // return;
 925         my $mfolder = $self->{ovv}->{dst};
 926         my (@cmd, $replaced);
 927         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 928                 @cmd = ($mua, '-f');
 929         # TODO: help wanted: other common FOSS MUAs
 930         } else {
 931                 require Text::ParseWords;
 932                 @cmd = Text::ParseWords::shellwords($mua);
 933                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 934                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 935         }
 936         push @cmd, $mfolder unless defined($replaced);
 937         if ($self->{sock}) { # lei(1) client process runs it
 938                 # restore terminal: echo $query | lei q --stdin --mua=...
 939                 my $io = [];
 940                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 941                 send_exec_cmd($self, $io, \@cmd, {});
 942         }
 943         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 944                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 945         }
 946         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 947         $self->{opt}->{quiet} = 1;
 948         delete $self->{-progress};
 949         delete $self->{opt}->{verbose};
 950 }
 951
 952 sub send_exec_cmd { # tell script/lei to execute a command
 953         my ($self, $io, $cmd, $env) = @_;
 954         my $sock = $self->{sock} // die 'lei client gone';
 955         my $fds = [ map { fileno($_) } @$io ];
 956         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 957 }
 958
 959 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 960         my ($self) = @_;
 961         my $alerts = $self->{opt}->{alert} // return;
 962         my $sock = $self->{sock};
 963         while (my $op = shift(@$alerts)) {
 964                 if ($op eq ':WINCH') {
 965                         # hit the process group that started the MUA
 966                         send($sock, '-WINCH', MSG_EOR) if $sock;
 967                 } elsif ($op eq ':bell') {
 968                         out($self, "\a");
 969                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 970                         push @$alerts, split(/(?<!\\),/, $op);
 971                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 972                         my $cmd = $1; # run an arbitrary command
 973                         require Text::ParseWords;
 974                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 975                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 976                 } else {
 977                         err($self, "W: unsupported --alert=$op"); # non-fatal
 978                 }
 979         }
 980 }
 981
 982 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 983 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 984
 985 # this also normalizes the path
 986 sub path_to_fd {
 987         my ($self, $path) = @_;
 988         $path = rel2abs($self, $path);
 989         $path =~ tr!/!/!s;
 990         $path_to_fd{$path} // (
 991                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 992                         fail($self, "cannot open $path from daemon") : -1
 993         );
 994 }
 995
 996 # caller needs to "-t $self->{1}" to check if tty
 997 sub start_pager {
 998         my ($self) = @_;
 999         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1000         chomp(my $pager = <$fh> // '');
1001         close($fh) or warn "`git var PAGER' error: \$?=$?";
1002         return if $pager eq 'cat' || $pager eq '';
1003         my $new_env = { LESS => 'FRX', LV => '-c' };
1004         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1005         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1006         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1007         my $pgr = [ undef, @$rdr{1, 2} ];
1008         my $env = $self->{env};
1009         if ($self->{sock}) { # lei(1) process runs it
1010                 delete @$new_env{keys %$env}; # only set iff unset
1011                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1012         } else {
1013                 die 'BUG: start_pager w/o socket';
1014         }
1015         $self->{1} = $wpager;
1016         $self->{2} = $wpager if -t $self->{2};
1017         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1018         $self->{pgr} = $pgr;
1019 }
1020
1021 sub stop_pager {
1022         my ($self) = @_;
1023         my $pgr = delete($self->{pgr}) or return;
1024         $self->{2} = $pgr->[2];
1025         # do not restore original stdout, just close it so we error out
1026         close(delete($self->{1})) if $self->{1};
1027 }
1028
1029 sub accept_dispatch { # Listener {post_accept} callback
1030         my ($sock) = @_; # ignore other
1031         $sock->autoflush(1);
1032         my $self = bless { sock => $sock }, __PACKAGE__;
1033         vec(my $rvec = '', fileno($sock), 1) = 1;
1034         select($rvec, undef, undef, 60) or
1035                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1036         # (4096 * 33) >MAX_ARG_STRLEN
1037         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1038         if (!defined($fds[0])) {
1039                 warn(my $msg = "recv_cmd failed: $!");
1040                 return send($sock, $msg, MSG_EOR);
1041         } else {
1042                 my $i = 0;
1043                 for my $fd (@fds) {
1044                         open($self->{$i++}, '+<&=', $fd) and next;
1045                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1046                 }
1047                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1048         }
1049         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1050         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1051         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1052                 return send($sock, 'request command truncated', MSG_EOR);
1053         my ($argc, @argv) = split(/\0/, $buf, -1);
1054         undef $buf;
1055         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1056         if (chdir($self->{3})) {
1057                 local %ENV = %env;
1058                 $self->{env} = \%env;
1059                 eval { dispatch($self, @argv) };
1060                 send($sock, $@, MSG_EOR) if $@;
1061         } else {
1062                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1063         }
1064 }
1065
1066 sub dclose {
1067         my ($self) = @_;
1068         delete $self->{-progress};
1069         _drop_wq($self) if $self->{failed};
1070         close(delete $self->{1}) if $self->{1}; # may reap_compress
1071         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1072 }
1073
1074 # for long-running results
1075 sub event_step {
1076         my ($self) = @_;
1077         local %ENV = %{$self->{env}};
1078         my $sock = $self->{sock};
1079         local $current_lei = $self;
1080         eval {
1081                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1082                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1083                                 return if $! == EAGAIN;
1084                                 next if $! == EINTR;
1085                                 last if $! == ECONNRESET;
1086                                 die "recvmsg: $!";
1087                         }
1088                         for my $fd (@fds) {
1089                                 open my $rfh, '+<&=', $fd;
1090                         }
1091                         die "unrecognized client signal: $buf";
1092                 }
1093                 dclose($self);
1094         };
1095         if (my $err = $@) {
1096                 eval { $self->fail($err) };
1097                 dclose($self);
1098         }
1099 }
1100
1101 sub event_step_init {
1102         my ($self) = @_;
1103         my $sock = $self->{sock} or return;
1104         $self->{-event_init_done} //= do { # persist til $ops done
1105                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1106                 $sock;
1107         };
1108 }
1109
1110 sub noop {}
1111
1112 sub oldset { $oldset }
1113
1114 sub dump_and_clear_log {
1115         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1116                 my @pfx = @_;
1117                 unshift(@pfx, "$errors_log ") if @pfx;
1118                 warn @pfx, do { local $/; <STDIN> };
1119                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1120         }
1121 }
1122
1123 # lei(1) calls this when it can't connect
1124 sub lazy_start {
1125         my ($path, $errno, $narg) = @_;
1126         local ($errors_log, $listener);
1127         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1128         $errors_log = "$sock_dir/errors.log";
1129         my $addr = pack_sockaddr_un($path);
1130         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1131         $lk->lock_acquire;
1132         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1133         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1134                 return if connect($listener, $addr); # another process won
1135                 if ($errno == ECONNREFUSED && -S $path) {
1136                         unlink($path) or die "unlink($path): $!";
1137                 }
1138         } else {
1139                 $! = $errno; # allow interpolation to stringify in die
1140                 die "connect($path): $!";
1141         }
1142         umask(077) // die("umask(077): $!");
1143         bind($listener, $addr) or die "bind($path): $!";
1144         listen($listener, 1024) or die "listen: $!";
1145         $lk->lock_release;
1146         undef $lk;
1147         my @st = stat($path) or die "stat($path): $!";
1148         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1149         local $oldset = PublicInbox::DS::block_signals();
1150         if ($narg == 5) {
1151                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1152                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1153                         require PublicInbox::CmdIPC4;
1154                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1155                         PublicInbox::CmdIPC4->can('recv_cmd4');
1156                 };
1157         }
1158         $recv_cmd or die <<"";
1159 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1160
1161         require PublicInbox::Listener;
1162         require PublicInbox::PktOp;
1163         (-p STDOUT) or die "E: stdout must be a pipe\n";
1164         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1165         STDIN->autoflush(1);
1166         dump_and_clear_log("from previous daemon process:\n");
1167         POSIX::setsid() > 0 or die "setsid: $!";
1168         my $pid = fork // die "fork: $!";
1169         return if $pid;
1170         $0 = "lei-daemon $path";
1171         local %PATH2CFG;
1172         $listener->blocking(0);
1173         my $exit_code;
1174         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1175         local $quit = do {
1176                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1177                 sub {
1178                         $exit_code //= shift;
1179                         my $lis = $pil or exit($exit_code);
1180                         # closing eof_p triggers \&noop wakeup
1181                         $listener = $eof_p = $pil = $path = undef;
1182                         $lis->close; # DS::close
1183                         PublicInbox::DS->SetLoopTimeout(1000);
1184                 };
1185         };
1186         my $sig = {
1187                 CHLD => \&PublicInbox::DS::enqueue_reap,
1188                 QUIT => $quit,
1189                 INT => $quit,
1190                 TERM => $quit,
1191                 HUP => \&noop,
1192                 USR1 => \&noop,
1193                 USR2 => \&noop,
1194         };
1195         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1196         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1197         undef $sig;
1198         local $SIG{PIPE} = 'IGNORE';
1199         require PublicInbox::DirIdle;
1200         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1201                 # just rely on wakeup ot hit PostLoopCallback set below
1202                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1203         }, 1);
1204         if ($sigfd) {
1205                 undef $sigfd; # unref, already in DS::DescriptorMap
1206         } else {
1207                 # wake up every second to accept signals if we don't
1208                 # have signalfd or IO::KQueue:
1209                 PublicInbox::DS::sig_setmask($oldset);
1210                 PublicInbox::DS->SetLoopTimeout(1000);
1211         }
1212         PublicInbox::DS->SetPostLoopCallback(sub {
1213                 my ($dmap, undef) = @_;
1214                 if (@st = defined($path) ? stat($path) : ()) {
1215                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1216                                 warn "$path dev/ino changed, quitting\n";
1217                                 $path = undef;
1218                         }
1219                 } elsif (defined($path)) { # ENOENT is common
1220                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1221                         undef $path;
1222                         $quit->();
1223                 }
1224                 return 1 if defined($path);
1225                 my $now = now();
1226                 my $n = 0;
1227                 for my $s (values %$dmap) {
1228                         $s->can('busy') or next;
1229                         if ($s->busy($now)) {
1230                                 ++$n;
1231                         } else {
1232                                 $s->close;
1233                         }
1234                 }
1235                 $n; # true: continue, false: stop
1236         });
1237
1238         # STDIN was redirected to /dev/null above, closing STDERR and
1239         # STDOUT will cause the calling `lei' client process to finish
1240         # reading the <$daemon> pipe.
1241         local $SIG{__WARN__} = sub {
1242                 $current_lei ? err($current_lei, @_) : warn(
1243                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1244         };
1245         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1246         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1247         # $daemon pipe to `lei' closed, main loop begins:
1248         PublicInbox::DS->EventLoop;
1249         exit($exit_code // 0);
1250 }
1251
1252 sub busy { 1 } # prevent daemon-shutdown if client is connected
1253
1254 # ensures stdout hits the FS before sock disconnects so a client
1255 # can immediately reread it
1256 sub DESTROY {
1257         my ($self) = @_;
1258         if (my $counters = delete $self->{counters}) {
1259                 for my $k (sort keys %$counters) {
1260                         my $nr = $counters->{$k};
1261                         $self->child_error(1 << 8, "$nr $k messages");
1262                 }
1263         }
1264         $self->{1}->autoflush(1) if $self->{1};
1265         stop_pager($self);
1266         # preserve $? for ->fail or ->x_it code
1267 }
1268
1269 sub wq_done_wait { # dwaitpid callback
1270         my ($arg, $pid) = @_;
1271         my ($wq, $lei) = @$arg;
1272         my $err_type = $lei->{-err_type};
1273         $? and $lei->child_error($?,
1274                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1275         $lei->dclose;
1276 }
1277
1278 sub fchdir {
1279         my ($lei) = @_;
1280         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1281         chdir($dh) || $lei->fail("fchdir: $!");
1282 }
1283
1284 sub wq_eof { # EOF callback for main daemon
1285         my ($lei) = @_;
1286         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1287         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1288 }
1289
1290 1;