lib/PublicInbox/LeiImport.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei import" sub-command
   5 package PublicInbox::LeiImport;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
   9 use PublicInbox::Eml;
  10 use PublicInbox::PktOp qw(pkt_do);
  11
  12 sub _import_eml { # MboxReader callback
  13         my ($eml, $lei, $mbox_keywords) = @_;
  14         my $vmd;
  15         if ($mbox_keywords) {
  16                 my $kw = $mbox_keywords->($eml);
  17                 $vmd = { kw => $kw } if scalar(@$kw);
  18         }
  19         my $xoids = $lei->{ale}->xoids_for($eml);
  20         $lei->{sto}->ipc_do('set_eml', $eml, $vmd, $xoids);
  21 }
  22
  23 sub import_done_wait { # dwaitpid callback
  24         my ($arg, $pid) = @_;
  25         my ($imp, $lei) = @$arg;
  26         $lei->child_error($?, 'non-fatal errors during import') if $?;
  27         my $sto = delete $lei->{sto};
  28         my $wait = $sto->ipc_do('done') if $sto; # PublicInbox::LeiStore::done
  29         $lei->dclose;
  30 }
  31
  32 sub import_done { # EOF callback for main daemon
  33         my ($lei) = @_;
  34         my $imp = delete $lei->{imp} or return;
  35         $imp->wq_wait_old(\&import_done_wait, $lei);
  36 }
  37
  38 sub net_merge_complete { # callback used by LeiAuth
  39         my ($self) = @_;
  40         for my $input (@{$self->{inputs}}) {
  41                 $self->wq_io_do('import_path_url', [], $input);
  42         }
  43         $self->wq_close(1);
  44 }
  45
  46 sub import_start {
  47         my ($lei) = @_;
  48         my $self = $lei->{imp};
  49         $lei->ale;
  50         my $j = $lei->{opt}->{jobs} // scalar(@{$self->{inputs}}) || 1;
  51         if (my $net = $lei->{net}) {
  52                 # $j = $net->net_concurrency($j); TODO
  53         } else {
  54                 my $nproc = $self->detect_nproc;
  55                 $j = $nproc if $j > $nproc;
  56         }
  57         my $ops = { '' => [ \&import_done, $lei ] };
  58         $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
  59         $self->{-wq_nr_workers} = $j // 1; # locked
  60         my $op = $lei->workers_start($self, 'lei_import', undef, $ops);
  61         $self->wq_io_do('import_stdin', []) if $self->{0};
  62         net_merge_complete($self) unless $lei->{auth};
  63         while ($op && $op->{sock}) { $op->event_step }
  64 }
  65
  66 sub lei_import { # the main "lei import" method
  67         my ($lei, @inputs) = @_;
  68         my $sto = $lei->_lei_store(1);
  69         $sto->write_prepare($lei);
  70         $lei->{opt}->{kw} //= 1;
  71         my $self = $lei->{imp} = bless {}, __PACKAGE__;
  72         $self->prepare_inputs($lei, \@inputs) or return;
  73         import_start($lei);
  74 }
  75
  76 sub ipc_atfork_child {
  77         my ($self) = @_;
  78         my $lei = $self->{lei};
  79         delete $lei->{imp}; # drop circular ref
  80         $lei->lei_atfork_child;
  81         $self->SUPER::ipc_atfork_child;
  82         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
  83         undef;
  84 }
  85
  86 sub _import_fh {
  87         my ($lei, $fh, $input, $ifmt) = @_;
  88         my $kw = $lei->{opt}->{kw} ?
  89                 PublicInbox::MboxReader->can('mbox_keywords') : undef;
  90         eval {
  91                 if ($ifmt eq 'eml') {
  92                         my $buf = do { local $/; <$fh> } //
  93                                 return $lei->child_error(1 << 8, <<"");
  94 error reading $input: $!
  95
  96                         my $eml = PublicInbox::Eml->new(\$buf);
  97                         _import_eml($eml, $lei, $kw);
  98                 } else { # some mbox (->can already checked in call);
  99                         my $cb = PublicInbox::MboxReader->reads($ifmt) //
 100                                 die "BUG: bad fmt=$ifmt";
 101                         $cb->(undef, $fh, \&_import_eml, $lei, $kw);
 102                 }
 103         };
 104         $lei->child_error(1 << 8, "$input: $@") if $@;
 105 }
 106
 107 sub _import_maildir { # maildir_each_eml cb
 108         my ($f, $kw, $eml, $sto, $set_kw) = @_;
 109         $sto->ipc_do('set_eml', $eml, $set_kw ? { kw => $kw }: ());
 110 }
 111
 112 sub _import_net { # imap_each, nntp_each cb
 113         my ($url, $uid, $kw, $eml, $sto, $set_kw) = @_;
 114         $sto->ipc_do('set_eml', $eml, $set_kw ? { kw => $kw } : ());
 115 }
 116
 117 sub import_path_url {
 118         my ($self, $input) = @_;
 119         my $lei = $self->{lei};
 120         my $ifmt = lc($lei->{opt}->{'in-format'} // '');
 121         # TODO auto-detect?
 122         if ($input =~ m!\Aimaps?://!i) {
 123                 $lei->{net}->imap_each($input, \&_import_net, $lei->{sto},
 124                                         $lei->{opt}->{kw});
 125                 return;
 126         } elsif ($input =~ m!\A(?:nntps?|s?news)://!i) {
 127                 $lei->{net}->nntp_each($input, \&_import_net, $lei->{sto}, 0);
 128                 return;
 129         } elsif ($input =~ s!\A([a-z0-9]+):!!i) {
 130                 $ifmt = lc $1;
 131         }
 132         if (-f $input) {
 133                 my $m = $lei->{opt}->{'lock'} // ($ifmt eq 'eml' ? ['none'] :
 134                                 PublicInbox::MboxLock->defaults);
 135                 my $mbl = PublicInbox::MboxLock->acq($input, 0, $m);
 136                 _import_fh($lei, $mbl->{fh}, $input, $ifmt);
 137         } elsif (-d _ && (-d "$input/cur" || -d "$input/new")) {
 138                 return $lei->fail(<<EOM) if $ifmt && $ifmt ne 'maildir';
 139 $input appears to a be a maildir, not $ifmt
 140 EOM
 141                 PublicInbox::MdirReader::maildir_each_eml($input,
 142                                         \&_import_maildir,
 143                                         $lei->{sto}, $lei->{opt}->{kw});
 144         } else {
 145                 $lei->fail("$input unsupported (TODO)");
 146         }
 147 }
 148
 149 sub import_stdin {
 150         my ($self) = @_;
 151         my $lei = $self->{lei};
 152         my $in = delete $self->{0};
 153         _import_fh($lei, $in, '<stdin>', $lei->{opt}->{'in-format'});
 154 }
 155
 156 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 157 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 158 1;