lib/PublicInbox/LeiAuth.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Authentication worker for anything that needs auth for read/write IMAP
   5 # (eventually for read-only NNTP access)
   6 package PublicInbox::LeiAuth;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::PktOp qw(pkt_do);
  11
  12 sub net_merge {
  13         my ($lei, $net_new) = @_;
  14         if ($lei->{pkt_op_p}) { # from lei_convert worker
  15                 pkt_do($lei->{pkt_op_p}, 'net_merge', $net_new);
  16         } else { # single lei-daemon consumer
  17                 my $self = $lei->{auth} or return; # client disconnected
  18                 my $net = $self->{net};
  19                 %$net = (%$net, %$net_new);
  20         }
  21 }
  22
  23 sub do_auth { # called via wq_io_do
  24         my ($self) = @_;
  25         my ($lei, $net) = @$self{qw(lei net)};
  26         $net->imap_common_init($lei);
  27         net_merge($lei, $net); # tell lei-daemon updated auth info
  28 }
  29
  30 sub do_auth_atfork { # used by IPC WQ workers
  31         my ($self, $wq) = @_;
  32         return if $wq->{-wq_worker_nr} != 0;
  33         my $lei = $wq->{lei};
  34         my $net = $self->{net};
  35         my $mics = $net->imap_common_init($lei);
  36         net_merge($lei, $net);
  37         $net->{mics_cached} = $mics;
  38 }
  39
  40 sub net_merge_done1 { # bump merge-count in top-level lei-daemon
  41         my ($wq) = @_;
  42         return if ++$wq->{nr_net_merge_done} != $wq->{-wq_nr_workers};
  43         $wq->net_merge_complete; # defined per wq-class (e.g. LeiImport)
  44 }
  45
  46 sub net_merge_all { # called via wq_broadcast
  47         my ($wq, $net_new) = @_;
  48         my $net = $wq->{lei}->{net};
  49         %$net = (%$net, %$net_new);
  50         pkt_do($wq->{lei}->{pkt_op_p}, 'net_merge_done1') or
  51                 die "pkt_op_do net_merge_done1: $!";
  52 }
  53
  54 # called by top-level lei-daemon when first worker is done with auth
  55 sub net_merge_continue {
  56         my ($wq, $net_new) = @_;
  57         $wq->wq_broadcast('net_merge_all', $net_new);
  58 }
  59
  60 sub op_merge { # prepares PktOp->pair ops
  61         my ($self, $ops, $wq) = @_;
  62         $ops->{net_merge} = [ \&net_merge_continue, $wq ];
  63         $ops->{net_merge_done1} = [ \&net_merge_done1, $wq ];
  64 }
  65
  66 sub do_finish_auth { # dwaitpid callback
  67         my ($arg, $pid) = @_;
  68         my ($self, $lei, $post_auth_cb, @args) = @$arg;
  69         $? ? $lei->dclose : $post_auth_cb->(@args);
  70 }
  71
  72 sub auth_eof {
  73         my ($lei, $post_auth_cb, @args) = @_;
  74         my $self = delete $lei->{auth} or return;
  75         $self->wq_wait_old(\&do_finish_auth, $lei, $post_auth_cb, @args);
  76 }
  77
  78 sub auth_start {
  79         my ($self, $lei, $post_auth_cb, @args) = @_;
  80         my $op = $lei->workers_start($self, 'auth', 1, {
  81                 'net_merge' => [ \&net_merge, $lei ],
  82                 '' => [ \&auth_eof, $lei, $post_auth_cb, @args ],
  83         });
  84         $self->wq_io_do('do_auth', []);
  85         $self->wq_close(1);
  86         while ($op && $op->{sock}) { $op->event_step }
  87 }
  88
  89 sub ipc_atfork_child {
  90         my ($self) = @_;
  91         delete $self->{lei}->{auth}; # drop circular ref
  92         $self->{lei}->lei_atfork_child;
  93         $self->SUPER::ipc_atfork_child;
  94 }
  95
  96 sub new {
  97         my ($cls, $net) = @_; # net may be NetReader or descendant (NetWriter)
  98         bless { net => $net }, $cls;
  99 }
 100
 101 1;