lib/PublicInbox/LeiExportKw.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei export-kw" sub-command
   5 package PublicInbox::LeiExportKw;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9 use Errno qw(EEXIST ENOENT);
  10
  11 sub export_kw_md { # LeiMailSync->each_src callback
  12         my ($oidbin, $id, $self, $mdir) = @_;
  13         my $oidhex = unpack('H*', $oidbin);
  14         my $sto_kw = $self->{lse}->oid_keywords($oidhex) or return;
  15         my $bn = $$id;
  16         my ($md_kw, $unknown, @try);
  17         if ($bn =~ s/:2,([a-zA-Z]*)\z//) {
  18                 ($md_kw, $unknown) = PublicInbox::MdirReader::flags2kw($1);
  19                 @try = qw(cur new);
  20         } else {
  21                 $unknown = [];
  22                 @try = qw(new cur);
  23         }
  24         if ($self->{-merge_kw} && $md_kw) { # merging keywords is the default
  25                 @$sto_kw{keys %$md_kw} = values(%$md_kw);
  26         }
  27         $bn .= ':2,'.
  28                 PublicInbox::LeiToMail::kw2suffix([keys %$sto_kw], @$unknown);
  29         my $dst = "$mdir/cur/$bn";
  30         my @fail;
  31         for my $d (@try) {
  32                 my $src = "$mdir/$d/$$id";
  33                 next if $src eq $dst;
  34
  35                 # we use link(2) + unlink(2) since rename(2) may
  36                 # inadvertently clobber if the "uniquefilename" part wasn't
  37                 # actually unique.
  38                 if (link($src, $dst)) { # success
  39                         # unlink(2) may ENOENT from parallel invocation,
  40                         # ignore it, but not other serious errors
  41                         if (!unlink($src) and $! != ENOENT) {
  42                                 $self->{lei}->child_error(1,
  43                                                         "E: unlink($src): $!");
  44                         }
  45                         $self->{lms}->mv_src("maildir:$mdir",
  46                                                 $oidbin, $id, $bn) or die;
  47                         return; # success anyways if link(2) worked
  48                 }
  49                 if ($! == ENOENT && !-e $src) { # some other process moved it
  50                         $self->{lms}->clear_src("maildir:$mdir", $id);
  51                         next;
  52                 }
  53                 push @fail, $src if $! != EEXIST;
  54         }
  55         return unless @fail;
  56         # both tries failed
  57         my $e = $!;
  58         my $orig = '['.join('|', @fail).']';
  59         $self->{lei}->child_error(1, "link($orig, $dst) ($oidhex): $e");
  60 }
  61
  62 sub export_kw_imap { # LeiMailSync->each_src callback
  63         my ($oidbin, $id, $self, $mic) = @_;
  64         my $oidhex = unpack('H*', $oidbin);
  65         my $sto_kw = $self->{lse}->oid_keywords($oidhex) or return;
  66         $self->{imap_mod_kw}->($self->{nwr}, $mic, $id, [ keys %$sto_kw ]);
  67 }
  68
  69 # overrides PublicInbox::LeiInput::input_path_url
  70 sub input_path_url {
  71         my ($self, $input, @args) = @_;
  72         my $lms = $self->{lms} //= $self->{lse}->lms;
  73         $lms->lms_begin;
  74         if ($input =~ /\Amaildir:(.+)/i) {
  75                 my $mdir = $1;
  76                 require PublicInbox::LeiToMail; # kw2suffix
  77                 $lms->each_src($input, \&export_kw_md, $self, $mdir);
  78         } elsif ($input =~ m!\Aimaps?://!) {
  79                 my $uri = PublicInbox::URIimap->new($input);
  80                 my $mic = $self->{nwr}->mic_for_folder($uri);
  81                 $lms->each_src($$uri, \&export_kw_imap, $self, $mic);
  82                 $mic->expunge;
  83         } else { die "BUG: $input not supported" }
  84         $lms->lms_commit;
  85 }
  86
  87 sub lei_export_kw {
  88         my ($lei, @folders) = @_;
  89         my $sto = $lei->_lei_store or return $lei->fail(<<EOM);
  90 lei/store uninitialized, see lei-import(1)
  91 EOM
  92         my $lse = $sto->search;
  93         my $lms = $lse->lms or return $lei->fail(<<EOM);
  94 lei mail_sync uninitialized, see lei-import(1)
  95 EOM
  96         my $opt = $lei->{opt};
  97         my $all = $opt->{all};
  98         my @all = $lms->folders;
  99         if (defined $all) { # --all=<local|remote>
 100                 my %x = map { $_ => $_ } split(/,/, $all);
 101                 my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 102                 my @no = keys %x;
 103                 if (@no) {
 104                         @no = (join(',', @no));
 105                         return $lei->fail(<<EOM);
 106 --all=@no not accepted (must be `local' and/or `remote')
 107 EOM
 108                 }
 109                 my (%seen, @inc);
 110                 for my $ok (@ok) {
 111                         if ($ok eq 'local') {
 112                                 @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 113                         } elsif ($ok eq 'remote') {
 114                                 @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 115                         } elsif ($ok ne '') {
 116                                 return $lei->fail("--all=$all not understood");
 117                         } else {
 118                                 @inc = @all;
 119                         }
 120                         for (@inc) {
 121                                 push(@folders, $_) unless $seen{$_}++;
 122                         }
 123                 }
 124                 return $lei->fail(<<EOM) if !@folders;
 125 no --mail-sync folders known to lei
 126 EOM
 127         } else {
 128                 my %all = map { $_ => 1 } @all;
 129                 my @no;
 130                 for (@folders) {
 131                         next if $all{$_}; # ok
 132                         if (-d "$_/new" && -d "$_/cur") {
 133                                 my $d = 'maildir:'.$lei->rel2abs($_);
 134                                 push(@no, $_) unless $all{$d};
 135                                 $_ = $d;
 136                         } else {
 137                                 push @no, $_;
 138                         }
 139                 }
 140                 my $no = join("\n\t", @no);
 141                 return $lei->fail(<<EOF) if @no;
 142 No sync information for: $no
 143 Run `lei ls-mail-sync' to display valid choices
 144 EOF
 145         }
 146         my $self = bless { lse => $lse }, __PACKAGE__;
 147         $lei->{opt}->{'mail-sync'} = 1; # for prepare_inputs
 148         $self->prepare_inputs($lei, \@folders) or return;
 149         my $j = $opt->{jobs} // scalar(@{$self->{inputs}}) || 1;
 150         if (my @ro = grep(!/\A(?:maildir|imaps?):/, @folders)) {
 151                 return $lei->fail("cannot export to read-only folders: @ro");
 152         }
 153         my $m = $opt->{mode} // 'merge';
 154         if ($m eq 'merge') { # default
 155                 $self->{-merge_kw} = 1;
 156         } elsif ($m eq 'set') {
 157         } else {
 158                 return $lei->fail(<<EOM);
 159 --mode=$m not supported (`set' or `merge')
 160 EOM
 161         }
 162         if (my $net = $lei->{net}) {
 163                 require PublicInbox::NetWriter;
 164                 $self->{nwr} = bless $net, 'PublicInbox::NetWriter';
 165                 $self->{imap_mod_kw} = $net->can($self->{-merge_kw} ?
 166                                         'imap_add_kw' : 'imap_set_kw');
 167         }
 168         undef $lms;
 169         my $ops = {};
 170         $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
 171         $self->{-wq_nr_workers} = $j // 1; # locked
 172         (my $op_c, $ops) = $lei->workers_start($self, $j, $ops);
 173         $lei->{wq1} = $self;
 174         $lei->{-err_type} = 'non-fatal';
 175         net_merge_all_done($self) unless $lei->{auth};
 176         $op_c->op_wait_event($ops); # calls net_merge_all_done if $lei->{auth}
 177 }
 178
 179 sub _complete_export_kw {
 180         my ($lei, @argv) = @_;
 181         my $sto = $lei->_lei_store or return;
 182         my $lms = $sto->search->lms or return;
 183         my $match_cb = $lei->complete_url_prepare(\@argv);
 184         map { $match_cb->($_) } $lms->folders;
 185 }
 186
 187 no warnings 'once';
 188
 189 *ipc_atfork_child = \&PublicInbox::LeiInput::input_only_atfork_child;
 190 *net_merge_all_done = \&PublicInbox::LeiInput::input_only_net_merge_all_done;
 191
 192 # the following works even when LeiAuth is lazy-loaded
 193 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 194
 195 1;