lib/PublicInbox/LeiInspect.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei inspect" general purpose inspector for stuff in SQLite and
   5 # Xapian.  Will eventually be useful with plain public-inboxes,
   6 # not just lei/store.  This is totally half-baked at the moment
   7 # but useful for testing.
   8 package PublicInbox::LeiInspect;
   9 use strict;
  10 use v5.10.1;
  11 use PublicInbox::Config;
  12 use PublicInbox::MID qw(mids);
  13
  14 sub inspect_blob ($$) {
  15         my ($lei, $oidhex) = @_;
  16         my $ent = {};
  17         if (my $lse = $lei->{lse}) {
  18                 my $oidbin = pack('H*', $oidhex);
  19                 my @docids = $lse ? $lse->over->oidbin_exists($oidbin) : ();
  20                 $ent->{'lei/store'} = \@docids if @docids;
  21                 my $lms = $lei->lms;
  22                 if (my $loc = $lms ? $lms->locations_for($oidbin) : undef) {
  23                         $ent->{'mail-sync'} = $loc;
  24                 }
  25         }
  26         $ent;
  27 }
  28
  29 sub inspect_imap_uid ($$) {
  30         my ($lei, $uid_uri) = @_;
  31         my $ent = {};
  32         my $lms = $lei->lms or return $ent;
  33         my $oidhex = $lms->imap_oid($lei, $uid_uri);
  34         if (ref(my $err = $oidhex)) { # art2folder error
  35                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
  36         }
  37         $ent->{$$uid_uri} = $oidhex;
  38         $ent;
  39 }
  40
  41 sub inspect_sync_folder ($$) {
  42         my ($lei, $folder) = @_;
  43         my $ent = {};
  44         my $lms = $lei->lms or return $ent;
  45         my $folders = [ $folder ];
  46         my $err = $lms->arg2folder($lei, $folders);
  47         if ($err) {
  48                 if ($err->{fail}) {
  49                         $lei->qerr("# no folders match $folder (non-fatal)");
  50                         @$folders = ();
  51                 }
  52                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
  53         }
  54         for my $f (@$folders) {
  55                 $ent->{$f} = $lms->location_stats($f); # may be undef
  56         }
  57         $ent
  58 }
  59
  60 sub inspect_docid ($$;$) {
  61         my ($lei, $docid, $ent) = @_;
  62         require PublicInbox::Search;
  63         $ent //= {};
  64         my $xdb;
  65         if ($xdb = delete $ent->{xdb}) { # from inspect_num
  66         } elsif (defined(my $dir = $lei->{opt}->{dir})) {
  67                 no warnings 'once';
  68                 $xdb = $PublicInbox::Search::X{Database}->new($dir);
  69         } else {
  70                 $xdb = $lei->{lse}->xdb;
  71         }
  72         $xdb or return $lei->fail('no Xapian DB');
  73         my $doc = $xdb->get_document($docid); # raises
  74         my $data = $doc->get_data;
  75         $ent->{docid} = $docid;
  76         $ent->{data_length} = length($data);
  77         $ent->{description} = $doc->get_description;
  78         $ent->{$_} = $doc->$_ for (qw(termlist_count values_count));
  79         my $cur = $doc->termlist_begin;
  80         my $end = $doc->termlist_end;
  81         for (; $cur != $end; $cur++) {
  82                 my $tn = $cur->get_termname;
  83                 $tn =~ s/\A([A-Z]+)// or warn "$tn no prefix! (???)";
  84                 my $term = ($1 // '');
  85                 push @{$ent->{terms}->{$term}}, $tn;
  86         }
  87         @$_ = sort(@$_) for values %{$ent->{terms} // {}};
  88         $cur = $doc->values_begin;
  89         $end = $doc->values_end;
  90         for (; $cur != $end; $cur++) {
  91                 my $n = $cur->get_valueno;
  92                 my $v = $cur->get_value;
  93                 my $iv = PublicInbox::Search::sortable_unserialise($v);
  94                 $v = $iv + 0 if defined $iv;
  95                 # not using ->[$n] since we may have large gaps in $n
  96                 $ent->{'values'}->{$n} = $v;
  97         }
  98         $ent;
  99 }
 100
 101 sub dir2ibx ($$) {
 102         my ($lei, $dir) = @_;
 103         if (-f "$dir/ei.lock") {
 104                 require PublicInbox::ExtSearch;
 105                 PublicInbox::ExtSearch->new($dir);
 106         } elsif (-f "$dir/inbox.lock" || -d "$dir/public-inbox") {
 107                 require PublicInbox::Inbox; # v2, v1
 108                 bless { inboxdir => $dir }, 'PublicInbox::Inbox';
 109         } else {
 110                 $lei->fail("no (indexed) inbox or extindex at $dir");
 111         }
 112 }
 113
 114 sub inspect_num ($$) {
 115         my ($lei, $num) = @_;
 116         my ($docid, $ibx);
 117         my $ent = { num => $num };
 118         if (defined(my $dir = $lei->{opt}->{dir})) {
 119                 $ibx = dir2ibx($lei, $dir) or return;
 120                 if ($ent->{xdb} = $ibx->xdb) {
 121                         my $num2docid = $lei->{lse}->can('num2docid');
 122                         $docid = $num2docid->($ibx, $num);
 123                 }
 124         } else {
 125                 $ibx = $lei->{lse};
 126                 $lei->{lse}->xdb; # set {nshard} for num2docid
 127                 $docid = $lei->{lse}->num2docid($num);
 128         }
 129         if ($ibx && $ibx->over) {
 130                 my $smsg = $ibx->over->get_art($num);
 131                 $ent->{smsg} = { %$smsg } if $smsg;
 132         }
 133         defined($docid) ? inspect_docid($lei, $docid, $ent) : $ent;
 134 }
 135
 136 sub inspect_mid ($$) {
 137         my ($lei, $mid) = @_;
 138         my ($ibx, $over);
 139         my $ent = { mid => $mid };
 140         if (defined(my $dir = $lei->{opt}->{dir})) {
 141                 my $num2docid = $lei->{lse}->can('num mid => [ $mid ] 2docid');
 142                 $ibx = dir2ibx($lei, $dir) or return;
 143                 # $ent->{xdb} = $ibx->xdb //
 144                         # return $lei->fail("no Xapian DB for $dir");
 145         } else {
 146                 $ibx = $lei->{lse};
 147                 $lei->{lse}->xdb; # set {nshard} for num2docid
 148         }
 149         if ($ibx && $ibx->over) {
 150                 my ($id, $prev);
 151                 while (my $smsg = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 152                         push @{$ent->{smsg}}, { %$smsg }
 153                 }
 154         }
 155         $ent;
 156 }
 157
 158 sub inspect1 ($$$) {
 159         my ($lei, $item, $more) = @_;
 160         my $ent;
 161         if ($item =~ /\Ablob:(.+)/) {
 162                 $ent = inspect_blob($lei, $1);
 163         } elsif ($item =~ m!\Aimaps?://!i) {
 164                 require PublicInbox::URIimap;
 165                 my $uri = PublicInbox::URIimap->new($item);
 166                 if (defined($uri->uid)) {
 167                         $ent = inspect_imap_uid($lei, $uri);
 168                 } else {
 169                         $ent = inspect_sync_folder($lei, $item);
 170                 }
 171         } elsif ($item =~ m!\A(?:maildir|mh):!i || -d $item) {
 172                 $ent = inspect_sync_folder($lei, $item);
 173         } elsif ($item =~ m!\Adocid:([0-9]+)\z!) {
 174                 $ent = inspect_docid($lei, $1 + 0);
 175         } elsif ($item =~ m!\Anum:([0-9]+)\z!) {
 176                 $ent = inspect_num($lei, $1 + 0);
 177         } elsif ($item =~ m!\A(?:mid|m):(.+)\z!) {
 178                 $ent = inspect_mid($lei, $1);
 179         } else { # TODO: more things
 180                 return $lei->fail("$item not understood");
 181         }
 182         $lei->out($lei->{json}->encode($ent));
 183         $lei->out(',') if $more;
 184         1;
 185 }
 186
 187 sub _inspect_argv ($$) {
 188         my ($lei, $argv) = @_;
 189         my $multi = scalar(@$argv) > 1;
 190         $lei->out('[') if $multi;
 191         while (defined(my $x = shift @$argv)) {
 192                 inspect1($lei, $x, scalar(@$argv)) or return;
 193         }
 194         $lei->out(']') if $multi;
 195 }
 196
 197 sub ins_add { # InputPipe->consume callback
 198         my ($lei) = @_; # $_[1] = $rbuf
 199         if (defined $_[1]) {
 200                 $_[1] eq '' and return eval {
 201                         my $str = delete $lei->{istr};
 202                         $str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 203                         my $eml = PublicInbox::Eml->new(\$str);
 204                         _inspect_argv($lei, [
 205                                 'blob:'.$lei->git_oid($eml)->hexdigest,
 206                                 map { "mid:$_" } @{mids($eml)} ]);
 207                 };
 208                 $lei->{istr} .= $_[1];
 209         } else {
 210                 $lei->fail("error reading stdin: $!");
 211         }
 212 }
 213
 214 sub lei_inspect {
 215         my ($lei, @argv) = @_;
 216         $lei->{json} = ref(PublicInbox::Config::json())->new->utf8->canonical;
 217         $lei->{lse} = ($lei->{opt}->{external} // 1) ? do {
 218                 my $sto = $lei->_lei_store;
 219                 $sto ? $sto->search : undef;
 220         } : undef;
 221         if ($lei->{opt}->{pretty} || -t $lei->{1}) {
 222                 $lei->{json}->pretty(1)->indent(2);
 223         }
 224         $lei->start_pager if -t $lei->{1};
 225         $lei->{1}->autoflush(0);
 226         if ($lei->{opt}->{stdin}) {
 227                 return $lei->fail(<<'') if @argv;
 228 no args allowed on command-line with --stdin
 229
 230                 require PublicInbox::InputPipe;
 231                 PublicInbox::InputPipe::consume($lei->{0}, \&ins_add, $lei);
 232                 return;
 233         }
 234         _inspect_argv($lei, \@argv);
 235 }
 236
 237 sub _complete_inspect {
 238         my ($lei, @argv) = @_;
 239         my $lms = $lei->lms or return;
 240         my $match_cb = $lei->complete_url_prepare(\@argv);
 241         map { $match_cb->($_) } $lms->folders;
 242 }
 243
 244 1;