lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'export-kw' => [ 'LOCATION...|--all',
 249         'one-time export of keywords of sync sources',
 250         qw(all:s mode=s), @c_opt ],
 251 'convert' => [ 'LOCATION...|--stdin',
 252         'one-time conversion from URL or filesystem to another format',
 253         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 254         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 255 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 256         "use a patch to generate a query for `lei q --stdin'",
 257         qw(stdin| want|w=s@ uri debug), @c_opt ],
 258 'config' => [ '[...]', sub {
 259                 'git-config(1) wrapper for '._config_path($_[0]);
 260         }, qw(config-file|system|global|file|f=s), # for conflict detection
 261          qw(c=s@ C=s@), pass_through('git config') ],
 262 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 263         qw(pretty ascii dir=s), @c_opt ],
 264
 265 'init' => [ '[DIRNAME]', sub {
 266         "initialize storage, default: ".store_path($_[0]);
 267         }, @c_opt ],
 268 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 269         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 270         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 271 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 272 'help' => [ '[SUBCOMMAND]', 'show help' ],
 273
 274 # TODO
 275 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 276 #       'rewrite git history in an attempt to improve compression',
 277 #       qw(gc!), @c_opt ],
 278 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 279 #
 280 # internal commands are prefixed with '_'
 281 '_complete' => [ '[...]', 'internal shell completion helper',
 282                 pass_through('everything') ],
 283 ); # @CMD
 284
 285 # switch descriptions, try to keep consistent across commands
 286 # $spec: Getopt::Long option specification
 287 # $spec => [@ALLOWED_VALUES (default is first), $description],
 288 # $spec => $description
 289 # "$SUB_COMMAND TAB $spec" => as above
 290 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 291                         'specify message input format' ];
 292 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 293
 294 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 295 my %OPTDESC = (
 296 'help|h' => 'show this built-in help',
 297 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 298 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 299 'quiet|q' => 'be quiet',
 300 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 301         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 302
 303 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 304 'globoff|g' => "do not match locations using '*?' wildcards ".
 305                 "and\xa0'[]'\x{a0}ranges",
 306 'invert-match|v' => 'select non-matching lines',
 307 'color!' => 'disable color (for --format=text)',
 308 'verbose|v+' => 'be more verbose',
 309 'external!' => 'do not use externals',
 310 'mail!' => 'do not look in mail storage for OID',
 311 'cwd!' => 'do not look in git repo of current working directory',
 312 'oid-a|A=s' => 'pre-image OID',
 313 'path-a|a=s' => 'pre-image pathname associated with OID',
 314 'path-b|b=s' => 'post-image pathname associated with OID',
 315 'git-dir=s@' => 'additional git repository to scan',
 316 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 317         "proxy for (e.g. `socks5h://0:9050')" ],
 318 'torsocks=s' => ['VAL|auto|no|yes',
 319                 'whether or not to wrap git and curl commands with torsocks'],
 320 'no-torsocks' => 'alias for --torsocks=no',
 321 'save' =>  "save a search for `lei up'",
 322 'import-remote!' => 'do not memoize remote messages into local store',
 323
 324 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 325
 326 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 327                 'deduplication strategy'],
 328 'threads|t+' =>
 329         'return all messages in the same threads as the actual match(es)',
 330
 331 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 332                 'search prefixes to extract (default: dfpost7)' ],
 333
 334 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 335         'run command(s) or perform ops when done writing to output ' .
 336         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 337         'nothing otherwise)' ],
 338
 339 'augment|a' => 'augment --output destination instead of clobbering',
 340
 341 'output|mfolder|o=s' => [ 'MFOLDER',
 342         "destination (e.g.\xa0`/path/to/Maildir', ".
 343         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 344 'mua=s' => [ 'CMD',
 345         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 346
 347 'inbox-version=i' => [ 'NUM|1|2',
 348                 'force a public-inbox version with --mirror'],
 349 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 350
 351 # public-inbox-index options
 352 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 353 'compact' => 'run compact index after mirroring',
 354 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 355         "indexlevel with --mirror (default: full)" ],
 356 'max_size|max-size=s' => [ 'SIZE',
 357         'do not index messages larger than SIZE (default: infinity)' ],
 358 'batch_size|batch-size=s' => [ 'SIZE',
 359         'flush changes to OS after given number of bytes (default: 1m)' ],
 360 'sequential_shard|sequential-shard' =>
 361         'index Xapian shards sequentially for slow storage',
 362 'skip-docdata' =>
 363         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 364
 365 'format|f=s     q' => [
 366         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 367                 'specify output format, default depends on --output'],
 368 'exclude=s@     q' => [ 'LOCATION',
 369                 'exclude specified external(s) from search' ],
 370 'include|I=s@   q' => [ 'LOCATION',
 371                 'include specified external(s) in search' ],
 372 'only=s@        q' => [ 'LOCATION',
 373                 'only use specified external(s) for search' ],
 374 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 375                 'control number of search and writer jobs' ],
 376 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 377
 378 'in-format|F=s' => $stdin_formats,
 379 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 380                         'listing output format' ],
 381 'l      ls-search' => 'long listing format',
 382 'format|f=s     ls-external' => $ls_format,
 383
 384 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 385 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 386
 387 'sort|s=s' => [ 'VAL|received|relevance|docid',
 388                 "order of results is `--output'-dependent"],
 389 'reverse|r' => 'reverse search results', # like sort(1)
 390
 391 'boost=i' => 'increase/decrease priority of results (default: 0)',
 392
 393 'local' => 'limit operations to the local filesystem',
 394 'local!' => 'exclude results from the local filesystem',
 395 'remote' => 'limit operations to those requiring network access',
 396 'remote!' => 'prevent operations requiring network access',
 397
 398 'all:s  up' => ['local', 'update all (local) saved searches' ],
 399
 400 'mid=s' => 'specify the Message-ID of a message',
 401 'oid=s' => 'specify the git object ID of a message',
 402
 403 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 404 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 405 'include=s' => 'include mailboxes/newsgroups based on pattern',
 406
 407 'exact' => 'operate on exact header matches only',
 408 'exact!' => 'rely on content match instead of exact header matches',
 409
 410 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 411
 412 'kw!' => 'disable/enable importing keywords (aka "flags")',
 413
 414 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 415 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 416
 417 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 418 ); # %OPTDESC
 419
 420 my %CONFIG_KEYS = (
 421         'leistore.dir' => 'top-level storage location',
 422 );
 423
 424 my @WQ_KEYS = qw(lxs l2m wq1 ikw); # internal workers
 425
 426 sub _drop_wq {
 427         my ($self) = @_;
 428         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 429                 if ($wq->wq_kill) {
 430                         $wq->wq_close(0, undef, $self);
 431                 } elsif ($wq->wq_kill_old) {
 432                         $wq->wq_wait_old(undef, $self);
 433                 }
 434                 $wq->DESTROY;
 435         }
 436 }
 437
 438 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 439 sub x_it ($$) {
 440         my ($self, $code) = @_;
 441         # make sure client sees stdout before exit
 442         $self->{1}->autoflush(1) if $self->{1};
 443         dump_and_clear_log();
 444         if ($self->{pkt_op_p}) { # to top lei-daemon
 445                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 446         } elsif ($self->{sock}) { # to lei(1) client
 447                 send($self->{sock}, "x_it $code", MSG_EOR);
 448         } # else ignore if client disconnected
 449 }
 450
 451 sub err ($;@) {
 452         my $self = shift;
 453         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 454         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 455         print $err @_, @eor and return;
 456         my $old_err = delete $self->{2};
 457         close($old_err) if $! == EPIPE && $old_err;
 458         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         print $err @_, @eor or print STDERR @_, @eor;
 460 }
 461
 462 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 463
 464 sub fail_handler ($;$$) {
 465         my ($lei, $code, $io) = @_;
 466         close($io) if $io; # needed to avoid warnings on SIGPIPE
 467         _drop_wq($lei);
 468         x_it($lei, $code // (1 << 8));
 469 }
 470
 471 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 472         fail_handler($_[0], 13, delete $_[0]->{1});
 473 }
 474
 475 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 476 sub sigint_reap {
 477         my ($pgid) = @_;
 478         dwaitpid($pgid) if kill('-INT', $pgid);
 479 }
 480
 481 sub fail ($$;$) {
 482         my ($self, $buf, $exit_code) = @_;
 483         err($self, $buf) if defined $buf;
 484         # calls fail_handler:
 485         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 486         x_it($self, ($exit_code // 1) << 8);
 487         undef;
 488 }
 489
 490 sub out ($;@) {
 491         my $self = shift;
 492         return if print { $self->{1} // return } @_; # likely
 493         return note_sigpipe($self, 1) if $! == EPIPE;
 494         my $err = "error writing to output: $!";
 495         delete $self->{1};
 496         fail($self, $err);
 497 }
 498
 499 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 500
 501 sub child_error { # passes non-fatal curl exit codes to user
 502         my ($self, $child_error, $msg) = @_; # child_error is $?
 503         $self->err($msg) if $msg;
 504         if ($self->{pkt_op_p}) { # to top lei-daemon
 505                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 506         } elsif ($self->{sock}) { # to lei(1) client
 507                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 508         } # else noop if client disconnected
 509 }
 510
 511 sub note_sigpipe { # triggers sigpipe_handler
 512         my ($self, $fd) = @_;
 513         close(delete($self->{$fd})); # explicit close silences Perl warning
 514         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 515         x_it($self, 13);
 516 }
 517
 518 sub _lei_atfork_child {
 519         my ($self, $persist) = @_;
 520         # we need to explicitly close things which are on stack
 521         if ($persist) {
 522                 chdir '/' or die "chdir(/): $!";
 523                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 524                 if (my $cfg = $self->{cfg}) {
 525                         delete $cfg->{-lei_store};
 526                 }
 527         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 528                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 529                 STDERR->autoflush(1);
 530         }
 531         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 532         if (my $op_c = delete $self->{pkt_op_c}) {
 533                 close(delete $op_c->{sock});
 534         }
 535         if (my $pgr = delete $self->{pgr}) {
 536                 close($_) for (@$pgr[1,2]);
 537         }
 538         close $listener if $listener;
 539         undef $listener;
 540         undef $dir_idle;
 541         %PATH2CFG = ();
 542         undef $errors_log;
 543         $quit = \&CORE::exit;
 544         $self->{-eml_noisy} or # only "lei import" sets this atm
 545                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 546         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 547 }
 548
 549 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 550         my ($self) = @_;
 551         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 552                 $op->close; # PublicInbox::PktOp::close
 553         }
 554         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 555         close $pkt_op_p->{op_p};
 556 }
 557
 558 sub pkt_op_pair {
 559         my ($self) = @_;
 560         require PublicInbox::OnDestroy;
 561         require PublicInbox::PktOp;
 562         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 563         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 564         $end;
 565 }
 566
 567 sub workers_start {
 568         my ($lei, $wq, $jobs, $ops) = @_;
 569         $ops = {
 570                 '!' => [ \&fail_handler, $lei ],
 571                 '|' => [ \&sigpipe_handler, $lei ],
 572                 'x_it' => [ \&x_it, $lei ],
 573                 'child_error' => [ \&child_error, $lei ],
 574                 ($ops ? %$ops : ()),
 575         };
 576         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 577         my $end = $lei->pkt_op_pair;
 578         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 579         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 580         delete $lei->{pkt_op_p};
 581         my $op_c = delete $lei->{pkt_op_c};
 582         @$end = ();
 583         $lei->event_step_init;
 584         ($op_c, $ops);
 585 }
 586
 587 sub _help {
 588         require PublicInbox::LeiHelp;
 589         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 590 }
 591
 592 sub optparse ($$$) {
 593         my ($self, $cmd, $argv) = @_;
 594         # allow _complete --help to complete, not show help
 595         return 1 if substr($cmd, 0, 1) eq '_';
 596         $self->{cmd} = $cmd;
 597         $OPT = $self->{opt} //= {};
 598         my $info = $CMD{$cmd} // [ '[...]' ];
 599         my ($proto, undef, @spec) = @$info;
 600         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 601         push @spec, qw(help|h);
 602         my $lone_dash;
 603         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 604                 $lone_dash = $spec[0];
 605                 $OPT->{$spec[0]} = \(my $var);
 606                 push @spec, '' => \$var;
 607         }
 608         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 609                 return _help($self, "bad arguments or options for $cmd");
 610         return _help($self) if $OPT->{help};
 611
 612         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 613
 614         # "-" aliases "stdin" or "clear"
 615         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 616
 617         my $i = 0;
 618         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 619         my ($err, $inf);
 620         my @args = split(/ /, $proto);
 621         for my $var (@args) {
 622                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 623                         $inf = defined($argv->[$i]) and last;
 624                         $var =~ s/\.\.\.\z//;
 625                         $err = "$var not supplied";
 626                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 627                         $argv->[$i++] // ($err = "$var not supplied");
 628                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 629                         $inf = 1;
 630                         last;
 631                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 632                         $i++;
 633                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 634                         $inf = 1 if index($var, '...') > 0;
 635                         my @or = split(/\|/, $var);
 636                         my $ok;
 637                         for my $o (@or) {
 638                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 639                                         my $sw = $1;
 640                                         # assume pipe/regular file on stdin
 641                                         # w/o args means stdin
 642                                         if ($sw eq 'stdin' && !@$argv &&
 643                                                         (-p $self->{0} ||
 644                                                          -f _) && -r _) {
 645                                                 $OPT->{stdin} //= 1;
 646                                         }
 647                                         $ok = defined($OPT->{$sw});
 648                                         last if $ok;
 649                                 } elsif (defined($argv->[$i])) {
 650                                         $ok = 1;
 651                                         $i++;
 652                                         last;
 653                                 } # else continue looping
 654                         }
 655                         last if $ok;
 656                         my $last = pop @or;
 657                         $err = join(', ', @or) . " or $last must be set";
 658                 } else {
 659                         warn "BUG: can't parse `$var' in $proto";
 660                 }
 661                 last if $err;
 662         }
 663         if (!$inf && scalar(@$argv) > scalar(@args)) {
 664                 $err //= 'too many arguments';
 665         }
 666         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 667 }
 668
 669 sub _tmp_cfg { # for lei -c <name>=<value> ...
 670         my ($self) = @_;
 671         my $cfg = _lei_cfg($self, 1);
 672         require File::Temp;
 673         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 674         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 675         $ft->autoflush(1);
 676         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 677 [include]
 678         path = $cfg->{-f}
 679 EOM
 680         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 681         for (@{$self->{opt}->{c}}) {
 682                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 683 `-c $_' is not of the form -c <name>=<value>'
 684 EOM
 685                 my $name = $1;
 686                 my $value = $2 // 1;
 687                 _config($self, '--add', $name, $value);
 688                 if (defined(my $v = $tmp->{$name})) {
 689                         if (ref($v) eq 'ARRAY') {
 690                                 push @$v, $value;
 691                         } else {
 692                                 $tmp->{$name} = [ $v, $value ];
 693                         }
 694                 } else {
 695                         $tmp->{$name} = $value;
 696                 }
 697         }
 698 }
 699
 700 sub lazy_cb ($$$) {
 701         my ($self, $cmd, $pfx) = @_;
 702         my $ucmd = $cmd;
 703         $ucmd =~ tr/-/_/;
 704         my $cb;
 705         $cb = $self->can($pfx.$ucmd) and return $cb;
 706         my $base = $ucmd;
 707         $base =~ s/_([a-z])/\u$1/g;
 708         my $pkg = "PublicInbox::Lei\u$base";
 709         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 710                 $pkg->can($pfx.$ucmd) : undef;
 711 }
 712
 713 sub dispatch {
 714         my ($self, $cmd, @argv) = @_;
 715         local $current_lei = $self; # for __WARN__
 716         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 717         dump_and_clear_log("from previous run\n");
 718         return _help($self, 'no command given') unless defined($cmd);
 719         # do not support Getopt bundling for this
 720         while ($cmd eq '-C' || $cmd eq '-c') {
 721                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 722                                         '-C DIRECTORY' : '-c <name>=<value>');
 723                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 724                 $cmd = shift(@argv) // return _help($self, 'no command given');
 725         }
 726         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 727                 optparse($self, $cmd, \@argv) or return;
 728                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 729                 if (my $chdir = $self->{opt}->{C}) {
 730                         for my $d (@$chdir) {
 731                                 next if $d eq ''; # same as git(1)
 732                                 chdir $d or return fail($self, "cd $d: $!");
 733                         }
 734                         if (delete $self->{3}) { # update cwd for rel2abs
 735                                 opendir my $dh, '.' or
 736                                         return fail($self, "opendir . $!");
 737                                 $self->{3} = $dh;
 738                         }
 739                 }
 740                 $cb->($self, @argv);
 741         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 742                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 743                         or return _help($self, 'bad arguments or options');
 744                 _help($self);
 745         } else {
 746                 fail($self, "`$cmd' is not an lei command");
 747         }
 748 }
 749
 750 sub _lei_cfg ($;$) {
 751         my ($self, $creat) = @_;
 752         return $self->{cfg} if $self->{cfg};
 753         my $f = _config_path($self);
 754         my @st = stat($f);
 755         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 756         my ($sto, $sto_dir);
 757         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 758                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 759                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 760         }
 761         if (!@st) {
 762                 unless ($creat) {
 763                         delete $self->{cfg};
 764                         return bless {}, 'PublicInbox::Config';
 765                 }
 766                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 767                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 768                 open my $fh, '>>', $f or die "open($f): $!\n";
 769                 @st = stat($fh) or die "fstat($f): $!\n";
 770                 $cur_st = pack('dd', $st[10], $st[7]);
 771                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 772         }
 773         my $cfg = PublicInbox::Config->git_config_dump($f);
 774         $cfg->{-st} = $cur_st;
 775         $cfg->{'-f'} = $f;
 776         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 777                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 778                                                 store_path($self))) {
 779                 $cfg->{-lei_store} = $sto;
 780         }
 781         if (scalar(keys %PATH2CFG) > 5) {
 782                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 783                 for my $k (keys %PATH2CFG) {
 784                         delete($PATH2CFG{$k}) unless -f $k
 785                 }
 786         }
 787         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 788 }
 789
 790 sub _lei_store ($;$) {
 791         my ($self, $creat) = @_;
 792         my $cfg = _lei_cfg($self, $creat);
 793         $cfg->{-lei_store} //= do {
 794                 require PublicInbox::LeiStore;
 795                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 796                 return unless $creat || -d $dir;
 797                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 798         };
 799 }
 800
 801 sub _config {
 802         my ($self, @argv) = @_;
 803         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 804         my $cfg = _lei_cfg($self, 1);
 805         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 806         my %rdr = map { $_ => $self->{$_} } (0..2);
 807         waitpid(spawn($cmd, \%env, \%rdr), 0);
 808 }
 809
 810 sub lei_config {
 811         my ($self, @argv) = @_;
 812         $self->{opt}->{'config-file'} and return fail $self,
 813                 "config file switches not supported by `lei config'";
 814         _config(@_);
 815         x_it($self, $?) if $?;
 816 }
 817
 818 sub lei_daemon_pid { puts shift, $$ }
 819
 820 sub lei_daemon_kill {
 821         my ($self) = @_;
 822         my $sig = $self->{opt}->{signal} // 'TERM';
 823         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 824 }
 825
 826 # Shell completion helper.  Used by lei-completion.bash and hopefully
 827 # other shells.  Try to do as much here as possible to avoid redundancy
 828 # and improve maintainability.
 829 sub lei__complete {
 830         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 831         shift @argv; # ignore "lei", the entire command is sent
 832         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 833         my $cmd = shift @argv;
 834         my $info = $CMD{$cmd} // do { # filter matching commands
 835                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 836                 return;
 837         };
 838         my ($proto, undef, @spec) = @$info;
 839         my $cur = pop @argv;
 840         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 841         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 842                 # gross special case since the only git-config options
 843                 # Consider moving to a table if we need more special cases
 844                 # we use Getopt::Long for are the ones we reject, so these
 845                 # are the ones we don't reject:
 846                 if ($cmd eq 'config') {
 847                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 848                         @spec = qw(add z|null get get-all unset unset-all
 849                                 replace-all get-urlmatch
 850                                 remove-section rename-section
 851                                 name-only list|l edit|e
 852                                 get-color-name get-colorbool);
 853                         # fall-through
 854                 }
 855                 # generate short/long names from Getopt::Long specs
 856                 puts $self, grep(/$re/, qw(--help -h -C), map {
 857                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 858                         } elsif (s/\+\z//) { # verbose|v+
 859                         } elsif (s/!\z//) {
 860                                 # negation: mail! => no-mail|mail
 861                                 s/([\w\-]+)/$1|no-$1/g
 862                         }
 863                         map {
 864                                 my $x = length > 1 ? "--$_" : "-$_";
 865                                 $x eq $_cur ? () : $x;
 866                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 867                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 868         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 869                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 870         }
 871
 872         # switch args (e.g. lei q -f mbox<TAB>)
 873         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 874                 my $opt = quotemeta $1;
 875                 puts $self, map {
 876                         my $v = $OPTDESC{$_};
 877                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 878                         # get rid of ALL CAPS placeholder (e.g "OUT")
 879                         # (TODO: completion for external paths)
 880                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 881                         @v;
 882                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 883         }
 884         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 885                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 886         }
 887         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 888         # proto parsing.
 889 }
 890
 891 sub exec_buf ($$) {
 892         my ($argv, $env) = @_;
 893         my $argc = scalar @$argv;
 894         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 895         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 896         $buf;
 897 }
 898
 899 sub start_mua {
 900         my ($self) = @_;
 901         my $mua = $self->{opt}->{mua} // return;
 902         my $mfolder = $self->{ovv}->{dst};
 903         my (@cmd, $replaced);
 904         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 905                 @cmd = ($mua, '-f');
 906         # TODO: help wanted: other common FOSS MUAs
 907         } else {
 908                 require Text::ParseWords;
 909                 @cmd = Text::ParseWords::shellwords($mua);
 910                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 911                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 912         }
 913         push @cmd, $mfolder unless defined($replaced);
 914         if ($self->{sock}) { # lei(1) client process runs it
 915                 # restore terminal: echo $query | lei q --stdin --mua=...
 916                 my $io = [];
 917                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 918                 send_exec_cmd($self, $io, \@cmd, {});
 919         }
 920         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 921                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 922         }
 923         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 924         $self->{opt}->{quiet} = 1;
 925         delete $self->{-progress};
 926         delete $self->{opt}->{verbose};
 927 }
 928
 929 sub send_exec_cmd { # tell script/lei to execute a command
 930         my ($self, $io, $cmd, $env) = @_;
 931         my $sock = $self->{sock} // die 'lei client gone';
 932         my $fds = [ map { fileno($_) } @$io ];
 933         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 934 }
 935
 936 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 937         my ($self) = @_;
 938         my $alerts = $self->{opt}->{alert} // return;
 939         my $sock = $self->{sock};
 940         while (my $op = shift(@$alerts)) {
 941                 if ($op eq ':WINCH') {
 942                         # hit the process group that started the MUA
 943                         send($sock, '-WINCH', MSG_EOR) if $sock;
 944                 } elsif ($op eq ':bell') {
 945                         out($self, "\a");
 946                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 947                         push @$alerts, split(/(?<!\\),/, $op);
 948                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 949                         my $cmd = $1; # run an arbitrary command
 950                         require Text::ParseWords;
 951                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 952                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 953                 } else {
 954                         err($self, "W: unsupported --alert=$op"); # non-fatal
 955                 }
 956         }
 957 }
 958
 959 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 960 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 961
 962 # this also normalizes the path
 963 sub path_to_fd {
 964         my ($self, $path) = @_;
 965         $path = rel2abs($self, $path);
 966         $path =~ tr!/!/!s;
 967         $path_to_fd{$path} // (
 968                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 969                         fail($self, "cannot open $path from daemon") : -1
 970         );
 971 }
 972
 973 # caller needs to "-t $self->{1}" to check if tty
 974 sub start_pager {
 975         my ($self) = @_;
 976         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 977         chomp(my $pager = <$fh> // '');
 978         close($fh) or warn "`git var PAGER' error: \$?=$?";
 979         return if $pager eq 'cat' || $pager eq '';
 980         my $new_env = { LESS => 'FRX', LV => '-c' };
 981         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 982         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 983         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 984         my $pgr = [ undef, @$rdr{1, 2} ];
 985         my $env = $self->{env};
 986         if ($self->{sock}) { # lei(1) process runs it
 987                 delete @$new_env{keys %$env}; # only set iff unset
 988                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 989         } else {
 990                 die 'BUG: start_pager w/o socket';
 991         }
 992         $self->{1} = $wpager;
 993         $self->{2} = $wpager if -t $self->{2};
 994         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 995         $self->{pgr} = $pgr;
 996 }
 997
 998 sub stop_pager {
 999         my ($self) = @_;
1000         my $pgr = delete($self->{pgr}) or return;
1001         $self->{2} = $pgr->[2];
1002         # do not restore original stdout, just close it so we error out
1003         close(delete($self->{1})) if $self->{1};
1004 }
1005
1006 sub accept_dispatch { # Listener {post_accept} callback
1007         my ($sock) = @_; # ignore other
1008         $sock->autoflush(1);
1009         my $self = bless { sock => $sock }, __PACKAGE__;
1010         vec(my $rvec = '', fileno($sock), 1) = 1;
1011         select($rvec, undef, undef, 60) or
1012                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1013         # (4096 * 33) >MAX_ARG_STRLEN
1014         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1015         if (!defined($fds[0])) {
1016                 warn(my $msg = "recv_cmd failed: $!");
1017                 return send($sock, $msg, MSG_EOR);
1018         } else {
1019                 my $i = 0;
1020                 for my $fd (@fds) {
1021                         open($self->{$i++}, '+<&=', $fd) and next;
1022                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1023                 }
1024                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1025         }
1026         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1027         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1028         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1029                 return send($sock, 'request command truncated', MSG_EOR);
1030         my ($argc, @argv) = split(/\0/, $buf, -1);
1031         undef $buf;
1032         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1033         if (chdir($self->{3})) {
1034                 local %ENV = %env;
1035                 $self->{env} = \%env;
1036                 eval { dispatch($self, @argv) };
1037                 send($sock, $@, MSG_EOR) if $@;
1038         } else {
1039                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1040         }
1041 }
1042
1043 sub dclose {
1044         my ($self) = @_;
1045         delete $self->{-progress};
1046         _drop_wq($self);
1047         close(delete $self->{1}) if $self->{1}; # may reap_compress
1048         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1049 }
1050
1051 # for long-running results
1052 sub event_step {
1053         my ($self) = @_;
1054         local %ENV = %{$self->{env}};
1055         my $sock = $self->{sock};
1056         local $current_lei = $self;
1057         eval {
1058                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1059                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1060                                 return if $! == EAGAIN;
1061                                 next if $! == EINTR;
1062                                 last if $! == ECONNRESET;
1063                                 die "recvmsg: $!";
1064                         }
1065                         for my $fd (@fds) {
1066                                 open my $rfh, '+<&=', $fd;
1067                         }
1068                         die "unrecognized client signal: $buf";
1069                 }
1070                 dclose($self);
1071         };
1072         if (my $err = $@) {
1073                 eval { $self->fail($err) };
1074                 dclose($self);
1075         }
1076 }
1077
1078 sub event_step_init {
1079         my ($self) = @_;
1080         return if $self->{-event_init_done}++;
1081         if (my $sock = $self->{sock}) { # using DS->EventLoop
1082                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1083         }
1084 }
1085
1086 sub noop {}
1087
1088 sub oldset { $oldset }
1089
1090 sub dump_and_clear_log {
1091         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1092                 my @pfx = @_;
1093                 unshift(@pfx, "$errors_log ") if @pfx;
1094                 warn @pfx, do { local $/; <STDIN> };
1095                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1096         }
1097 }
1098
1099 # lei(1) calls this when it can't connect
1100 sub lazy_start {
1101         my ($path, $errno, $narg) = @_;
1102         local ($errors_log, $listener);
1103         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1104         $errors_log = "$sock_dir/errors.log";
1105         my $addr = pack_sockaddr_un($path);
1106         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1107         $lk->lock_acquire;
1108         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1109         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1110                 return if connect($listener, $addr); # another process won
1111                 if ($errno == ECONNREFUSED && -S $path) {
1112                         unlink($path) or die "unlink($path): $!";
1113                 }
1114         } else {
1115                 $! = $errno; # allow interpolation to stringify in die
1116                 die "connect($path): $!";
1117         }
1118         umask(077) // die("umask(077): $!");
1119         bind($listener, $addr) or die "bind($path): $!";
1120         listen($listener, 1024) or die "listen: $!";
1121         $lk->lock_release;
1122         undef $lk;
1123         my @st = stat($path) or die "stat($path): $!";
1124         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1125         local $oldset = PublicInbox::DS::block_signals();
1126         if ($narg == 5) {
1127                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1128                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1129                         require PublicInbox::CmdIPC4;
1130                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1131                         PublicInbox::CmdIPC4->can('recv_cmd4');
1132                 };
1133         }
1134         $recv_cmd or die <<"";
1135 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1136
1137         require PublicInbox::Listener;
1138         require PublicInbox::PktOp;
1139         (-p STDOUT) or die "E: stdout must be a pipe\n";
1140         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1141         STDIN->autoflush(1);
1142         dump_and_clear_log("from previous daemon process:\n");
1143         POSIX::setsid() > 0 or die "setsid: $!";
1144         my $pid = fork // die "fork: $!";
1145         return if $pid;
1146         $0 = "lei-daemon $path";
1147         local %PATH2CFG;
1148         $listener->blocking(0);
1149         my $exit_code;
1150         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1151         local $quit = do {
1152                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1153                 sub {
1154                         $exit_code //= shift;
1155                         my $lis = $pil or exit($exit_code);
1156                         # closing eof_p triggers \&noop wakeup
1157                         $listener = $eof_p = $pil = $path = undef;
1158                         $lis->close; # DS::close
1159                         PublicInbox::DS->SetLoopTimeout(1000);
1160                 };
1161         };
1162         my $sig = {
1163                 CHLD => \&PublicInbox::DS::enqueue_reap,
1164                 QUIT => $quit,
1165                 INT => $quit,
1166                 TERM => $quit,
1167                 HUP => \&noop,
1168                 USR1 => \&noop,
1169                 USR2 => \&noop,
1170         };
1171         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1172         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1173         undef $sig;
1174         local $SIG{PIPE} = 'IGNORE';
1175         require PublicInbox::DirIdle;
1176         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1177                 # just rely on wakeup ot hit PostLoopCallback set below
1178                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1179         }, 1);
1180         if ($sigfd) {
1181                 undef $sigfd; # unref, already in DS::DescriptorMap
1182         } else {
1183                 # wake up every second to accept signals if we don't
1184                 # have signalfd or IO::KQueue:
1185                 PublicInbox::DS::sig_setmask($oldset);
1186                 PublicInbox::DS->SetLoopTimeout(1000);
1187         }
1188         PublicInbox::DS->SetPostLoopCallback(sub {
1189                 my ($dmap, undef) = @_;
1190                 if (@st = defined($path) ? stat($path) : ()) {
1191                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1192                                 warn "$path dev/ino changed, quitting\n";
1193                                 $path = undef;
1194                         }
1195                 } elsif (defined($path)) { # ENOENT is common
1196                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1197                         undef $path;
1198                         $quit->();
1199                 }
1200                 return 1 if defined($path);
1201                 my $now = now();
1202                 my $n = 0;
1203                 for my $s (values %$dmap) {
1204                         $s->can('busy') or next;
1205                         if ($s->busy($now)) {
1206                                 ++$n;
1207                         } else {
1208                                 $s->close;
1209                         }
1210                 }
1211                 $n; # true: continue, false: stop
1212         });
1213
1214         # STDIN was redirected to /dev/null above, closing STDERR and
1215         # STDOUT will cause the calling `lei' client process to finish
1216         # reading the <$daemon> pipe.
1217         local $SIG{__WARN__} = sub {
1218                 $current_lei ? err($current_lei, @_) : warn(
1219                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1220         };
1221         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1222         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1223         # $daemon pipe to `lei' closed, main loop begins:
1224         PublicInbox::DS->EventLoop;
1225         exit($exit_code // 0);
1226 }
1227
1228 sub busy { 1 } # prevent daemon-shutdown if client is connected
1229
1230 # ensures stdout hits the FS before sock disconnects so a client
1231 # can immediately reread it
1232 sub DESTROY {
1233         my ($self) = @_;
1234         $self->{1}->autoflush(1) if $self->{1};
1235         stop_pager($self);
1236         # preserve $? for ->fail or ->x_it code
1237 }
1238
1239 sub wq_done_wait { # dwaitpid callback
1240         my ($arg, $pid) = @_;
1241         my ($wq, $lei) = @$arg;
1242         my $err_type = $lei->{-err_type};
1243         $? and $lei->child_error($?,
1244                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1245         $lei->dclose;
1246 }
1247
1248 sub fchdir {
1249         my ($lei) = @_;
1250         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1251         chdir($dh) || $lei->fail("fchdir: $!");
1252 }
1253
1254 sub wq_eof { # EOF callback for main daemon
1255         my ($lei) = @_;
1256         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1257         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1258 }
1259
1260 1;