lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we generate shell completion + help using %CMD and %OPTDESC,
 139 # see lei__complete() and PublicInbox::LeiHelp
 140 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 141 our %CMD = ( # sorted in order of importance/use:
 142 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 143         'stdin|', # /|\z/ must be first for lone dash
 144         @lxs_opt,
 145         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 146         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 147         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 148         opt_dash('limit|n=i', '[0-9]+') ],
 149
 150 'up' => [ 'OUTPUT|--all', 'update saved search',
 151         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 152
 153 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 154         'stdin|', # /|\z/ must be first for lone dash
 155         # some of these options are ridiculous for lcat
 156         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 157         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 158         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 159         opt_dash('limit|n=i', '[0-9]+') ],
 160
 161 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 162         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 163         @lxs_opt, @c_opt ],
 164
 165 'add-external' => [ 'LOCATION',
 166         'add/set priority of a publicinbox|extindex for extra matches',
 167         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 168         verbose|v+), @c_opt, index_opt(),
 169         PublicInbox::LeiQuery::curl_opt() ],
 170 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 171         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 172 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 173 'ls-sync' => [ '', 'list sync folders',
 174                 qw(z|0 z|0 globoff|g invert-match|v local remote), @c_opt ],
 175 'forget-external' => [ 'LOCATION...|--prune',
 176         'exclude further results from a publicinbox|extindex',
 177         qw(prune), @c_opt ],
 178
 179 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 180                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 181 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 182                 qw(verbose|v+), @c_opt ],
 183 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 184                         @c_opt ],
 185
 186 'plonk' => [ '--threads|--from=IDENT',
 187         'exclude mail matching From: or threads from non-Message-ID searches',
 188         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 189 'tag' => [ 'KEYWORDS...',
 190         'set/unset keywords and/or labels on message(s)',
 191         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 192         pass_through('-kw:foo for delete') ],
 193 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 194         "exclude message(s) on stdin from `q' search results",
 195         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 196
 197 'purge-mailsource' => [ 'LOCATION|--all',
 198         'remove imported messages from IMAP, Maildirs, and MH',
 199         qw(exact! all jobs:i indexed), @c_opt ],
 200
 201 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 202         qw(import! kw! interval=s recursive|r
 203         exclude=s include=s), @c_opt ],
 204 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 205                 qw(format|f=s z), @c_opt ],
 206 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 207 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 208 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 209         qw(prune), @c_opt ],
 210
 211 'import' => [ 'LOCATION...|--stdin',
 212         'one-time import/update from URL or filesystem',
 213         qw(stdin| offset=i recursive|r exclude=s include|I=s
 214         lock=s@ in-format|F=s kw! verbose|v+ incremental! sync!), @c_opt ],
 215 'convert' => [ 'LOCATION...|--stdin',
 216         'one-time conversion from URL or filesystem to another format',
 217         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 218         lock=s@ kw!), @c_opt ],
 219 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 220         "use a patch to generate a query for `lei q --stdin'",
 221         qw(stdin| want|w=s@ uri debug), @c_opt ],
 222 'config' => [ '[...]', sub {
 223                 'git-config(1) wrapper for '._config_path($_[0]);
 224         }, qw(config-file|system|global|file|f=s), # for conflict detection
 225          qw(c=s@ C=s@), pass_through('git config') ],
 226 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 227         qw(pretty ascii dir=s), @c_opt ],
 228
 229 'init' => [ '[DIRNAME]', sub {
 230         "initialize storage, default: ".store_path($_[0]);
 231         }, @c_opt ],
 232 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 233         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 234         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 235 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 236 'help' => [ '[SUBCOMMAND]', 'show help' ],
 237
 238 # XXX do we need this?
 239 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 240
 241 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 242         'rewrite git history in an attempt to improve compression',
 243         qw(gc!), @c_opt ],
 244
 245 # internal commands are prefixed with '_'
 246 '_complete' => [ '[...]', 'internal shell completion helper',
 247                 pass_through('everything') ],
 248 ); # @CMD
 249
 250 # switch descriptions, try to keep consistent across commands
 251 # $spec: Getopt::Long option specification
 252 # $spec => [@ALLOWED_VALUES (default is first), $description],
 253 # $spec => $description
 254 # "$SUB_COMMAND TAB $spec" => as above
 255 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 256                         'specify message input format' ];
 257 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 258
 259 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 260 my %OPTDESC = (
 261 'help|h' => 'show this built-in help',
 262 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 263 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 264 'quiet|q' => 'be quiet',
 265 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 266         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 267
 268 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 269 'globoff|g' => "do not match locations using '*?' wildcards ".
 270                 "and\xa0'[]'\x{a0}ranges",
 271 'verbose|v+' => 'be more verbose',
 272 'external!' => 'do not use externals',
 273 'mail!' => 'do not look in mail storage for OID',
 274 'cwd!' => 'do not look in git repo of current working directory',
 275 'oid-a|A=s' => 'pre-image OID',
 276 'path-a|a=s' => 'pre-image pathname associated with OID',
 277 'path-b|b=s' => 'post-image pathname associated with OID',
 278 'git-dir=s@' => 'additional git repository to scan',
 279 'torsocks=s' => ['VAL|auto|no|yes',
 280                 'whether or not to wrap git and curl commands with torsocks'],
 281 'no-torsocks' => 'alias for --torsocks=no',
 282 'save' =>  "save a search for `lei up'",
 283 'import-remote!' => 'do not memoize remote messages into local store',
 284
 285 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 286
 287 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 288                 'deduplication strategy'],
 289 'threads|t+' =>
 290         'return all messages in the same threads as the actual match(es)',
 291
 292 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 293                 'search prefixes to extract (default: dfpost7)' ],
 294
 295 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 296         'run command(s) or perform ops when done writing to output ' .
 297         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 298         'nothing otherwise)' ],
 299
 300 'augment|a' => 'augment --output destination instead of clobbering',
 301
 302 'output|mfolder|o=s' => [ 'MFOLDER',
 303         "destination (e.g.\xa0`/path/to/Maildir', ".
 304         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 305 'mua=s' => [ 'CMD',
 306         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 307
 308 'inbox-version=i' => [ 'NUM|1|2',
 309                 'force a public-inbox version with --mirror'],
 310 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 311
 312 # public-inbox-index options
 313 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 314 'compact' => 'run compact index after mirroring',
 315 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 316         "indexlevel with --mirror (default: full)" ],
 317 'max_size|max-size=s' => [ 'SIZE',
 318         'do not index messages larger than SIZE (default: infinity)' ],
 319 'batch_size|batch-size=s' => [ 'SIZE',
 320         'flush changes to OS after given number of bytes (default: 1m)' ],
 321 'sequential_shard|sequential-shard' =>
 322         'index Xapian shards sequentially for slow storage',
 323 'skip-docdata' =>
 324         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 325
 326 'format|f=s     q' => [
 327         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 328                 'specify output format, default depends on --output'],
 329 'exclude=s@     q' => [ 'LOCATION',
 330                 'exclude specified external(s) from search' ],
 331 'include|I=s@   q' => [ 'LOCATION',
 332                 'include specified external(s) in search' ],
 333 'only=s@        q' => [ 'LOCATION',
 334                 'only use specified external(s) for search' ],
 335 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 336                 'control number of search and writer jobs' ],
 337 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 338
 339 'in-format|F=s' => $stdin_formats,
 340 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 341                         'listing output format' ],
 342 'l      ls-search' => 'long listing format',
 343 'format|f=s     ls-external' => $ls_format,
 344
 345 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 346 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 347
 348 'sort|s=s' => [ 'VAL|received|relevance|docid',
 349                 "order of results is `--output'-dependent"],
 350 'reverse|r' => 'reverse search results', # like sort(1)
 351
 352 'boost=i' => 'increase/decrease priority of results (default: 0)',
 353
 354 'local' => 'limit operations to the local filesystem',
 355 'local!' => 'exclude results from the local filesystem',
 356 'remote' => 'limit operations to those requiring network access',
 357 'remote!' => 'prevent operations requiring network access',
 358
 359 'all:s  up' => ['local', 'update all (local) saved searches' ],
 360
 361 'mid=s' => 'specify the Message-ID of a message',
 362 'oid=s' => 'specify the git object ID of a message',
 363
 364 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 365 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 366 'include=s' => 'include mailboxes/newsgroups based on pattern',
 367
 368 'exact' => 'operate on exact header matches only',
 369 'exact!' => 'rely on content match instead of exact header matches',
 370
 371 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 372
 373 'kw!' => 'disable/enable importing keywords (aka "flags")',
 374
 375 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 376 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 377
 378 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 379 ); # %OPTDESC
 380
 381 my %CONFIG_KEYS = (
 382         'leistore.dir' => 'top-level storage location',
 383 );
 384
 385 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 386
 387 sub _drop_wq {
 388         my ($self) = @_;
 389         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) { $wq->DESTROY }
 390 }
 391
 392 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 393 sub x_it ($$) {
 394         my ($self, $code) = @_;
 395         # make sure client sees stdout before exit
 396         $self->{1}->autoflush(1) if $self->{1};
 397         dump_and_clear_log();
 398         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 399                 send($s, "x_it $code", MSG_EOR);
 400         } elsif ($self->{oneshot}) {
 401                 # don't want to end up using $? from child processes
 402                 _drop_wq($self);
 403                 # cleanup anything that has tempfiles or open file handles
 404                 %PATH2CFG = ();
 405                 delete @$self{qw(ovv dedupe sto cfg)};
 406                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 407                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 408                         kill $signum, $$;
 409                         sleep(1) while 1; # wait for signal
 410                 } else {
 411                         $quit->($code >> 8);
 412                 }
 413         } # else ignore if client disconnected
 414 }
 415
 416 sub err ($;@) {
 417         my $self = shift;
 418         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 419         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 420         print $err @_, @eor and return;
 421         my $old_err = delete $self->{2};
 422         close($old_err) if $! == EPIPE && $old_err;
 423         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 424         print $err @_, @eor or print STDERR @_, @eor;
 425 }
 426
 427 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 428
 429 sub fail_handler ($;$$) {
 430         my ($lei, $code, $io) = @_;
 431         close($io) if $io; # needed to avoid warnings on SIGPIPE
 432         _drop_wq($lei);
 433         x_it($lei, $code // (1 << 8));
 434 }
 435
 436 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 437         fail_handler($_[0], 13, delete $_[0]->{1});
 438 }
 439
 440 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 441 sub sigint_reap {
 442         my ($pgid) = @_;
 443         dwaitpid($pgid) if kill('-INT', $pgid);
 444 }
 445
 446 sub fail ($$;$) {
 447         my ($self, $buf, $exit_code) = @_;
 448         err($self, $buf) if defined $buf;
 449         # calls fail_handler:
 450         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 451         x_it($self, ($exit_code // 1) << 8);
 452         undef;
 453 }
 454
 455 sub out ($;@) {
 456         my $self = shift;
 457         return if print { $self->{1} // return } @_; # likely
 458         return note_sigpipe($self, 1) if $! == EPIPE;
 459         my $err = "error writing to output: $!";
 460         delete $self->{1};
 461         fail($self, $err);
 462 }
 463
 464 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 465
 466 sub child_error { # passes non-fatal curl exit codes to user
 467         my ($self, $child_error, $msg) = @_; # child_error is $?
 468         $self->err($msg) if $msg;
 469         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 470                 # send to the parent lei-daemon or to lei(1) client
 471                 send($s, "child_error $child_error", MSG_EOR);
 472         } elsif (!$PublicInbox::DS::in_loop) {
 473                 $self->{child_error} = $child_error;
 474         } # else noop if client disconnected
 475 }
 476
 477 sub note_sigpipe { # triggers sigpipe_handler
 478         my ($self, $fd) = @_;
 479         close(delete($self->{$fd})); # explicit close silences Perl warning
 480         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 481         x_it($self, 13);
 482 }
 483
 484 sub _lei_atfork_child {
 485         my ($self, $persist) = @_;
 486         # we need to explicitly close things which are on stack
 487         if ($persist) {
 488                 chdir '/' or die "chdir(/): $!";
 489                 my @io = delete @$self{qw(0 1 2 sock)};
 490                 unless ($self->{oneshot}) {
 491                         close($_) for @io;
 492                 }
 493                 if (my $cfg = $self->{cfg}) {
 494                         delete $cfg->{-lei_store};
 495                 }
 496         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 497                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 498         }
 499         for (delete @$self{qw(3 old_1 au_done)}) {
 500                 close($_) if defined($_);
 501         }
 502         if (my $op_c = delete $self->{pkt_op_c}) {
 503                 close(delete $op_c->{sock});
 504         }
 505         if (my $pgr = delete $self->{pgr}) {
 506                 close($_) for (@$pgr[1,2]);
 507         }
 508         close $listener if $listener;
 509         undef $listener;
 510         %PATH2CFG = ();
 511         undef $errors_log;
 512         $quit = \&CORE::exit;
 513         $self->{-eml_noisy} or # only "lei import" sets this atm
 514                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 515         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 516 }
 517
 518 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 519         my ($self) = @_;
 520         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 521                 $op->close; # PublicInbox::PktOp::close
 522         }
 523         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 524         close $unclosed_after_die;
 525 }
 526
 527 sub pkt_op_pair {
 528         my ($self) = @_;
 529         require PublicInbox::OnDestroy;
 530         require PublicInbox::PktOp;
 531         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 532         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 533         $end;
 534 }
 535
 536 sub workers_start {
 537         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 538         $ops = {
 539                 '!' => [ \&fail_handler, $lei ],
 540                 '|' => [ \&sigpipe_handler, $lei ],
 541                 'x_it' => [ \&x_it, $lei ],
 542                 'child_error' => [ \&child_error, $lei ],
 543                 ($ops ? %$ops : ()),
 544         };
 545         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 546         my $end = $lei->pkt_op_pair;
 547         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 548         delete $lei->{pkt_op_p};
 549         my $op_c = delete $lei->{pkt_op_c};
 550         @$end = ();
 551         $lei->event_step_init;
 552         ($op_c, $ops);
 553 }
 554
 555 sub _help {
 556         require PublicInbox::LeiHelp;
 557         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 558 }
 559
 560 sub optparse ($$$) {
 561         my ($self, $cmd, $argv) = @_;
 562         # allow _complete --help to complete, not show help
 563         return 1 if substr($cmd, 0, 1) eq '_';
 564         $self->{cmd} = $cmd;
 565         $OPT = $self->{opt} //= {};
 566         my $info = $CMD{$cmd} // [ '[...]' ];
 567         my ($proto, undef, @spec) = @$info;
 568         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 569         push @spec, qw(help|h);
 570         my $lone_dash;
 571         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 572                 $lone_dash = $spec[0];
 573                 $OPT->{$spec[0]} = \(my $var);
 574                 push @spec, '' => \$var;
 575         }
 576         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 577                 return _help($self, "bad arguments or options for $cmd");
 578         return _help($self) if $OPT->{help};
 579
 580         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 581
 582         # "-" aliases "stdin" or "clear"
 583         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 584
 585         my $i = 0;
 586         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 587         my ($err, $inf);
 588         my @args = split(/ /, $proto);
 589         for my $var (@args) {
 590                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 591                         $inf = defined($argv->[$i]) and last;
 592                         $var =~ s/\.\.\.\z//;
 593                         $err = "$var not supplied";
 594                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 595                         $argv->[$i++] // ($err = "$var not supplied");
 596                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 597                         $inf = 1;
 598                         last;
 599                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 600                         $i++;
 601                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 602                         $inf = 1 if index($var, '...') > 0;
 603                         my @or = split(/\|/, $var);
 604                         my $ok;
 605                         for my $o (@or) {
 606                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 607                                         $ok = defined($OPT->{$1});
 608                                         last if $ok;
 609                                 } elsif (defined($argv->[$i])) {
 610                                         $ok = 1;
 611                                         $i++;
 612                                         last;
 613                                 } # else continue looping
 614                         }
 615                         last if $ok;
 616                         my $last = pop @or;
 617                         $err = join(', ', @or) . " or $last must be set";
 618                 } else {
 619                         warn "BUG: can't parse `$var' in $proto";
 620                 }
 621                 last if $err;
 622         }
 623         if (!$inf && scalar(@$argv) > scalar(@args)) {
 624                 $err //= 'too many arguments';
 625         }
 626         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 627 }
 628
 629 sub _tmp_cfg { # for lei -c <name>=<value> ...
 630         my ($self) = @_;
 631         my $cfg = _lei_cfg($self, 1);
 632         require File::Temp;
 633         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 634         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 635         $ft->autoflush(1);
 636         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 637 [include]
 638         path = $cfg->{-f}
 639 EOM
 640         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 641         for (@{$self->{opt}->{c}}) {
 642                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 643 `-c $_' is not of the form -c <name>=<value>'
 644 EOM
 645                 my $name = $1;
 646                 my $value = $2 // 1;
 647                 _config($self, '--add', $name, $value);
 648                 if (defined(my $v = $tmp->{$name})) {
 649                         if (ref($v) eq 'ARRAY') {
 650                                 push @$v, $value;
 651                         } else {
 652                                 $tmp->{$name} = [ $v, $value ];
 653                         }
 654                 } else {
 655                         $tmp->{$name} = $value;
 656                 }
 657         }
 658 }
 659
 660 sub lazy_cb ($$$) {
 661         my ($self, $cmd, $pfx) = @_;
 662         my $ucmd = $cmd;
 663         $ucmd =~ tr/-/_/;
 664         my $cb;
 665         $cb = $self->can($pfx.$ucmd) and return $cb;
 666         my $base = $ucmd;
 667         $base =~ s/_([a-z])/\u$1/g;
 668         my $pkg = "PublicInbox::Lei\u$base";
 669         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 670                 $pkg->can($pfx.$ucmd) : undef;
 671 }
 672
 673 sub dispatch {
 674         my ($self, $cmd, @argv) = @_;
 675         local $current_lei = $self; # for __WARN__
 676         dump_and_clear_log("from previous run\n");
 677         return _help($self, 'no command given') unless defined($cmd);
 678         # do not support Getopt bundling for this
 679         while ($cmd eq '-C' || $cmd eq '-c') {
 680                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 681                                         '-C DIRECTORY' : '-c <name>=<value>');
 682                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 683                 $cmd = shift(@argv) // return _help($self, 'no command given');
 684         }
 685         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 686                 optparse($self, $cmd, \@argv) or return;
 687                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 688                 if (my $chdir = $self->{opt}->{C}) {
 689                         for my $d (@$chdir) {
 690                                 next if $d eq ''; # same as git(1)
 691                                 chdir $d or return fail($self, "cd $d: $!");
 692                         }
 693                         if (delete $self->{3}) { # update cwd for rel2abs
 694                                 opendir my $dh, '.' or
 695                                         return fail($self, "opendir . $!");
 696                                 $self->{3} = $dh;
 697                         }
 698                 }
 699                 $cb->($self, @argv);
 700         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 701                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 702                         or return _help($self, 'bad arguments or options');
 703                 _help($self);
 704         } else {
 705                 fail($self, "`$cmd' is not an lei command");
 706         }
 707 }
 708
 709 sub _lei_cfg ($;$) {
 710         my ($self, $creat) = @_;
 711         return $self->{cfg} if $self->{cfg};
 712         my $f = _config_path($self);
 713         my @st = stat($f);
 714         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 715         my ($sto, $sto_dir);
 716         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 717                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 718                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 719         }
 720         if (!@st) {
 721                 unless ($creat) {
 722                         delete $self->{cfg};
 723                         return bless {}, 'PublicInbox::Config';
 724                 }
 725                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 726                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 727                 open my $fh, '>>', $f or die "open($f): $!\n";
 728                 @st = stat($fh) or die "fstat($f): $!\n";
 729                 $cur_st = pack('dd', $st[10], $st[7]);
 730                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 731         }
 732         my $cfg = PublicInbox::Config->git_config_dump($f);
 733         $cfg->{-st} = $cur_st;
 734         $cfg->{'-f'} = $f;
 735         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 736                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 737                                                 store_path($self))) {
 738                 $cfg->{-lei_store} = $sto;
 739         }
 740         if (scalar(keys %PATH2CFG) > 5) {
 741                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 742                 for my $k (keys %PATH2CFG) {
 743                         delete($PATH2CFG{$k}) unless -f $k
 744                 }
 745         }
 746         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 747 }
 748
 749 sub _lei_store ($;$) {
 750         my ($self, $creat) = @_;
 751         my $cfg = _lei_cfg($self, $creat);
 752         $cfg->{-lei_store} //= do {
 753                 require PublicInbox::LeiStore;
 754                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 755                 return unless $creat || -d $dir;
 756                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 757         };
 758 }
 759
 760 sub _config {
 761         my ($self, @argv) = @_;
 762         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 763         my $cfg = _lei_cfg($self, 1);
 764         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 765         my %rdr = map { $_ => $self->{$_} } (0..2);
 766         waitpid(spawn($cmd, \%env, \%rdr), 0);
 767 }
 768
 769 sub lei_config {
 770         my ($self, @argv) = @_;
 771         $self->{opt}->{'config-file'} and return fail $self,
 772                 "config file switches not supported by `lei config'";
 773         _config(@_);
 774         x_it($self, $?) if $?;
 775 }
 776
 777 sub lei_daemon_pid { puts shift, $$ }
 778
 779 sub lei_daemon_kill {
 780         my ($self) = @_;
 781         my $sig = $self->{opt}->{signal} // 'TERM';
 782         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 783 }
 784
 785 # Shell completion helper.  Used by lei-completion.bash and hopefully
 786 # other shells.  Try to do as much here as possible to avoid redundancy
 787 # and improve maintainability.
 788 sub lei__complete {
 789         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 790         shift @argv; # ignore "lei", the entire command is sent
 791         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 792         my $cmd = shift @argv;
 793         my $info = $CMD{$cmd} // do { # filter matching commands
 794                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 795                 return;
 796         };
 797         my ($proto, undef, @spec) = @$info;
 798         my $cur = pop @argv;
 799         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 800         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 801                 # gross special case since the only git-config options
 802                 # Consider moving to a table if we need more special cases
 803                 # we use Getopt::Long for are the ones we reject, so these
 804                 # are the ones we don't reject:
 805                 if ($cmd eq 'config') {
 806                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 807                         @spec = qw(add z|null get get-all unset unset-all
 808                                 replace-all get-urlmatch
 809                                 remove-section rename-section
 810                                 name-only list|l edit|e
 811                                 get-color-name get-colorbool);
 812                         # fall-through
 813                 }
 814                 # generate short/long names from Getopt::Long specs
 815                 puts $self, grep(/$re/, qw(--help -h -C), map {
 816                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 817                         } elsif (s/\+\z//) { # verbose|v+
 818                         } elsif (s/!\z//) {
 819                                 # negation: mail! => no-mail|mail
 820                                 s/([\w\-]+)/$1|no-$1/g
 821                         }
 822                         map {
 823                                 my $x = length > 1 ? "--$_" : "-$_";
 824                                 $x eq $_cur ? () : $x;
 825                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 826                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 827         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 828                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 829         }
 830
 831         # switch args (e.g. lei q -f mbox<TAB>)
 832         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 833                 my $opt = quotemeta $1;
 834                 puts $self, map {
 835                         my $v = $OPTDESC{$_};
 836                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 837                         # get rid of ALL CAPS placeholder (e.g "OUT")
 838                         # (TODO: completion for external paths)
 839                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 840                         @v;
 841                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 842         }
 843         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 844                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 845         }
 846         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 847         # proto parsing.
 848 }
 849
 850 sub exec_buf ($$) {
 851         my ($argv, $env) = @_;
 852         my $argc = scalar @$argv;
 853         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 854         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 855         $buf;
 856 }
 857
 858 sub start_mua {
 859         my ($self) = @_;
 860         my $mua = $self->{opt}->{mua} // return;
 861         my $mfolder = $self->{ovv}->{dst};
 862         my (@cmd, $replaced);
 863         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 864                 @cmd = ($mua, '-f');
 865         # TODO: help wanted: other common FOSS MUAs
 866         } else {
 867                 require Text::ParseWords;
 868                 @cmd = Text::ParseWords::shellwords($mua);
 869                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 870                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 871         }
 872         push @cmd, $mfolder unless defined($replaced);
 873         if ($self->{sock}) { # lei(1) client process runs it
 874                 # restore terminal: echo $query | lei q -stdin --mua=...
 875                 my $io = [];
 876                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 877                 send_exec_cmd($self, $io, \@cmd, {});
 878         } elsif ($self->{oneshot}) {
 879                 my $pid = fork // die "fork: $!";
 880                 if ($pid > 0) { # original process
 881                         if ($self->{opt}->{stdin} && -t STDOUT) {
 882                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 883                         }
 884                         exec(@cmd);
 885                         warn "exec @cmd: $!\n";
 886                         POSIX::_exit(1);
 887                 }
 888                 POSIX::setsid() > 0 or die "setsid: $!";
 889         }
 890         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 891                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 892         }
 893         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 894         $self->{opt}->{quiet} = 1;
 895         delete $self->{-progress};
 896         delete $self->{opt}->{verbose};
 897 }
 898
 899 sub send_exec_cmd { # tell script/lei to execute a command
 900         my ($self, $io, $cmd, $env) = @_;
 901         my $sock = $self->{sock} // die 'lei client gone';
 902         my $fds = [ map { fileno($_) } @$io ];
 903         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 904 }
 905
 906 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 907         my ($self) = @_;
 908         my $alerts = $self->{opt}->{alert} // return;
 909         while (my $op = shift(@$alerts)) {
 910                 if ($op eq ':WINCH') {
 911                         # hit the process group that started the MUA
 912                         if ($self->{sock}) {
 913                                 send($self->{sock}, '-WINCH', MSG_EOR);
 914                         } elsif ($self->{oneshot}) {
 915                                 kill('-WINCH', $$);
 916                         }
 917                 } elsif ($op eq ':bell') {
 918                         out($self, "\a");
 919                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 920                         push @$alerts, split(/(?<!\\),/, $op);
 921                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 922                         my $cmd = $1; # run an arbitrary command
 923                         require Text::ParseWords;
 924                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 925                         if (my $s = $self->{sock}) {
 926                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 927                         } elsif ($self->{oneshot}) {
 928                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 929                         }
 930                 } else {
 931                         err($self, "W: unsupported --alert=$op"); # non-fatal
 932                 }
 933         }
 934 }
 935
 936 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 937 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 938
 939 # this also normalizes the path
 940 sub path_to_fd {
 941         my ($self, $path) = @_;
 942         $path = rel2abs($self, $path);
 943         $path =~ tr!/!/!s;
 944         $path_to_fd{$path} // (
 945                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 946                         fail($self, "cannot open $path from daemon") : -1
 947         );
 948 }
 949
 950 # caller needs to "-t $self->{1}" to check if tty
 951 sub start_pager {
 952         my ($self) = @_;
 953         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 954         chomp(my $pager = <$fh> // '');
 955         close($fh) or warn "`git var PAGER' error: \$?=$?";
 956         return if $pager eq 'cat' || $pager eq '';
 957         my $new_env = { LESS => 'FRX', LV => '-c' };
 958         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 959         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 960         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 961         my $pgr = [ undef, @$rdr{1, 2} ];
 962         my $env = $self->{env};
 963         if ($self->{sock}) { # lei(1) process runs it
 964                 delete @$new_env{keys %$env}; # only set iff unset
 965                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 966         } elsif ($self->{oneshot}) {
 967                 my $cmd = [$pager];
 968                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 969         } else {
 970                 die 'BUG: start_pager w/o socket';
 971         }
 972         $self->{1} = $wpager;
 973         $self->{2} = $wpager if -t $self->{2};
 974         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 975         $self->{pgr} = $pgr;
 976 }
 977
 978 sub stop_pager {
 979         my ($self) = @_;
 980         my $pgr = delete($self->{pgr}) or return;
 981         $self->{2} = $pgr->[2];
 982         # do not restore original stdout, just close it so we error out
 983         close(delete($self->{1})) if $self->{1};
 984 }
 985
 986 sub accept_dispatch { # Listener {post_accept} callback
 987         my ($sock) = @_; # ignore other
 988         $sock->autoflush(1);
 989         my $self = bless { sock => $sock }, __PACKAGE__;
 990         vec(my $rvec = '', fileno($sock), 1) = 1;
 991         select($rvec, undef, undef, 60) or
 992                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 993         # (4096 * 33) >MAX_ARG_STRLEN
 994         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 995         if (!defined($fds[0])) {
 996                 warn(my $msg = "recv_cmd failed: $!");
 997                 return send($sock, $msg, MSG_EOR);
 998         } else {
 999                 my $i = 0;
1000                 for my $fd (@fds) {
1001                         open($self->{$i++}, '+<&=', $fd) and next;
1002                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1003                 }
1004                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1005         }
1006         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
1007         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1008         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1009         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1010                 return send($sock, 'request command truncated', MSG_EOR);
1011         my ($argc, @argv) = split(/\0/, $buf, -1);
1012         undef $buf;
1013         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1014         if (chdir($self->{3})) {
1015                 local %ENV = %env;
1016                 $self->{env} = \%env;
1017                 eval { dispatch($self, @argv) };
1018                 send($sock, $@, MSG_EOR) if $@;
1019         } else {
1020                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1021         }
1022 }
1023
1024 sub dclose {
1025         my ($self) = @_;
1026         delete $self->{-progress};
1027         _drop_wq($self);
1028         close(delete $self->{1}) if $self->{1}; # may reap_compress
1029         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1030 }
1031
1032 # for long-running results
1033 sub event_step {
1034         my ($self) = @_;
1035         local %ENV = %{$self->{env}};
1036         my $sock = $self->{sock};
1037         local $current_lei = $self;
1038         eval {
1039                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1040                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1041                                 return if $! == EAGAIN;
1042                                 next if $! == EINTR;
1043                                 last if $! == ECONNRESET;
1044                                 die "recvmsg: $!";
1045                         }
1046                         for my $fd (@fds) {
1047                                 open my $rfh, '+<&=', $fd;
1048                         }
1049                         die "unrecognized client signal: $buf";
1050                 }
1051                 dclose($self);
1052         };
1053         if (my $err = $@) {
1054                 eval { $self->fail($err) };
1055                 dclose($self);
1056         }
1057 }
1058
1059 sub event_step_init {
1060         my ($self) = @_;
1061         return if $self->{-event_init_done}++;
1062         if (my $sock = $self->{sock}) { # using DS->EventLoop
1063                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1064         }
1065 }
1066
1067 sub noop {}
1068
1069 sub oldset { $oldset }
1070
1071 sub dump_and_clear_log {
1072         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1073                 my @pfx = @_;
1074                 unshift(@pfx, "$errors_log ") if @pfx;
1075                 warn @pfx, do { local $/; <STDIN> };
1076                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1077         }
1078 }
1079
1080 # lei(1) calls this when it can't connect
1081 sub lazy_start {
1082         my ($path, $errno, $narg) = @_;
1083         local ($errors_log, $listener);
1084         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1085         $errors_log .= 'errors.log';
1086         my $addr = pack_sockaddr_un($path);
1087         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1088         $lk->lock_acquire;
1089         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1090         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1091                 return if connect($listener, $addr); # another process won
1092                 if ($errno == ECONNREFUSED && -S $path) {
1093                         unlink($path) or die "unlink($path): $!";
1094                 }
1095         } else {
1096                 $! = $errno; # allow interpolation to stringify in die
1097                 die "connect($path): $!";
1098         }
1099         umask(077) // die("umask(077): $!");
1100         bind($listener, $addr) or die "bind($path): $!";
1101         listen($listener, 1024) or die "listen: $!";
1102         $lk->lock_release;
1103         undef $lk;
1104         my @st = stat($path) or die "stat($path): $!";
1105         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1106         local $oldset = PublicInbox::DS::block_signals();
1107         if ($narg == 5) {
1108                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1109                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1110                         require PublicInbox::CmdIPC4;
1111                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1112                         PublicInbox::CmdIPC4->can('recv_cmd4');
1113                 };
1114         }
1115         $recv_cmd or die <<"";
1116 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1117
1118         require PublicInbox::Listener;
1119         require PublicInbox::EOFpipe;
1120         (-p STDOUT) or die "E: stdout must be a pipe\n";
1121         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1122         STDIN->autoflush(1);
1123         dump_and_clear_log("from previous daemon process:\n");
1124         POSIX::setsid() > 0 or die "setsid: $!";
1125         my $pid = fork // die "fork: $!";
1126         return if $pid;
1127         $0 = "lei-daemon $path";
1128         local %PATH2CFG;
1129         $listener->blocking(0);
1130         my $exit_code;
1131         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1132         local $quit = do {
1133                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1134                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1135                 sub {
1136                         $exit_code //= shift;
1137                         my $lis = $pil or exit($exit_code);
1138                         # closing eof_w triggers \&noop wakeup
1139                         $listener = $eof_w = $pil = $path = undef;
1140                         $lis->close; # DS::close
1141                         PublicInbox::DS->SetLoopTimeout(1000);
1142                 };
1143         };
1144         my $sig = {
1145                 CHLD => \&PublicInbox::DS::enqueue_reap,
1146                 QUIT => $quit,
1147                 INT => $quit,
1148                 TERM => $quit,
1149                 HUP => \&noop,
1150                 USR1 => \&noop,
1151                 USR2 => \&noop,
1152         };
1153         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1154         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1155         undef $sig;
1156         local $SIG{PIPE} = 'IGNORE';
1157         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1158                 undef $sigfd;
1159                 PublicInbox::DS->SetLoopTimeout(5000);
1160         } else {
1161                 # wake up every second to accept signals if we don't
1162                 # have signalfd or IO::KQueue:
1163                 PublicInbox::DS::sig_setmask($oldset);
1164                 PublicInbox::DS->SetLoopTimeout(1000);
1165         }
1166         PublicInbox::DS->SetPostLoopCallback(sub {
1167                 my ($dmap, undef) = @_;
1168                 if (@st = defined($path) ? stat($path) : ()) {
1169                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1170                                 warn "$path dev/ino changed, quitting\n";
1171                                 $path = undef;
1172                         }
1173                 } elsif (defined($path)) { # ENOENT is common
1174                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1175                         undef $path;
1176                         $quit->();
1177                 }
1178                 return 1 if defined($path);
1179                 my $now = now();
1180                 my $n = 0;
1181                 for my $s (values %$dmap) {
1182                         $s->can('busy') or next;
1183                         if ($s->busy($now)) {
1184                                 ++$n;
1185                         } else {
1186                                 $s->close;
1187                         }
1188                 }
1189                 $n; # true: continue, false: stop
1190         });
1191
1192         # STDIN was redirected to /dev/null above, closing STDERR and
1193         # STDOUT will cause the calling `lei' client process to finish
1194         # reading the <$daemon> pipe.
1195         local $SIG{__WARN__} = sub {
1196                 $current_lei ? err($current_lei, @_) : warn(
1197                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1198         };
1199         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1200         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1201         # $daemon pipe to `lei' closed, main loop begins:
1202         PublicInbox::DS->EventLoop;
1203         exit($exit_code // 0);
1204 }
1205
1206 sub busy { 1 } # prevent daemon-shutdown if client is connected
1207
1208 # for users w/o Socket::Msghdr installed or Inline::C enabled
1209 sub oneshot {
1210         my ($main_pkg) = @_;
1211         my $exit = $main_pkg->can('exit'); # caller may override exit()
1212         local $quit = $exit if $exit;
1213         local %PATH2CFG;
1214         umask(077) // die("umask(077): $!");
1215         my $self = bless {
1216                 oneshot => 1,
1217                 0 => *STDIN{GLOB},
1218                 1 => *STDOUT{GLOB},
1219                 2 => *STDERR{GLOB},
1220                 env => \%ENV
1221         }, __PACKAGE__;
1222         dispatch($self, @ARGV);
1223         x_it($self, $self->{child_error}) if $self->{child_error};
1224 }
1225
1226 # ensures stdout hits the FS before sock disconnects so a client
1227 # can immediately reread it
1228 sub DESTROY {
1229         my ($self) = @_;
1230         $self->{1}->autoflush(1) if $self->{1};
1231         stop_pager($self);
1232         my $err = $?;
1233         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1234         waitpid($_, 0) for keys %$oneshot_pids;
1235         $? = $err if $err; # preserve ->fail or ->x_it code
1236 }
1237
1238 sub wq_done_wait { # dwaitpid callback
1239         my ($arg, $pid) = @_;
1240         my ($wq, $lei) = @$arg;
1241         my $err_type = $lei->{-err_type};
1242         $? and $lei->child_error($?,
1243                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1244         $lei->dclose;
1245 }
1246
1247 sub wq_eof { # EOF callback for main daemon
1248         my ($lei) = @_;
1249         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1250         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1251 }
1252
1253 1;