lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 use Sys::Syslog qw(openlog syslog closelog);
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  33         $recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  41 our %LIVE_SOCK; # "GLOB(0x....)" => $lei->{sock}
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         my $cwd;
  81         if (defined $pwd) {
  82                 my $xcwd = $self->{3} //
  83                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  84                 if (my @st_pwd = stat($pwd)) {
  85                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  86                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  87                                 $self->{env}->{PWD} = $pwd = undef;
  88                 } else { # PWD was invalid
  89                         $self->{env}->{PWD} = $pwd = undef;
  90                 }
  91         }
  92         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  93         File::Spec->rel2abs($p, $pwd);
  94 }
  95
  96 # abs_path resolves symlinks in parent iff all parents exist
  97 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  98
  99 sub canonpath_harder {
 100         my $p = $_[-1]; # $_[0] may be self
 101         $p = File::Spec->canonpath($p);
 102         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 103 }
 104
 105 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 109                 .'/lei');
 110 }
 111
 112 sub store_path ($) { share_path($_[0]) . '/store' }
 113
 114 sub _config_path ($) {
 115         my ($self) = @_;
 116         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 117                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 118                 .'/lei/config');
 119 }
 120
 121 sub cache_dir ($) {
 122         my ($self) = @_;
 123         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 124                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 125                 .'/lei');
 126 }
 127
 128 sub url_folder_cache {
 129         my ($self) = @_;
 130         require PublicInbox::SharedKV; # URI => updated_at_sec_
 131         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 132 }
 133
 134 sub ale {
 135         my ($self) = @_;
 136         $self->{ale} //= do {
 137                 require PublicInbox::LeiALE;
 138                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 139         };
 140 }
 141
 142 sub index_opt {
 143         # TODO: drop underscore variants everywhere, they're undocumented
 144         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 145         max_size|max-size=s sequential-shard
 146         batch_size|batch-size=s skip-docdata)
 147 }
 148
 149 my @c_opt = qw(c=s@ C=s@ quiet|q);
 150 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 151 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 152         import-remote!);
 153
 154 # we don't support -C as an alias for --find-copies since it's already
 155 # used for chdir
 156 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 157         output-indicator-context=s indent-heuristic!
 158         minimal patience histogram anchored=s@ diff-algorithm=s
 159         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 160         word-diff:s word-diff-regex=s color-words:s no-renames
 161         rename-empty! check ws-error-highlight=s full-index binary
 162         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 163         find-copies-harder irreversible-delete|D l=i diff-filter=s
 164         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 165         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 166         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 167         inter-hunk-context=i function-context|W exit-code ext-diff
 168         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 169         line-prefix=s);
 170
 171 # we generate shell completion + help using %CMD and %OPTDESC,
 172 # see lei__complete() and PublicInbox::LeiHelp
 173 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 174 our %CMD = ( # sorted in order of importance/use:
 175 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 176         'stdin|', # /|\z/ must be first for lone dash
 177         @lxs_opt, @net_opt,
 178         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 179         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 180         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 181         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 182
 183 'up' => [ 'OUTPUT...|--all', 'update saved search',
 184         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 185
 186 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 187         'stdin|', # /|\z/ must be first for lone dash
 188         # some of these options are ridiculous for lcat
 189         @lxs_opt, @net_opt,
 190         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 191         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 192         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 193         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 194
 195 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 196         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 197         @lxs_opt, @net_opt, @c_opt ],
 198
 199 'rediff' => [ '--stdin|LOCATION...',
 200                 'regenerate a diff with different options',
 201         'stdin|', # /|\z/ must be first for lone dash
 202         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 203         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 204
 205 'add-external' => [ 'LOCATION',
 206         'add/set priority of a publicinbox|extindex for extra matches',
 207         qw(boost=i mirror=s inbox-version=i verbose|v+),
 208         @c_opt, index_opt(), @net_opt ],
 209 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 210         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 211 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 212 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 213                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 215                 qw(z|0 ascii l url), @c_opt ],
 216 'forget-external' => [ 'LOCATION...|--prune',
 217         'exclude further results from a publicinbox|extindex',
 218         qw(prune), @c_opt ],
 219
 220 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 221                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 222 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 223                 qw(verbose|v+), @c_opt ],
 224 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 225                         @c_opt ],
 226 'rm' => [ '--stdin|LOCATION...',
 227         'remove a message from the index and prevent reindexing',
 228         'stdin|', # /|\z/ must be first for lone dash
 229         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 230 'plonk' => [ '--threads|--from=IDENT',
 231         'exclude mail matching From: or threads from non-Message-ID searches',
 232         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 233 'tag' => [ 'KEYWORDS...',
 234         'set/unset keywords and/or labels on message(s)',
 235         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 236         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 237
 238 'purge-mailsource' => [ 'LOCATION|--all',
 239         'remove imported messages from IMAP, Maildirs, and MH',
 240         qw(exact! all jobs:i indexed), @c_opt ],
 241
 242 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 243         qw(poll-interval=s state=s recursive|r), @c_opt ],
 244 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 245         qw(recursive|r), @c_opt ],
 246 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 247                 qw(l z|0), @c_opt ],
 248 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 249 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 250 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 251         qw(prune), @c_opt ],
 252
 253 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 254         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 255         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 256          @c_opt ],
 257 'import' => [ 'LOCATION...|--stdin',
 258         'one-time import/update from URL or filesystem',
 259         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 260         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 261         @net_opt, @c_opt ],
 262 'forget-mail-sync' => [ 'LOCATION...',
 263         'forget sync information for a mail folder', @c_opt ],
 264 'prune-mail-sync' => [ 'LOCATION...|--all',
 265         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 266 'export-kw' => [ 'LOCATION...|--all',
 267         'one-time export of keywords of sync sources',
 268         qw(all:s mode=s), @net_opt, @c_opt ],
 269 'convert' => [ 'LOCATION...|--stdin',
 270         'one-time conversion from URL or filesystem to another format',
 271         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 272         @net_opt, @c_opt ],
 273 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 274         "use a patch to generate a query for `lei q --stdin'",
 275         qw(stdin| want|w=s@ uri debug), @c_opt ],
 276 'config' => [ '[...]', sub {
 277                 'git-config(1) wrapper for '._config_path($_[0]);
 278         }, qw(config-file|system|global|file|f=s), # for conflict detection
 279          qw(c=s@ C=s@), pass_through('git config') ],
 280 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 281         qw(stdin| pretty ascii dir=s), @c_opt ],
 282
 283 'init' => [ '[DIRNAME]', sub {
 284         "initialize storage, default: ".store_path($_[0]);
 285         }, @c_opt ],
 286 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 287         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 288         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 289 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 290 'help' => [ '[SUBCOMMAND]', 'show help' ],
 291
 292 # TODO
 293 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 294 #       'rewrite git history in an attempt to improve compression',
 295 #       qw(gc!), @c_opt ],
 296 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 297 #
 298 # internal commands are prefixed with '_'
 299 '_complete' => [ '[...]', 'internal shell completion helper',
 300                 pass_through('everything') ],
 301 ); # @CMD
 302
 303 # switch descriptions, try to keep consistent across commands
 304 # $spec: Getopt::Long option specification
 305 # $spec => [@ALLOWED_VALUES (default is first), $description],
 306 # $spec => $description
 307 # "$SUB_COMMAND TAB $spec" => as above
 308 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 309                         'specify message input format' ];
 310 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 311
 312 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 313 my %OPTDESC = (
 314 'help|h' => 'show this built-in help',
 315 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 316 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 317 'quiet|q' => 'be quiet',
 318 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 319         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 320
 321 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 322 'globoff|g' => "do not match locations using '*?' wildcards ".
 323                 "and\xa0'[]'\x{a0}ranges",
 324 'invert-match|v' => 'select non-matching lines',
 325 'color!' => 'disable color (for --format=text)',
 326 'verbose|v+' => 'be more verbose',
 327 'external!' => 'do not use externals',
 328 'mail!' => 'do not look in mail storage for OID',
 329 'cwd!' => 'do not look in git repo of current working directory',
 330 'oid-a|A=s' => 'pre-image OID',
 331 'path-a|a=s' => 'pre-image pathname associated with OID',
 332 'path-b|b=s' => 'post-image pathname associated with OID',
 333 'git-dir=s@' => 'additional git repository to scan',
 334 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 335 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 336         "proxy for (e.g. `socks5h://0:9050')" ],
 337 'torsocks=s' => ['VAL|auto|no|yes',
 338                 'whether or not to wrap git and curl commands with torsocks'],
 339 'no-torsocks' => 'alias for --torsocks=no',
 340 'save!' =>  "do not save a search for `lei up'",
 341 'import-remote!' => 'do not memoize remote messages into local store',
 342
 343 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 344
 345 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 346                 'deduplication strategy'],
 347 'threads|t+' =>
 348         'return all messages in the same threads as the actual match(es)',
 349
 350 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 351                 'search prefixes to extract (default: dfpost7)' ],
 352
 353 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 354         'run command(s) or perform ops when done writing to output ' .
 355         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 356         'nothing otherwise)' ],
 357
 358 'augment|a' => 'augment --output destination instead of clobbering',
 359
 360 'output|mfolder|o=s' => [ 'MFOLDER',
 361         "destination (e.g.\xa0`/path/to/Maildir', ".
 362         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 363 'mua=s' => [ 'CMD',
 364         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 365 'new-only       import' => 'only import new messages from IMAP source',
 366
 367 'inbox-version=i' => [ 'NUM|1|2',
 368                 'force a public-inbox version with --mirror'],
 369 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 370
 371 # public-inbox-index options
 372 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 373 'compact' => 'run compact index after mirroring',
 374 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 375         "indexlevel with --mirror (default: full)" ],
 376 'max_size|max-size=s' => [ 'SIZE',
 377         'do not index messages larger than SIZE (default: infinity)' ],
 378 'batch_size|batch-size=s' => [ 'SIZE',
 379         'flush changes to OS after given number of bytes (default: 1m)' ],
 380 'sequential-shard' =>
 381         'index Xapian shards sequentially for slow storage',
 382 'skip-docdata' =>
 383         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 384
 385 'format|f=s     q' => [
 386         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 387                 'specify output format, default depends on --output'],
 388 'exclude=s@     q' => [ 'LOCATION',
 389                 'exclude specified external(s) from search' ],
 390 'include|I=s@   q' => [ 'LOCATION',
 391                 'include specified external(s) in search' ],
 392 'only=s@        q' => [ 'LOCATION',
 393                 'only use specified external(s) for search' ],
 394 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 395                 'control number of search and writer jobs' ],
 396 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 397
 398 'in-format|F=s' => $stdin_formats,
 399 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 400                         'listing output format' ],
 401 'l      ls-search' => 'long listing format',
 402 'l      ls-watch' => 'long listing format',
 403 'l      ls-mail-source' => 'long listing format',
 404 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 405 'format|f=s     ls-external' => $ls_format,
 406
 407 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 408 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 409
 410 'sort|s=s' => [ 'VAL|received|relevance|docid',
 411                 "order of results is `--output'-dependent"],
 412 'reverse|r' => 'reverse search results', # like sort(1)
 413
 414 'boost=i' => 'increase/decrease priority of results (default: 0)',
 415
 416 'local' => 'limit operations to the local filesystem',
 417 'local!' => 'exclude results from the local filesystem',
 418 'remote' => 'limit operations to those requiring network access',
 419 'remote!' => 'prevent operations requiring network access',
 420
 421 'all:s  up' => ['local', 'update all (local) saved searches' ],
 422
 423 'mid=s' => 'specify the Message-ID of a message',
 424 'oid=s' => 'specify the git object ID of a message',
 425
 426 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 427 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 428 'include=s' => 'include mailboxes/newsgroups based on pattern',
 429
 430 'exact' => 'operate on exact header matches only',
 431 'exact!' => 'rely on content match instead of exact header matches',
 432
 433 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 434
 435 'kw!' => 'disable/enable importing keywords (aka "flags")',
 436
 437 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 438 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 439
 440 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 441 ); # %OPTDESC
 442
 443 my %CONFIG_KEYS = (
 444         'leistore.dir' => 'top-level storage location',
 445 );
 446
 447 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 448
 449 sub _drop_wq {
 450         my ($self) = @_;
 451         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 452                 if ($wq->wq_kill) {
 453                         $wq->wq_close(0, undef, $self);
 454                 } elsif ($wq->wq_kill_old) {
 455                         $wq->wq_wait_old(undef, $self);
 456                 }
 457                 $wq->DESTROY;
 458         }
 459 }
 460
 461 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 462 sub x_it ($$) {
 463         my ($self, $code) = @_;
 464         # make sure client sees stdout before exit
 465         $self->{1}->autoflush(1) if $self->{1};
 466         stop_pager($self);
 467         if ($self->{pkt_op_p}) { # to top lei-daemon
 468                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 469         } elsif ($self->{sock}) { # to lei(1) client
 470                 send($self->{sock}, "x_it $code", MSG_EOR);
 471         } # else ignore if client disconnected
 472 }
 473
 474 sub err ($;@) {
 475         my $self = shift;
 476         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 477         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 478         print $err @_, @eor and return;
 479         my $old_err = delete $self->{2};
 480         close($old_err) if $! == EPIPE && $old_err;
 481         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 482         print $err @_, @eor or print STDERR @_, @eor;
 483 }
 484
 485 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 486
 487 sub qfin { # show message on finalization (LeiFinmsg)
 488         my ($lei, $msg) = @_;
 489         return if $lei->{opt}->{quiet};
 490         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 491 }
 492
 493 sub fail_handler ($;$$) {
 494         my ($lei, $code, $io) = @_;
 495         close($io) if $io; # needed to avoid warnings on SIGPIPE
 496         _drop_wq($lei);
 497         x_it($lei, $code // (1 << 8));
 498 }
 499
 500 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 501         fail_handler($_[0], 13, delete $_[0]->{1});
 502 }
 503
 504 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 505 sub sigint_reap {
 506         my ($pgid) = @_;
 507         dwaitpid($pgid) if kill('-INT', $pgid);
 508 }
 509
 510 sub fail ($$;$) {
 511         my ($self, $buf, $exit_code) = @_;
 512         $self->{failed}++;
 513         err($self, $buf) if defined $buf;
 514         # calls fail_handler:
 515         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 516         x_it($self, ($exit_code // 1) << 8);
 517         undef;
 518 }
 519
 520 sub out ($;@) {
 521         my $self = shift;
 522         return if print { $self->{1} // return } @_; # likely
 523         return note_sigpipe($self, 1) if $! == EPIPE;
 524         my $err = "error writing to output: $!";
 525         delete $self->{1};
 526         fail($self, $err);
 527 }
 528
 529 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 530
 531 sub child_error { # passes non-fatal curl exit codes to user
 532         my ($self, $child_error, $msg) = @_; # child_error is $?
 533         $child_error ||= 1 << 8;
 534         $self->err($msg) if $msg;
 535         if ($self->{pkt_op_p}) { # to top lei-daemon
 536                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 537         } elsif ($self->{sock}) { # to lei(1) client
 538                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 539         } # else noop if client disconnected
 540 }
 541
 542 sub note_sigpipe { # triggers sigpipe_handler
 543         my ($self, $fd) = @_;
 544         close(delete($self->{$fd})); # explicit close silences Perl warning
 545         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 546         x_it($self, 13);
 547 }
 548
 549 sub _lei_atfork_child {
 550         my ($self, $persist) = @_;
 551         # we need to explicitly close things which are on stack
 552         if ($persist) {
 553                 chdir '/' or die "chdir(/): $!";
 554                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 555                 if (my $cfg = $self->{cfg}) {
 556                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 557                 }
 558         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 559                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 560                 STDERR->autoflush(1);
 561         }
 562         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 563         if (my $op_c = delete $self->{pkt_op_c}) {
 564                 close(delete $op_c->{sock});
 565         }
 566         if (my $pgr = delete $self->{pgr}) {
 567                 close($_) for (@$pgr[1,2]);
 568         }
 569         close $listener if $listener;
 570         undef $listener;
 571         $dir_idle->force_close if $dir_idle;
 572         %PATH2CFG = ();
 573         $MDIR2CFGPATH = {};
 574         %LIVE_SOCK = ();
 575         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 576         undef $errors_log;
 577         $quit = \&CORE::exit;
 578         $self->{-eml_noisy} or # only "lei import" sets this atm
 579                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 580         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 581 }
 582
 583 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 584         my ($self) = @_;
 585         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 586                 $op->close; # PublicInbox::PktOp::close
 587         }
 588         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 589         close $pkt_op_p->{op_p};
 590 }
 591
 592 sub pkt_op_pair {
 593         my ($self) = @_;
 594         require PublicInbox::OnDestroy;
 595         require PublicInbox::PktOp;
 596         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 597         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 598         $end;
 599 }
 600
 601 sub incr {
 602         my ($self, $field, $nr) = @_;
 603         $self->{counters}->{$field} += $nr;
 604 }
 605
 606 sub pkt_ops {
 607         my ($lei, $ops) = @_;
 608         $ops->{'!'} = [ \&fail_handler, $lei ];
 609         $ops->{'|'} = [ \&sigpipe_handler, $lei ];
 610         $ops->{x_it} = [ \&x_it, $lei ];
 611         $ops->{child_error} = [ \&child_error, $lei ];
 612         $ops->{incr} = [ \&incr, $lei ];
 613         $ops;
 614 }
 615
 616 sub workers_start {
 617         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 618         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 619         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 620         my $end = $lei->pkt_op_pair;
 621         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 622         $flds->{lei} = $lei;
 623         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 624         delete $lei->{pkt_op_p};
 625         my $op_c = delete $lei->{pkt_op_c};
 626         @$end = ();
 627         $lei->event_step_init;
 628         ($op_c, $ops);
 629 }
 630
 631 # call this when we're ready to wait on events and yield to other clients
 632 sub wait_wq_events {
 633         my ($lei, $op_c, $ops) = @_;
 634         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 635                 $wq->wq_close(1);
 636         }
 637         $op_c->{ops} = $ops;
 638 }
 639
 640 sub _help {
 641         require PublicInbox::LeiHelp;
 642         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 643 }
 644
 645 sub optparse ($$$) {
 646         my ($self, $cmd, $argv) = @_;
 647         # allow _complete --help to complete, not show help
 648         return 1 if substr($cmd, 0, 1) eq '_';
 649         $self->{cmd} = $cmd;
 650         $OPT = $self->{opt} //= {};
 651         my $info = $CMD{$cmd} // [ '[...]' ];
 652         my ($proto, undef, @spec) = @$info;
 653         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 654         push @spec, qw(help|h);
 655         my $lone_dash;
 656         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 657                 $lone_dash = $spec[0];
 658                 $OPT->{$spec[0]} = \(my $var);
 659                 push @spec, '' => \$var;
 660         }
 661         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 662                 return _help($self, "bad arguments or options for $cmd");
 663         return _help($self) if $OPT->{help};
 664
 665         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 666
 667         # "-" aliases "stdin" or "clear"
 668         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 669
 670         my $i = 0;
 671         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 672         my ($err, $inf);
 673         my @args = split(/ /, $proto);
 674         for my $var (@args) {
 675                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 676                         $inf = defined($argv->[$i]) and last;
 677                         $var =~ s/\.\.\.\z//;
 678                         $err = "$var not supplied";
 679                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 680                         $argv->[$i++] // ($err = "$var not supplied");
 681                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 682                         $inf = 1;
 683                         last;
 684                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 685                         $i++;
 686                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 687                         $inf = 1 if index($var, '...') > 0;
 688                         my @or = split(/\|/, $var);
 689                         my $ok;
 690                         for my $o (@or) {
 691                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 692                                         my $sw = $1;
 693                                         # assume pipe/regular file on stdin
 694                                         # w/o args means stdin
 695                                         if ($sw eq 'stdin' && !@$argv &&
 696                                                         (-p $self->{0} ||
 697                                                          -f _) && -r _) {
 698                                                 $OPT->{stdin} //= 1;
 699                                         }
 700                                         $ok = defined($OPT->{$sw});
 701                                         last if $ok;
 702                                 } elsif (defined($argv->[$i])) {
 703                                         $ok = 1;
 704                                         $i++;
 705                                         last;
 706                                 } # else continue looping
 707                         }
 708                         last if $ok;
 709                         my $last = pop @or;
 710                         $err = join(', ', @or) . " or $last must be set";
 711                 } else {
 712                         warn "BUG: can't parse `$var' in $proto";
 713                 }
 714                 last if $err;
 715         }
 716         if (!$inf && scalar(@$argv) > scalar(@args)) {
 717                 $err //= 'too many arguments';
 718         }
 719         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 720 }
 721
 722 sub _tmp_cfg { # for lei -c <name>=<value> ...
 723         my ($self) = @_;
 724         my $cfg = _lei_cfg($self, 1);
 725         require File::Temp;
 726         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 727         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 728         $ft->autoflush(1);
 729         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 730 [include]
 731         path = $cfg->{-f}
 732 EOM
 733         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 734         for (@{$self->{opt}->{c}}) {
 735                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 736 `-c $_' is not of the form -c <name>=<value>'
 737 EOM
 738                 my $name = $1;
 739                 my $value = $2 // 1;
 740                 _config($self, '--add', $name, $value);
 741                 if (defined(my $v = $tmp->{$name})) {
 742                         if (ref($v) eq 'ARRAY') {
 743                                 push @$v, $value;
 744                         } else {
 745                                 $tmp->{$name} = [ $v, $value ];
 746                         }
 747                 } else {
 748                         $tmp->{$name} = $value;
 749                 }
 750         }
 751 }
 752
 753 sub lazy_cb ($$$) {
 754         my ($self, $cmd, $pfx) = @_;
 755         my $ucmd = $cmd;
 756         $ucmd =~ tr/-/_/;
 757         my $cb;
 758         $cb = $self->can($pfx.$ucmd) and return $cb;
 759         my $base = $ucmd;
 760         $base =~ s/_([a-z])/\u$1/g;
 761         my $pkg = "PublicInbox::Lei\u$base";
 762         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 763                 $pkg->can($pfx.$ucmd) : undef;
 764 }
 765
 766 sub dispatch {
 767         my ($self, $cmd, @argv) = @_;
 768         local $current_lei = $self; # for __WARN__
 769         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 770         return _help($self, 'no command given') unless defined($cmd);
 771         # do not support Getopt bundling for this
 772         while ($cmd eq '-C' || $cmd eq '-c') {
 773                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 774                                         '-C DIRECTORY' : '-c <name>=<value>');
 775                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 776                 $cmd = shift(@argv) // return _help($self, 'no command given');
 777         }
 778         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 779                 optparse($self, $cmd, \@argv) or return;
 780                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 781                 if (my $chdir = $self->{opt}->{C}) {
 782                         for my $d (@$chdir) {
 783                                 next if $d eq ''; # same as git(1)
 784                                 chdir $d or return fail($self, "cd $d: $!");
 785                         }
 786                         open $self->{3}, '.' or return fail($self, "open . $!");
 787                 }
 788                 $cb->($self, @argv);
 789         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 790                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 791                         or return _help($self, 'bad arguments or options');
 792                 _help($self);
 793         } else {
 794                 fail($self, "`$cmd' is not an lei command");
 795         }
 796 }
 797
 798 sub _lei_cfg ($;$) {
 799         my ($self, $creat) = @_;
 800         return $self->{cfg} if $self->{cfg};
 801         my $f = _config_path($self);
 802         my @st = stat($f);
 803         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 804         my ($sto, $sto_dir, $watches, $lne);
 805         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 806                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 807                 ($sto, $sto_dir, $watches, $lne) =
 808                                 @$cfg{qw(-lei_store leistore.dir -watches
 809                                         -lei_note_event)};
 810         }
 811         if (!@st) {
 812                 unless ($creat) {
 813                         delete $self->{cfg};
 814                         return bless {}, 'PublicInbox::Config';
 815                 }
 816                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 817                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 818                 open my $fh, '>>', $f or die "open($f): $!\n";
 819                 @st = stat($fh) or die "fstat($f): $!\n";
 820                 $cur_st = pack('dd', $st[10], $st[7]);
 821                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 822         }
 823         my $cfg = PublicInbox::Config->git_config_dump($f);
 824         $cfg->{-st} = $cur_st;
 825         $cfg->{'-f'} = $f;
 826         if ($sto && canonpath_harder($sto_dir // store_path($self))
 827                         eq canonpath_harder($cfg->{'leistore.dir'} //
 828                                                 store_path($self))) {
 829                 $cfg->{-lei_store} = $sto;
 830                 $cfg->{-lei_note_event} = $lne;
 831                 $cfg->{-watches} = $watches if $watches;
 832         }
 833         if (scalar(keys %PATH2CFG) > 5) {
 834                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 835                 for my $k (keys %PATH2CFG) {
 836                         delete($PATH2CFG{$k}) unless -f $k
 837                 }
 838         }
 839         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 840         refresh_watches($self);
 841         $cfg;
 842 }
 843
 844 sub _lei_store ($;$) {
 845         my ($self, $creat) = @_;
 846         my $cfg = _lei_cfg($self, $creat) // return;
 847         $cfg->{-lei_store} //= do {
 848                 require PublicInbox::LeiStore;
 849                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 850                 return unless $creat || -d $dir;
 851                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 852         };
 853 }
 854
 855 sub _config {
 856         my ($self, @argv) = @_;
 857         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 858         my $cfg = _lei_cfg($self, 1);
 859         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 860         my %rdr = map { $_ => $self->{$_} } (0..2);
 861         waitpid(spawn($cmd, \%env, \%rdr), 0);
 862 }
 863
 864 sub lei_config {
 865         my ($self, @argv) = @_;
 866         $self->{opt}->{'config-file'} and return fail $self,
 867                 "config file switches not supported by `lei config'";
 868         _config(@_);
 869         x_it($self, $?) if $?;
 870 }
 871
 872 sub lei_daemon_pid { puts shift, $$ }
 873
 874 sub lei_daemon_kill {
 875         my ($self) = @_;
 876         my $sig = $self->{opt}->{signal} // 'TERM';
 877         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 878 }
 879
 880 # Shell completion helper.  Used by lei-completion.bash and hopefully
 881 # other shells.  Try to do as much here as possible to avoid redundancy
 882 # and improve maintainability.
 883 sub lei__complete {
 884         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 885         shift @argv; # ignore "lei", the entire command is sent
 886         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 887         my $cmd = shift @argv;
 888         my $info = $CMD{$cmd} // do { # filter matching commands
 889                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 890                 return;
 891         };
 892         my ($proto, undef, @spec) = @$info;
 893         my $cur = pop @argv;
 894         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 895         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 896                 # gross special case since the only git-config options
 897                 # Consider moving to a table if we need more special cases
 898                 # we use Getopt::Long for are the ones we reject, so these
 899                 # are the ones we don't reject:
 900                 if ($cmd eq 'config') {
 901                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 902                         @spec = qw(add z|null get get-all unset unset-all
 903                                 replace-all get-urlmatch
 904                                 remove-section rename-section
 905                                 name-only list|l edit|e
 906                                 get-color-name get-colorbool);
 907                         # fall-through
 908                 }
 909                 # generate short/long names from Getopt::Long specs
 910                 puts $self, grep(/$re/, qw(--help -h -C), map {
 911                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 912                         } elsif (s/\+\z//) { # verbose|v+
 913                         } elsif (s/!\z//) {
 914                                 # negation: mail! => no-mail|mail
 915                                 s/([\w\-]+)/$1|no-$1/g
 916                         }
 917                         map {
 918                                 my $x = length > 1 ? "--$_" : "-$_";
 919                                 $x eq $_cur ? () : $x;
 920                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 921                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 922         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 923                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 924         }
 925
 926         # switch args (e.g. lei q -f mbox<TAB>)
 927         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 928                 my $opt = quotemeta $1;
 929                 puts $self, map {
 930                         my $v = $OPTDESC{$_};
 931                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 932                         # get rid of ALL CAPS placeholder (e.g "OUT")
 933                         # (TODO: completion for external paths)
 934                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 935                         @v;
 936                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 937         }
 938         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 939                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 940         }
 941         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 942         # proto parsing.
 943 }
 944
 945 sub exec_buf ($$) {
 946         my ($argv, $env) = @_;
 947         my $argc = scalar @$argv;
 948         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 949         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 950         $buf;
 951 }
 952
 953 sub start_mua {
 954         my ($self) = @_;
 955         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 956                 refresh_watches($self);
 957         }
 958         my $mua = $self->{opt}->{mua} // return;
 959         my $mfolder = $self->{ovv}->{dst};
 960         my (@cmd, $replaced);
 961         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 962                 @cmd = ($mua, '-f');
 963         # TODO: help wanted: other common FOSS MUAs
 964         } else {
 965                 require Text::ParseWords;
 966                 @cmd = Text::ParseWords::shellwords($mua);
 967                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 968                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 969         }
 970         push @cmd, $mfolder unless defined($replaced);
 971         if ($self->{sock}) { # lei(1) client process runs it
 972                 # restore terminal: echo $query | lei q --stdin --mua=...
 973                 my $io = [];
 974                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 975                 send_exec_cmd($self, $io, \@cmd, {});
 976         }
 977         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 978                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 979         }
 980         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 981         $self->{opt}->{quiet} = 1;
 982         delete $self->{-progress};
 983         delete $self->{opt}->{verbose};
 984 }
 985
 986 sub send_exec_cmd { # tell script/lei to execute a command
 987         my ($self, $io, $cmd, $env) = @_;
 988         my $sock = $self->{sock} // die 'lei client gone';
 989         my $fds = [ map { fileno($_) } @$io ];
 990         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 991 }
 992
 993 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 994         my ($self) = @_;
 995         my $alerts = $self->{opt}->{alert} // return;
 996         my $sock = $self->{sock};
 997         while (my $op = shift(@$alerts)) {
 998                 if ($op eq ':WINCH') {
 999                         # hit the process group that started the MUA
1000                         send($sock, '-WINCH', MSG_EOR) if $sock;
1001                 } elsif ($op eq ':bell') {
1002                         out($self, "\a");
1003                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1004                         push @$alerts, split(/(?<!\\),/, $op);
1005                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1006                         my $cmd = $1; # run an arbitrary command
1007                         require Text::ParseWords;
1008                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1009                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1010                 } else {
1011                         err($self, "W: unsupported --alert=$op"); # non-fatal
1012                 }
1013         }
1014 }
1015
1016 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1017 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1018
1019 # this also normalizes the path
1020 sub path_to_fd {
1021         my ($self, $path) = @_;
1022         $path = rel2abs($self, $path);
1023         $path =~ tr!/!/!s;
1024         $path_to_fd{$path} // (
1025                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1026                         fail($self, "cannot open $path from daemon") : -1
1027         );
1028 }
1029
1030 # caller needs to "-t $self->{1}" to check if tty
1031 sub start_pager {
1032         my ($self) = @_;
1033         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1034         chomp(my $pager = <$fh> // '');
1035         close($fh) or warn "`git var PAGER' error: \$?=$?";
1036         return if $pager eq 'cat' || $pager eq '';
1037         my $new_env = { LESS => 'FRX', LV => '-c' };
1038         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1039         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1040         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1041         my $pgr = [ undef, @$rdr{1, 2} ];
1042         my $env = $self->{env};
1043         if ($self->{sock}) { # lei(1) process runs it
1044                 delete @$new_env{keys %$env}; # only set iff unset
1045                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1046         } else {
1047                 die 'BUG: start_pager w/o socket';
1048         }
1049         $self->{1} = $wpager;
1050         $self->{2} = $wpager if -t $self->{2};
1051         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1052         $self->{pgr} = $pgr;
1053 }
1054
1055 sub stop_pager {
1056         my ($self) = @_;
1057         my $pgr = delete($self->{pgr}) or return;
1058         $self->{2} = $pgr->[2];
1059         # do not restore original stdout, just close it so we error out
1060         close(delete($self->{1})) if $self->{1};
1061 }
1062
1063 sub accept_dispatch { # Listener {post_accept} callback
1064         my ($sock) = @_; # ignore other
1065         $sock->autoflush(1);
1066         my $self = bless { sock => $sock }, __PACKAGE__;
1067         vec(my $rvec = '', fileno($sock), 1) = 1;
1068         select($rvec, undef, undef, 60) or
1069                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1070         # (4096 * 33) >MAX_ARG_STRLEN
1071         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1072         if (!defined($fds[0])) {
1073                 warn(my $msg = "recv_cmd failed: $!");
1074                 return send($sock, $msg, MSG_EOR);
1075         } else {
1076                 my $i = 0;
1077                 for my $fd (@fds) {
1078                         open($self->{$i++}, '+<&=', $fd) and next;
1079                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1080                 }
1081                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1082         }
1083         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1084         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1085         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1086                 return send($sock, 'request command truncated', MSG_EOR);
1087         my ($argc, @argv) = split(/\0/, $buf, -1);
1088         undef $buf;
1089         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1090         if (chdir($self->{3})) {
1091                 local %ENV = %env;
1092                 $self->{env} = \%env;
1093                 eval { dispatch($self, @argv) };
1094                 send($sock, $@, MSG_EOR) if $@;
1095         } else {
1096                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1097         }
1098 }
1099
1100 sub dclose {
1101         my ($self) = @_;
1102         delete $self->{-progress};
1103         _drop_wq($self) if $self->{failed};
1104         close(delete $self->{1}) if $self->{1}; # may reap_compress
1105         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1106 }
1107
1108 # for long-running results
1109 sub event_step {
1110         my ($self) = @_;
1111         local %ENV = %{$self->{env}};
1112         my $sock = $self->{sock};
1113         local $current_lei = $self;
1114         eval {
1115                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1116                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1117                                 return if $! == EAGAIN;
1118                                 next if $! == EINTR;
1119                                 last if $! == ECONNRESET;
1120                                 die "recvmsg: $!";
1121                         }
1122                         for my $fd (@fds) {
1123                                 open my $rfh, '+<&=', $fd;
1124                         }
1125                         die "unrecognized client signal: $buf";
1126                 }
1127                 _drop_wq($self); # EOF, client disconnected
1128                 dclose($self);
1129         };
1130         if (my $err = $@) {
1131                 eval { $self->fail($err) };
1132                 dclose($self);
1133         }
1134 }
1135
1136 sub event_step_init {
1137         my ($self) = @_;
1138         my $sock = $self->{sock} or return;
1139         $self->{-event_init_done} //= do { # persist til $ops done
1140                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1141                 $sock;
1142         };
1143 }
1144
1145 sub noop {}
1146
1147 sub oldset { $oldset }
1148
1149 sub dump_and_clear_log {
1150         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1151                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1152                 chomp(my @lines = <STDIN>);
1153                 truncate(STDIN, 0) or
1154                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1155                 for my $l (@lines) { syslog('warning', '%s', $l) }
1156                 closelog(); # don't share across fork
1157         }
1158 }
1159
1160 sub cfg2lei ($) {
1161         my ($cfg) = @_;
1162         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1163         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1164         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1165         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1166         open($lei->{3}, '/') or die "open /: $!";
1167         chdir($lei->{3}) or die "chdir /': $!";
1168         my ($x, $y);
1169         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1170         $lei->{sock} = $x;
1171         require PublicInbox::LeiSelfSocket;
1172         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1173         $lei;
1174 }
1175
1176 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1177         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1178         my $fn = $ev->fullname;
1179         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1180                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1181                 $nc = '' if $ev->IN_DELETE;
1182                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1183                         my $cfg = $PATH2CFG{$f} // next;
1184                         eval {
1185                                 local %ENV = %{$cfg->{-env}};
1186                                 my $lei = cfg2lei($cfg);
1187                                 $lei->dispatch('note-event',
1188                                                 "maildir:$mdir", $nc, $bn, $fn);
1189                         };
1190                         warn "E note-event $f: $@\n" if $@;
1191                 }
1192         }
1193         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1194                 $ev->cancel;
1195         }
1196         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1197                 delete $MDIR2CFGPATH->{$1};
1198         }
1199         if (!-e $fn) { # config file or Maildir gone
1200                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1201                         delete $cfgpaths->{$fn};
1202                 }
1203                 delete $PATH2CFG{$fn};
1204         }
1205 }
1206
1207 # lei(1) calls this when it can't connect
1208 sub lazy_start {
1209         my ($path, $errno, $narg) = @_;
1210         local ($errors_log, $listener);
1211         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1212         $errors_log = "$sock_dir/errors.log";
1213         my $addr = pack_sockaddr_un($path);
1214         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1215         $lk->lock_acquire;
1216         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1217         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1218                 return if connect($listener, $addr); # another process won
1219                 if ($errno == ECONNREFUSED && -S $path) {
1220                         unlink($path) or die "unlink($path): $!";
1221                 }
1222         } else {
1223                 $! = $errno; # allow interpolation to stringify in die
1224                 die "connect($path): $!";
1225         }
1226         umask(077) // die("umask(077): $!");
1227         bind($listener, $addr) or die "bind($path): $!";
1228         $lk->lock_release;
1229         undef $lk;
1230         my @st = stat($path) or die "stat($path): $!";
1231         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1232         local $oldset = PublicInbox::DS::block_signals();
1233         if ($narg == 5) {
1234                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1235                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1236                         require PublicInbox::CmdIPC4;
1237                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1238                         PublicInbox::CmdIPC4->can('recv_cmd4');
1239                 };
1240         }
1241         $recv_cmd or die <<"";
1242 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1243
1244         require PublicInbox::Listener;
1245         require PublicInbox::PktOp;
1246         (-p STDOUT) or die "E: stdout must be a pipe\n";
1247         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1248         STDIN->autoflush(1);
1249         dump_and_clear_log();
1250         POSIX::setsid() > 0 or die "setsid: $!";
1251         my $pid = fork // die "fork: $!";
1252         return if $pid;
1253         $0 = "lei-daemon $path";
1254         local %PATH2CFG;
1255         local $MDIR2CFGPATH;
1256         $listener->blocking(0);
1257         my $exit_code;
1258         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1259         local $quit = do {
1260                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1261                 sub {
1262                         $exit_code //= shift;
1263                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1264                         my $lis = $pil or exit($exit_code);
1265                         # closing eof_p triggers \&noop wakeup
1266                         $listener = $eof_p = $pil = $path = undef;
1267                         $lis->close; # DS::close
1268                         PublicInbox::DS->SetLoopTimeout(1000);
1269                 };
1270         };
1271         my $sig = {
1272                 CHLD => \&PublicInbox::DS::enqueue_reap,
1273                 QUIT => $quit,
1274                 INT => $quit,
1275                 TERM => $quit,
1276                 HUP => \&noop,
1277                 USR1 => \&noop,
1278                 USR2 => \&noop,
1279         };
1280         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1281         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1282         undef $sig;
1283         local $SIG{PIPE} = 'IGNORE';
1284         require PublicInbox::DirIdle;
1285         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1286                 # just rely on wakeup to hit PostLoopCallback set below
1287                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1288         }, 1);
1289         if ($sigfd) {
1290                 undef $sigfd; # unref, already in DS::DescriptorMap
1291         } else {
1292                 # wake up every second to accept signals if we don't
1293                 # have signalfd or IO::KQueue:
1294                 PublicInbox::DS::sig_setmask($oldset);
1295                 PublicInbox::DS->SetLoopTimeout(1000);
1296         }
1297         PublicInbox::DS->SetPostLoopCallback(sub {
1298                 my ($dmap, undef) = @_;
1299                 if (@st = defined($path) ? stat($path) : ()) {
1300                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1301                                 warn "$path dev/ino changed, quitting\n";
1302                                 $path = undef;
1303                         }
1304                 } elsif (defined($path)) { # ENOENT is common
1305                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1306                         undef $path;
1307                         $quit->();
1308                 }
1309                 return 1 if defined($path);
1310                 my $now = now();
1311                 my $n = 0;
1312                 for my $s (values %$dmap) {
1313                         $s->can('busy') or next;
1314                         if ($s->busy($now)) {
1315                                 ++$n;
1316                         } else {
1317                                 $s->close;
1318                         }
1319                 }
1320                 $n; # true: continue, false: stop
1321         });
1322
1323         # STDIN was redirected to /dev/null above, closing STDERR and
1324         # STDOUT will cause the calling `lei' client process to finish
1325         # reading the <$daemon> pipe.
1326         local $SIG{__WARN__} = sub {
1327                 $current_lei ? err($current_lei, @_) : warn(
1328                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1329         };
1330         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1331         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1332         # $daemon pipe to `lei' closed, main loop begins:
1333         PublicInbox::DS->EventLoop;
1334         dump_and_clear_log();
1335         exit($exit_code // 0);
1336 }
1337
1338 sub busy { 1 } # prevent daemon-shutdown if client is connected
1339
1340 # ensures stdout hits the FS before sock disconnects so a client
1341 # can immediately reread it
1342 sub DESTROY {
1343         my ($self) = @_;
1344         if (my $counters = delete $self->{counters}) {
1345                 for my $k (sort keys %$counters) {
1346                         my $nr = $counters->{$k};
1347                         $self->child_error(0, "$nr $k messages");
1348                 }
1349         }
1350         $self->{1}->autoflush(1) if $self->{1};
1351         stop_pager($self);
1352         dump_and_clear_log();
1353         # preserve $? for ->fail or ->x_it code
1354 }
1355
1356 sub wq_done_wait { # dwaitpid callback
1357         my ($arg, $pid) = @_;
1358         my ($wq, $lei) = @$arg;
1359         my $err_type = $lei->{-err_type};
1360         $? and $lei->child_error($?,
1361                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1362         $lei->dclose;
1363 }
1364
1365 sub fchdir {
1366         my ($lei) = @_;
1367         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1368         chdir($dh) || $lei->fail("fchdir: $!");
1369 }
1370
1371 sub wq_eof { # EOF callback for main daemon
1372         my ($lei) = @_;
1373         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1374         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1375 }
1376
1377 sub watch_state_ok ($) {
1378         my ($state) = $_[-1]; # $_[0] may be $self
1379         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1380 }
1381
1382 sub cancel_maildir_watch ($$) {
1383         my ($d, $cfg_f) = @_;
1384         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1385         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1386                 delete $MDIR2CFGPATH->{$d};
1387         for my $x (@{$w // []}) { $x->cancel }
1388 }
1389
1390 sub add_maildir_watch ($$) {
1391         my ($d, $cfg_f) = @_;
1392         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1393                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1394                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1395         }
1396 }
1397
1398 sub refresh_watches {
1399         my ($lei) = @_;
1400         my $cfg = _lei_cfg($lei) or return;
1401         my $old = $cfg->{-watches};
1402         my $watches = $cfg->{-watches} //= {};
1403         my %seen;
1404         my $cfg_f = $cfg->{'-f'};
1405         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1406                 my $url = substr($w, length('watch.'), -length('.state'));
1407                 require PublicInbox::LeiWatch;
1408                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1409                 $seen{$url} = undef;
1410                 my $state = $cfg->get_1("watch.$url", 'state');
1411                 if (!watch_state_ok($state)) {
1412                         $lei->err("watch.$url.state=$state not supported");
1413                         next;
1414                 }
1415                 if ($url =~ /\Amaildir:(.+)/i) {
1416                         my $d = canonpath_harder($1);
1417                         if ($state eq 'pause') {
1418                                 cancel_maildir_watch($d, $cfg_f);
1419                         } else {
1420                                 add_maildir_watch($d, $cfg_f);
1421                         }
1422                 } else { # TODO: imap/nntp/jmap
1423                         $lei->child_error(0, "E: watch $url not supported, yet")
1424                 }
1425         }
1426
1427         # add all known Maildir folders as implicit watches
1428         my $sto = $lei->_lei_store;
1429         my $renames = 0;
1430         if (my $lms = $sto ? $sto->search->lms : undef) {
1431                 for my $d ($lms->folders('maildir:')) {
1432                         substr($d, 0, length('maildir:')) = '';
1433                         my $cd = canonpath_harder($d);
1434                         my $f = "maildir:$cd";
1435
1436                         # fixup old bugs while we're iterating:
1437                         if ($d ne $cd) {
1438                                 $sto->ipc_do('lms_rename_folder',
1439                                                 "maildir:$d", $f);
1440                                 ++$renames;
1441                         }
1442                         next if $watches->{$f}; # may be set to pause
1443                         require PublicInbox::LeiWatch;
1444                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1445                         $seen{$f} = undef;
1446                         add_maildir_watch($cd, $cfg_f);
1447                 }
1448         }
1449         $lei->sto_done_request if $renames;
1450         if ($old) { # cull old non-existent entries
1451                 for my $url (keys %$old) {
1452                         next if exists $seen{$url};
1453                         delete $old->{$url};
1454                         if ($url =~ /\Amaildir:(.+)/i) {
1455                                 my $d = canonpath_harder($1);
1456                                 cancel_maildir_watch($d, $cfg_f);
1457                         } else { # TODO: imap/nntp/jmap
1458                                 $lei->child_error(0, "E: watch $url TODO");
1459                         }
1460                 }
1461         }
1462         if (scalar keys %$watches) {
1463                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1464         } else {
1465                 delete $cfg->{-watches};
1466         }
1467 }
1468
1469 sub git_blob_id {
1470         my ($lei, $eml) = @_;
1471         ($lei->{sto} // _lei_store($lei, 1))->git_blob_id($eml);
1472 }
1473
1474 sub lms { # read-only LeiMailSync
1475         my ($lei) = @_;
1476         my $lse = $lei->{lse} // do {
1477                 my $sto = $lei->{sto} // _lei_store($lei);
1478                 $sto ? $sto->search : undef
1479         };
1480         $lse ? $lse->lms : undef;
1481 }
1482
1483 sub sto_done_request { # only call this from lei-daemon process (not workers)
1484         my ($lei, $sock) = @_;
1485         if ($sock //= $lei->{sock}) {
1486                 $LIVE_SOCK{"$sock"} = $sock;
1487                 $lei->{sto}->ipc_do('done', "$sock"); # issue, async wait
1488         } else { # forcibly wait
1489                 my $wait = $lei->{sto}->ipc_do('done');
1490         }
1491 }
1492
1493 sub sto_done_complete { # called in lei-daemon when LeiStore->done is complete
1494         my ($sock_str) = @_;
1495         delete $LIVE_SOCK{$sock_str}; # frees {sock} for waiting lei clients
1496 }
1497
1498 1;