lib/PublicInbox/LeiAuth.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Authentication worker for anything that needs auth for read/write IMAP
   5 # (eventually for read-only NNTP access)
   6 package PublicInbox::LeiAuth;
   7 use strict;
   8 use v5.10.1;
   9
  10 sub do_auth_atfork { # used by IPC WQ workers
  11         my ($self, $wq) = @_;
  12         return if $wq->{-wq_worker_nr} != 0;
  13         my $lei = $wq->{lei};
  14         my $net = $lei->{net};
  15         eval {
  16                 my $mics = $net->imap_common_init($lei);
  17                 my $nn = $net->nntp_common_init($lei);
  18                 $lei->{pkt_op_p}->pkt_do('net_merge_continue', $net) or
  19                                 die "pkt_do net_merge_continue: $!";
  20                 $net->{mics_cached} = $mics if $mics;
  21                 $net->{nn_cached} = $nn if $nn;
  22         };
  23         $lei->fail($@) if $@;
  24 }
  25
  26 sub net_merge_done1 { # bump merge-count in top-level lei-daemon
  27         my ($wq) = @_;
  28         return if ++$wq->{nr_net_merge_done} != $wq->{-wq_nr_workers};
  29         $wq->net_merge_all_done; # defined per wq-class (e.g. LeiImport)
  30 }
  31
  32 sub net_merge_all { # called in wq worker via wq_broadcast
  33         my ($wq, $net_new) = @_;
  34         my $net = $wq->{lei}->{net};
  35         %$net = (%$net, %$net_new);
  36         $wq->{lei}->{pkt_op_p}->pkt_do('net_merge_done1') or
  37                 die "pkt_op_do net_merge_done1: $!";
  38 }
  39
  40 # called by top-level lei-daemon when first worker is done with auth
  41 sub net_merge_continue {
  42         my ($wq, $net_new) = @_;
  43         $wq->wq_broadcast('net_merge_all', $net_new);
  44 }
  45
  46 sub op_merge { # prepares PktOp->pair ops
  47         my ($self, $ops, $wq) = @_;
  48         $ops->{net_merge_continue} = [ \&net_merge_continue, $wq ];
  49         $ops->{net_merge_done1} = [ \&net_merge_done1, $wq ];
  50 }
  51
  52 sub new { bless \(my $x), __PACKAGE__ }
  53
  54 1;