lib/PublicInbox/LeiInspect.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei inspect" general purpose inspector for stuff in SQLite and
   5 # Xapian.  Will eventually be useful with plain public-inboxes,
   6 # not just lei/store.  This is totally half-baked at the moment
   7 # but useful for testing.
   8 package PublicInbox::LeiInspect;
   9 use strict;
  10 use v5.10.1;
  11 use PublicInbox::Config;
  12
  13 sub inspect_blob ($$) {
  14         my ($lei, $oidhex) = @_;
  15         my $ent = {};
  16         if (my $lse = $lei->{lse}) {
  17                 my @docids = $lse ? $lse->over->blob_exists($oidhex) : ();
  18                 $ent->{'lei/store'} = \@docids if @docids;
  19                 my $lms = $lse->lms;
  20                 if (my $loc = $lms ? $lms->locations_for($oidhex) : undef) {
  21                         $ent->{sync} = $loc;
  22                 }
  23         }
  24         $ent;
  25 }
  26
  27 sub inspect_sync_folder ($$) {
  28         my ($lei, $folder) = @_;
  29         my $ent = {};
  30         my $lse = $lei->{lse} or return $ent;
  31         my $lms = $lse->lms or return $ent;
  32         my @folders;
  33         if ($folder =~ m!\Aimaps?://!i) {
  34                 require PublicInbox::URIimap;
  35                 my $uri = PublicInbox::URIimap->new($folder)->canonical;
  36                 if (defined($uri->uidvalidity)) {
  37                         $folders[0] = $$uri;
  38                 } else {
  39                         my @maybe = $lms->folders($$uri);
  40                         @folders = grep {
  41                                 my $u = PublicInbox::URIimap->new($_);
  42                                 $uri->uidvalidity($u->uidvalidity);
  43                                 $$uri eq $$u;
  44                         } @maybe;
  45                 }
  46         } elsif ($folder =~ m!\A(maildir|mh):(.+)!i) {
  47                 my $type = $1;
  48                 $folders[0] = "$type:".$lei->abs_path($2);
  49         } elsif (-d $folder) {
  50                 $folders[0] = 'maildir:'.$lei->abs_path($folder);
  51         } else {
  52                 $lei->fail("$folder not understood");
  53         }
  54         $lei->qerr("# no folders match $folder (non-fatal)") if !@folders;
  55         for my $f (@folders) {
  56                 $ent->{$f} = $lms->location_stats($f); # may be undef
  57         }
  58         $ent
  59 }
  60
  61 sub inspect1 ($$$) {
  62         my ($lei, $item, $more) = @_;
  63         my $ent;
  64         if ($item =~ /\Ablob:(.+)/) {
  65                 $ent = inspect_blob($lei, $1);
  66         } elsif ($item =~ m!\Aimaps?://!i ||
  67                         $item =~ m!\A(?:maildir|mh):!i || -d $item) {
  68                 $ent = inspect_sync_folder($lei, $item);
  69         } else { # TODO: more things
  70                 return $lei->fail("$item not understood");
  71         }
  72         $lei->out($lei->{json}->encode($ent));
  73         $lei->out(',') if $more;
  74         1;
  75 }
  76
  77 sub lei_inspect {
  78         my ($lei, @argv) = @_;
  79         $lei->{1}->autoflush(0);
  80         my $multi = scalar(@argv) > 1;
  81         $lei->out('[') if $multi;
  82         $lei->{json} = ref(PublicInbox::Config::json())->new->utf8->canonical;
  83         $lei->{lse} = ($lei->{opt}->{external} // 1) ? do {
  84                 my $sto = $lei->_lei_store;
  85                 $sto ? $sto->search : undef;
  86         } : undef;
  87         if ($lei->{opt}->{pretty} || -t $lei->{1}) {
  88                 $lei->{json}->pretty(1)->indent(2);
  89         }
  90         while (defined(my $x = shift @argv)) {
  91                 inspect1($lei, $x, scalar(@argv)) or return;
  92         }
  93         $lei->out(']') if $multi;
  94 }
  95
  96 1;