lib/PublicInbox/LeiDaemon.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LeiDaemon;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS);
  12 use Getopt::Long ();
  13 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  14 use POSIX qw(setsid);
  15 use IO::Socket::UNIX;
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw($SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now);
  22 use PublicInbox::Spawn qw(spawn);
  23 use Text::Wrap qw(wrap);
  24 use File::Path qw(mkpath);
  25 use File::Spec;
  26 our $quit = \&CORE::exit;
  27 my $glp = Getopt::Long::Parser->new;
  28 $glp->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  29 our %PATH2CFG; # persistent for socket daemon
  30
  31 # TBD: this is a documentation mechanism to show a subcommand
  32 # (may) pass options through to another command:
  33 sub pass_through { () }
  34
  35 # TODO: generate shell completion + help using %CMD and %OPTDESC
  36 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  37 our %CMD = ( # sorted in order of importance/use:
  38 'query' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  39         save-as=s output|o=s format|f=s dedupe|d=s thread|t augment|a
  40         limit|n=i sort|s=s@ reverse|r offset=i remote local! extinbox!
  41         since|after=s until|before=s) ],
  42
  43 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  44         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  45         pass_through('git show') ],
  46
  47 'add-extinbox' => [ 'URL_OR_PATHNAME',
  48         'add/set priority of a publicinbox|extindex for extra matches',
  49         qw(prio=i) ],
  50 'ls-extinbox' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  51         qw(format|f=s z local remote) ],
  52 'forget-extinbox' => [ '{URL_OR_PATHNAME|--prune}',
  53         'exclude further results from a publicinbox|extindex',
  54         qw(prune) ],
  55
  56 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  57                 qw(name-only format|f=s z) ],
  58 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  59 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  60
  61 'plonk' => [ '--thread|--from=IDENT',
  62         'exclude mail matching From: or thread from non-Message-ID searches',
  63         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  64 'mark' => [ 'MESSAGE_FLAGS...',
  65         'set/unset flags on message(s) from stdin',
  66         qw(stdin| oid=s exact by-mid|mid:s) ],
  67 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
  68         'exclude message(s) on stdin from query results',
  69         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
  70
  71 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
  72         'remove imported messages from IMAP, Maildirs, and MH',
  73         qw(exact! all jobs:i indexed) ],
  74
  75 # code repos are used for `show' to solve blobs from patch mails
  76 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
  77         qw(prio=i) ],
  78 'ls-coderepo' => [ '[FILTER_TERMS...]',
  79                 'list known code repos', qw(format|f=s z) ],
  80 'forget-coderepo' => [ 'PATHNAME',
  81         'stop using repo to solve blobs from patches',
  82         qw(prune) ],
  83
  84 'add-watch' => [ '[URL_OR_PATHNAME]',
  85                 'watch for new messages and flag changes',
  86         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
  87 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
  88                 qw(format|f=s z) ],
  89 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
  90 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
  91 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
  92         qw(prune) ],
  93
  94 'import' => [ '{URL_OR_PATHNAME|--stdin}',
  95         'one-shot import/update from URL or filesystem',
  96         qw(stdin| limit|n=i offset=i recursive|r exclude=s include=s !flags),
  97         ],
  98
  99 'config' => [ '[...]', 'git-config(1) wrapper for ~/.config/lei/config',
 100                 pass_through('git config') ],
 101 'init' => [ '[PATHNAME]',
 102         'initialize storage, default: ~/.local/share/lei/store',
 103         qw(quiet|q) ],
 104 'daemon-stop' => [ '', 'stop the lei-daemon' ],
 105 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 106 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 107         qw(clear| unset|u=s@ z|0) ],
 108 'help' => [ '[SUBCOMMAND]', 'show help' ],
 109
 110 # XXX do we need this?
 111 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 112
 113 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 114         'rewrite git history in an attempt to improve compression',
 115         'gc!' ]
 116 ); # @CMD
 117
 118 # switch descriptions, try to keep consistent across commands
 119 # $spec: Getopt::Long option specification
 120 # $spec => [@ALLOWED_VALUES (default is first), $description],
 121 # $spec => $description
 122 # "$SUB_COMMAND TAB $spec" => as above
 123 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 124                 'specify message input format' ];
 125 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 126
 127 my %OPTDESC = (
 128 'help|h' => 'show this built-in help',
 129 'quiet|q' => 'be quiet',
 130 'solve!' => 'do not attempt to reconstruct blobs from emails',
 131 'save-as=s' => ['NAME', 'save a search terms by given name'],
 132
 133 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 134
 135 'dedupe|d=s' => ['STRAT|content|oid|mid',
 136                 'deduplication strategy'],
 137 'show   thread|t' => 'display entire thread a message belongs to',
 138 'query  thread|t' =>
 139         'return all messages in the same thread as the actual match(es)',
 140 'augment|a' => 'augment --output destination instead of clobbering',
 141
 142 'output|o=s' => [ 'DEST',
 143         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 144
 145 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 146                         'message/object output format' ],
 147 'mark   format|f=s' => $stdin_formats,
 148 'forget format|f=s' => $stdin_formats,
 149 'query  format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid',
 150                 'specify output format, default depends on --output'],
 151 'ls-query       format|f=s' => $ls_format,
 152 'ls-extinbox    format|f=s' => $ls_format,
 153
 154 'limit|n=i' => ['NUM',
 155         'limit on number of matches (default: 10000)' ],
 156 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 157
 158 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 159                 "order of results `--output'-dependent"],
 160
 161 'prio=i' => 'priority of query source',
 162
 163 'local' => 'limit operations to the local filesystem',
 164 'local!' => 'exclude results from the local filesystem',
 165 'remote' => 'limit operations to those requiring network access',
 166 'remote!' => 'prevent operations requiring network access',
 167
 168 'mid=s' => 'specify the Message-ID of a message',
 169 'oid=s' => 'specify the git object ID of a message',
 170
 171 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 172 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 173 'include=s' => 'include mailboxes/newsgroups based on pattern',
 174
 175 'exact' => 'operate on exact header matches only',
 176 'exact!' => 'rely on content match instead of exact header matches',
 177
 178 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 179 'jobs:i' => 'set parallelism level',
 180
 181 # xargs, env, use "-0", git(1) uses "-z".  Should we support z|0 everywhere?
 182 'z' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 183 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 184
 185 # note: no "--ignore-environment" / "-i" support like env(1) since that
 186 # is one-shot and this is for a persistent daemon:
 187 'clear|' => 'clear the daemon environment',
 188 'unset|u=s@' => ['NAME',
 189         'unset matching NAME, may be specified multiple times'],
 190 ); # %OPTDESC
 191
 192 sub x_it ($$) { # pronounced "exit"
 193         my ($client, $code) = @_;
 194         if (my $sig = ($code & 127)) {
 195                 kill($sig, $client->{pid} // $$);
 196         } else {
 197                 $code >>= 8;
 198                 if (my $sock = $client->{sock}) {
 199                         say $sock "exit=$code";
 200                 } else { # for oneshot
 201                         $quit->($code);
 202                 }
 203         }
 204 }
 205
 206 sub emit {
 207         my ($client, $channel) = @_; # $buf = $_[2]
 208         print { $client->{$channel} } $_[2] or die "print FD[$channel]: $!";
 209 }
 210
 211 sub err {
 212         my ($client, $buf) = @_;
 213         $buf .= "\n" unless $buf =~ /\n\z/s;
 214         emit($client, 2, $buf);
 215 }
 216
 217 sub qerr { $_[0]->{opt}->{quiet} or err(@_) }
 218
 219 sub fail ($$;$) {
 220         my ($client, $buf, $exit_code) = @_;
 221         err($client, $buf);
 222         x_it($client, ($exit_code // 1) << 8);
 223         undef;
 224 }
 225
 226 sub _help ($;$) {
 227         my ($client, $errmsg) = @_;
 228         my $cmd = $client->{cmd} // 'COMMAND';
 229         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 230         my @top = ($cmd, shift(@info) // ());
 231         my $cmd_desc = shift(@info);
 232         my @opt_desc;
 233         my $lpad = 2;
 234         for my $sw (@info) { # qw(prio=s
 235                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 236                 my $arg_vals = '';
 237                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 238
 239                 # lower-case is a keyword (e.g. `content', `oid'),
 240                 # ALL_CAPS is a string description (e.g. `PATH')
 241                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 242                         $desc .= "\ndefault: `$1'";
 243                 }
 244                 my (@vals, @s, @l);
 245                 my $x = $sw;
 246                 if ($x =~ s/!\z//) { # solve! => --no-solve
 247                         $x = "no-$x";
 248                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 249                         @vals = (' [', undef, ']');
 250                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 251                         @vals = (' ', undef);
 252                 } # else: no args $x = 'thread|t'
 253                 for (split(/\|/, $x)) { # help|h
 254                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 255                 }
 256                 if (!scalar(@vals)) { # no args 'thread|t'
 257                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 258                         $vals[1] = $1;
 259                 } else {
 260                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 261                 }
 262                 if ($arg_vals =~ /([,\|])/) {
 263                         my $sep = $1;
 264                         my @allow = split(/\Q$sep\E/, $arg_vals);
 265                         my $must = $sep eq '|' ? 'Must' : 'Can';
 266                         @allow = map { "`$_'" } @allow;
 267                         my $last = pop @allow;
 268                         $desc .= "\n$must be one of: " .
 269                                 join(', ', @allow) . " or $last";
 270                 }
 271                 my $lhs = join(', ', @s, @l) . join('', @vals);
 272                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 273                         $lhs =~ s/\A--/- , --/;
 274                 } else {
 275                         $lhs =~ s/\A--/    --/; # pad if no short options
 276                 }
 277                 $lpad = length($lhs) if length($lhs) > $lpad;
 278                 push @opt_desc, $lhs, $desc;
 279         }
 280         my $msg = $errmsg ? "E: $errmsg\n" : '';
 281         $msg .= <<EOF;
 282 usage: lei @top
 283   $cmd_desc
 284
 285 EOF
 286         $lpad += 2;
 287         local $Text::Wrap::columns = 78 - $lpad;
 288         my $padding = ' ' x ($lpad + 2);
 289         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 290                 $msg .= '  '.pack("A$lpad", $lhs);
 291                 $rhs = wrap('', '', $rhs);
 292                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 293                 $msg .= $rhs;
 294                 $msg .= "\n";
 295         }
 296         my $channel = $errmsg ? 2 : 1;
 297         emit($client, $channel, $msg);
 298         x_it($client, $errmsg ? 1 << 8 : 0); # stderr => failure
 299         undef;
 300 }
 301
 302 sub optparse ($$$) {
 303         my ($client, $cmd, $argv) = @_;
 304         $client->{cmd} = $cmd;
 305         my $opt = $client->{opt} = {};
 306         my $info = $CMD{$cmd} // [ '[...]', '(undocumented command)' ];
 307         my ($proto, $desc, @spec) = @$info;
 308         push @spec, qw(help|h);
 309         my $lone_dash;
 310         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 311                 $lone_dash = $spec[0];
 312                 $opt->{$spec[0]} = \(my $var);
 313                 push @spec, '' => \$var;
 314         }
 315         $glp->getoptionsfromarray($argv, $opt, @spec) or
 316                 return _help($client, "bad arguments or options for $cmd");
 317         return _help($client) if $opt->{help};
 318
 319         # "-" aliases "stdin" or "clear"
 320         $opt->{$lone_dash} = ${$opt->{$lone_dash}} if defined $lone_dash;
 321
 322         my $i = 0;
 323         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 324         my ($err, $inf);
 325         my @args = split(/ /, $proto);
 326         for my $var (@args) {
 327                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 328                         $inf = defined($argv->[$i]) and last;
 329                         $var =~ s/\.\.\.\z//;
 330                         $err = "$var not supplied";
 331                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 332                         $argv->[$i++] // ($err = "$var not supplied");
 333                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 334                         $inf = 1;
 335                         last;
 336                 } elsif ($var =~ /\A\[$POS_ARG\]\z/) { # one optional arg
 337                         $i++;
 338                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 339                         my @or = split(/\|/, $var);
 340                         my $ok;
 341                         for my $o (@or) {
 342                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 343                                         $ok = defined($opt->{$1});
 344                                         last;
 345                                 } elsif (defined($argv->[$i])) {
 346                                         $ok = 1;
 347                                         $i++;
 348                                         last;
 349                                 } # else continue looping
 350                         }
 351                         my $last = pop @or;
 352                         $err = join(', ', @or) . " or $last must be set";
 353                 } else {
 354                         warn "BUG: can't parse `$var' in $proto";
 355                 }
 356                 last if $err;
 357         }
 358         # warn "inf=$inf ".scalar(@$argv). ' '.scalar(@args)."\n";
 359         if (!$inf && scalar(@$argv) > scalar(@args)) {
 360                 $err //= 'too many arguments';
 361         }
 362         $err ? fail($client, "usage: lei $cmd $proto\nE: $err") : 1;
 363 }
 364
 365 sub dispatch {
 366         my ($client, $cmd, @argv) = @_;
 367         local $SIG{__WARN__} = sub { err($client, "@_") };
 368         local $SIG{__DIE__} = 'DEFAULT';
 369         return _help($client, 'no command given') unless defined($cmd);
 370         my $func = "lei_$cmd";
 371         $func =~ tr/-/_/;
 372         if (my $cb = __PACKAGE__->can($func)) {
 373                 optparse($client, $cmd, \@argv) or return;
 374                 $cb->($client, @argv);
 375         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 376                 my $opt = {};
 377                 $glp->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 378                         return _help($client, 'bad arguments or options');
 379                 _help($client);
 380         } else {
 381                 fail($client, "`$cmd' is not an lei command");
 382         }
 383 }
 384
 385 sub _lei_cfg ($;$) {
 386         my ($client, $creat) = @_;
 387         my $env = $client->{env};
 388         my $cfg_dir = File::Spec->canonpath(( $env->{XDG_CONFIG_HOME} //
 389                         ($env->{HOME} // '/nonexistent').'/.config').'/lei');
 390         my $f = "$cfg_dir/config";
 391         my @st = stat($f);
 392         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 393         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 394                 return ($client->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 395         }
 396         if (!@st) {
 397                 unless ($creat) {
 398                         delete $client->{cfg};
 399                         return;
 400                 }
 401                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 402                 open my $fh, '>>', $f or die "open($f): $!\n";
 403                 @st = stat($fh) or die "fstat($f): $!\n";
 404                 $cur_st = pack('dd', $st[10], $st[7]);
 405                 qerr($client, "I: $f created");
 406         }
 407         my $cfg = PublicInbox::Config::git_config_dump($f);
 408         $cfg->{-st} = $cur_st;
 409         $cfg->{'-f'} = $f;
 410         $client->{cfg} = $PATH2CFG{$f} = $cfg;
 411 }
 412
 413 sub _lei_store ($;$) {
 414         my ($client, $creat) = @_;
 415         my $cfg = _lei_cfg($client, $creat);
 416         $cfg->{-lei_store} //= do {
 417                 require PublicInbox::LeiStore;
 418                 PublicInbox::SearchIdx::load_xapian_writable();
 419                 defined(my $dir = $cfg->{'leistore.dir'}) or return;
 420                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 421         };
 422 }
 423
 424 sub lei_show {
 425         my ($client, @argv) = @_;
 426 }
 427
 428 sub lei_query {
 429         my ($client, @argv) = @_;
 430 }
 431
 432 sub lei_mark {
 433         my ($client, @argv) = @_;
 434 }
 435
 436 sub lei_config {
 437         my ($client, @argv) = @_;
 438         my $env = $client->{env};
 439         if (defined $env->{GIT_CONFIG}) {
 440                 my %copy = %$env;
 441                 delete $copy{GIT_CONFIG};
 442                 $env = \%copy;
 443         }
 444         if (my @conflict = (grep(/\A-f=?\z/, @argv),
 445                                 grep(/\A--(?:global|system|
 446                                         file|config-file)=?\z/x, @argv))) {
 447                 return fail($client, "@conflict not supported by lei config");
 448         }
 449         my $cfg = _lei_cfg($client, 1);
 450         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 451         my %rdr = map { $_ => $client->{$_} } (0..2);
 452         require PublicInbox::Import;
 453         PublicInbox::Import::run_die($cmd, $env, \%rdr);
 454 }
 455
 456 sub lei_init {
 457         my ($client, $dir) = @_;
 458         my $cfg = _lei_cfg($client, 1);
 459         my $cur = $cfg->{'leistore.dir'};
 460         my $env = $client->{env};
 461         $dir //= ( $env->{XDG_DATA_HOME} //
 462                 ($env->{HOME} // '/nonexistent').'/.local/share'
 463                 ) . '/lei/store';
 464         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 465         my @cur = stat($cur) if defined($cur);
 466         $cur = File::Spec->canonpath($cur) if $cur;
 467         my @dir = stat($dir);
 468         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 469         if (@cur) {
 470                 if ($cur eq $dir) {
 471                         _lei_store($client, 1)->done;
 472                         return qerr($client, $exists);
 473                 }
 474
 475                 # some folks like symlinks and bind mounts :P
 476                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 477                         lei_config($client, 'leistore.dir', $dir);
 478                         _lei_store($client, 1)->done;
 479                         return qerr($client, "$exists (as $cur)");
 480                 }
 481                 return fail($client, <<"");
 482 E: leistore.dir=$cur already initialized and it is not $dir
 483
 484         }
 485         lei_config($client, 'leistore.dir', $dir);
 486         _lei_store($client, 1)->done;
 487         $exists //= "I: leistore.dir=$dir newly initialized";
 488         return qerr($client, $exists);
 489 }
 490
 491 sub lei_daemon_pid { emit($_[0], 1, "$$\n") }
 492
 493 sub lei_daemon_stop { $quit->(0) }
 494
 495 sub lei_daemon_env {
 496         my ($client, @argv) = @_;
 497         my $opt = $client->{opt};
 498         if (defined $opt->{clear}) {
 499                 %ENV = ();
 500         } elsif (my $u = $opt->{unset}) {
 501                 delete @ENV{@$u};
 502         }
 503         if (@argv) {
 504                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 505         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 506                 my $eor = $opt->{z} ? "\0" : "\n";
 507                 my $buf = '';
 508                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 509                 emit($client, 1, $buf)
 510         }
 511 }
 512
 513 sub lei_help { _help($_[0]) }
 514
 515 sub reap_exec { # dwaitpid callback
 516         my ($client, $pid) = @_;
 517         x_it($client, $?);
 518 }
 519
 520 sub lei_git { # support passing through random git commands
 521         my ($client, @argv) = @_;
 522         my %rdr = map { $_ => $client->{$_} } (0..2);
 523         my $pid = spawn(['git', @argv], $client->{env}, \%rdr);
 524         PublicInbox::DS::dwaitpid($pid, \&reap_exec, $client);
 525 }
 526
 527 sub accept_dispatch { # Listener {post_accept} callback
 528         my ($sock) = @_; # ignore other
 529         $sock->blocking(1);
 530         $sock->autoflush(1);
 531         my $client = { sock => $sock };
 532         vec(my $rin = '', fileno($sock), 1) = 1;
 533         # `say $sock' triggers "die" in lei(1)
 534         for my $i (0..2) {
 535                 if (select(my $rout = $rin, undef, undef, 1)) {
 536                         my $fd = IO::FDPass::recv(fileno($sock));
 537                         if ($fd >= 0) {
 538                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 539                                 if (open(my $fh, $rdr, $fd)) {
 540                                         $client->{$i} = $fh;
 541                                 } else {
 542                                         say $sock "open($rdr$fd) (FD=$i): $!";
 543                                         return;
 544                                 }
 545                         } else {
 546                                 say $sock "recv FD=$i: $!";
 547                                 return;
 548                         }
 549                 } else {
 550                         say $sock "timed out waiting to recv FD=$i";
 551                         return;
 552                 }
 553         }
 554         # $ARGV_STR = join("]\0[", @ARGV);
 555         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 556         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 557         my ($client_pid, $argv, $env) = do {
 558                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 559                 chomp(my $line = <$sock>);
 560                 split(/\0\0>/, $line, 3);
 561         };
 562         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 563         if (chdir($env{PWD})) {
 564                 $client->{env} = \%env;
 565                 $client->{pid} = $client_pid;
 566                 eval { dispatch($client, split(/\]\0\[/, $argv)) };
 567                 say $sock $@ if $@;
 568         } else {
 569                 say $sock "chdir($env{PWD}): $!"; # implicit close
 570         }
 571 }
 572
 573 sub noop {}
 574
 575 # lei(1) calls this when it can't connect
 576 sub lazy_start {
 577         my ($path, $err) = @_;
 578         if ($err == ECONNREFUSED) {
 579                 unlink($path) or die "unlink($path): $!";
 580         } elsif ($err != ENOENT) {
 581                 die "connect($path): $!";
 582         }
 583         require IO::FDPass;
 584         umask(077) // die("umask(077): $!");
 585         my $l = IO::Socket::UNIX->new(Local => $path,
 586                                         Listen => 1024,
 587                                         Type => SOCK_STREAM) or
 588                 $err = $!;
 589         $l or return die "bind($path): $err";
 590         my @st = stat($path) or die "stat($path): $!";
 591         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 592         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 593         my $oldset = PublicInbox::Sigfd::block_signals();
 594         my $pid = fork // die "fork: $!";
 595         return if $pid;
 596         openlog($path, 'pid', 'user');
 597         local $SIG{__DIE__} = sub {
 598                 syslog('crit', "@_");
 599                 exit $! if $!;
 600                 exit $? >> 8 if $? >> 8;
 601                 exit 255;
 602         };
 603         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 604         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!\n";
 605         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 606         open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 607         setsid();
 608         $pid = fork // die "fork: $!";
 609         return if $pid;
 610         $0 = "lei-daemon $path";
 611         local %PATH2CFG;
 612         require PublicInbox::Listener;
 613         require PublicInbox::EOFpipe;
 614         $l->blocking(0);
 615         $eof_w->blocking(0);
 616         $eof_r->blocking(0);
 617         my $listener = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 618         my $exit_code;
 619         local $quit = sub {
 620                 $exit_code //= shift;
 621                 my $tmp = $listener or exit($exit_code);
 622                 unlink($path) if defined($path);
 623                 syswrite($eof_w, '.');
 624                 $l = $listener = $path = undef;
 625                 $tmp->close if $tmp; # DS::close
 626                 PublicInbox::DS->SetLoopTimeout(1000);
 627         };
 628         PublicInbox::EOFpipe->new($eof_r, sub {}, undef);
 629         my $sig = {
 630                 CHLD => \&PublicInbox::DS::enqueue_reap,
 631                 QUIT => $quit,
 632                 INT => $quit,
 633                 TERM => $quit,
 634                 HUP => \&noop,
 635                 USR1 => \&noop,
 636                 USR2 => \&noop,
 637         };
 638         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 639         local %SIG = (%SIG, %$sig) if !$sigfd;
 640         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 641                 PublicInbox::DS->SetLoopTimeout(5000);
 642         } else {
 643                 # wake up every second to accept signals if we don't
 644                 # have signalfd or IO::KQueue:
 645                 PublicInbox::Sigfd::sig_setmask($oldset);
 646                 PublicInbox::DS->SetLoopTimeout(1000);
 647         }
 648         PublicInbox::DS->SetPostLoopCallback(sub {
 649                 my ($dmap, undef) = @_;
 650                 if (@st = defined($path) ? stat($path) : ()) {
 651                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 652                                 warn "$path dev/ino changed, quitting\n";
 653                                 $path = undef;
 654                         }
 655                 } elsif (defined($path)) {
 656                         warn "stat($path): $!, quitting ...\n";
 657                         undef $path; # don't unlink
 658                         $quit->();
 659                 }
 660                 return 1 if defined($path);
 661                 my $now = now();
 662                 my $n = 0;
 663                 for my $s (values %$dmap) {
 664                         $s->can('busy') or next;
 665                         if ($s->busy($now)) {
 666                                 ++$n;
 667                         } else {
 668                                 $s->close;
 669                         }
 670                 }
 671                 $n; # true: continue, false: stop
 672         });
 673         PublicInbox::DS->EventLoop;
 674         exit($exit_code // 0);
 675 }
 676
 677 # for users w/o IO::FDPass
 678 sub oneshot {
 679         my ($main_pkg) = @_;
 680         my $exit = $main_pkg->can('exit'); # caller may override exit()
 681         local $quit = $exit if $exit;
 682         local %PATH2CFG;
 683         umask(077) // die("umask(077): $!");
 684         dispatch({
 685                 0 => *STDIN{IO},
 686                 1 => *STDOUT{IO},
 687                 2 => *STDERR{IO},
 688                 env => \%ENV
 689         }, @ARGV);
 690 }
 691
 692 1;