lib/PublicInbox/LeiBlob.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei blob $OID" command
   5 # TODO: this doesn't scan submodules, but maybe it should
   6 package PublicInbox::LeiBlob;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::Spawn qw(spawn popen_rd which);
  11 use PublicInbox::DS;
  12
  13 sub sol_done_wait { # dwaitpid callback
  14         my ($arg, $pid) = @_;
  15         my (undef, $lei) = @$arg;
  16         $lei->child_error($?) if $?;
  17         $lei->dclose;
  18 }
  19
  20 sub sol_done { # EOF callback for main daemon
  21         my ($lei) = @_;
  22         my $sol = delete $lei->{sol} // return $lei->dclose; # already failed
  23         $sol->wq_wait_old(\&sol_done_wait, $lei);
  24 }
  25
  26 sub get_git_dir ($) {
  27         my ($d) = @_;
  28         return $d if -d "$d/objects" && -d "$d/refs" && -e "$d/HEAD";
  29
  30         my $cmd = [ qw(git rev-parse --git-dir) ];
  31         my ($r, $pid) = popen_rd($cmd, {GIT_DIR => undef}, { '-C' => $d });
  32         chomp(my $gd = do { local $/; <$r> });
  33         waitpid($pid, 0) == $pid or die "BUG: waitpid @$cmd ($!)";
  34         $? == 0 ? $gd : undef;
  35 }
  36
  37 sub solver_user_cb { # called by solver when done
  38         my ($res, $self) = @_;
  39         my $lei = $self->{lei};
  40         my $log_buf = delete $lei->{'log_buf'};
  41         $$log_buf =~ s/^/# /sgm;
  42         ref($res) eq 'ARRAY' or return $lei->child_error(1 << 8, $$log_buf);
  43         $lei->qerr($$log_buf);
  44         my ($git, $oid, $type, $size, $di) = @$res;
  45         my $gd = $git->{git_dir};
  46
  47         # don't try to support all the git-show(1) options for non-blob,
  48         # this is just a convenience:
  49         $type ne 'blob' and
  50                 $lei->err("# $oid is a $type of $size bytes in:\n#\t$gd");
  51
  52         my $cmd = [ 'git', "--git-dir=$gd", 'show', $oid ];
  53         my $rdr = { 1 => $lei->{1}, 2 => $lei->{2} };
  54         waitpid(spawn($cmd, $lei->{env}, $rdr), 0);
  55         $lei->child_error($?) if $?;
  56 }
  57
  58 sub do_solve_blob { # via wq_do
  59         my ($self) = @_;
  60         my $lei = $self->{lei};
  61         my $git_dirs = $lei->{opt}->{'git-dir'};
  62         my $hints = {};
  63         for my $x (qw(oid-a path-a path-b)) {
  64                 my $v = $lei->{opt}->{$x} // next;
  65                 $x =~ tr/-/_/;
  66                 $hints->{$x} = $v;
  67         }
  68         open my $log, '+>', \(my $log_buf = '') or die "PerlIO::scalar: $!";
  69         $lei->{log_buf} = \$log_buf;
  70         my $git = $lei->{ale}->git;
  71         my @rmt = map {
  72                 PublicInbox::LeiRemote->new($lei, $_)
  73         } $self->{lxs}->remotes;
  74         my $solver = bless {
  75                 gits => [ map {
  76                                 PublicInbox::Git->new($lei->rel2abs($_))
  77                         } @$git_dirs ],
  78                 user_cb => \&solver_user_cb,
  79                 uarg => $self,
  80                 # -cur_di, -qsp, -msg => temporary fields for Qspawn callbacks
  81                 inboxes => [ $self->{lxs}->locals, @rmt ],
  82         }, 'PublicInbox::SolverGit';
  83         $lei->{env}->{'psgi.errors'} = $lei->{2}; # ugh...
  84         local $PublicInbox::DS::in_loop = 0; # waitpid synchronously
  85         $solver->solve($lei->{env}, $log, $self->{oid_b}, $hints);
  86 }
  87
  88 sub lei_blob {
  89         my ($lei, $blob) = @_;
  90         $lei->start_pager if -t $lei->{1};
  91         my $opt = $lei->{opt};
  92         my $has_hints = grep(defined, @$opt{qw(oid-a path-a path-b)});
  93
  94         # first, see if it's a blob returned by "lei q" JSON output:k
  95         if ($opt->{mail} // ($has_hints ? 0 : 1)) {
  96                 my $rdr = { 1 => $lei->{1} };
  97                 open $rdr->{2}, '>', '/dev/null' or die "open: $!";
  98                 my $cmd = [ 'git', '--git-dir='.$lei->ale->git->{git_dir},
  99                                 'cat-file', 'blob', $blob ];
 100                 waitpid(spawn($cmd, $lei->{env}, $rdr), 0);
 101                 return if $? == 0;
 102         }
 103
 104         # maybe it's a non-email (code) blob from a coderepo
 105         my $git_dirs = $opt->{'git-dir'} //= [];
 106         if ($opt->{'cwd'} // 1) {
 107                 my $cgd = get_git_dir('.');
 108                 unshift(@$git_dirs, $cgd) if defined $cgd;
 109         }
 110         return $lei->fail('no --git-dir to try') unless @$git_dirs;
 111         my $lxs = $lei->lxs_prepare or return;
 112         if ($lxs->remotes) {
 113                 require PublicInbox::LeiRemote;
 114                 $lei->{curl} //= which('curl') or return
 115                         $lei->fail('curl needed for', $lxs->remotes);
 116                 $lei->_lei_store(1)->write_prepare($lei);
 117         }
 118         require PublicInbox::SolverGit;
 119         my $self = bless { lxs => $lxs, oid_b => $blob }, __PACKAGE__;
 120         $lei->ale;
 121         my ($op_c, $ops) = $lei->workers_start($self, 'lei_solve', 1,
 122                 { '' => [ \&sol_done, $lei ] });
 123         $lei->{sol} = $self;
 124         $self->wq_io_do('do_solve_blob', []);
 125         $self->wq_close(1);
 126         $op_c->op_wait_event($ops);
 127 }
 128
 129 sub ipc_atfork_child {
 130         my ($self) = @_;
 131         $self->{lei}->_lei_atfork_child;
 132         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 133         $self->SUPER::ipc_atfork_child;
 134 }
 135
 136 1;