lib/PublicInbox/LeiImportKw.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # WQ worker for dealing with LeiImport IMAP flags on already-imported messages
   5 # WQ key: {ikw}
   6 package PublicInbox::LeiImportKw;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10
  11 sub new {
  12         my ($cls, $lei) = @_;
  13         my $self = bless { -wq_ident => 'lei import_kw worker' }, $cls;
  14         my ($op_c, $ops) = $lei->workers_start($self, $self->detect_nproc);
  15         $op_c->{ops} = $ops; # for PktOp->event_step
  16         $self->{lei_sock} = $lei->{sock};
  17         $lei->{ikw} = $self;
  18 }
  19
  20 sub ipc_atfork_child {
  21         my ($self) = @_;
  22         my $lei = $self->{lei};
  23         $lei->_lei_atfork_child;
  24         my $net = delete $lei->{net} // die 'BUG: no lei->{net}';
  25         $self->{sto} = $lei->{sto} // die 'BUG: no lei->{sto}';
  26         $self->{verbose} = $lei->{opt}->{verbose};
  27         $self->{lse} = $self->{sto}->search;
  28         $self->{over} = $self->{lse}->over;
  29         $self->{-lms_ro} = $net->{-lms_ro} || die 'BUG: net->{-lms_ro} FALSE';
  30         $self->SUPER::ipc_atfork_child;
  31 }
  32
  33 sub ck_update_kw { # via wq_io_do
  34         my ($self, $url, $uid, $kw) = @_;
  35         my $oidbin = $self->{-lms_ro}->imap_oidbin($url, $uid) // return;
  36         my @docids = $self->{over}->oidbin_exists($oidbin) or return;
  37         $self->{lse}->kw_changed(undef, $kw, \@docids) or return;
  38         $self->{verbose} and
  39                 $self->{lei}->qerr('# '.unpack('H*', $oidbin)." => @$kw\n");
  40         $self->{sto}->ipc_do('set_eml_vmd', undef, { kw => $kw }, \@docids);
  41 }
  42
  43 sub ikw_done_wait {
  44         my ($arg, $pid) = @_;
  45         my ($self, $lei) = @$arg;
  46         $lei->can('wq_done_wait')->($arg, $pid);
  47 }
  48
  49 sub _lei_wq_eof { # EOF callback for main lei daemon
  50         my ($lei) = @_;
  51         my $ikw = delete $lei->{ikw} or return $lei->fail;
  52         $lei->sto_done_request($ikw->{lei_sock});
  53         $ikw->wq_wait_old(\&ikw_done_wait, $lei);
  54 }
  55
  56 1;