lib/PublicInbox/LeiExternal.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # *-external commands of lei
   5 package PublicInbox::LeiExternal;
   6 use strict;
   7 use v5.10.1;
   8 use PublicInbox::Config;
   9
  10 sub externals_each {
  11         my ($self, $cb, @arg) = @_;
  12         my $cfg = $self->_lei_cfg;
  13         my %boost;
  14         for my $sec (grep(/\Aexternal\./, @{$cfg->{-section_order}})) {
  15                 my $loc = substr($sec, length('external.'));
  16                 $boost{$loc} = $cfg->{"$sec.boost"};
  17         }
  18         return \%boost if !wantarray && !$cb;
  19
  20         # highest boost first, but stable for alphabetic tie break
  21         use sort 'stable';
  22         my @order = sort { $boost{$b} <=> $boost{$a} } sort keys %boost;
  23         if (ref($cb) eq 'CODE') {
  24                 for my $loc (@order) {
  25                         $cb->(@arg, $loc, $boost{$loc});
  26                 }
  27         } elsif (ref($cb) eq 'HASH') {
  28                 %$cb = %boost;
  29         }
  30         @order; # scalar or array
  31 }
  32
  33 sub ext_canonicalize {
  34         my ($location) = @_;
  35         if ($location !~ m!\Ahttps?://!) {
  36                 PublicInbox::Config::rel2abs_collapsed($location);
  37         } else {
  38                 require URI;
  39                 my $uri = URI->new($location)->canonical;
  40                 my $path = $uri->path . '/';
  41                 $path =~ tr!/!/!s; # squeeze redundant '/'
  42                 $uri->path($path);
  43                 $uri->as_string;
  44         }
  45 }
  46
  47 # TODO: we will probably extract glob2re into a separate module for
  48 # PublicInbox::Filter::Base and maybe other places
  49 my %re_map = ( '*' => '[^/]*?', '?' => '[^/]',
  50                 '[' => '[', ']' => ']', ',' => ',' );
  51
  52 sub glob2re {
  53         my ($re) = @_;
  54         my $p = '';
  55         my $in_bracket = 0;
  56         my $qm = 0;
  57         my $schema_host_port = '';
  58
  59         # don't glob URL-looking things that look like IPv6
  60         if ($re =~ s!\A([a-z0-9\+]+://\[[a-f0-9\:]+\](?::[0-9]+)?/)!!i) {
  61                 $schema_host_port = quotemeta $1; # "http://[::1]:1234"
  62         }
  63         my $changes = ($re =~ s!(.)!
  64                 $re_map{$p eq '\\' ? '' : do {
  65                         if ($1 eq '[') { ++$in_bracket }
  66                         elsif ($1 eq ']') { --$in_bracket }
  67                         elsif ($1 eq ',') { ++$qm } # no change
  68                         $p = $1;
  69                 }} // do {
  70                         $p = $1;
  71                         ($p eq '-' && $in_bracket) ? $p : (++$qm, "\Q$p")
  72                 }!sge);
  73         # bashism (also supported by curl): {a,b,c} => (a|b|c)
  74         $changes += ($re =~ s/([^\\]*)\\\{([^,]*,[^\\]*)\\\}/
  75                         (my $in_braces = $2) =~ tr!,!|!;
  76                         $1."($in_braces)";
  77                         /sge);
  78         ($changes - $qm) ? $schema_host_port.$re : undef;
  79 }
  80
  81 # get canonicalized externals list matching $loc
  82 # $is_exclude denotes it's for --exclude
  83 # otherwise it's for --only/--include is assumed
  84 sub get_externals {
  85         my ($self, $loc, $is_exclude) = @_;
  86         return (ext_canonicalize($loc)) if -e $loc;
  87         my @m;
  88         my @cur = externals_each($self);
  89         my $do_glob = !$self->{opt}->{globoff}; # glob by default
  90         if ($do_glob && (my $re = glob2re($loc))) {
  91                 @m = grep(m!$re!, @cur);
  92                 return @m if scalar(@m);
  93         } elsif (index($loc, '/') < 0) { # exact basename match:
  94                 @m = grep(m!/\Q$loc\E/?\z!, @cur);
  95                 return @m if scalar(@m) == 1;
  96         } elsif ($is_exclude) { # URL, maybe:
  97                 my $canon = ext_canonicalize($loc);
  98                 @m = grep(m!\A\Q$canon\E\z!, @cur);
  99                 return @m if scalar(@m) == 1;
 100         } else { # URL:
 101                 return (ext_canonicalize($loc));
 102         }
 103         if (scalar(@m) == 0) {
 104                 $self->fail("`$loc' is unknown");
 105         } else {
 106                 $self->fail("`$loc' is ambiguous:\n", map { "\t$_\n" } @m);
 107         }
 108         ();
 109 }
 110
 111 # TODO: does this need JSON output?
 112 sub lei_ls_external {
 113         my ($self, $filter) = @_;
 114         my $opt = $self->{opt};
 115         my $do_glob = !$opt->{globoff}; # glob by default
 116         my ($OFS, $ORS) = $opt->{z} ? ("\0", "\0\0") : (" ", "\n");
 117         $filter //= '*';
 118         my $re = $do_glob ? glob2re($filter) : undef;
 119         $re //= index($filter, '/') < 0 ?
 120                         qr!/\Q$filter\E/?\z! : # exact basename match
 121                         qr/\Q$filter\E/; # grep -F semantics
 122         my @ext = externals_each($self, my $boost = {});
 123         @ext = $opt->{'invert-match'} ? grep(!/$re/, @ext)
 124                                         : grep(/$re/, @ext);
 125         if ($opt->{'local'} && !$opt->{remote}) {
 126                 @ext = grep(!m!\A[a-z\+]+://!, @ext);
 127         } elsif ($opt->{remote} && !$opt->{'local'}) {
 128                 @ext = grep(m!\A[a-z\+]+://!, @ext);
 129         }
 130         for my $loc (@ext) {
 131                 $self->out($loc, $OFS, 'boost=', $boost->{$loc}, $ORS);
 132         }
 133 }
 134
 135 sub add_external_finish {
 136         my ($self, $location) = @_;
 137         my $cfg = $self->_lei_cfg(1);
 138         my $new_boost = $self->{opt}->{boost} // 0;
 139         my $key = "external.$location.boost";
 140         my $cur_boost = $cfg->{$key};
 141         return if defined($cur_boost) && $cur_boost == $new_boost; # idempotent
 142         if (-d $location) {
 143                 require PublicInbox::LeiXSearch;
 144                 my $lxs = PublicInbox::LeiXSearch->new;
 145                 $lxs->prepare_external($location);
 146                 $self->ale->refresh_externals($lxs);
 147         }
 148         $self->lei_config($key, $new_boost);
 149 }
 150
 151 sub lei_add_external {
 152         my ($self, $location) = @_;
 153         $self->_lei_store(1)->write_prepare($self);
 154         my $opt = $self->{opt};
 155         my $mirror = $opt->{mirror} // do {
 156                 my @fail;
 157                 for my $sw ($self->index_opt, $self->curl_opt,
 158                                 qw(c no-torsocks torsocks inbox-version)) {
 159                         my ($f) = (split(/|/, $sw, 2))[0];
 160                         next unless defined $opt->{$f};
 161                         $f = length($f) == 1 ? "-$f" : "--$f";
 162                         push @fail, $f;
 163                 }
 164                 if (scalar(@fail) == 1) {
 165                         return $self->("@fail requires --mirror");
 166                 } elsif (@fail) {
 167                         my $last = pop @fail;
 168                         my $fail = join(', ', @fail);
 169                         return $self->("@fail and $last require --mirror");
 170                 }
 171                 undef;
 172         };
 173         my $new_boost = $opt->{boost} // 0;
 174         $location = ext_canonicalize($location);
 175         if (defined($mirror) && -d $location) {
 176                 $self->fail(<<""); # TODO: did you mean "update-external?"
 177 --mirror destination `$location' already exists
 178
 179         } elsif (-d $location) {
 180                 index($location, "\n") >= 0 and
 181                         return $self->fail("`\\n' not allowed in `$location'");
 182         }
 183         if ($location !~ m!\Ahttps?://! && !-d $location) {
 184                 $mirror // return $self->fail("$location not a directory");
 185                 index($location, "\n") >= 0 and
 186                         return $self->fail("`\\n' not allowed in `$location'");
 187                 $mirror = ext_canonicalize($mirror);
 188                 require PublicInbox::LeiMirror;
 189                 PublicInbox::LeiMirror->start($self, $mirror => $location);
 190         } else {
 191                 add_external_finish($self, $location);
 192         }
 193 }
 194
 195 sub lei_forget_external {
 196         my ($self, @locations) = @_;
 197         my $cfg = $self->_lei_cfg(1);
 198         my $quiet = $self->{opt}->{quiet};
 199         my %seen;
 200         for my $loc (@locations) {
 201                 my (@unset, @not_found);
 202                 for my $l ($loc, ext_canonicalize($loc)) {
 203                         next if $seen{$l}++;
 204                         my $key = "external.$l.boost";
 205                         delete($cfg->{$key});
 206                         $self->_config('--unset', $key);
 207                         if ($? == 0) {
 208                                 push @unset, $l;
 209                         } elsif (($? >> 8) == 5) {
 210                                 push @not_found, $l;
 211                         } else {
 212                                 $self->err("# --unset $key error");
 213                                 return $self->x_it($?);
 214                         }
 215                 }
 216                 if (@unset) {
 217                         next if $quiet;
 218                         $self->err("# $_ gone") for @unset;
 219                 } elsif (@not_found) {
 220                         $self->err("# $_ not found") for @not_found;
 221                 } # else { already exited
 222         }
 223 }
 224
 225 sub _complete_url_common ($) {
 226         my ($argv) = @_;
 227         # Workaround bash word-splitting URLs to ['https', ':', '//' ...]
 228         # Maybe there's a better way to go about this in
 229         # contrib/completion/lei-completion.bash
 230         my $re = '';
 231         my $cur = pop @$argv;
 232         if (@$argv) {
 233                 my @x = @$argv;
 234                 if ($cur eq ':' && @x) {
 235                         push @x, $cur;
 236                         $cur = '';
 237                 }
 238                 while (@x > 2 && $x[0] !~ /\Ahttps?\z/ && $x[1] ne ':') {
 239                         shift @x;
 240                 }
 241                 if (@x >= 2) { # qw(https : hostname : 443) or qw(http :)
 242                         $re = join('', @x);
 243                 } else { # just filter out the flags and hope for the best
 244                         $re = join('', grep(!/^-/, @$argv));
 245                 }
 246                 $re = quotemeta($re);
 247         }
 248         ($cur, $re);
 249 }
 250
 251 # shell completion helper called by lei__complete
 252 sub _complete_forget_external {
 253         my ($self, @argv) = @_;
 254         my $cfg = $self->_lei_cfg;
 255         my ($cur, $re) = _complete_url_common(\@argv);
 256         # FIXME: bash completion off "http:" or "https:" when the last
 257         # character is a colon doesn't work properly even if we're
 258         # returning "//$HTTP_HOST/$PATH_INFO/", not sure why, could
 259         # be a bash issue.
 260         map {
 261                 my $x = substr($_, length('external.'));
 262                 # only return the part specified on the CLI
 263                 # don't duplicate if already 100% completed
 264                 $x =~ /\A$re(\Q$cur\E.*)/ ? ($cur eq $1 ? () : $1) : ();
 265         } grep(/\Aexternal\.$re\Q$cur/, @{$cfg->{-section_order}});
 266 }
 267
 268 sub _complete_add_external { # for bash, this relies on "compopt -o nospace"
 269         my ($self, @argv) = @_;
 270         my $cfg = $self->_lei_cfg;
 271         my ($cur, $re) = _complete_url_common(\@argv);
 272         require URI;
 273         map {
 274                 my $u = URI->new(substr($_, length('external.')));
 275                 my ($base) = ($u->path =~ m!((?:/?.*)?/)[^/]+/?\z!);
 276                 $u->path($base);
 277                 $u = $u->as_string;
 278                 $u =~ /\A$re(\Q$cur\E.*)/ ? ($cur eq $1 ? () : $1) : ();
 279         } grep(m!\Aexternal\.https?://!, @{$cfg->{-section_order}});
 280 }
 281
 282 1;