lib/PublicInbox/LeiImport.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei import" sub-command
   5 package PublicInbox::LeiImport;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9
  10 # /^input_/ subs are used by (or override) PublicInbox::LeiInput superclass
  11
  12 sub input_eml_cb { # used by PublicInbox::LeiInput::input_fh
  13         my ($self, $eml, $vmd) = @_;
  14         my $xoids = $self->{lei}->{ale}->xoids_for($eml);
  15         if (my $all_vmd = $self->{all_vmd}) {
  16                 @$vmd{keys %$all_vmd} = values %$all_vmd;
  17         }
  18         $self->{lei}->{sto}->ipc_do('set_eml', $eml, $vmd, $xoids);
  19 }
  20
  21 sub input_mbox_cb { # MboxReader callback
  22         my ($eml, $self) = @_;
  23         my $vmd;
  24         if ($self->{-import_kw}) {
  25                 my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
  26                 $vmd = { kw => $kw } if scalar(@$kw);
  27         }
  28         input_eml_cb($self, $eml, $vmd);
  29 }
  30
  31 sub input_maildir_cb { # maildir_each_eml cb
  32         my ($f, $kw, $eml, $self) = @_;
  33         my $vmd = $self->{-import_kw} ? { kw => $kw } : undef;
  34         if ($self->{-mail_sync}) {
  35                 if ($f =~ m!\A(.+?)/(?:new|cur)/([^/]+)\z!) { # ugh...
  36                         $vmd->{sync_info} = [ "maildir:$1", \(my $n = $2) ];
  37                 } else {
  38                         warn "E: $f was not from a Maildir?\n";
  39                 }
  40         }
  41         $self->input_eml_cb($eml, $vmd);
  42 }
  43
  44 sub input_net_cb { # imap_each / nntp_each
  45         my ($uri, $uid, $kw, $eml, $self) = @_;
  46         my $vmd = $self->{-import_kw} ? { kw => $kw } : undef;
  47         $vmd->{sync_info} = [ $$uri, $uid ] if $self->{-mail_sync};
  48         if (defined $eml) {
  49                 $self->input_eml_cb($eml, $vmd);
  50         } elsif ($vmd) { # old message, kw only
  51                 my $oid = $self->{-lms_ro}->imap_oid2($uri, $uid) // return;
  52                 my @docids = $self->{lse}->over->blob_exists($oid) or return;
  53                 my $lei = $self->{lei};
  54                 $lei->qerr("# $oid => @$kw\n") if $lei->{opt}->{verbose};
  55                 $self->{lei}->{sto}->ipc_do('set_eml_vmd', undef,
  56                                                 $vmd, \@docids);
  57         }
  58 }
  59
  60 sub do_import_index ($$@) {
  61         my ($self, $lei, @inputs) = @_;
  62         my $sto = $lei->_lei_store(1);
  63         $sto->write_prepare($lei);
  64         $self->{-import_kw} = $lei->{opt}->{kw} // 1;
  65         my $vmd_mod = $self->vmd_mod_extract(\@inputs);
  66         return $lei->fail(join("\n", @{$vmd_mod->{err}})) if $vmd_mod->{err};
  67         $self->{all_vmd} = $vmd_mod if scalar keys %$vmd_mod;
  68         $self->prepare_inputs($lei, \@inputs) or return;
  69         $self->{-mail_sync} = $lei->{opt}->{'mail-sync'} // 1;
  70
  71         $lei->ale; # initialize for workers to read
  72         my $j = $lei->{opt}->{jobs} // scalar(@{$self->{inputs}}) || 1;
  73         if (my $net = $lei->{net}) {
  74                 # $j = $net->net_concurrency($j); TODO
  75                 if ($lei->{opt}->{incremental} // 1) {
  76                         $net->{incremental} = 1;
  77                         $net->{-lms_ro} = $sto->search->lms // 0;
  78                         if ($self->{-import_kw}) {
  79                                 $net->{each_old} = 1;
  80                                 $self->{-lms_ro} = $net->{-lms_ro};
  81                                 $self->{lse} = $sto->search;
  82                         }
  83                 }
  84         } else {
  85                 my $nproc = $self->detect_nproc;
  86                 $j = $nproc if $j > $nproc;
  87         }
  88         my $ops = {};
  89         $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
  90         $self->{-wq_nr_workers} = $j // 1; # locked
  91         $lei->{-eml_noisy} = 1;
  92         (my $op_c, $ops) = $lei->workers_start($self, $j, $ops);
  93         $lei->{wq1} = $self;
  94         $lei->{-err_type} = 'non-fatal';
  95         net_merge_all_done($self) unless $lei->{auth};
  96         $op_c->op_wait_event($ops);
  97 }
  98
  99 sub lei_import { # the main "lei import" method
 100         my ($lei, @inputs) = @_;
 101         my $self = bless {}, __PACKAGE__;
 102         do_import_index($self, $lei, @inputs);
 103 }
 104
 105 sub _complete_import {
 106         my ($lei, @argv) = @_;
 107         my $sto = $lei->_lei_store or return;
 108         my $lms = $sto->search->lms or return;
 109         my $match_cb = $lei->complete_url_prepare(\@argv);
 110         map { $match_cb->($_) } $lms->folders;
 111 }
 112
 113 no warnings 'once';
 114 *ipc_atfork_child = \&PublicInbox::LeiInput::input_only_atfork_child;
 115 *net_merge_all_done = \&PublicInbox::LeiInput::input_only_net_merge_all_done;
 116
 117 # the following works even when LeiAuth is lazy-loaded
 118 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 119 1;