lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'ls-query       format|f=s' => $ls_format,
 233 'ls-external    format|f=s' => $ls_format,
 234
 235 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 236 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 237
 238 'sort|s=s' => [ 'VAL|received,relevance,docid',
 239                 "order of results `--output'-dependent"],
 240 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 241
 242 'boost=i' => 'increase/decrease priority of results (default: 0)',
 243
 244 'local' => 'limit operations to the local filesystem',
 245 'local!' => 'exclude results from the local filesystem',
 246 'remote' => 'limit operations to those requiring network access',
 247 'remote!' => 'prevent operations requiring network access',
 248
 249 'mid=s' => 'specify the Message-ID of a message',
 250 'oid=s' => 'specify the git object ID of a message',
 251
 252 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 253 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 254 'include=s' => 'include mailboxes/newsgroups based on pattern',
 255
 256 'exact' => 'operate on exact header matches only',
 257 'exact!' => 'rely on content match instead of exact header matches',
 258
 259 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 260 'jobs:i' => 'set parallelism level',
 261
 262 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 263 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 264
 265 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 266 ); # %OPTDESC
 267
 268 my %CONFIG_KEYS = (
 269         'leistore.dir' => 'top-level storage location',
 270 );
 271
 272 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 273 sub x_it ($$) {
 274         my ($self, $code) = @_;
 275         # make sure client sees stdout before exit
 276         $self->{1}->autoflush(1) if $self->{1};
 277         dump_and_clear_log();
 278         if (my $sock = $self->{sock}) {
 279                 send($sock, "x_it $code", MSG_EOR);
 280         } elsif (my $signum = ($code & 127)) { # oneshot, usually SIGPIPE (13)
 281                 $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 282                 kill $signum, $$;
 283                 sleep; # wait for signal
 284         } else { # oneshot
 285                 # don't want to end up using $? from child processes
 286                 for my $f (qw(lxs l2m)) {
 287                         my $wq = delete $self->{$f} or next;
 288                         $wq->DESTROY;
 289                 }
 290                 $quit->($code >> 8);
 291         }
 292 }
 293
 294 sub err ($;@) {
 295         my $self = shift;
 296         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 297         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 298         print $err @_, $eor and return;
 299         my $old_err = delete $self->{2};
 300         close($old_err) if $! == EPIPE && $old_err;;
 301         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 302         print $err @_, $eor or print STDERR @_, $eor;
 303 }
 304
 305 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 306
 307 sub fail ($$;$) {
 308         my ($self, $buf, $exit_code) = @_;
 309         err($self, $buf) if defined $buf;
 310         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 311         x_it($self, ($exit_code // 1) << 8);
 312         undef;
 313 }
 314
 315 sub out ($;@) {
 316         my $self = shift;
 317         return if print { $self->{1} // return } @_; # likely
 318         return note_sigpipe($self, 1) if $! == EPIPE;
 319         my $err = "error writing to stdout: $!";
 320         delete $self->{1};
 321         fail($self, $err);
 322 }
 323
 324 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 325
 326 sub child_error { # passes non-fatal curl exit codes to user
 327         my ($self, $child_error) = @_; # child_error is $?
 328         if (my $sock = $self->{sock}) { # send to lei(1) client
 329                 send($sock, "child_error $child_error", MSG_EOR);
 330         } else { # oneshot
 331                 $self->{child_error} = $child_error;
 332         }
 333         undef;
 334 }
 335
 336 sub atfork_prepare_wq {
 337         my ($self, $wq) = @_;
 338         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 339         if (my $sock = $self->{sock}) {
 340                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 341         }
 342         if (my $pgr = $self->{pgr}) {
 343                 push @$tcafc, @$pgr[1,2];
 344         }
 345         if (my $old_1 = $self->{old_1}) {
 346                 push @$tcafc, $old_1;
 347         }
 348         for my $f (qw(lxs l2m)) {
 349                 my $ipc = $self->{$f} or next;
 350                 push @$tcafc, grep { defined }
 351                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 352         }
 353 }
 354
 355 sub io_restore ($$) {
 356         my ($dst, $src) = @_;
 357         for my $i (0..2) { # standard FDs
 358                 my $io = delete $src->{$i} or next;
 359                 $dst->{$i} = $io;
 360         }
 361         for my $i (3..9) { # named (non-standard) FDs
 362                 my $io = $src->{$i} or next;
 363                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 364                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 365                 $dst->{$f} = $io;
 366                 delete $src->{$i};
 367         }
 368 }
 369
 370 sub note_sigpipe { # triggers sigpipe_handler
 371         my ($self, $fd) = @_;
 372         close(delete($self->{$fd})); # explicit close silences Perl warning
 373         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 374         x_it($self, 13);
 375 }
 376
 377 sub atfork_child_wq {
 378         my ($self, $wq) = @_;
 379         io_restore($self, $wq);
 380         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 381         io_restore($self->{l2m}, $wq);
 382         %PATH2CFG = ();
 383         undef $errors_log;
 384         $quit = \&CORE::exit;
 385         $current_lei = $self; # for SIG{__WARN__}
 386 }
 387
 388 sub io_extract ($;@) {
 389         my ($obj, @fields) = @_;
 390         my @io;
 391         for my $f (@fields) {
 392                 my $io = delete $obj->{$f} or next;
 393                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 394                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 395                 push @io, $io;
 396         }
 397         @io
 398 }
 399
 400 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 401 sub atfork_parent_wq {
 402         my ($self, $wq) = @_;
 403         my $env = delete $self->{env}; # env is inherited at fork
 404         my $lei = bless { %$self }, ref($self);
 405         for my $f (qw(dedupe ovv)) {
 406                 my $tmp = delete($lei->{$f}) or next;
 407                 $lei->{$f} = $wq->deep_clone($tmp);
 408         }
 409         $self->{env} = $env;
 410         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 411         my @io = (delete(@$lei{qw(0 1 2)}),
 412                         io_extract($lei, qw(sock pkt_op startq)));
 413         my $l2m = $lei->{l2m};
 414         if ($l2m && $l2m != $wq) { # $wq == lxs
 415                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 416                         push @io, io_extract($l2m, '-wq_s1');
 417                         $l2m->{-wq_s1} = $wq_s1;
 418                 }
 419                 $l2m->wq_close(1);
 420         }
 421         ($lei, @io);
 422 }
 423
 424 sub _help ($;$) {
 425         my ($self, $errmsg) = @_;
 426         my $cmd = $self->{cmd} // 'COMMAND';
 427         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 428         my @top = ($cmd, shift(@info) // ());
 429         my $cmd_desc = shift(@info);
 430         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 431         my @opt_desc;
 432         my $lpad = 2;
 433         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 434                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 435                 my $arg_vals = '';
 436                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 437
 438                 # lower-case is a keyword (e.g. `content', `oid'),
 439                 # ALL_CAPS is a string description (e.g. `PATH')
 440                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 441                         $desc .= "\ndefault: `$1'";
 442                 }
 443                 my (@vals, @s, @l);
 444                 my $x = $sw;
 445                 if ($x =~ s/!\z//) { # solve! => --no-solve
 446                         $x = "no-$x";
 447                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 448                         @vals = (' [', undef, ']');
 449                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 450                         @vals = (' ', undef);
 451                 } # else: no args $x = 'thread|t'
 452                 for (split(/\|/, $x)) { # help|h
 453                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 454                 }
 455                 if (!scalar(@vals)) { # no args 'thread|t'
 456                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 457                         $vals[1] = $1;
 458                 } else {
 459                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 460                 }
 461                 if ($arg_vals =~ /([,\|])/) {
 462                         my $sep = $1;
 463                         my @allow = split(/\Q$sep\E/, $arg_vals);
 464                         my $must = $sep eq '|' ? 'Must' : 'Can';
 465                         @allow = map { "`$_'" } @allow;
 466                         my $last = pop @allow;
 467                         $desc .= "\n$must be one of: " .
 468                                 join(', ', @allow) . " or $last";
 469                 }
 470                 my $lhs = join(', ', @s, @l) . join('', @vals);
 471                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 472                         $lhs =~ s/\A--/- , --/;
 473                 } else {
 474                         $lhs =~ s/\A--/    --/; # pad if no short options
 475                 }
 476                 $lpad = length($lhs) if length($lhs) > $lpad;
 477                 push @opt_desc, $lhs, $desc;
 478         }
 479         my $msg = $errmsg ? "E: $errmsg\n" : '';
 480         $msg .= <<EOF;
 481 usage: lei @top
 482   $cmd_desc
 483
 484 EOF
 485         $lpad += 2;
 486         local $Text::Wrap::columns = 78 - $lpad;
 487         my $padding = ' ' x ($lpad + 2);
 488         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 489                 $msg .= '  '.pack("A$lpad", $lhs);
 490                 $rhs = wrap('', '', $rhs);
 491                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 492                 $msg .= $rhs;
 493                 $msg .= "\n";
 494         }
 495         print { $self->{$errmsg ? 2 : 1} } $msg;
 496         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 497         undef;
 498 }
 499
 500 sub optparse ($$$) {
 501         my ($self, $cmd, $argv) = @_;
 502         $self->{cmd} = $cmd;
 503         $OPT = $self->{opt} = {};
 504         my $info = $CMD{$cmd} // [ '[...]' ];
 505         my ($proto, undef, @spec) = @$info;
 506         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 507         push @spec, qw(help|h);
 508         my $lone_dash;
 509         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 510                 $lone_dash = $spec[0];
 511                 $OPT->{$spec[0]} = \(my $var);
 512                 push @spec, '' => \$var;
 513         }
 514         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 515                 return _help($self, "bad arguments or options for $cmd");
 516         return _help($self) if $OPT->{help};
 517
 518         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 519
 520         # "-" aliases "stdin" or "clear"
 521         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 522
 523         my $i = 0;
 524         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 525         my ($err, $inf);
 526         my @args = split(/ /, $proto);
 527         for my $var (@args) {
 528                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 529                         $inf = defined($argv->[$i]) and last;
 530                         $var =~ s/\.\.\.\z//;
 531                         $err = "$var not supplied";
 532                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 533                         $argv->[$i++] // ($err = "$var not supplied");
 534                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 535                         $inf = 1;
 536                         last;
 537                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 538                         $i++;
 539                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 540                         my @or = split(/\|/, $var);
 541                         my $ok;
 542                         for my $o (@or) {
 543                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 544                                         $ok = defined($OPT->{$1});
 545                                         last;
 546                                 } elsif (defined($argv->[$i])) {
 547                                         $ok = 1;
 548                                         $i++;
 549                                         last;
 550                                 } # else continue looping
 551                         }
 552                         last if $ok;
 553                         my $last = pop @or;
 554                         $err = join(', ', @or) . " or $last must be set";
 555                 } else {
 556                         warn "BUG: can't parse `$var' in $proto";
 557                 }
 558                 last if $err;
 559         }
 560         if (!$inf && scalar(@$argv) > scalar(@args)) {
 561                 $err //= 'too many arguments';
 562         }
 563         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 564 }
 565
 566 sub dispatch {
 567         my ($self, $cmd, @argv) = @_;
 568         local $current_lei = $self; # for __WARN__
 569         dump_and_clear_log("from previous run\n");
 570         return _help($self, 'no command given') unless defined($cmd);
 571         my $func = "lei_$cmd";
 572         $func =~ tr/-/_/;
 573         if (my $cb = __PACKAGE__->can($func)) {
 574                 optparse($self, $cmd, \@argv) or return;
 575                 $cb->($self, @argv);
 576         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 577                 my $opt = {};
 578                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 579                         return _help($self, 'bad arguments or options');
 580                 _help($self);
 581         } else {
 582                 fail($self, "`$cmd' is not an lei command");
 583         }
 584 }
 585
 586 sub _lei_cfg ($;$) {
 587         my ($self, $creat) = @_;
 588         my $f = _config_path($self);
 589         my @st = stat($f);
 590         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 591         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 592                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 593         }
 594         if (!@st) {
 595                 unless ($creat) {
 596                         delete $self->{cfg};
 597                         return;
 598                 }
 599                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 600                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 601                 open my $fh, '>>', $f or die "open($f): $!\n";
 602                 @st = stat($fh) or die "fstat($f): $!\n";
 603                 $cur_st = pack('dd', $st[10], $st[7]);
 604                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 605         }
 606         my $cfg = PublicInbox::Config::git_config_dump($f);
 607         $cfg->{-st} = $cur_st;
 608         $cfg->{'-f'} = $f;
 609         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 610 }
 611
 612 sub _lei_store ($;$) {
 613         my ($self, $creat) = @_;
 614         my $cfg = _lei_cfg($self, $creat);
 615         $cfg->{-lei_store} //= do {
 616                 require PublicInbox::LeiStore;
 617                 my $dir = $cfg->{'leistore.dir'};
 618                 $dir //= $creat ? _store_path($self) : return;
 619                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 620         };
 621 }
 622
 623 sub lei_show {
 624         my ($self, @argv) = @_;
 625 }
 626
 627 sub lei_mark {
 628         my ($self, @argv) = @_;
 629 }
 630
 631 sub _config {
 632         my ($self, @argv) = @_;
 633         my $env = $self->{env};
 634         delete local $env->{GIT_CONFIG};
 635         delete local $ENV{GIT_CONFIG};
 636         my $cfg = _lei_cfg($self, 1);
 637         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 638         my %rdr = map { $_ => $self->{$_} } (0..2);
 639         waitpid(spawn($cmd, $env, \%rdr), 0);
 640 }
 641
 642 sub lei_config {
 643         my ($self, @argv) = @_;
 644         $self->{opt}->{'config-file'} and return fail $self,
 645                 "config file switches not supported by `lei config'";
 646         _config(@_);
 647         x_it($self, $?) if $?;
 648 }
 649
 650 sub lei_init {
 651         my ($self, $dir) = @_;
 652         my $cfg = _lei_cfg($self, 1);
 653         my $cur = $cfg->{'leistore.dir'};
 654         $dir //= _store_path($self);
 655         $dir = rel2abs($self, $dir);
 656         my @cur = stat($cur) if defined($cur);
 657         $cur = File::Spec->canonpath($cur // $dir);
 658         my @dir = stat($dir);
 659         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 660         if (@cur) {
 661                 if ($cur eq $dir) {
 662                         _lei_store($self, 1)->done;
 663                         return qerr($self, $exists);
 664                 }
 665
 666                 # some folks like symlinks and bind mounts :P
 667                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 668                         lei_config($self, 'leistore.dir', $dir);
 669                         _lei_store($self, 1)->done;
 670                         return qerr($self, "$exists (as $cur)");
 671                 }
 672                 return fail($self, <<"");
 673 E: leistore.dir=$cur already initialized and it is not $dir
 674
 675         }
 676         lei_config($self, 'leistore.dir', $dir);
 677         _lei_store($self, 1)->done;
 678         $exists //= "I: leistore.dir=$dir newly initialized";
 679         return qerr($self, $exists);
 680 }
 681
 682 sub lei_daemon_pid { puts shift, $$ }
 683
 684 sub lei_daemon_kill {
 685         my ($self) = @_;
 686         my $sig = $self->{opt}->{signal} // 'TERM';
 687         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 688 }
 689
 690 sub lei_help { _help($_[0]) }
 691
 692 # Shell completion helper.  Used by lei-completion.bash and hopefully
 693 # other shells.  Try to do as much here as possible to avoid redundancy
 694 # and improve maintainability.
 695 sub lei__complete {
 696         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 697         shift @argv; # ignore "lei", the entire command is sent
 698         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 699         my $cmd = shift @argv;
 700         my $info = $CMD{$cmd} // do { # filter matching commands
 701                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 702                 return;
 703         };
 704         my ($proto, undef, @spec) = @$info;
 705         my $cur = pop @argv;
 706         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 707         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 708                 # gross special case since the only git-config options
 709                 # Consider moving to a table if we need more special cases
 710                 # we use Getopt::Long for are the ones we reject, so these
 711                 # are the ones we don't reject:
 712                 if ($cmd eq 'config') {
 713                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 714                         @spec = qw(add z|null get get-all unset unset-all
 715                                 replace-all get-urlmatch
 716                                 remove-section rename-section
 717                                 name-only list|l edit|e
 718                                 get-color-name get-colorbool);
 719                         # fall-through
 720                 }
 721                 puts $self, grep(/$re/, map { # generate short/long names
 722                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 723                         } else { # negation: solve! => no-solve|solve
 724                                 s/\A(.+)!\z/no-$1|$1/;
 725                         }
 726                         map {
 727                                 my $x = length > 1 ? "--$_" : "-$_";
 728                                 $x eq $cur ? () : $x;
 729                         } split(/\|/, $_, -1) # help|h
 730                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 731         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 732                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 733         }
 734
 735         # switch args (e.g. lei q -f mbox<TAB>)
 736         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 737                 my $opt = quotemeta $1;
 738                 puts $self, map {
 739                         my $v = $OPTDESC{$_};
 740                         $v = $v->[0] if ref($v);
 741                         my @v = split(/\|/, $v);
 742                         # get rid of ALL CAPS placeholder (e.g "OUT")
 743                         # (TODO: completion for external paths)
 744                         shift(@v) if uc($v[0]) eq $v[0];
 745                         @v;
 746                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 747         }
 748         $cmd =~ tr/-/_/;
 749         if (my $sub = $self->can("_complete_$cmd")) {
 750                 puts $self, $sub->($self, @argv, $cur);
 751         }
 752         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 753         # proto parsing.
 754 }
 755
 756 sub exec_buf ($$) {
 757         my ($argv, $env) = @_;
 758         my $argc = scalar @$argv;
 759         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 760         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 761         $buf;
 762 }
 763
 764 sub start_mua {
 765         my ($self) = @_;
 766         my $mua = $self->{opt}->{'mua-cmd'} // return;
 767         my $mfolder = $self->{ovv}->{dst};
 768         my (@cmd, $replaced);
 769         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 770                 @cmd = ($mua, '-f');
 771         # TODO: help wanted: other common FOSS MUAs
 772         } else {
 773                 require Text::ParseWords;
 774                 my @cmd = Text::ParseWords::shellwords($mua);
 775                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 776                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 777         }
 778         push @cmd, $mfolder unless defined($replaced);
 779         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 780                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 781         } else { # oneshot
 782                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 783         }
 784 }
 785
 786 # caller needs to "-t $self->{1}" to check if tty
 787 sub start_pager {
 788         my ($self) = @_;
 789         my $env = $self->{env};
 790         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 791         chomp(my $pager = <$fh> // '');
 792         close($fh) or warn "`git var PAGER' error: \$?=$?";
 793         return if $pager eq 'cat' || $pager eq '';
 794         # TODO TIOCGWINSZ
 795         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 796         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 797         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 798         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 799         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 800         if (my $sock = $self->{sock}) { # lei(1) process runs it
 801                 delete @$new_env{keys %$env}; # only set iff unset
 802                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 803                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 804         } else {
 805                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 806         }
 807         $self->{1} = $wpager;
 808         $self->{2} = $wpager if -t $self->{2};
 809         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 810         $self->{pgr} = $pgr;
 811 }
 812
 813 sub stop_pager {
 814         my ($self) = @_;
 815         my $pgr = delete($self->{pgr}) or return;
 816         $self->{2} = $pgr->[2];
 817         # do not restore original stdout, just close it so we error out
 818         close(delete($self->{1})) if $self->{1};
 819         my $pid = $pgr->[0];
 820         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 821 }
 822
 823 sub accept_dispatch { # Listener {post_accept} callback
 824         my ($sock) = @_; # ignore other
 825         $sock->autoflush(1);
 826         my $self = bless { sock => $sock }, __PACKAGE__;
 827         vec(my $rvec = '', fileno($sock), 1) = 1;
 828         select($rvec, undef, undef, 60) or
 829                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 830         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 831         if (scalar(@fds) == 4) {
 832                 for my $i (0..3) {
 833                         my $fd = shift(@fds);
 834                         open($self->{$i}, '+<&=', $fd) and next;
 835                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 836                 }
 837         } else {
 838                 my $msg = "recv_cmd failed: $!";
 839                 warn $msg;
 840                 return send($sock, $msg, MSG_EOR);
 841         }
 842         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 843         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 844         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 845         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 846                 return send($sock, 'request command truncated', MSG_EOR);
 847         my ($argc, @argv) = split(/\0/, $buf, -1);
 848         undef $buf;
 849         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 850         if (chdir($self->{3})) {
 851                 local %ENV = %env;
 852                 $self->{env} = \%env;
 853                 eval { dispatch($self, @argv) };
 854                 send($sock, $@, MSG_EOR) if $@;
 855         } else {
 856                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 857         }
 858 }
 859
 860 sub dclose {
 861         my ($self) = @_;
 862         for my $f (qw(lxs l2m)) {
 863                 my $wq = delete $self->{$f} or next;
 864                 if ($wq->wq_kill) {
 865                         $wq->wq_close
 866                 } elsif ($wq->wq_kill_old) {
 867                         $wq->wq_wait_old($self);
 868                 }
 869         }
 870         close(delete $self->{1}) if $self->{1}; # may reap_compress
 871         $self->close if $self->{sock}; # PublicInbox::DS::close
 872 }
 873
 874 # for long-running results
 875 sub event_step {
 876         my ($self) = @_;
 877         local %ENV = %{$self->{env}};
 878         my $sock = $self->{sock};
 879         local $current_lei = $self;
 880         eval {
 881                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 882                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 883                                 return if $! == EAGAIN;
 884                                 next if $! == EINTR;
 885                                 last if $! == ECONNRESET;
 886                                 die "recvmsg: $!";
 887                         }
 888                         for my $fd (@fds) {
 889                                 open my $rfh, '+<&=', $fd;
 890                         }
 891                         die "unrecognized client signal: $buf";
 892                 }
 893                 dclose($self);
 894         };
 895         if (my $err = $@) {
 896                 eval { $self->fail($err) };
 897                 dclose($self);
 898         }
 899 }
 900
 901 sub event_step_init {
 902         my ($self) = @_;
 903         if (my $sock = $self->{sock}) { # using DS->EventLoop
 904                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 905         }
 906 }
 907
 908 sub noop {}
 909
 910 our $oldset; sub oldset { $oldset }
 911
 912 sub dump_and_clear_log {
 913         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 914                 my @pfx = @_;
 915                 unshift(@pfx, "$errors_log ") if @pfx;
 916                 warn @pfx, do { local $/; <STDIN> };
 917                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 918         }
 919 }
 920
 921 # lei(1) calls this when it can't connect
 922 sub lazy_start {
 923         my ($path, $errno, $narg) = @_;
 924         if ($errno == ECONNREFUSED) {
 925                 unlink($path) or die "unlink($path): $!";
 926         } elsif ($errno != ENOENT) {
 927                 $! = $errno; # allow interpolation to stringify in die
 928                 die "connect($path): $!";
 929         }
 930         if (eval { require BSD::Resource }) {
 931                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 932                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 933                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 934         }
 935         umask(077) // die("umask(077): $!");
 936         local $listener;
 937         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 938         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 939         listen($listener, 1024) or die "listen: $!";
 940         my @st = stat($path) or die "stat($path): $!";
 941         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 942         local $oldset = PublicInbox::DS::block_signals();
 943         if ($narg == 5) {
 944                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 945                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 946                         require PublicInbox::CmdIPC4;
 947                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 948                         PublicInbox::CmdIPC4->can('recv_cmd4');
 949                 };
 950         }
 951         $recv_cmd or die <<"";
 952 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 953
 954         require PublicInbox::Listener;
 955         require PublicInbox::EOFpipe;
 956         (-p STDOUT) or die "E: stdout must be a pipe\n";
 957         local $errors_log;
 958         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 959         $errors_log .= 'errors.log';
 960         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 961         STDIN->autoflush(1);
 962         dump_and_clear_log("from previous daemon process:\n");
 963         POSIX::setsid() > 0 or die "setsid: $!";
 964         my $pid = fork // die "fork: $!";
 965         return if $pid;
 966         $0 = "lei-daemon $path";
 967         local %PATH2CFG;
 968         $listener->blocking(0);
 969         my $exit_code;
 970         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 971         local $quit = do {
 972                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 973                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 974                 sub {
 975                         $exit_code //= shift;
 976                         my $lis = $pil or exit($exit_code);
 977                         # closing eof_w triggers \&noop wakeup
 978                         $listener = $eof_w = $pil = $path = undef;
 979                         $lis->close; # DS::close
 980                         PublicInbox::DS->SetLoopTimeout(1000);
 981                 };
 982         };
 983         my $sig = {
 984                 CHLD => \&PublicInbox::DS::enqueue_reap,
 985                 QUIT => $quit,
 986                 INT => $quit,
 987                 TERM => $quit,
 988                 HUP => \&noop,
 989                 USR1 => \&noop,
 990                 USR2 => \&noop,
 991         };
 992         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 993         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 994         undef $sig;
 995         local $SIG{PIPE} = 'IGNORE';
 996         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 997                 undef $sigfd;
 998                 PublicInbox::DS->SetLoopTimeout(5000);
 999         } else {
1000                 # wake up every second to accept signals if we don't
1001                 # have signalfd or IO::KQueue:
1002                 PublicInbox::DS::sig_setmask($oldset);
1003                 PublicInbox::DS->SetLoopTimeout(1000);
1004         }
1005         PublicInbox::DS->SetPostLoopCallback(sub {
1006                 my ($dmap, undef) = @_;
1007                 if (@st = defined($path) ? stat($path) : ()) {
1008                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1009                                 warn "$path dev/ino changed, quitting\n";
1010                                 $path = undef;
1011                         }
1012                 } elsif (defined($path)) { # ENOENT is common
1013                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1014                         undef $path;
1015                         $quit->();
1016                 }
1017                 return 1 if defined($path);
1018                 my $now = now();
1019                 my $n = 0;
1020                 for my $s (values %$dmap) {
1021                         $s->can('busy') or next;
1022                         if ($s->busy($now)) {
1023                                 ++$n;
1024                         } else {
1025                                 $s->close;
1026                         }
1027                 }
1028                 $n; # true: continue, false: stop
1029         });
1030
1031         # STDIN was redirected to /dev/null above, closing STDERR and
1032         # STDOUT will cause the calling `lei' client process to finish
1033         # reading the <$daemon> pipe.
1034         local $SIG{__WARN__} = sub {
1035                 $current_lei ? err($current_lei, @_) : warn(
1036                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1037         };
1038         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1039         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1040         # $daemon pipe to `lei' closed, main loop begins:
1041         PublicInbox::DS->EventLoop;
1042         exit($exit_code // 0);
1043 }
1044
1045 # for users w/o Socket::Msghdr installed or Inline::C enabled
1046 sub oneshot {
1047         my ($main_pkg) = @_;
1048         my $exit = $main_pkg->can('exit'); # caller may override exit()
1049         local $quit = $exit if $exit;
1050         local %PATH2CFG;
1051         umask(077) // die("umask(077): $!");
1052         my $self = bless {
1053                 0 => *STDIN{GLOB},
1054                 1 => *STDOUT{GLOB},
1055                 2 => *STDERR{GLOB},
1056                 env => \%ENV
1057         }, __PACKAGE__;
1058         dispatch($self, @ARGV);
1059         x_it($self, $self->{child_error}) if $self->{child_error};
1060 }
1061
1062 # ensures stdout hits the FS before sock disconnects so a client
1063 # can immediately reread it
1064 sub DESTROY {
1065         my ($self) = @_;
1066         $self->{1}->autoflush(1) if $self->{1};
1067         stop_pager($self);
1068         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1069                 waitpid($mua_pid, 0);
1070         }
1071 }
1072
1073 1;