lib/PublicInbox/LeiImport.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei import" sub-command
   5 package PublicInbox::LeiImport;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9
  10 # /^input_/ subs are used by (or override) PublicInbox::LeiInput superclass
  11
  12 sub input_eml_cb { # used by PublicInbox::LeiInput::input_fh
  13         my ($self, $eml, $vmd) = @_;
  14         my $xoids = $self->{lei}->{ale}->xoids_for($eml);
  15         if (my $all_vmd = $self->{all_vmd}) {
  16                 @$vmd{keys %$all_vmd} = values %$all_vmd;
  17         }
  18         $self->{lei}->{sto}->ipc_do('set_eml', $eml, $vmd, $xoids);
  19 }
  20
  21 sub input_mbox_cb { # MboxReader callback
  22         my ($eml, $self) = @_;
  23         my $vmd;
  24         if ($self->{-import_kw}) {
  25                 my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
  26                 $vmd = { kw => $kw } if scalar(@$kw);
  27         }
  28         input_eml_cb($self, $eml, $vmd);
  29 }
  30
  31 sub input_maildir_cb { # maildir_each_eml cb
  32         my ($f, $kw, $eml, $self) = @_;
  33         my $vmd = $self->{-import_kw} ? { kw => $kw } : undef;
  34         if ($self->{-mail_sync}) {
  35                 if ($f =~ m!\A(.+?)/(?:new|cur)/([^/]+)\z!) { # ugh...
  36                         $vmd->{sync_info} = [ "maildir:$1", \(my $n = $2) ];
  37                 } else {
  38                         warn "E: $f was not from a Maildir?\n";
  39                 }
  40         }
  41         input_eml_cb($self, $eml, $vmd);
  42 }
  43
  44 sub input_imap_cb { # imap_each
  45         my ($url, $uid, $kw, $eml, $self) = @_;
  46         my $vmd = $self->{-import_kw} ? { kw => $kw } : undef;
  47         $vmd->{sync_info} = [ $url, $uid ] if $self->{-mail_sync};
  48         input_eml_cb($self, $eml, $vmd);
  49 }
  50
  51 sub input_nntp_cb { # nntp_each
  52         my ($url, $num, $kw, $eml, $self) = @_;
  53         input_eml_cb($self, $eml, $self->{-import_kw} ? { kw => $kw } : undef);
  54 }
  55
  56 sub _lei_wq_eof { # EOF callback for main daemon
  57         my ($lei) = @_;
  58         my $imp = delete $lei->{imp} // return $lei->fail('BUG: {imp} gone');
  59         $imp->wq_wait_old($lei->can('wq_done_wait'), $lei, 'non-fatal');
  60 }
  61
  62 sub net_merge_complete { # callback used by LeiAuth
  63         my ($self) = @_;
  64         $self->wq_io_do('process_inputs');
  65         $self->wq_close(1);
  66 }
  67
  68 sub lei_import { # the main "lei import" method
  69         my ($lei, @inputs) = @_;
  70         my $sto = $lei->_lei_store(1);
  71         $sto->write_prepare($lei);
  72         my $self = bless {}, __PACKAGE__;
  73         $self->{-import_kw} = $lei->{opt}->{kw} // 1;
  74         my $vmd_mod = $self->vmd_mod_extract(\@inputs);
  75         return $lei->fail(join("\n", @{$vmd_mod->{err}})) if $vmd_mod->{err};
  76         $self->{all_vmd} = $vmd_mod if scalar keys %$vmd_mod;
  77         $self->prepare_inputs($lei, \@inputs) or return;
  78         $self->{-mail_sync} = $lei->{opt}->{sync} // 1;
  79
  80         $lei->ale; # initialize for workers to read
  81         my $j = $lei->{opt}->{jobs} // scalar(@{$self->{inputs}}) || 1;
  82         if (my $net = $lei->{net}) {
  83                 # $j = $net->net_concurrency($j); TODO
  84                 if ($lei->{opt}->{incremental} // 1) {
  85                         $net->{incremental} = 1;
  86                         $net->{itrk_fn} = $lei->store_path .
  87                                                 '/net_last.sqlite3';
  88                 }
  89         } else {
  90                 my $nproc = $self->detect_nproc;
  91                 $j = $nproc if $j > $nproc;
  92         }
  93         my $ops = {};
  94         $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
  95         $self->{-wq_nr_workers} = $j // 1; # locked
  96         (my $op_c, $ops) = $lei->workers_start($self, 'lei-import', $j, $ops);
  97         $lei->{imp} = $self;
  98         net_merge_complete($self) unless $lei->{auth};
  99         $op_c->op_wait_event($ops);
 100 }
 101
 102 no warnings 'once';
 103 *ipc_atfork_child = \&PublicInbox::LeiInput::input_only_atfork_child;
 104
 105 # the following works even when LeiAuth is lazy-loaded
 106 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 107 1;