lib/PublicInbox/LeiConvert.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei convert" sub-command
   5 package PublicInbox::LeiConvert;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9 use PublicInbox::LeiOverview;
  10 use PublicInbox::DS;
  11
  12 # /^input_/ subs are used by PublicInbox::LeiInput
  13
  14 sub input_mbox_cb { # MboxReader callback
  15         my ($eml, $self) = @_;
  16         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
  17         $eml->header_set($_) for qw(Status X-Status);
  18         $self->{wcb}->(undef, { kw => $kw }, $eml);
  19 }
  20
  21 sub input_eml_cb { # used by PublicInbox::LeiInput::input_fh
  22         my ($self, $eml) = @_;
  23         $self->{wcb}->(undef, {}, $eml);
  24 }
  25
  26 sub input_net_cb { # callback for ->imap_each, ->nntp_each
  27         my (undef, undef, $kw, $eml, $self) = @_; # @_[0,1]: url + uid ignored
  28         $self->{wcb}->(undef, { kw => $kw }, $eml);
  29 }
  30
  31 sub input_maildir_cb {
  32         my (undef, $kw, $eml, $self) = @_; # $_[0] $filename ignored
  33         $self->{wcb}->(undef, { kw => $kw }, $eml);
  34 }
  35
  36 sub process_inputs { # via wq_do
  37         my ($self) = @_;
  38         local $PublicInbox::DS::in_loop = 0; # force synchronous dwaitpid
  39         $self->SUPER::process_inputs;
  40         delete $self->{lei}->{1};
  41         delete $self->{wcb}; # commit
  42 }
  43
  44 sub lei_convert { # the main "lei convert" method
  45         my ($lei, @inputs) = @_;
  46         $lei->{opt}->{kw} //= 1;
  47         $lei->{opt}->{dedupe} //= 'none';
  48         my $self = bless {}, __PACKAGE__;
  49         my $ovv = PublicInbox::LeiOverview->new($lei, 'out-format');
  50         $lei->{l2m} or return
  51                 $lei->fail("output not specified or is not a mail destination");
  52         my $devfd = $lei->path_to_fd($ovv->{dst}) // return;
  53         $lei->{opt}->{augment} = 1 if $devfd < 0;
  54         $self->prepare_inputs($lei, \@inputs) or return;
  55         my ($op_c, $ops) = $lei->workers_start($self, 'lei-convert', 1);
  56         $lei->{wq1} = $self;
  57         $self->wq_io_do('process_inputs', []);
  58         $self->wq_close(1);
  59         $op_c->op_wait_event($ops);
  60 }
  61
  62 sub ipc_atfork_child {
  63         my ($self) = @_;
  64         my $lei = $self->{lei};
  65         $lei->_lei_atfork_child;
  66         my $l2m = delete $lei->{l2m};
  67         if (my $net = $lei->{net}) { # may prompt user once
  68                 $net->{mics_cached} = $net->imap_common_init($lei);
  69                 $net->{nn_cached} = $net->nntp_common_init($lei);
  70         }
  71         $l2m->pre_augment($lei);
  72         $l2m->do_augment($lei);
  73         $l2m->post_augment($lei);
  74         $self->{wcb} = $l2m->write_cb($lei);
  75         $self->SUPER::ipc_atfork_child;
  76 }
  77
  78 1;