lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 use Sys::Syslog qw(openlog syslog closelog);
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  33         $recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  41 our %LIVE_SOCK; # "GLOB(0x....)" => $lei->{sock}
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         my $cwd;
  81         if (defined $pwd) {
  82                 my $xcwd = $self->{3} //
  83                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  84                 if (my @st_pwd = stat($pwd)) {
  85                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  86                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  87                                 $self->{env}->{PWD} = $pwd = undef;
  88                 } else { # PWD was invalid
  89                         $self->{env}->{PWD} = $pwd = undef;
  90                 }
  91         }
  92         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  93         File::Spec->rel2abs($p, $pwd);
  94 }
  95
  96 # abs_path resolves symlinks in parent iff all parents exist
  97 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  98
  99 sub canonpath_harder {
 100         my $p = $_[-1]; # $_[0] may be self
 101         $p = File::Spec->canonpath($p);
 102         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 103 }
 104
 105 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 109                 .'/lei');
 110 }
 111
 112 sub store_path ($) { share_path($_[0]) . '/store' }
 113
 114 sub _config_path ($) {
 115         my ($self) = @_;
 116         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 117                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 118                 .'/lei/config');
 119 }
 120
 121 sub cache_dir ($) {
 122         my ($self) = @_;
 123         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 124                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 125                 .'/lei');
 126 }
 127
 128 sub url_folder_cache {
 129         my ($self) = @_;
 130         require PublicInbox::SharedKV; # URI => updated_at_sec_
 131         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 132 }
 133
 134 sub ale {
 135         my ($self) = @_;
 136         $self->{ale} //= do {
 137                 require PublicInbox::LeiALE;
 138                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 139         };
 140 }
 141
 142 sub index_opt {
 143         # TODO: drop underscore variants everywhere, they're undocumented
 144         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 145         max_size|max-size=s sequential-shard
 146         batch_size|batch-size=s skip-docdata)
 147 }
 148
 149 my @c_opt = qw(c=s@ C=s@ quiet|q);
 150 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 151         import-remote! no-torsocks torsocks=s),
 152         PublicInbox::LeiQuery::curl_opt());
 153
 154 # we don't support -C as an alias for --find-copies since it's already
 155 # used for chdir
 156 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 157         output-indicator-context=s indent-heuristic!
 158         minimal patience histogram anchored=s@ diff-algorithm=s
 159         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 160         word-diff:s word-diff-regex=s color-words:s no-renames
 161         rename-empty! check ws-error-highlight=s full-index binary
 162         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 163         find-copies-harder irreversible-delete|D l=i diff-filter=s
 164         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 165         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 166         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 167         inter-hunk-context=i function-context|W exit-code ext-diff
 168         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 169         line-prefix=s);
 170
 171 # we generate shell completion + help using %CMD and %OPTDESC,
 172 # see lei__complete() and PublicInbox::LeiHelp
 173 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 174 our %CMD = ( # sorted in order of importance/use:
 175 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 176         'stdin|', # /|\z/ must be first for lone dash
 177         @lxs_opt,
 178         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 179         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 180         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 181         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 182
 183 'up' => [ 'OUTPUT...|--all', 'update saved search',
 184         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 185
 186 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 187         'stdin|', # /|\z/ must be first for lone dash
 188         # some of these options are ridiculous for lcat
 189         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 190         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 191         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 192         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 193
 194 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 195         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 196         @lxs_opt, @c_opt ],
 197
 198 'rediff' => [ '--stdin|LOCATION...',
 199                 'regenerate a diff with different options',
 200         'stdin|', # /|\z/ must be first for lone dash
 201         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 202         @diff_opt, @lxs_opt, @c_opt ],
 203
 204 'add-external' => [ 'LOCATION',
 205         'add/set priority of a publicinbox|extindex for extra matches',
 206         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 207         verbose|v+), @c_opt, index_opt(),
 208         PublicInbox::LeiQuery::curl_opt() ],
 209 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 210         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 211 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 212 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 213                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 215                 qw(z|0 ascii l url), @c_opt ],
 216 'forget-external' => [ 'LOCATION...|--prune',
 217         'exclude further results from a publicinbox|extindex',
 218         qw(prune), @c_opt ],
 219
 220 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 221                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 222 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 223                 qw(verbose|v+), @c_opt ],
 224 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 225                         @c_opt ],
 226 'rm' => [ '--stdin|LOCATION...',
 227         'remove a message from the index and prevent reindexing',
 228         'stdin|', # /|\z/ must be first for lone dash
 229         qw(in-format|F=s lock=s@), @c_opt ],
 230 'plonk' => [ '--threads|--from=IDENT',
 231         'exclude mail matching From: or threads from non-Message-ID searches',
 232         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 233 'tag' => [ 'KEYWORDS...',
 234         'set/unset keywords and/or labels on message(s)',
 235         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 236         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 237         pass_through('-kw:foo for delete') ],
 238
 239 'purge-mailsource' => [ 'LOCATION|--all',
 240         'remove imported messages from IMAP, Maildirs, and MH',
 241         qw(exact! all jobs:i indexed), @c_opt ],
 242
 243 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 244         qw(poll-interval=s state=s recursive|r), @c_opt ],
 245 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 246         qw(recursive|r), @c_opt ],
 247 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 248                 qw(l z|0), @c_opt ],
 249 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 250 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 251 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 252         qw(prune), @c_opt ],
 253
 254 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 255         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 256         verbose|v+ incremental!),
 257          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 258          @c_opt ],
 259 'import' => [ 'LOCATION...|--stdin',
 260         'one-time import/update from URL or filesystem',
 261         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 262         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 263         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 264 'forget-mail-sync' => [ 'LOCATION...',
 265         'forget sync information for a mail folder', @c_opt ],
 266 'prune-mail-sync' => [ 'LOCATION...|--all',
 267         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 268 'export-kw' => [ 'LOCATION...|--all',
 269         'one-time export of keywords of sync sources',
 270         qw(all:s mode=s), @c_opt ],
 271 'convert' => [ 'LOCATION...|--stdin',
 272         'one-time conversion from URL or filesystem to another format',
 273         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 274         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 275 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 276         "use a patch to generate a query for `lei q --stdin'",
 277         qw(stdin| want|w=s@ uri debug), @c_opt ],
 278 'config' => [ '[...]', sub {
 279                 'git-config(1) wrapper for '._config_path($_[0]);
 280         }, qw(config-file|system|global|file|f=s), # for conflict detection
 281          qw(c=s@ C=s@), pass_through('git config') ],
 282 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 283         qw(stdin| pretty ascii dir=s), @c_opt ],
 284
 285 'init' => [ '[DIRNAME]', sub {
 286         "initialize storage, default: ".store_path($_[0]);
 287         }, @c_opt ],
 288 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 289         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 290         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 291 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 292 'help' => [ '[SUBCOMMAND]', 'show help' ],
 293
 294 # TODO
 295 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 296 #       'rewrite git history in an attempt to improve compression',
 297 #       qw(gc!), @c_opt ],
 298 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 299 #
 300 # internal commands are prefixed with '_'
 301 '_complete' => [ '[...]', 'internal shell completion helper',
 302                 pass_through('everything') ],
 303 ); # @CMD
 304
 305 # switch descriptions, try to keep consistent across commands
 306 # $spec: Getopt::Long option specification
 307 # $spec => [@ALLOWED_VALUES (default is first), $description],
 308 # $spec => $description
 309 # "$SUB_COMMAND TAB $spec" => as above
 310 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 311                         'specify message input format' ];
 312 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 313
 314 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 315 my %OPTDESC = (
 316 'help|h' => 'show this built-in help',
 317 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 318 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 319 'quiet|q' => 'be quiet',
 320 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 321         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 322
 323 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 324 'globoff|g' => "do not match locations using '*?' wildcards ".
 325                 "and\xa0'[]'\x{a0}ranges",
 326 'invert-match|v' => 'select non-matching lines',
 327 'color!' => 'disable color (for --format=text)',
 328 'verbose|v+' => 'be more verbose',
 329 'external!' => 'do not use externals',
 330 'mail!' => 'do not look in mail storage for OID',
 331 'cwd!' => 'do not look in git repo of current working directory',
 332 'oid-a|A=s' => 'pre-image OID',
 333 'path-a|a=s' => 'pre-image pathname associated with OID',
 334 'path-b|b=s' => 'post-image pathname associated with OID',
 335 'git-dir=s@' => 'additional git repository to scan',
 336 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 337 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 338         "proxy for (e.g. `socks5h://0:9050')" ],
 339 'torsocks=s' => ['VAL|auto|no|yes',
 340                 'whether or not to wrap git and curl commands with torsocks'],
 341 'no-torsocks' => 'alias for --torsocks=no',
 342 'save!' =>  "do not save a search for `lei up'",
 343 'import-remote!' => 'do not memoize remote messages into local store',
 344
 345 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 346
 347 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 348                 'deduplication strategy'],
 349 'threads|t+' =>
 350         'return all messages in the same threads as the actual match(es)',
 351
 352 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 353                 'search prefixes to extract (default: dfpost7)' ],
 354
 355 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 356         'run command(s) or perform ops when done writing to output ' .
 357         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 358         'nothing otherwise)' ],
 359
 360 'augment|a' => 'augment --output destination instead of clobbering',
 361
 362 'output|mfolder|o=s' => [ 'MFOLDER',
 363         "destination (e.g.\xa0`/path/to/Maildir', ".
 364         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 365 'mua=s' => [ 'CMD',
 366         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 367 'new-only       import' => 'only import new messages from IMAP source',
 368
 369 'inbox-version=i' => [ 'NUM|1|2',
 370                 'force a public-inbox version with --mirror'],
 371 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 372
 373 # public-inbox-index options
 374 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 375 'compact' => 'run compact index after mirroring',
 376 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 377         "indexlevel with --mirror (default: full)" ],
 378 'max_size|max-size=s' => [ 'SIZE',
 379         'do not index messages larger than SIZE (default: infinity)' ],
 380 'batch_size|batch-size=s' => [ 'SIZE',
 381         'flush changes to OS after given number of bytes (default: 1m)' ],
 382 'sequential-shard' =>
 383         'index Xapian shards sequentially for slow storage',
 384 'skip-docdata' =>
 385         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 386
 387 'format|f=s     q' => [
 388         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 389                 'specify output format, default depends on --output'],
 390 'exclude=s@     q' => [ 'LOCATION',
 391                 'exclude specified external(s) from search' ],
 392 'include|I=s@   q' => [ 'LOCATION',
 393                 'include specified external(s) in search' ],
 394 'only=s@        q' => [ 'LOCATION',
 395                 'only use specified external(s) for search' ],
 396 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 397                 'control number of search and writer jobs' ],
 398 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 399
 400 'in-format|F=s' => $stdin_formats,
 401 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 402                         'listing output format' ],
 403 'l      ls-search' => 'long listing format',
 404 'l      ls-watch' => 'long listing format',
 405 'l      ls-mail-source' => 'long listing format',
 406 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 407 'format|f=s     ls-external' => $ls_format,
 408
 409 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 410 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 411
 412 'sort|s=s' => [ 'VAL|received|relevance|docid',
 413                 "order of results is `--output'-dependent"],
 414 'reverse|r' => 'reverse search results', # like sort(1)
 415
 416 'boost=i' => 'increase/decrease priority of results (default: 0)',
 417
 418 'local' => 'limit operations to the local filesystem',
 419 'local!' => 'exclude results from the local filesystem',
 420 'remote' => 'limit operations to those requiring network access',
 421 'remote!' => 'prevent operations requiring network access',
 422
 423 'all:s  up' => ['local', 'update all (local) saved searches' ],
 424
 425 'mid=s' => 'specify the Message-ID of a message',
 426 'oid=s' => 'specify the git object ID of a message',
 427
 428 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 429 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 430 'include=s' => 'include mailboxes/newsgroups based on pattern',
 431
 432 'exact' => 'operate on exact header matches only',
 433 'exact!' => 'rely on content match instead of exact header matches',
 434
 435 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 436
 437 'kw!' => 'disable/enable importing keywords (aka "flags")',
 438
 439 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 440 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 441
 442 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 443 ); # %OPTDESC
 444
 445 my %CONFIG_KEYS = (
 446         'leistore.dir' => 'top-level storage location',
 447 );
 448
 449 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 450
 451 sub _drop_wq {
 452         my ($self) = @_;
 453         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 454                 if ($wq->wq_kill) {
 455                         $wq->wq_close(0, undef, $self);
 456                 } elsif ($wq->wq_kill_old) {
 457                         $wq->wq_wait_old(undef, $self);
 458                 }
 459                 $wq->DESTROY;
 460         }
 461 }
 462
 463 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 464 sub x_it ($$) {
 465         my ($self, $code) = @_;
 466         # make sure client sees stdout before exit
 467         $self->{1}->autoflush(1) if $self->{1};
 468         stop_pager($self);
 469         if ($self->{pkt_op_p}) { # to top lei-daemon
 470                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 471         } elsif ($self->{sock}) { # to lei(1) client
 472                 send($self->{sock}, "x_it $code", MSG_EOR);
 473         } # else ignore if client disconnected
 474 }
 475
 476 sub err ($;@) {
 477         my $self = shift;
 478         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 479         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 480         print $err @_, @eor and return;
 481         my $old_err = delete $self->{2};
 482         close($old_err) if $! == EPIPE && $old_err;
 483         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 484         print $err @_, @eor or print STDERR @_, @eor;
 485 }
 486
 487 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 488
 489 sub qfin { # show message on finalization (LeiFinmsg)
 490         my ($lei, $msg) = @_;
 491         return if $lei->{opt}->{quiet};
 492         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 493 }
 494
 495 sub fail_handler ($;$$) {
 496         my ($lei, $code, $io) = @_;
 497         close($io) if $io; # needed to avoid warnings on SIGPIPE
 498         _drop_wq($lei);
 499         x_it($lei, $code // (1 << 8));
 500 }
 501
 502 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 503         fail_handler($_[0], 13, delete $_[0]->{1});
 504 }
 505
 506 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 507 sub sigint_reap {
 508         my ($pgid) = @_;
 509         dwaitpid($pgid) if kill('-INT', $pgid);
 510 }
 511
 512 sub fail ($$;$) {
 513         my ($self, $buf, $exit_code) = @_;
 514         $self->{failed}++;
 515         err($self, $buf) if defined $buf;
 516         # calls fail_handler:
 517         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 518         x_it($self, ($exit_code // 1) << 8);
 519         undef;
 520 }
 521
 522 sub out ($;@) {
 523         my $self = shift;
 524         return if print { $self->{1} // return } @_; # likely
 525         return note_sigpipe($self, 1) if $! == EPIPE;
 526         my $err = "error writing to output: $!";
 527         delete $self->{1};
 528         fail($self, $err);
 529 }
 530
 531 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 532
 533 sub child_error { # passes non-fatal curl exit codes to user
 534         my ($self, $child_error, $msg) = @_; # child_error is $?
 535         $child_error ||= 1 << 8;
 536         $self->err($msg) if $msg;
 537         if ($self->{pkt_op_p}) { # to top lei-daemon
 538                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 539         } elsif ($self->{sock}) { # to lei(1) client
 540                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 541         } # else noop if client disconnected
 542 }
 543
 544 sub note_sigpipe { # triggers sigpipe_handler
 545         my ($self, $fd) = @_;
 546         close(delete($self->{$fd})); # explicit close silences Perl warning
 547         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 548         x_it($self, 13);
 549 }
 550
 551 sub _lei_atfork_child {
 552         my ($self, $persist) = @_;
 553         # we need to explicitly close things which are on stack
 554         if ($persist) {
 555                 chdir '/' or die "chdir(/): $!";
 556                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 557                 if (my $cfg = $self->{cfg}) {
 558                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 559                 }
 560         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 561                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 562                 STDERR->autoflush(1);
 563         }
 564         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 565         if (my $op_c = delete $self->{pkt_op_c}) {
 566                 close(delete $op_c->{sock});
 567         }
 568         if (my $pgr = delete $self->{pgr}) {
 569                 close($_) for (@$pgr[1,2]);
 570         }
 571         close $listener if $listener;
 572         undef $listener;
 573         $dir_idle->force_close if $dir_idle;
 574         %PATH2CFG = ();
 575         $MDIR2CFGPATH = {};
 576         %LIVE_SOCK = ();
 577         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 578         undef $errors_log;
 579         $quit = \&CORE::exit;
 580         $self->{-eml_noisy} or # only "lei import" sets this atm
 581                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 582         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 583 }
 584
 585 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 586         my ($self) = @_;
 587         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 588                 $op->close; # PublicInbox::PktOp::close
 589         }
 590         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 591         close $pkt_op_p->{op_p};
 592 }
 593
 594 sub pkt_op_pair {
 595         my ($self) = @_;
 596         require PublicInbox::OnDestroy;
 597         require PublicInbox::PktOp;
 598         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 599         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 600         $end;
 601 }
 602
 603 sub incr {
 604         my ($self, $field, $nr) = @_;
 605         $self->{counters}->{$field} += $nr;
 606 }
 607
 608 sub pkt_ops {
 609         my ($lei, $ops) = @_;
 610         $ops->{'!'} = [ \&fail_handler, $lei ];
 611         $ops->{'|'} = [ \&sigpipe_handler, $lei ];
 612         $ops->{x_it} = [ \&x_it, $lei ];
 613         $ops->{child_error} = [ \&child_error, $lei ];
 614         $ops->{incr} = [ \&incr, $lei ];
 615         $ops;
 616 }
 617
 618 sub workers_start {
 619         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 620         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 621         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 622         my $end = $lei->pkt_op_pair;
 623         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 624         $flds->{lei} = $lei;
 625         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 626         delete $lei->{pkt_op_p};
 627         my $op_c = delete $lei->{pkt_op_c};
 628         @$end = ();
 629         $lei->event_step_init;
 630         ($op_c, $ops);
 631 }
 632
 633 # call this when we're ready to wait on events and yield to other clients
 634 sub wait_wq_events {
 635         my ($lei, $op_c, $ops) = @_;
 636         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 637                 $wq->wq_close(1);
 638         }
 639         $op_c->{ops} = $ops;
 640 }
 641
 642 sub _help {
 643         require PublicInbox::LeiHelp;
 644         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 645 }
 646
 647 sub optparse ($$$) {
 648         my ($self, $cmd, $argv) = @_;
 649         # allow _complete --help to complete, not show help
 650         return 1 if substr($cmd, 0, 1) eq '_';
 651         $self->{cmd} = $cmd;
 652         $OPT = $self->{opt} //= {};
 653         my $info = $CMD{$cmd} // [ '[...]' ];
 654         my ($proto, undef, @spec) = @$info;
 655         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 656         push @spec, qw(help|h);
 657         my $lone_dash;
 658         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 659                 $lone_dash = $spec[0];
 660                 $OPT->{$spec[0]} = \(my $var);
 661                 push @spec, '' => \$var;
 662         }
 663         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 664                 return _help($self, "bad arguments or options for $cmd");
 665         return _help($self) if $OPT->{help};
 666
 667         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 668
 669         # "-" aliases "stdin" or "clear"
 670         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 671
 672         my $i = 0;
 673         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 674         my ($err, $inf);
 675         my @args = split(/ /, $proto);
 676         for my $var (@args) {
 677                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 678                         $inf = defined($argv->[$i]) and last;
 679                         $var =~ s/\.\.\.\z//;
 680                         $err = "$var not supplied";
 681                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 682                         $argv->[$i++] // ($err = "$var not supplied");
 683                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 684                         $inf = 1;
 685                         last;
 686                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 687                         $i++;
 688                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 689                         $inf = 1 if index($var, '...') > 0;
 690                         my @or = split(/\|/, $var);
 691                         my $ok;
 692                         for my $o (@or) {
 693                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 694                                         my $sw = $1;
 695                                         # assume pipe/regular file on stdin
 696                                         # w/o args means stdin
 697                                         if ($sw eq 'stdin' && !@$argv &&
 698                                                         (-p $self->{0} ||
 699                                                          -f _) && -r _) {
 700                                                 $OPT->{stdin} //= 1;
 701                                         }
 702                                         $ok = defined($OPT->{$sw});
 703                                         last if $ok;
 704                                 } elsif (defined($argv->[$i])) {
 705                                         $ok = 1;
 706                                         $i++;
 707                                         last;
 708                                 } # else continue looping
 709                         }
 710                         last if $ok;
 711                         my $last = pop @or;
 712                         $err = join(', ', @or) . " or $last must be set";
 713                 } else {
 714                         warn "BUG: can't parse `$var' in $proto";
 715                 }
 716                 last if $err;
 717         }
 718         if (!$inf && scalar(@$argv) > scalar(@args)) {
 719                 $err //= 'too many arguments';
 720         }
 721         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 722 }
 723
 724 sub _tmp_cfg { # for lei -c <name>=<value> ...
 725         my ($self) = @_;
 726         my $cfg = _lei_cfg($self, 1);
 727         require File::Temp;
 728         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 729         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 730         $ft->autoflush(1);
 731         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 732 [include]
 733         path = $cfg->{-f}
 734 EOM
 735         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 736         for (@{$self->{opt}->{c}}) {
 737                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 738 `-c $_' is not of the form -c <name>=<value>'
 739 EOM
 740                 my $name = $1;
 741                 my $value = $2 // 1;
 742                 _config($self, '--add', $name, $value);
 743                 if (defined(my $v = $tmp->{$name})) {
 744                         if (ref($v) eq 'ARRAY') {
 745                                 push @$v, $value;
 746                         } else {
 747                                 $tmp->{$name} = [ $v, $value ];
 748                         }
 749                 } else {
 750                         $tmp->{$name} = $value;
 751                 }
 752         }
 753 }
 754
 755 sub lazy_cb ($$$) {
 756         my ($self, $cmd, $pfx) = @_;
 757         my $ucmd = $cmd;
 758         $ucmd =~ tr/-/_/;
 759         my $cb;
 760         $cb = $self->can($pfx.$ucmd) and return $cb;
 761         my $base = $ucmd;
 762         $base =~ s/_([a-z])/\u$1/g;
 763         my $pkg = "PublicInbox::Lei\u$base";
 764         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 765                 $pkg->can($pfx.$ucmd) : undef;
 766 }
 767
 768 sub dispatch {
 769         my ($self, $cmd, @argv) = @_;
 770         local $current_lei = $self; # for __WARN__
 771         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 772         return _help($self, 'no command given') unless defined($cmd);
 773         # do not support Getopt bundling for this
 774         while ($cmd eq '-C' || $cmd eq '-c') {
 775                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 776                                         '-C DIRECTORY' : '-c <name>=<value>');
 777                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 778                 $cmd = shift(@argv) // return _help($self, 'no command given');
 779         }
 780         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 781                 optparse($self, $cmd, \@argv) or return;
 782                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 783                 if (my $chdir = $self->{opt}->{C}) {
 784                         for my $d (@$chdir) {
 785                                 next if $d eq ''; # same as git(1)
 786                                 chdir $d or return fail($self, "cd $d: $!");
 787                         }
 788                         open $self->{3}, '.' or return fail($self, "open . $!");
 789                 }
 790                 $cb->($self, @argv);
 791         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 792                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 793                         or return _help($self, 'bad arguments or options');
 794                 _help($self);
 795         } else {
 796                 fail($self, "`$cmd' is not an lei command");
 797         }
 798 }
 799
 800 sub _lei_cfg ($;$) {
 801         my ($self, $creat) = @_;
 802         return $self->{cfg} if $self->{cfg};
 803         my $f = _config_path($self);
 804         my @st = stat($f);
 805         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 806         my ($sto, $sto_dir, $watches, $lne);
 807         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 808                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 809                 ($sto, $sto_dir, $watches, $lne) =
 810                                 @$cfg{qw(-lei_store leistore.dir -watches
 811                                         -lei_note_event)};
 812         }
 813         if (!@st) {
 814                 unless ($creat) {
 815                         delete $self->{cfg};
 816                         return bless {}, 'PublicInbox::Config';
 817                 }
 818                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 819                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 820                 open my $fh, '>>', $f or die "open($f): $!\n";
 821                 @st = stat($fh) or die "fstat($f): $!\n";
 822                 $cur_st = pack('dd', $st[10], $st[7]);
 823                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 824         }
 825         my $cfg = PublicInbox::Config->git_config_dump($f);
 826         $cfg->{-st} = $cur_st;
 827         $cfg->{'-f'} = $f;
 828         if ($sto && canonpath_harder($sto_dir // store_path($self))
 829                         eq canonpath_harder($cfg->{'leistore.dir'} //
 830                                                 store_path($self))) {
 831                 $cfg->{-lei_store} = $sto;
 832                 $cfg->{-lei_note_event} = $lne;
 833                 $cfg->{-watches} = $watches if $watches;
 834         }
 835         if (scalar(keys %PATH2CFG) > 5) {
 836                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 837                 for my $k (keys %PATH2CFG) {
 838                         delete($PATH2CFG{$k}) unless -f $k
 839                 }
 840         }
 841         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 842         refresh_watches($self);
 843         $cfg;
 844 }
 845
 846 sub _lei_store ($;$) {
 847         my ($self, $creat) = @_;
 848         my $cfg = _lei_cfg($self, $creat) // return;
 849         $cfg->{-lei_store} //= do {
 850                 require PublicInbox::LeiStore;
 851                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 852                 return unless $creat || -d $dir;
 853                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 854         };
 855 }
 856
 857 sub _config {
 858         my ($self, @argv) = @_;
 859         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 860         my $cfg = _lei_cfg($self, 1);
 861         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 862         my %rdr = map { $_ => $self->{$_} } (0..2);
 863         waitpid(spawn($cmd, \%env, \%rdr), 0);
 864 }
 865
 866 sub lei_config {
 867         my ($self, @argv) = @_;
 868         $self->{opt}->{'config-file'} and return fail $self,
 869                 "config file switches not supported by `lei config'";
 870         _config(@_);
 871         x_it($self, $?) if $?;
 872 }
 873
 874 sub lei_daemon_pid { puts shift, $$ }
 875
 876 sub lei_daemon_kill {
 877         my ($self) = @_;
 878         my $sig = $self->{opt}->{signal} // 'TERM';
 879         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 880 }
 881
 882 # Shell completion helper.  Used by lei-completion.bash and hopefully
 883 # other shells.  Try to do as much here as possible to avoid redundancy
 884 # and improve maintainability.
 885 sub lei__complete {
 886         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 887         shift @argv; # ignore "lei", the entire command is sent
 888         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 889         my $cmd = shift @argv;
 890         my $info = $CMD{$cmd} // do { # filter matching commands
 891                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 892                 return;
 893         };
 894         my ($proto, undef, @spec) = @$info;
 895         my $cur = pop @argv;
 896         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 897         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 898                 # gross special case since the only git-config options
 899                 # Consider moving to a table if we need more special cases
 900                 # we use Getopt::Long for are the ones we reject, so these
 901                 # are the ones we don't reject:
 902                 if ($cmd eq 'config') {
 903                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 904                         @spec = qw(add z|null get get-all unset unset-all
 905                                 replace-all get-urlmatch
 906                                 remove-section rename-section
 907                                 name-only list|l edit|e
 908                                 get-color-name get-colorbool);
 909                         # fall-through
 910                 }
 911                 # generate short/long names from Getopt::Long specs
 912                 puts $self, grep(/$re/, qw(--help -h -C), map {
 913                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 914                         } elsif (s/\+\z//) { # verbose|v+
 915                         } elsif (s/!\z//) {
 916                                 # negation: mail! => no-mail|mail
 917                                 s/([\w\-]+)/$1|no-$1/g
 918                         }
 919                         map {
 920                                 my $x = length > 1 ? "--$_" : "-$_";
 921                                 $x eq $_cur ? () : $x;
 922                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 923                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 924         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 925                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 926         }
 927
 928         # switch args (e.g. lei q -f mbox<TAB>)
 929         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 930                 my $opt = quotemeta $1;
 931                 puts $self, map {
 932                         my $v = $OPTDESC{$_};
 933                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 934                         # get rid of ALL CAPS placeholder (e.g "OUT")
 935                         # (TODO: completion for external paths)
 936                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 937                         @v;
 938                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 939         }
 940         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 941                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 942         }
 943         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 944         # proto parsing.
 945 }
 946
 947 sub exec_buf ($$) {
 948         my ($argv, $env) = @_;
 949         my $argc = scalar @$argv;
 950         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 951         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 952         $buf;
 953 }
 954
 955 sub start_mua {
 956         my ($self) = @_;
 957         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 958                 refresh_watches($self);
 959         }
 960         my $mua = $self->{opt}->{mua} // return;
 961         my $mfolder = $self->{ovv}->{dst};
 962         my (@cmd, $replaced);
 963         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 964                 @cmd = ($mua, '-f');
 965         # TODO: help wanted: other common FOSS MUAs
 966         } else {
 967                 require Text::ParseWords;
 968                 @cmd = Text::ParseWords::shellwords($mua);
 969                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 970                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 971         }
 972         push @cmd, $mfolder unless defined($replaced);
 973         if ($self->{sock}) { # lei(1) client process runs it
 974                 # restore terminal: echo $query | lei q --stdin --mua=...
 975                 my $io = [];
 976                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 977                 send_exec_cmd($self, $io, \@cmd, {});
 978         }
 979         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 980                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 981         }
 982         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 983         $self->{opt}->{quiet} = 1;
 984         delete $self->{-progress};
 985         delete $self->{opt}->{verbose};
 986 }
 987
 988 sub send_exec_cmd { # tell script/lei to execute a command
 989         my ($self, $io, $cmd, $env) = @_;
 990         my $sock = $self->{sock} // die 'lei client gone';
 991         my $fds = [ map { fileno($_) } @$io ];
 992         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 993 }
 994
 995 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 996         my ($self) = @_;
 997         my $alerts = $self->{opt}->{alert} // return;
 998         my $sock = $self->{sock};
 999         while (my $op = shift(@$alerts)) {
1000                 if ($op eq ':WINCH') {
1001                         # hit the process group that started the MUA
1002                         send($sock, '-WINCH', MSG_EOR) if $sock;
1003                 } elsif ($op eq ':bell') {
1004                         out($self, "\a");
1005                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1006                         push @$alerts, split(/(?<!\\),/, $op);
1007                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1008                         my $cmd = $1; # run an arbitrary command
1009                         require Text::ParseWords;
1010                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1011                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1012                 } else {
1013                         err($self, "W: unsupported --alert=$op"); # non-fatal
1014                 }
1015         }
1016 }
1017
1018 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1019 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1020
1021 # this also normalizes the path
1022 sub path_to_fd {
1023         my ($self, $path) = @_;
1024         $path = rel2abs($self, $path);
1025         $path =~ tr!/!/!s;
1026         $path_to_fd{$path} // (
1027                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1028                         fail($self, "cannot open $path from daemon") : -1
1029         );
1030 }
1031
1032 # caller needs to "-t $self->{1}" to check if tty
1033 sub start_pager {
1034         my ($self) = @_;
1035         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1036         chomp(my $pager = <$fh> // '');
1037         close($fh) or warn "`git var PAGER' error: \$?=$?";
1038         return if $pager eq 'cat' || $pager eq '';
1039         my $new_env = { LESS => 'FRX', LV => '-c' };
1040         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1041         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1042         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1043         my $pgr = [ undef, @$rdr{1, 2} ];
1044         my $env = $self->{env};
1045         if ($self->{sock}) { # lei(1) process runs it
1046                 delete @$new_env{keys %$env}; # only set iff unset
1047                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1048         } else {
1049                 die 'BUG: start_pager w/o socket';
1050         }
1051         $self->{1} = $wpager;
1052         $self->{2} = $wpager if -t $self->{2};
1053         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1054         $self->{pgr} = $pgr;
1055 }
1056
1057 sub stop_pager {
1058         my ($self) = @_;
1059         my $pgr = delete($self->{pgr}) or return;
1060         $self->{2} = $pgr->[2];
1061         # do not restore original stdout, just close it so we error out
1062         close(delete($self->{1})) if $self->{1};
1063 }
1064
1065 sub accept_dispatch { # Listener {post_accept} callback
1066         my ($sock) = @_; # ignore other
1067         $sock->autoflush(1);
1068         my $self = bless { sock => $sock }, __PACKAGE__;
1069         vec(my $rvec = '', fileno($sock), 1) = 1;
1070         select($rvec, undef, undef, 60) or
1071                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1072         # (4096 * 33) >MAX_ARG_STRLEN
1073         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1074         if (!defined($fds[0])) {
1075                 warn(my $msg = "recv_cmd failed: $!");
1076                 return send($sock, $msg, MSG_EOR);
1077         } else {
1078                 my $i = 0;
1079                 for my $fd (@fds) {
1080                         open($self->{$i++}, '+<&=', $fd) and next;
1081                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1082                 }
1083                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1084         }
1085         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1086         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1087         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1088                 return send($sock, 'request command truncated', MSG_EOR);
1089         my ($argc, @argv) = split(/\0/, $buf, -1);
1090         undef $buf;
1091         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1092         if (chdir($self->{3})) {
1093                 local %ENV = %env;
1094                 $self->{env} = \%env;
1095                 eval { dispatch($self, @argv) };
1096                 send($sock, $@, MSG_EOR) if $@;
1097         } else {
1098                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1099         }
1100 }
1101
1102 sub dclose {
1103         my ($self) = @_;
1104         delete $self->{-progress};
1105         _drop_wq($self) if $self->{failed};
1106         close(delete $self->{1}) if $self->{1}; # may reap_compress
1107         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1108 }
1109
1110 # for long-running results
1111 sub event_step {
1112         my ($self) = @_;
1113         local %ENV = %{$self->{env}};
1114         my $sock = $self->{sock};
1115         local $current_lei = $self;
1116         eval {
1117                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1118                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1119                                 return if $! == EAGAIN;
1120                                 next if $! == EINTR;
1121                                 last if $! == ECONNRESET;
1122                                 die "recvmsg: $!";
1123                         }
1124                         for my $fd (@fds) {
1125                                 open my $rfh, '+<&=', $fd;
1126                         }
1127                         die "unrecognized client signal: $buf";
1128                 }
1129                 _drop_wq($self); # EOF, client disconnected
1130                 dclose($self);
1131         };
1132         if (my $err = $@) {
1133                 eval { $self->fail($err) };
1134                 dclose($self);
1135         }
1136 }
1137
1138 sub event_step_init {
1139         my ($self) = @_;
1140         my $sock = $self->{sock} or return;
1141         $self->{-event_init_done} //= do { # persist til $ops done
1142                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1143                 $sock;
1144         };
1145 }
1146
1147 sub noop {}
1148
1149 sub oldset { $oldset }
1150
1151 sub dump_and_clear_log {
1152         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1153                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1154                 chomp(my @lines = <STDIN>);
1155                 truncate(STDIN, 0) or
1156                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1157                 for my $l (@lines) { syslog('warning', '%s', $l) }
1158                 closelog(); # don't share across fork
1159         }
1160 }
1161
1162 sub cfg2lei ($) {
1163         my ($cfg) = @_;
1164         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1165         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1166         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1167         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1168         open($lei->{3}, '/') or die "open /: $!";
1169         chdir($lei->{3}) or die "chdir /': $!";
1170         my ($x, $y);
1171         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1172         $lei->{sock} = $x;
1173         require PublicInbox::LeiSelfSocket;
1174         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1175         $lei;
1176 }
1177
1178 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1179         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1180         my $fn = $ev->fullname;
1181         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1182                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1183                 $nc = '' if $ev->IN_DELETE;
1184                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1185                         my $cfg = $PATH2CFG{$f} // next;
1186                         eval {
1187                                 local %ENV = %{$cfg->{-env}};
1188                                 my $lei = cfg2lei($cfg);
1189                                 $lei->dispatch('note-event',
1190                                                 "maildir:$mdir", $nc, $bn, $fn);
1191                         };
1192                         warn "E note-event $f: $@\n" if $@;
1193                 }
1194         }
1195         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1196                 $ev->cancel;
1197         }
1198         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1199                 delete $MDIR2CFGPATH->{$1};
1200         }
1201         if (!-e $fn) { # config file or Maildir gone
1202                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1203                         delete $cfgpaths->{$fn};
1204                 }
1205                 delete $PATH2CFG{$fn};
1206         }
1207 }
1208
1209 # lei(1) calls this when it can't connect
1210 sub lazy_start {
1211         my ($path, $errno, $narg) = @_;
1212         local ($errors_log, $listener);
1213         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1214         $errors_log = "$sock_dir/errors.log";
1215         my $addr = pack_sockaddr_un($path);
1216         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1217         $lk->lock_acquire;
1218         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1219         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1220                 return if connect($listener, $addr); # another process won
1221                 if ($errno == ECONNREFUSED && -S $path) {
1222                         unlink($path) or die "unlink($path): $!";
1223                 }
1224         } else {
1225                 $! = $errno; # allow interpolation to stringify in die
1226                 die "connect($path): $!";
1227         }
1228         umask(077) // die("umask(077): $!");
1229         bind($listener, $addr) or die "bind($path): $!";
1230         $lk->lock_release;
1231         undef $lk;
1232         my @st = stat($path) or die "stat($path): $!";
1233         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1234         local $oldset = PublicInbox::DS::block_signals();
1235         if ($narg == 5) {
1236                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1237                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1238                         require PublicInbox::CmdIPC4;
1239                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1240                         PublicInbox::CmdIPC4->can('recv_cmd4');
1241                 };
1242         }
1243         $recv_cmd or die <<"";
1244 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1245
1246         require PublicInbox::Listener;
1247         require PublicInbox::PktOp;
1248         (-p STDOUT) or die "E: stdout must be a pipe\n";
1249         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1250         STDIN->autoflush(1);
1251         dump_and_clear_log();
1252         POSIX::setsid() > 0 or die "setsid: $!";
1253         my $pid = fork // die "fork: $!";
1254         return if $pid;
1255         $0 = "lei-daemon $path";
1256         local %PATH2CFG;
1257         local $MDIR2CFGPATH;
1258         $listener->blocking(0);
1259         my $exit_code;
1260         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1261         local $quit = do {
1262                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1263                 sub {
1264                         $exit_code //= shift;
1265                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1266                         my $lis = $pil or exit($exit_code);
1267                         # closing eof_p triggers \&noop wakeup
1268                         $listener = $eof_p = $pil = $path = undef;
1269                         $lis->close; # DS::close
1270                         PublicInbox::DS->SetLoopTimeout(1000);
1271                 };
1272         };
1273         my $sig = {
1274                 CHLD => \&PublicInbox::DS::enqueue_reap,
1275                 QUIT => $quit,
1276                 INT => $quit,
1277                 TERM => $quit,
1278                 HUP => \&noop,
1279                 USR1 => \&noop,
1280                 USR2 => \&noop,
1281         };
1282         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1283         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1284         undef $sig;
1285         local $SIG{PIPE} = 'IGNORE';
1286         require PublicInbox::DirIdle;
1287         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1288                 # just rely on wakeup to hit PostLoopCallback set below
1289                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1290         }, 1);
1291         if ($sigfd) {
1292                 undef $sigfd; # unref, already in DS::DescriptorMap
1293         } else {
1294                 # wake up every second to accept signals if we don't
1295                 # have signalfd or IO::KQueue:
1296                 PublicInbox::DS::sig_setmask($oldset);
1297                 PublicInbox::DS->SetLoopTimeout(1000);
1298         }
1299         PublicInbox::DS->SetPostLoopCallback(sub {
1300                 my ($dmap, undef) = @_;
1301                 if (@st = defined($path) ? stat($path) : ()) {
1302                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1303                                 warn "$path dev/ino changed, quitting\n";
1304                                 $path = undef;
1305                         }
1306                 } elsif (defined($path)) { # ENOENT is common
1307                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1308                         undef $path;
1309                         $quit->();
1310                 }
1311                 return 1 if defined($path);
1312                 my $now = now();
1313                 my $n = 0;
1314                 for my $s (values %$dmap) {
1315                         $s->can('busy') or next;
1316                         if ($s->busy($now)) {
1317                                 ++$n;
1318                         } else {
1319                                 $s->close;
1320                         }
1321                 }
1322                 $n; # true: continue, false: stop
1323         });
1324
1325         # STDIN was redirected to /dev/null above, closing STDERR and
1326         # STDOUT will cause the calling `lei' client process to finish
1327         # reading the <$daemon> pipe.
1328         local $SIG{__WARN__} = sub {
1329                 $current_lei ? err($current_lei, @_) : warn(
1330                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1331         };
1332         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1333         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1334         # $daemon pipe to `lei' closed, main loop begins:
1335         PublicInbox::DS->EventLoop;
1336         dump_and_clear_log();
1337         exit($exit_code // 0);
1338 }
1339
1340 sub busy { 1 } # prevent daemon-shutdown if client is connected
1341
1342 # ensures stdout hits the FS before sock disconnects so a client
1343 # can immediately reread it
1344 sub DESTROY {
1345         my ($self) = @_;
1346         if (my $counters = delete $self->{counters}) {
1347                 for my $k (sort keys %$counters) {
1348                         my $nr = $counters->{$k};
1349                         $self->child_error(0, "$nr $k messages");
1350                 }
1351         }
1352         $self->{1}->autoflush(1) if $self->{1};
1353         stop_pager($self);
1354         dump_and_clear_log();
1355         # preserve $? for ->fail or ->x_it code
1356 }
1357
1358 sub wq_done_wait { # dwaitpid callback
1359         my ($arg, $pid) = @_;
1360         my ($wq, $lei) = @$arg;
1361         my $err_type = $lei->{-err_type};
1362         $? and $lei->child_error($?,
1363                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1364         $lei->dclose;
1365 }
1366
1367 sub fchdir {
1368         my ($lei) = @_;
1369         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1370         chdir($dh) || $lei->fail("fchdir: $!");
1371 }
1372
1373 sub wq_eof { # EOF callback for main daemon
1374         my ($lei) = @_;
1375         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1376         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1377 }
1378
1379 sub watch_state_ok ($) {
1380         my ($state) = $_[-1]; # $_[0] may be $self
1381         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1382 }
1383
1384 sub cancel_maildir_watch ($$) {
1385         my ($d, $cfg_f) = @_;
1386         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1387         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1388                 delete $MDIR2CFGPATH->{$d};
1389         for my $x (@{$w // []}) { $x->cancel }
1390 }
1391
1392 sub add_maildir_watch ($$) {
1393         my ($d, $cfg_f) = @_;
1394         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1395                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1396                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1397         }
1398 }
1399
1400 sub refresh_watches {
1401         my ($lei) = @_;
1402         my $cfg = _lei_cfg($lei) or return;
1403         my $old = $cfg->{-watches};
1404         my $watches = $cfg->{-watches} //= {};
1405         my %seen;
1406         my $cfg_f = $cfg->{'-f'};
1407         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1408                 my $url = substr($w, length('watch.'), -length('.state'));
1409                 require PublicInbox::LeiWatch;
1410                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1411                 $seen{$url} = undef;
1412                 my $state = $cfg->get_1("watch.$url", 'state');
1413                 if (!watch_state_ok($state)) {
1414                         $lei->err("watch.$url.state=$state not supported");
1415                         next;
1416                 }
1417                 if ($url =~ /\Amaildir:(.+)/i) {
1418                         my $d = canonpath_harder($1);
1419                         if ($state eq 'pause') {
1420                                 cancel_maildir_watch($d, $cfg_f);
1421                         } else {
1422                                 add_maildir_watch($d, $cfg_f);
1423                         }
1424                 } else { # TODO: imap/nntp/jmap
1425                         $lei->child_error(0, "E: watch $url not supported, yet")
1426                 }
1427         }
1428
1429         # add all known Maildir folders as implicit watches
1430         my $sto = $lei->_lei_store;
1431         my $renames = 0;
1432         if (my $lms = $sto ? $sto->search->lms : undef) {
1433                 for my $d ($lms->folders('maildir:')) {
1434                         substr($d, 0, length('maildir:')) = '';
1435                         my $cd = canonpath_harder($d);
1436                         my $f = "maildir:$cd";
1437
1438                         # fixup old bugs while we're iterating:
1439                         if ($d ne $cd) {
1440                                 $sto->ipc_do('lms_rename_folder',
1441                                                 "maildir:$d", $f);
1442                                 ++$renames;
1443                         }
1444                         next if $watches->{$f}; # may be set to pause
1445                         require PublicInbox::LeiWatch;
1446                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1447                         $seen{$f} = undef;
1448                         add_maildir_watch($cd, $cfg_f);
1449                 }
1450         }
1451         $lei->sto_done_request if $renames;
1452         if ($old) { # cull old non-existent entries
1453                 for my $url (keys %$old) {
1454                         next if exists $seen{$url};
1455                         delete $old->{$url};
1456                         if ($url =~ /\Amaildir:(.+)/i) {
1457                                 my $d = canonpath_harder($1);
1458                                 cancel_maildir_watch($d, $cfg_f);
1459                         } else { # TODO: imap/nntp/jmap
1460                                 $lei->child_error(0, "E: watch $url TODO");
1461                         }
1462                 }
1463         }
1464         if (scalar keys %$watches) {
1465                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1466         } else {
1467                 delete $cfg->{-watches};
1468         }
1469 }
1470
1471 sub git_blob_id {
1472         my ($lei, $eml) = @_;
1473         ($lei->{sto} // _lei_store($lei, 1))->git_blob_id($eml);
1474 }
1475
1476 sub lms { # read-only LeiMailSync
1477         my ($lei) = @_;
1478         my $lse = $lei->{lse} // do {
1479                 my $sto = $lei->{sto} // _lei_store($lei);
1480                 $sto ? $sto->search : undef
1481         };
1482         $lse ? $lse->lms : undef;
1483 }
1484
1485 sub sto_done_request { # only call this from lei-daemon process (not workers)
1486         my ($lei, $sock) = @_;
1487         if ($sock //= $lei->{sock}) {
1488                 $LIVE_SOCK{"$sock"} = $sock;
1489                 $lei->{sto}->ipc_do('done', "$sock"); # issue, async wait
1490         } else { # forcibly wait
1491                 my $wait = $lei->{sto}->ipc_do('done');
1492         }
1493 }
1494
1495 sub sto_done_complete { # called in lei-daemon when LeiStore->done is complete
1496         my ($sock_str) = @_;
1497         delete $LIVE_SOCK{$sock_str}; # frees {sock} for waiting lei clients
1498 }
1499
1500 1;