lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn popen_rd);
  24 use PublicInbox::Lock;
  25 use PublicInbox::Eml;
  26 use PublicInbox::Import;
  27 use PublicInbox::ContentHash qw(git_sha);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 use Sys::Syslog qw(openlog syslog closelog);
  32 our $quit = \&CORE::exit;
  33 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  34         $recv_cmd, $send_cmd);
  35 my $GLP = Getopt::Long::Parser->new;
  36 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  37 my $GLP_PASS = Getopt::Long::Parser->new;
  38 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  39
  40 our %PATH2CFG; # persistent for socket daemon
  41 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         my $cwd;
  81         if (defined $pwd) {
  82                 my $xcwd = $self->{3} //
  83                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  84                 if (my @st_pwd = stat($pwd)) {
  85                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  86                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  87                                 $self->{env}->{PWD} = $pwd = undef;
  88                 } else { # PWD was invalid
  89                         $self->{env}->{PWD} = $pwd = undef;
  90                 }
  91         }
  92         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  93         File::Spec->rel2abs($p, $pwd);
  94 }
  95
  96 # abs_path resolves symlinks in parent iff all parents exist
  97 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  98
  99 sub canonpath_harder {
 100         my $p = $_[-1]; # $_[0] may be self
 101         $p = File::Spec->canonpath($p);
 102         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 103 }
 104
 105 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 109                 .'/lei');
 110 }
 111
 112 sub store_path ($) { share_path($_[0]) . '/store' }
 113
 114 sub _config_path ($) {
 115         my ($self) = @_;
 116         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 117                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 118                 .'/lei/config');
 119 }
 120
 121 sub cache_dir ($) {
 122         my ($self) = @_;
 123         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 124                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 125                 .'/lei');
 126 }
 127
 128 sub url_folder_cache {
 129         my ($self) = @_;
 130         require PublicInbox::SharedKV; # URI => updated_at_sec_
 131         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 132 }
 133
 134 sub ale {
 135         my ($self) = @_;
 136         $self->{ale} //= do {
 137                 require PublicInbox::LeiALE;
 138                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 139         };
 140 }
 141
 142 sub index_opt {
 143         # TODO: drop underscore variants everywhere, they're undocumented
 144         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 145         max_size|max-size=s sequential-shard
 146         batch_size|batch-size=s skip-docdata)
 147 }
 148
 149 my @c_opt = qw(c=s@ C=s@ quiet|q);
 150 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 151 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 152         import-remote!);
 153
 154 # we don't support -C as an alias for --find-copies since it's already
 155 # used for chdir
 156 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 157         output-indicator-context=s indent-heuristic!
 158         minimal patience histogram anchored=s@ diff-algorithm=s
 159         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 160         word-diff:s word-diff-regex=s color-words:s no-renames
 161         rename-empty! check ws-error-highlight=s full-index binary
 162         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 163         find-copies-harder irreversible-delete|D l=i diff-filter=s
 164         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 165         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 166         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 167         inter-hunk-context=i function-context|W exit-code ext-diff
 168         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 169         line-prefix=s);
 170
 171 # we generate shell completion + help using %CMD and %OPTDESC,
 172 # see lei__complete() and PublicInbox::LeiHelp
 173 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 174 our %CMD = ( # sorted in order of importance/use:
 175 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 176         'stdin|', # /|\z/ must be first for lone dash
 177         @lxs_opt, @net_opt,
 178         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 179         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 180         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 181         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 182
 183 'up' => [ 'OUTPUT...|--all', 'update saved search',
 184         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+
 185         remote-fudge-time=s all:s), @c_opt ],
 186
 187 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 188         'stdin|', # /|\z/ must be first for lone dash
 189         # some of these options are ridiculous for lcat
 190         @lxs_opt, @net_opt,
 191         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 192         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 193         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 194         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 195
 196 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 197         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 198         @lxs_opt, @net_opt, @c_opt ],
 199
 200 'rediff' => [ '--stdin|LOCATION...',
 201                 'regenerate a diff with different options',
 202         'stdin|', # /|\z/ must be first for lone dash
 203         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 204         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 205
 206 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 207         'stdin|', # /|\z/ must be first for lone dash
 208         qw(verbose|v+ color:s no-color raw-header),
 209         @diff_opt, @net_opt, @c_opt ],
 210
 211 'add-external' => [ 'LOCATION',
 212         'add/set priority of a publicinbox|extindex for extra matches',
 213         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 214         @c_opt, index_opt(), @net_opt ],
 215 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 216         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 217 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 218 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 219                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 220 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 221                 qw(z|0 ascii l pretty url), @c_opt ],
 222 'forget-external' => [ 'LOCATION...|--prune',
 223         'exclude further results from a publicinbox|extindex',
 224         qw(prune), @c_opt ],
 225
 226 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 227                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 228 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 229                 qw(verbose|v+), @c_opt ],
 230 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 231                         @c_opt ],
 232 'rm' => [ '--stdin|LOCATION...',
 233         'remove a message from the index and prevent reindexing',
 234         'stdin|', # /|\z/ must be first for lone dash
 235         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 236 'plonk' => [ '--threads|--from=IDENT',
 237         'exclude mail matching From: or threads from non-Message-ID searches',
 238         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 239 'tag' => [ 'KEYWORDS...',
 240         'set/unset keywords and/or labels on message(s)',
 241         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 242         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 243
 244 'purge-mailsource' => [ 'LOCATION|--all',
 245         'remove imported messages from IMAP, Maildirs, and MH',
 246         qw(exact! all jobs:i indexed), @c_opt ],
 247
 248 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 249         qw(poll-interval=s state=s recursive|r), @c_opt ],
 250 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 251         qw(recursive|r), @c_opt ],
 252 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 253                 qw(l z|0), @c_opt ],
 254 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 255 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 256 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 257         qw(prune), @c_opt ],
 258
 259 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 260         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 261         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 262          @c_opt ],
 263 'import' => [ 'LOCATION...|--stdin',
 264         'one-time import/update from URL or filesystem',
 265         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 266         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 267         @net_opt, @c_opt ],
 268 'forget-mail-sync' => [ 'LOCATION...',
 269         'forget sync information for a mail folder', @c_opt ],
 270 'refresh-mail-sync' => [ 'LOCATION...|--all',
 271         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 272 'export-kw' => [ 'LOCATION...|--all',
 273         'one-time export of keywords of sync sources',
 274         qw(all:s mode=s), @net_opt, @c_opt ],
 275 'convert' => [ 'LOCATION...|--stdin',
 276         'one-time conversion from URL or filesystem to another format',
 277         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 278         @net_opt, @c_opt ],
 279 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 280         "use a patch to generate a query for `lei q --stdin'",
 281         qw(stdin| want|w=s@ uri debug), @c_opt ],
 282 'config' => [ '[...]', sub {
 283                 'git-config(1) wrapper for '._config_path($_[0]);
 284         }, qw(config-file|system|global|file|f=s), # for conflict detection
 285          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 286 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 287         qw(stdin| pretty ascii dir=s), @c_opt ],
 288
 289 'init' => [ '[DIRNAME]', sub {
 290         "initialize storage, default: ".store_path($_[0]);
 291         }, @c_opt ],
 292 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 293         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 294         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 295 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 296 'help' => [ '[SUBCOMMAND]', 'show help' ],
 297
 298 # TODO
 299 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 300 #       'rewrite git history in an attempt to improve compression',
 301 #       qw(gc!), @c_opt ],
 302 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 303 #
 304 # internal commands are prefixed with '_'
 305 '_complete' => [ '[...]', 'internal shell completion helper',
 306                 pass_through('everything') ],
 307 ); # @CMD
 308
 309 # switch descriptions, try to keep consistent across commands
 310 # $spec: Getopt::Long option specification
 311 # $spec => [@ALLOWED_VALUES (default is first), $description],
 312 # $spec => $description
 313 # "$SUB_COMMAND TAB $spec" => as above
 314 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 315                         'specify message input format' ];
 316 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 317
 318 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 319 my %OPTDESC = (
 320 'help|h' => 'show this built-in help',
 321 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 322 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 323 'quiet|q' => 'be quiet',
 324 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 325         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 326
 327 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 328 'globoff|g' => "do not match locations using '*?' wildcards ".
 329                 "and\xa0'[]'\x{a0}ranges",
 330 'invert-match|v' => 'select non-matching lines',
 331 'color!' => 'disable color (for --format=text)',
 332 'verbose|v+' => 'be more verbose',
 333 'external!' => 'do not use externals',
 334 'mail!' => 'do not look in mail storage for OID',
 335 'cwd!' => 'do not look in git repo of current working directory',
 336 'oid-a|A=s' => 'pre-image OID',
 337 'path-a|a=s' => 'pre-image pathname associated with OID',
 338 'path-b|b=s' => 'post-image pathname associated with OID',
 339 'git-dir=s@' => 'additional git repository to scan',
 340 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 341 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 342         "proxy for (e.g. `socks5h://0:9050')" ],
 343 'torsocks=s' => ['VAL|auto|no|yes',
 344                 'whether or not to wrap git and curl commands with torsocks'],
 345 'no-torsocks' => 'alias for --torsocks=no',
 346 'save!' =>  "do not save a search for `lei up'",
 347 'import-remote!' => 'do not memoize remote messages into local store',
 348
 349 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 350
 351 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 352                 'deduplication strategy'],
 353 'threads|t+' =>
 354         'return all messages in the same threads as the actual match(es)',
 355
 356 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 357                 'search prefixes to extract (default: dfpost7)' ],
 358
 359 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 360         'run command(s) or perform ops when done writing to output ' .
 361         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 362         'nothing otherwise)' ],
 363
 364 'augment|a' => 'augment --output destination instead of clobbering',
 365
 366 'output|mfolder|o=s' => [ 'MFOLDER',
 367         "destination (e.g.\xa0`/path/to/Maildir', ".
 368         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 369 'mua=s' => [ 'CMD',
 370         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 371 'new-only       import' => 'only import new messages from IMAP source',
 372
 373 'inbox-version=i' => [ 'NUM|1|2',
 374                 'force a public-inbox version with --mirror'],
 375 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 376
 377 # public-inbox-index options
 378 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 379 'compact' => 'run compact index after mirroring',
 380 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 381         "indexlevel with --mirror (default: full)" ],
 382 'max_size|max-size=s' => [ 'SIZE',
 383         'do not index messages larger than SIZE (default: infinity)' ],
 384 'batch_size|batch-size=s' => [ 'SIZE',
 385         'flush changes to OS after given number of bytes (default: 1m)' ],
 386 'sequential-shard' =>
 387         'index Xapian shards sequentially for slow storage',
 388 'skip-docdata' =>
 389         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 390
 391 'format|f=s     q' => [
 392         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 393                 'specify output format, default depends on --output'],
 394 'exclude=s@     q' => [ 'LOCATION',
 395                 'exclude specified external(s) from search' ],
 396 'include|I=s@   q' => [ 'LOCATION',
 397                 'include specified external(s) in search' ],
 398 'only=s@        q' => [ 'LOCATION',
 399                 'only use specified external(s) for search' ],
 400 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 401                 'control number of search and writer jobs' ],
 402 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 403
 404 'in-format|F=s' => $stdin_formats,
 405 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 406                         'listing output format' ],
 407 'l      ls-search' => 'long listing format',
 408 'l      ls-watch' => 'long listing format',
 409 'l      ls-mail-source' => 'long listing format',
 410 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 411 'format|f=s     ls-external' => $ls_format,
 412
 413 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 414 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 415
 416 'sort|s=s' => [ 'VAL|received|relevance|docid',
 417                 "order of results is `--output'-dependent"],
 418 'reverse|r' => 'reverse search results', # like sort(1)
 419
 420 'boost=i' => 'increase/decrease priority of results (default: 0)',
 421
 422 'local' => 'limit operations to the local filesystem',
 423 'local!' => 'exclude results from the local filesystem',
 424 'remote' => 'limit operations to those requiring network access',
 425 'remote!' => 'prevent operations requiring network access',
 426
 427 # up, refresh-mail-sync, export-kw
 428 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 429
 430 'remote-fudge-time=s' => [ 'INTERVAL',
 431         'look for mail INTERVAL older than the last successful query' ],
 432
 433 'mid=s' => 'specify the Message-ID of a message',
 434 'oid=s' => 'specify the git object ID of a message',
 435
 436 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 437 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 438 'include=s' => 'include mailboxes/newsgroups based on pattern',
 439
 440 'exact' => 'operate on exact header matches only',
 441 'exact!' => 'rely on content match instead of exact header matches',
 442
 443 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 444
 445 'kw!' => 'disable/enable importing keywords (aka "flags")',
 446
 447 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 448 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 449
 450 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 451 ); # %OPTDESC
 452
 453 my %CONFIG_KEYS = (
 454         'leistore.dir' => 'top-level storage location',
 455 );
 456
 457 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 458
 459 sub _drop_wq {
 460         my ($self) = @_;
 461         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 462                 if ($wq->wq_kill) {
 463                         $wq->wq_close(0, undef, $self);
 464                 } elsif ($wq->wq_kill_old) {
 465                         $wq->wq_wait_old(undef, $self);
 466                 }
 467                 $wq->DESTROY;
 468         }
 469 }
 470
 471 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 472 sub x_it ($$) {
 473         my ($self, $code) = @_;
 474         local $current_lei = $self;
 475         # make sure client sees stdout before exit
 476         $self->{1}->autoflush(1) if $self->{1};
 477         stop_pager($self);
 478         if ($self->{pkt_op_p}) { # worker => lei-daemon
 479                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 480         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 481                 send($self->{sock}, "x_it $code", MSG_EOR);
 482         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 483                 exit($code >> 8);
 484         } # else ignore if client disconnected
 485 }
 486
 487 sub err ($;@) {
 488         my $self = shift;
 489         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 490         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 491         print $err @_, @eor and return;
 492         my $old_err = delete $self->{2};
 493         close($old_err) if $! == EPIPE && $old_err;
 494         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 495         print $err @_, @eor or print STDERR @_, @eor;
 496 }
 497
 498 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 499
 500 sub qfin { # show message on finalization (LeiFinmsg)
 501         my ($lei, $msg) = @_;
 502         return if $lei->{opt}->{quiet};
 503         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 504 }
 505
 506 sub fail_handler ($;$$) {
 507         my ($lei, $code, $io) = @_;
 508         local $current_lei = $lei;
 509         close($io) if $io; # needed to avoid warnings on SIGPIPE
 510         _drop_wq($lei);
 511         x_it($lei, $code // (1 << 8));
 512 }
 513
 514 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 515         fail_handler($_[0], 13, delete $_[0]->{1});
 516 }
 517
 518 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 519 sub sigint_reap {
 520         my ($pgid) = @_;
 521         dwaitpid($pgid) if kill('-INT', $pgid);
 522 }
 523
 524 sub fail ($$;$) {
 525         my ($self, $buf, $exit_code) = @_;
 526         local $current_lei = $self;
 527         $self->{failed}++;
 528         warn($buf, "\n") if defined $buf;
 529         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 530         x_it($self, ($exit_code // 1) << 8);
 531         undef;
 532 }
 533
 534 sub out ($;@) {
 535         my $self = shift;
 536         return if print { $self->{1} // return } @_; # likely
 537         return note_sigpipe($self, 1) if $! == EPIPE;
 538         my $err = "error writing to output: $!";
 539         delete $self->{1};
 540         fail($self, $err);
 541 }
 542
 543 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 544
 545 sub child_error { # passes non-fatal curl exit codes to user
 546         my ($self, $child_error, $msg) = @_; # child_error is $?
 547         local $current_lei = $self;
 548         $child_error ||= 1 << 8;
 549         warn($msg, "\n") if defined $msg;
 550         if ($self->{pkt_op_p}) { # to top lei-daemon
 551                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 552         } elsif ($self->{sock}) { # to lei(1) client
 553                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 554         } else { # non-lei admin command
 555                 $self->{child_error} ||= $child_error;
 556         } # else noop if client disconnected
 557 }
 558
 559 sub note_sigpipe { # triggers sigpipe_handler
 560         my ($self, $fd) = @_;
 561         close(delete($self->{$fd})); # explicit close silences Perl warning
 562         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 563         x_it($self, 13);
 564 }
 565
 566 sub _lei_atfork_child {
 567         my ($self, $persist) = @_;
 568         # we need to explicitly close things which are on stack
 569         if ($persist) {
 570                 chdir '/' or die "chdir(/): $!";
 571                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 572                 if (my $cfg = $self->{cfg}) {
 573                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 574                 }
 575         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 576                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 577                 STDERR->autoflush(1);
 578         }
 579         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 580         if (my $op_c = delete $self->{pkt_op_c}) {
 581                 close(delete $op_c->{sock});
 582         }
 583         if (my $pgr = delete $self->{pgr}) {
 584                 close($_) for (@$pgr[1,2]);
 585         }
 586         close $listener if $listener;
 587         undef $listener;
 588         $dir_idle->force_close if $dir_idle;
 589         undef $dir_idle;
 590         %PATH2CFG = ();
 591         $MDIR2CFGPATH = {};
 592         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 593         undef $errors_log;
 594         $quit = \&CORE::exit;
 595         if (!$self->{-eml_noisy}) { # only "lei import" sets this atm
 596                 my $cb = $SIG{__WARN__} // \&CORE::warn;
 597                 $SIG{__WARN__} = sub {
 598                         $cb->(@_) unless PublicInbox::Eml::warn_ignore(@_)
 599                 };
 600         }
 601         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 602 }
 603
 604 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 605         my ($self) = @_;
 606         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 607                 $op->close; # PublicInbox::PktOp::close
 608         }
 609         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 610         close $pkt_op_p->{op_p};
 611 }
 612
 613 sub pkt_op_pair {
 614         my ($self) = @_;
 615         require PublicInbox::OnDestroy;
 616         require PublicInbox::PktOp;
 617         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 618         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 619         $end;
 620 }
 621
 622 sub incr {
 623         my ($self, $field, $nr) = @_;
 624         $self->{counters}->{$field} += $nr;
 625 }
 626
 627 sub pkt_ops {
 628         my ($lei, $ops) = @_;
 629         $ops->{fail_handler} = [ $lei ];
 630         $ops->{sigpipe_handler} = [ $lei ];
 631         $ops->{x_it} = [ $lei ];
 632         $ops->{child_error} = [ $lei ];
 633         $ops->{incr} = [ $lei ];
 634         $ops;
 635 }
 636
 637 sub workers_start {
 638         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 639         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 640         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 641         my $end = $lei->pkt_op_pair;
 642         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 643         $flds->{lei} = $lei;
 644         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 645         delete $lei->{pkt_op_p};
 646         my $op_c = delete $lei->{pkt_op_c};
 647         @$end = ();
 648         $lei->event_step_init;
 649         ($op_c, $ops);
 650 }
 651
 652 # call this when we're ready to wait on events and yield to other clients
 653 sub wait_wq_events {
 654         my ($lei, $op_c, $ops) = @_;
 655         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 656                 $wq->wq_close(1);
 657         }
 658         $op_c->{ops} = $ops;
 659 }
 660
 661 sub _help {
 662         require PublicInbox::LeiHelp;
 663         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 664 }
 665
 666 sub optparse ($$$) {
 667         my ($self, $cmd, $argv) = @_;
 668         # allow _complete --help to complete, not show help
 669         return 1 if substr($cmd, 0, 1) eq '_';
 670         $self->{cmd} = $cmd;
 671         $OPT = $self->{opt} //= {};
 672         my $info = $CMD{$cmd} // [ '[...]' ];
 673         my ($proto, undef, @spec) = @$info;
 674         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 675         push @spec, qw(help|h);
 676         my $lone_dash;
 677         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 678                 $lone_dash = $spec[0];
 679                 $OPT->{$spec[0]} = \(my $var);
 680                 push @spec, '' => \$var;
 681         }
 682         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 683                 return _help($self, "bad arguments or options for $cmd");
 684         return _help($self) if $OPT->{help};
 685
 686         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 687
 688         # "-" aliases "stdin" or "clear"
 689         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 690
 691         my $i = 0;
 692         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 693         my ($err, $inf);
 694         my @args = split(/ /, $proto);
 695         for my $var (@args) {
 696                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 697                         $inf = defined($argv->[$i]) and last;
 698                         $var =~ s/\.\.\.\z//;
 699                         $err = "$var not supplied";
 700                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 701                         $argv->[$i++] // ($err = "$var not supplied");
 702                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 703                         $inf = 1;
 704                         last;
 705                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 706                         $i++;
 707                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 708                         $inf = 1 if index($var, '...') > 0;
 709                         my @or = split(/\|/, $var);
 710                         my $ok;
 711                         for my $o (@or) {
 712                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 713                                         my $sw = $1;
 714                                         # assume pipe/regular file on stdin
 715                                         # w/o args means stdin
 716                                         if ($sw eq 'stdin' && !@$argv &&
 717                                                         (-p $self->{0} ||
 718                                                          -f _) && -r _) {
 719                                                 $OPT->{stdin} //= 1;
 720                                         }
 721                                         $ok = defined($OPT->{$sw});
 722                                         last if $ok;
 723                                 } elsif (defined($argv->[$i])) {
 724                                         $ok = 1;
 725                                         $i++;
 726                                         last;
 727                                 } # else continue looping
 728                         }
 729                         last if $ok;
 730                         my $last = pop @or;
 731                         $err = join(', ', @or) . " or $last must be set";
 732                 } else {
 733                         warn "BUG: can't parse `$var' in $proto";
 734                 }
 735                 last if $err;
 736         }
 737         if (!$inf && scalar(@$argv) > scalar(@args)) {
 738                 $err //= 'too many arguments';
 739         }
 740         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 741 }
 742
 743 sub _tmp_cfg { # for lei -c <name>=<value> ...
 744         my ($self) = @_;
 745         my $cfg = _lei_cfg($self, 1);
 746         require File::Temp;
 747         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 748         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 749         $ft->autoflush(1);
 750         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 751 [include]
 752         path = $cfg->{-f}
 753 EOM
 754         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 755         for (@{$self->{opt}->{c}}) {
 756                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 757 `-c $_' is not of the form -c <name>=<value>'
 758 EOM
 759                 my $name = $1;
 760                 my $value = $2 // 1;
 761                 _config($self, '--add', $name, $value);
 762                 if (defined(my $v = $tmp->{$name})) {
 763                         if (ref($v) eq 'ARRAY') {
 764                                 push @$v, $value;
 765                         } else {
 766                                 $tmp->{$name} = [ $v, $value ];
 767                         }
 768                 } else {
 769                         $tmp->{$name} = $value;
 770                 }
 771         }
 772 }
 773
 774 sub lazy_cb ($$$) {
 775         my ($self, $cmd, $pfx) = @_;
 776         my $ucmd = $cmd;
 777         $ucmd =~ tr/-/_/;
 778         my $cb;
 779         $cb = $self->can($pfx.$ucmd) and return $cb;
 780         my $base = $ucmd;
 781         $base =~ s/_([a-z])/\u$1/g;
 782         my $pkg = "PublicInbox::Lei\u$base";
 783         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 784                 $pkg->can($pfx.$ucmd) : undef;
 785 }
 786
 787 sub dispatch {
 788         my ($self, $cmd, @argv) = @_;
 789         fchdir($self) or return;
 790         local %ENV = %{$self->{env}};
 791         local $current_lei = $self; # for __WARN__
 792         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 793         return _help($self, 'no command given') unless defined($cmd);
 794         # do not support Getopt bundling for this
 795         while ($cmd eq '-C' || $cmd eq '-c') {
 796                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 797                                         '-C DIRECTORY' : '-c <name>=<value>');
 798                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 799                 $cmd = shift(@argv) // return _help($self, 'no command given');
 800         }
 801         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 802                 optparse($self, $cmd, \@argv) or return;
 803                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 804                 if (my $chdir = $self->{opt}->{C}) {
 805                         for my $d (@$chdir) {
 806                                 next if $d eq ''; # same as git(1)
 807                                 chdir $d or return fail($self, "cd $d: $!");
 808                         }
 809                         open $self->{3}, '.' or return fail($self, "open . $!");
 810                 }
 811                 $cb->($self, @argv);
 812         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 813                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 814                         or return _help($self, 'bad arguments or options');
 815                 _help($self);
 816         } else {
 817                 fail($self, "`$cmd' is not an lei command");
 818         }
 819 }
 820
 821 sub _lei_cfg ($;$) {
 822         my ($self, $creat) = @_;
 823         return $self->{cfg} if $self->{cfg};
 824         my $f = _config_path($self);
 825         my @st = stat($f);
 826         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 827         my ($sto, $sto_dir, $watches, $lne);
 828         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 829                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 830                 ($sto, $sto_dir, $watches, $lne) =
 831                                 @$cfg{qw(-lei_store leistore.dir -watches
 832                                         -lei_note_event)};
 833         }
 834         if (!@st) {
 835                 unless ($creat) {
 836                         delete $self->{cfg};
 837                         return bless {}, 'PublicInbox::Config';
 838                 }
 839                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 840                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 841                 open my $fh, '>>', $f or die "open($f): $!\n";
 842                 @st = stat($fh) or die "fstat($f): $!\n";
 843                 $cur_st = pack('dd', $st[10], $st[7]);
 844                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 845         }
 846         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 847         $cfg->{-st} = $cur_st;
 848         $cfg->{'-f'} = $f;
 849         if ($sto && canonpath_harder($sto_dir // store_path($self))
 850                         eq canonpath_harder($cfg->{'leistore.dir'} //
 851                                                 store_path($self))) {
 852                 $cfg->{-lei_store} = $sto;
 853                 $cfg->{-lei_note_event} = $lne;
 854                 $cfg->{-watches} = $watches if $watches;
 855         }
 856         if (scalar(keys %PATH2CFG) > 5) {
 857                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 858                 for my $k (keys %PATH2CFG) {
 859                         delete($PATH2CFG{$k}) unless -f $k
 860                 }
 861         }
 862         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 863         refresh_watches($self);
 864         $cfg;
 865 }
 866
 867 sub _lei_store ($;$) {
 868         my ($self, $creat) = @_;
 869         my $cfg = _lei_cfg($self, $creat) // return;
 870         $cfg->{-lei_store} //= do {
 871                 require PublicInbox::LeiStore;
 872                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 873                 return unless $creat || -d $dir;
 874                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 875         };
 876 }
 877
 878 sub _config {
 879         my ($self, @argv) = @_;
 880         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 881         my $cfg = _lei_cfg($self, 1);
 882         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 883         my %rdr = map { $_ => $self->{$_} } (0..2);
 884         waitpid(spawn($cmd, \%env, \%rdr), 0);
 885 }
 886
 887 sub lei_daemon_pid { puts shift, $$ }
 888
 889 sub lei_daemon_kill {
 890         my ($self) = @_;
 891         my $sig = $self->{opt}->{signal} // 'TERM';
 892         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 893 }
 894
 895 # Shell completion helper.  Used by lei-completion.bash and hopefully
 896 # other shells.  Try to do as much here as possible to avoid redundancy
 897 # and improve maintainability.
 898 sub lei__complete {
 899         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 900         shift @argv; # ignore "lei", the entire command is sent
 901         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 902         my $cmd = shift @argv;
 903         my $info = $CMD{$cmd} // do { # filter matching commands
 904                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 905                 return;
 906         };
 907         my ($proto, undef, @spec) = @$info;
 908         my $cur = pop @argv;
 909         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 910         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 911                 # gross special case since the only git-config options
 912                 # Consider moving to a table if we need more special cases
 913                 # we use Getopt::Long for are the ones we reject, so these
 914                 # are the ones we don't reject:
 915                 if ($cmd eq 'config') {
 916                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 917                         @spec = qw(add z|null get get-all unset unset-all
 918                                 replace-all get-urlmatch
 919                                 remove-section rename-section
 920                                 name-only list|l edit|e
 921                                 get-color-name get-colorbool);
 922                         # fall-through
 923                 }
 924                 # generate short/long names from Getopt::Long specs
 925                 puts $self, grep(/$re/, qw(--help -h -C), map {
 926                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 927                         } elsif (s/\+\z//) { # verbose|v+
 928                         } elsif (s/!\z//) {
 929                                 # negation: mail! => no-mail|mail
 930                                 s/([\w\-]+)/$1|no-$1/g
 931                         }
 932                         map {
 933                                 my $x = length > 1 ? "--$_" : "-$_";
 934                                 $x eq $_cur ? () : $x;
 935                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 936                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 937         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 938                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 939         }
 940
 941         # switch args (e.g. lei q -f mbox<TAB>)
 942         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 943                 my $opt = quotemeta $1;
 944                 puts $self, map {
 945                         my $v = $OPTDESC{$_};
 946                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 947                         # get rid of ALL CAPS placeholder (e.g "OUT")
 948                         # (TODO: completion for external paths)
 949                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 950                         @v;
 951                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 952         }
 953         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 954                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 955         }
 956         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 957         # proto parsing.
 958 }
 959
 960 sub exec_buf ($$) {
 961         my ($argv, $env) = @_;
 962         my $argc = scalar @$argv;
 963         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 964         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 965         $buf;
 966 }
 967
 968 sub start_mua {
 969         my ($self) = @_;
 970         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 971                 refresh_watches($self);
 972         }
 973         my $mua = $self->{opt}->{mua} // return;
 974         my $mfolder = $self->{ovv}->{dst};
 975         my (@cmd, $replaced);
 976         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 977                 @cmd = ($mua, '-f');
 978         # TODO: help wanted: other common FOSS MUAs
 979         } else {
 980                 require Text::ParseWords;
 981                 @cmd = Text::ParseWords::shellwords($mua);
 982                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 983                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 984         }
 985         push @cmd, $mfolder unless defined($replaced);
 986         if ($self->{sock}) { # lei(1) client process runs it
 987                 # restore terminal: echo $query | lei q --stdin --mua=...
 988                 my $io = [];
 989                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 990                 send_exec_cmd($self, $io, \@cmd, {});
 991         }
 992         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 993                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 994         }
 995         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 996         $self->{opt}->{quiet} = 1;
 997         delete $self->{-progress};
 998         delete $self->{opt}->{verbose};
 999 }
1000
1001 sub send_exec_cmd { # tell script/lei to execute a command
1002         my ($self, $io, $cmd, $env) = @_;
1003         my $sock = $self->{sock} // die 'lei client gone';
1004         my $fds = [ map { fileno($_) } @$io ];
1005         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
1006 }
1007
1008 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1009         my ($self) = @_;
1010         my $alerts = $self->{opt}->{alert} // return;
1011         my $sock = $self->{sock};
1012         while (my $op = shift(@$alerts)) {
1013                 if ($op eq ':WINCH') {
1014                         # hit the process group that started the MUA
1015                         send($sock, '-WINCH', MSG_EOR) if $sock;
1016                 } elsif ($op eq ':bell') {
1017                         out($self, "\a");
1018                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1019                         push @$alerts, split(/(?<!\\),/, $op);
1020                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1021                         my $cmd = $1; # run an arbitrary command
1022                         require Text::ParseWords;
1023                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1024                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1025                 } else {
1026                         warn("W: unsupported --alert=$op\n"); # non-fatal
1027                 }
1028         }
1029 }
1030
1031 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1032 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1033
1034 # this also normalizes the path
1035 sub path_to_fd {
1036         my ($self, $path) = @_;
1037         $path = rel2abs($self, $path);
1038         $path =~ tr!/!/!s;
1039         $path_to_fd{$path} // (
1040                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1041                         fail($self, "cannot open $path from daemon") : -1
1042         );
1043 }
1044
1045 # caller needs to "-t $self->{1}" to check if tty
1046 sub start_pager {
1047         my ($self, $new_env) = @_;
1048         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1049         chomp(my $pager = <$fh> // '');
1050         close($fh) or warn "`git var PAGER' error: \$?=$?";
1051         return if $pager eq 'cat' || $pager eq '';
1052         $new_env //= {};
1053         $new_env->{LESS} //= 'FRX';
1054         $new_env->{LV} //= '-c';
1055         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1056         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1057         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1058         my $pgr = [ undef, @$rdr{1, 2} ];
1059         my $env = $self->{env};
1060         if ($self->{sock}) { # lei(1) process runs it
1061                 delete @$new_env{keys %$env}; # only set iff unset
1062                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1063         } else {
1064                 die 'BUG: start_pager w/o socket';
1065         }
1066         $self->{1} = $wpager;
1067         $self->{2} = $wpager if -t $self->{2};
1068         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1069         $self->{pgr} = $pgr;
1070 }
1071
1072 # display a message for user before spawning full-screen $VISUAL
1073 sub pgr_err {
1074         my ($self, @msg) = @_;
1075         return warn(@msg) unless $self->{sock} && -t $self->{2};
1076         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1077         print { $self->{2} } @msg;
1078         $self->{2}->autoflush(1);
1079         stop_pager($self);
1080         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1081 }
1082
1083 sub stop_pager {
1084         my ($self) = @_;
1085         my $pgr = delete($self->{pgr}) or return;
1086         $self->{2} = $pgr->[2];
1087         close(delete($self->{1})) if $self->{1};
1088         $self->{1} = $pgr->[1];
1089 }
1090
1091 sub accept_dispatch { # Listener {post_accept} callback
1092         my ($sock) = @_; # ignore other
1093         $sock->autoflush(1);
1094         my $self = bless { sock => $sock }, __PACKAGE__;
1095         vec(my $rvec = '', fileno($sock), 1) = 1;
1096         select($rvec, undef, undef, 60) or
1097                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1098         # (4096 * 33) >MAX_ARG_STRLEN
1099         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1100         if (!defined($fds[0])) {
1101                 warn(my $msg = "recv_cmd failed: $!");
1102                 return send($sock, $msg, MSG_EOR);
1103         } else {
1104                 my $i = 0;
1105                 for my $fd (@fds) {
1106                         open($self->{$i++}, '+<&=', $fd) and next;
1107                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1108                 }
1109                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1110         }
1111         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1112         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1113         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1114                 return send($sock, 'request command truncated', MSG_EOR);
1115         my ($argc, @argv) = split(/\0/, $buf, -1);
1116         undef $buf;
1117         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1118         $self->{env} = \%env;
1119         eval { dispatch($self, @argv) };
1120         send($sock, $@, MSG_EOR) if $@;
1121 }
1122
1123 sub dclose {
1124         my ($self) = @_;
1125         local $current_lei = $self;
1126         delete $self->{-progress};
1127         _drop_wq($self) if $self->{failed};
1128         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1129 }
1130
1131 # for long-running results
1132 sub event_step {
1133         my ($self) = @_;
1134         local %ENV = %{$self->{env}};
1135         local $current_lei = $self;
1136         eval {
1137                 my $buf;
1138                 while (my @fds = $recv_cmd->($self->{sock}, $buf, 4096)) {
1139                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1140                                 return if $! == EAGAIN;
1141                                 next if $! == EINTR;
1142                                 last if $! == ECONNRESET;
1143                                 die "recvmsg: $!";
1144                         }
1145                         for (@fds) { open my $rfh, '+<&=', $_ }
1146                 }
1147                 if ($buf eq '') {
1148                         _drop_wq($self); # EOF, client disconnected
1149                         dclose($self);
1150                 } elsif ($buf =~ /\A(STOP|CONT)\z/) {
1151                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1152                                 $wq->wq_kill($buf) or $wq->wq_kill_old($buf);
1153                         }
1154                 } else {
1155                         die "unrecognized client signal: $buf";
1156                 }
1157         };
1158         if (my $err = $@) {
1159                 eval { $self->fail($err) };
1160                 dclose($self);
1161         }
1162 }
1163
1164 sub event_step_init {
1165         my ($self) = @_;
1166         my $sock = $self->{sock} or return;
1167         $self->{-event_init_done} //= do { # persist til $ops done
1168                 $sock->blocking(0);
1169                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1170                 $sock;
1171         };
1172 }
1173
1174 sub noop {}
1175
1176 sub oldset { $oldset }
1177
1178 sub dump_and_clear_log {
1179         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1180                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1181                 chomp(my @lines = <STDIN>);
1182                 truncate(STDIN, 0) or
1183                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1184                 for my $l (@lines) { syslog('warning', '%s', $l) }
1185                 closelog(); # don't share across fork
1186         }
1187 }
1188
1189 sub cfg2lei ($) {
1190         my ($cfg) = @_;
1191         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1192         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1193         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1194         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1195         open($lei->{3}, '/') or die "open /: $!";
1196         my ($x, $y);
1197         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1198         $lei->{sock} = $x;
1199         require PublicInbox::LeiSelfSocket;
1200         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1201         $lei;
1202 }
1203
1204 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1205         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1206         my $fn = $ev->fullname;
1207         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1208                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1209                 $nc = '' if $ev->IN_DELETE;
1210                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1211                         my $cfg = $PATH2CFG{$f} // next;
1212                         eval {
1213                                 my $lei = cfg2lei($cfg);
1214                                 $lei->dispatch('note-event',
1215                                                 "maildir:$mdir", $nc, $bn, $fn);
1216                         };
1217                         warn "E: note-event $f: $@\n" if $@;
1218                 }
1219         }
1220         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1221                 $ev->cancel;
1222         }
1223         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1224                 delete $MDIR2CFGPATH->{$1};
1225         }
1226         if (!-e $fn) { # config file or Maildir gone
1227                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1228                         delete $cfgpaths->{$fn};
1229                 }
1230                 delete $PATH2CFG{$fn};
1231         }
1232 }
1233
1234 # lei(1) calls this when it can't connect
1235 sub lazy_start {
1236         my ($path, $errno, $narg) = @_;
1237         local ($errors_log, $listener);
1238         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1239         $errors_log = "$sock_dir/errors.log";
1240         my $addr = pack_sockaddr_un($path);
1241         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1242         umask(077) // die("umask(077): $!");
1243         $lk->lock_acquire;
1244         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1245         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1246                 return if connect($listener, $addr); # another process won
1247                 if ($errno == ECONNREFUSED && -S $path) {
1248                         unlink($path) or die "unlink($path): $!";
1249                 }
1250         } else {
1251                 $! = $errno; # allow interpolation to stringify in die
1252                 die "connect($path): $!";
1253         }
1254         bind($listener, $addr) or die "bind($path): $!";
1255         $lk->lock_release;
1256         undef $lk;
1257         my @st = stat($path) or die "stat($path): $!";
1258         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1259         local $oldset = PublicInbox::DS::block_signals();
1260         if ($narg == 5) {
1261                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1262                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1263                         require PublicInbox::CmdIPC4;
1264                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1265                         PublicInbox::CmdIPC4->can('recv_cmd4');
1266                 };
1267         }
1268         $recv_cmd or die <<"";
1269 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1270
1271         require PublicInbox::Listener;
1272         require PublicInbox::PktOp;
1273         (-p STDOUT) or die "E: stdout must be a pipe\n";
1274         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1275         STDIN->autoflush(1);
1276         dump_and_clear_log();
1277         POSIX::setsid() > 0 or die "setsid: $!";
1278         my $pid = fork // die "fork: $!";
1279         return if $pid;
1280         $0 = "lei-daemon $path";
1281         local %PATH2CFG;
1282         local $MDIR2CFGPATH;
1283         $listener->blocking(0);
1284         my $exit_code;
1285         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1286         local $quit = do {
1287                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1288                 sub {
1289                         $exit_code //= shift;
1290                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1291                         my $lis = $pil or exit($exit_code);
1292                         # closing eof_p triggers \&noop wakeup
1293                         $listener = $eof_p = $pil = $path = undef;
1294                         $lis->close; # DS::close
1295                         PublicInbox::DS->SetLoopTimeout(1000);
1296                 };
1297         };
1298         my $sig = {
1299                 CHLD => \&PublicInbox::DS::enqueue_reap,
1300                 QUIT => $quit,
1301                 INT => $quit,
1302                 TERM => $quit,
1303                 HUP => \&noop,
1304                 USR1 => \&noop,
1305                 USR2 => \&noop,
1306         };
1307         require PublicInbox::DirIdle;
1308         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1309                 # just rely on wakeup to hit PostLoopCallback set below
1310                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1311         }, 1);
1312         PublicInbox::DS->SetPostLoopCallback(sub {
1313                 my ($dmap, undef) = @_;
1314                 if (@st = defined($path) ? stat($path) : ()) {
1315                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1316                                 warn "$path dev/ino changed, quitting\n";
1317                                 $path = undef;
1318                         }
1319                 } elsif (defined($path)) { # ENOENT is common
1320                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1321                         undef $path;
1322                         $quit->();
1323                 }
1324                 return 1 if defined($path);
1325                 my $now = now();
1326                 my $n = 0;
1327                 for my $s (values %$dmap) {
1328                         $s->can('busy') or next;
1329                         if ($s->busy($now)) {
1330                                 ++$n;
1331                         } else {
1332                                 $s->close;
1333                         }
1334                 }
1335                 $n; # true: continue, false: stop
1336         });
1337
1338         # STDIN was redirected to /dev/null above, closing STDERR and
1339         # STDOUT will cause the calling `lei' client process to finish
1340         # reading the <$daemon> pipe.
1341         local $SIG{__WARN__} = sub {
1342                 $current_lei ? err($current_lei, @_) : warn(
1343                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1344         };
1345         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1346         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1347         # $daemon pipe to `lei' closed, main loop begins:
1348         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1349         warn "event loop error: $@\n" if $@;
1350         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1351         PublicInbox::DS::sig_setmask($oldset);
1352         dump_and_clear_log();
1353         exit($exit_code // 0);
1354 }
1355
1356 sub busy { 1 } # prevent daemon-shutdown if client is connected
1357
1358 # ensures stdout hits the FS before sock disconnects so a client
1359 # can immediately reread it
1360 sub DESTROY {
1361         my ($self) = @_;
1362         if (my $counters = delete $self->{counters}) {
1363                 for my $k (sort keys %$counters) {
1364                         my $nr = $counters->{$k};
1365                         $self->child_error(0, "$nr $k messages");
1366                 }
1367         }
1368         $self->{1}->autoflush(1) if $self->{1};
1369         stop_pager($self);
1370         dump_and_clear_log();
1371         # preserve $? for ->fail or ->x_it code
1372 }
1373
1374 sub wq_done_wait { # dwaitpid callback
1375         my ($arg, $pid) = @_;
1376         my ($wq, $lei) = @$arg;
1377         local $current_lei = $lei;
1378         my $err_type = $lei->{-err_type};
1379         $? and $lei->child_error($?,
1380                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1381         $lei->dclose;
1382 }
1383
1384 sub fchdir {
1385         my ($lei) = @_;
1386         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1387         chdir($dh) || $lei->fail("fchdir: $!");
1388 }
1389
1390 sub wq_eof { # EOF callback for main daemon
1391         my ($lei) = @_;
1392         local $current_lei = $lei;
1393         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1394         $wq1->wq_wait_old($wq1->can('_wq_done_wait') // \&wq_done_wait, $lei);
1395 }
1396
1397 sub watch_state_ok ($) {
1398         my ($state) = $_[-1]; # $_[0] may be $self
1399         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1400 }
1401
1402 sub cancel_maildir_watch ($$) {
1403         my ($d, $cfg_f) = @_;
1404         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1405         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1406                 delete $MDIR2CFGPATH->{$d};
1407         for my $x (@{$w // []}) { $x->cancel }
1408 }
1409
1410 sub add_maildir_watch ($$) {
1411         my ($d, $cfg_f) = @_;
1412         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1413                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1414                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1415         }
1416 }
1417
1418 sub refresh_watches {
1419         my ($lei) = @_;
1420         $dir_idle or return;
1421         my $cfg = _lei_cfg($lei) or return;
1422         my $old = $cfg->{-watches};
1423         my $watches = $cfg->{-watches} //= {};
1424         my %seen;
1425         my $cfg_f = $cfg->{'-f'};
1426         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1427                 my $url = substr($w, length('watch.'), -length('.state'));
1428                 require PublicInbox::LeiWatch;
1429                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1430                 $seen{$url} = undef;
1431                 my $state = $cfg->get_1("watch.$url.state");
1432                 if (!watch_state_ok($state)) {
1433                         warn("watch.$url.state=$state not supported\n");
1434                         next;
1435                 }
1436                 if ($url =~ /\Amaildir:(.+)/i) {
1437                         my $d = canonpath_harder($1);
1438                         if ($state eq 'pause') {
1439                                 cancel_maildir_watch($d, $cfg_f);
1440                         } else {
1441                                 add_maildir_watch($d, $cfg_f);
1442                         }
1443                 } else { # TODO: imap/nntp/jmap
1444                         $lei->child_error(0, "E: watch $url not supported, yet")
1445                 }
1446         }
1447
1448         # add all known Maildir folders as implicit watches
1449         my $lms = $lei->lms;
1450         if ($lms) {
1451                 $lms->lms_write_prepare;
1452                 for my $d ($lms->folders('maildir:')) {
1453                         substr($d, 0, length('maildir:')) = '';
1454
1455                         # fixup old bugs while we're iterating:
1456                         my $cd = canonpath_harder($d);
1457                         my $f = "maildir:$cd";
1458                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1459                         next if $watches->{$f}; # may be set to pause
1460                         require PublicInbox::LeiWatch;
1461                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1462                         $seen{$f} = undef;
1463                         add_maildir_watch($cd, $cfg_f);
1464                 }
1465         }
1466         if ($old) { # cull old non-existent entries
1467                 for my $url (keys %$old) {
1468                         next if exists $seen{$url};
1469                         delete $old->{$url};
1470                         if ($url =~ /\Amaildir:(.+)/i) {
1471                                 my $d = canonpath_harder($1);
1472                                 cancel_maildir_watch($d, $cfg_f);
1473                         } else { # TODO: imap/nntp/jmap
1474                                 $lei->child_error(0, "E: watch $url TODO");
1475                         }
1476                 }
1477         }
1478         if (scalar keys %$watches) {
1479                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1480         } else {
1481                 delete $cfg->{-watches};
1482         }
1483 }
1484
1485 # TODO: support SHA-256
1486 sub git_oid {
1487         my $eml = $_[-1];
1488         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1489         git_sha(1, $eml);
1490 }
1491
1492 sub lms {
1493         my ($lei, $rw) = @_;
1494         my $sto = $lei->{sto} // _lei_store($lei) // return;
1495         require PublicInbox::LeiMailSync;
1496         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1497         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1498 }
1499
1500 sub sto_done_request {
1501         my ($lei, $sock) = @_;
1502         local $current_lei = $lei;
1503         eval {
1504                 if ($sock //= $lei->{sock}) { # issue, async wait
1505                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1506                 } else { # forcibly wait
1507                         my $wait = $lei->{sto}->wq_do('done');
1508                 }
1509         };
1510         warn($@) if $@;
1511 }
1512
1513 sub cfg_dump ($$) {
1514         my ($lei, $f) = @_;
1515         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1516         return $ret if !$@;
1517         warn($@);
1518         undef;
1519 }
1520
1521 sub request_umask {
1522         my ($lei) = @_;
1523         my $s = $lei->{sock} // return;
1524         send($s, 'umask', MSG_EOR) // die "send: $!";
1525         vec(my $rvec = '', fileno($s), 1) = 1;
1526         select($rvec, undef, undef, 2) or die 'timeout waiting for umask';
1527         recv($s, my $v, 5, 0) // die "recv: $!";
1528         (my $u, $lei->{client_umask}) = unpack('AV', $v);
1529         $u eq 'u' or warn "E: recv $v has no umask";
1530 }
1531
1532 1;