lib/PublicInbox/LeiImport.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei import" sub-command
   5 package PublicInbox::LeiImport;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9
  10 # /^input_/ subs are used by (or override) PublicInbox::LeiInput superclass
  11
  12 sub input_eml_cb { # used by PublicInbox::LeiInput::input_fh
  13         my ($self, $eml, $vmd) = @_;
  14         my $xoids = $self->{lei}->{ale}->xoids_for($eml);
  15         $self->{lei}->{sto}->ipc_do('set_eml', $eml, $vmd, $xoids);
  16 }
  17
  18 sub input_mbox_cb { # MboxReader callback
  19         my ($eml, $self) = @_;
  20         my $vmd;
  21         if ($self->{-import_kw}) {
  22                 my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
  23                 $vmd = { kw => $kw } if scalar(@$kw);
  24         }
  25         input_eml_cb($self, $eml, $vmd);
  26 }
  27
  28 sub input_maildir_cb { # maildir_each_eml cb
  29         my ($f, $kw, $eml, $self) = @_;
  30         input_eml_cb($self, $eml, $self->{-import_kw} ? { kw => $kw } : undef);
  31 }
  32
  33 sub input_net_cb { # imap_each, nntp_each cb
  34         my ($url, $uid, $kw, $eml, $self) = @_;
  35         input_eml_cb($self, $eml, $self->{-import_kw} ? { kw => $kw } : undef);
  36 }
  37
  38 sub import_done_wait { # dwaitpid callback
  39         my ($arg, $pid) = @_;
  40         my ($imp, $lei) = @$arg;
  41         $lei->child_error($?, 'non-fatal errors during import') if $?;
  42         $lei->dclose;
  43 }
  44
  45 sub import_done { # EOF callback for main daemon
  46         my ($lei) = @_;
  47         my $imp = delete $lei->{imp} // return $lei->fail('BUG: {imp} gone');
  48         $imp->wq_wait_old(\&import_done_wait, $lei);
  49 }
  50
  51 sub net_merge_complete { # callback used by LeiAuth
  52         my ($self) = @_;
  53         $self->wq_io_do('process_inputs');
  54         $self->wq_close(1);
  55 }
  56
  57 sub lei_import { # the main "lei import" method
  58         my ($lei, @inputs) = @_;
  59         my $sto = $lei->_lei_store(1);
  60         $sto->write_prepare($lei);
  61         my $self = bless {}, __PACKAGE__;
  62         $self->{-import_kw} = $lei->{opt}->{kw} // 1;
  63         $self->prepare_inputs($lei, \@inputs) or return;
  64         $lei->ale; # initialize for workers to read
  65         my $j = $lei->{opt}->{jobs} // scalar(@{$self->{inputs}}) || 1;
  66         if (my $net = $lei->{net}) {
  67                 # $j = $net->net_concurrency($j); TODO
  68         } else {
  69                 my $nproc = $self->detect_nproc;
  70                 $j = $nproc if $j > $nproc;
  71         }
  72         my $ops = { '' => [ \&import_done, $lei ] };
  73         $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
  74         $self->{-wq_nr_workers} = $j // 1; # locked
  75         (my $op_c, $ops) = $lei->workers_start($self, 'lei_import', $j, $ops);
  76         $lei->{imp} = $self;
  77         net_merge_complete($self) unless $lei->{auth};
  78         $op_c->op_wait_event($ops);
  79 }
  80
  81 no warnings 'once';
  82 *ipc_atfork_child = \&PublicInbox::LeiInput::input_only_atfork_child;
  83
  84 # the following works even when LeiAuth is lazy-loaded
  85 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
  86 1;