lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  18                 AutoCommit => 1,
  19                 RaiseError => 1,
  20                 PrintError => 0,
  21                 ReadOnly => !$rw,
  22                 sqlite_use_immediate_transaction => 1,
  23         });
  24         # no sqlite_unicode, here, all strings are binary
  25         create_tables($self, $dbh) if $rw;
  26         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  27         $dbh->do('PRAGMA case_sensitive_like = ON');
  28         $dbh;
  29 }
  30
  31 sub new {
  32         my ($cls, $f) = @_;
  33         bless {
  34                 filename => $f,
  35                 fmap => {},
  36                 lock_path => "$f.flock",
  37         }, $cls;
  38 }
  39
  40 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  41
  42 sub lms_pause {
  43         my ($self) = @_;
  44         $self->{fmap} = {};
  45         delete $self->{dbh};
  46 }
  47
  48 sub create_tables {
  49         my ($self, $dbh) = @_;
  50         my $lk = $self->lock_for_scope;
  51
  52         $dbh->do(<<'');
  53 CREATE TABLE IF NOT EXISTS folders (
  54         fid INTEGER PRIMARY KEY,
  55         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  56         UNIQUE (loc)
  57 )
  58
  59         $dbh->do(<<'');
  60 CREATE TABLE IF NOT EXISTS blob2num (
  61         oidbin VARBINARY NOT NULL,
  62         fid INTEGER NOT NULL, /* folder ID */
  63         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  64         UNIQUE (oidbin, fid, uid)
  65 )
  66
  67         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  68         $dbh->do(<<'');
  69 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  70
  71         $dbh->do(<<'');
  72 CREATE TABLE IF NOT EXISTS blob2name (
  73         oidbin VARBINARY NOT NULL,
  74         fid INTEGER NOT NULL, /* folder ID */
  75         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  76         UNIQUE (oidbin, fid, name)
  77 )
  78
  79         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  80         $dbh->do(<<'');
  81 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  82
  83 }
  84
  85 sub fid_for {
  86         my ($self, $folder, $rw) = @_;
  87         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  88         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  89         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  90         return $fid if defined $fid;
  91
  92         # caller had trailing slash (LeiToMail)
  93         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  94                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  95                 if (defined $fid) {
  96                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  97 UPDATE folders SET loc = ? WHERE fid = ?
  98 EOM
  99                         return $fid;
 100                 }
 101         # sometimes we stored trailing slash..
 102         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 103                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 104                 if (defined $fid) {
 105                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 106 UPDATE folders SET loc = ? WHERE fid = ?
 107 EOM
 108                         return $fid;
 109                 }
 110         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 111                 require PublicInbox::URIimap;
 112                 PublicInbox::URIimap->new($folder)->uidvalidity //
 113                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 114         }
 115         return unless $rw;
 116
 117         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 118
 119         $fid += 1;
 120         # in case we're reusing, clobber existing stale refs:
 121         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 122         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 123
 124         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 125         $sth->execute($fid, $folder);
 126
 127         $fid;
 128 }
 129
 130 sub add_folders {
 131         my ($self, @folders) = @_;
 132         my $lk = $self->lock_for_scope;
 133         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 134 }
 135
 136 sub set_src {
 137         my ($self, $oidbin, $folder, $id) = @_;
 138         my $lk = $self->lock_for_scope;
 139         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 140         my $sth;
 141         if (ref($id)) { # scalar name
 142                 $id = $$id;
 143                 $sth = $self->{dbh}->prepare_cached(<<'');
 144 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 145
 146         } else { # numeric ID (IMAP UID, MH number)
 147                 $sth = $self->{dbh}->prepare_cached(<<'');
 148 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 149
 150         }
 151         $sth->execute($oidbin, $fid, $id);
 152 }
 153
 154 sub clear_src {
 155         my ($self, $folder, $id) = @_;
 156         my $lk = $self->lock_for_scope;
 157         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 158         my $sth;
 159         if (ref($id)) { # scalar name
 160                 $id = $$id;
 161                 $sth = $self->{dbh}->prepare_cached(<<'');
 162 DELETE FROM blob2name WHERE fid = ? AND name = ?
 163
 164         } else {
 165                 $sth = $self->{dbh}->prepare_cached(<<'');
 166 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 167
 168         }
 169         $sth->execute($fid, $id);
 170 }
 171
 172 # Maildir-only
 173 sub mv_src {
 174         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 175         my $lk = $self->lock_for_scope;
 176         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 177         my $sth = $self->{dbh}->prepare_cached(<<'');
 178 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 179
 180         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 181         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 182                 $sth = $self->{dbh}->prepare_cached(<<'');
 183 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 184
 185                 $sth->execute($oidbin, $fid, $newbn);
 186         }
 187 }
 188
 189 # read-only, iterates every oidbin + UID or name for a given folder
 190 sub each_src {
 191         my ($self, $folder, $cb, @args) = @_;
 192         my $dbh = $self->{dbh} //= dbh_new($self);
 193         my $fid;
 194         if (ref($folder) eq 'HASH') {
 195                 $fid = $folder->{fid} // die "BUG: no `fid'";
 196         } else {
 197                 $fid = $self->{fmap}->{$folder} //=
 198                         fid_for($self, $folder) // return;
 199         }
 200
 201         # minimize implicit txn time to avoid blocking writers by
 202         # batching SELECTs.  This looks wonky but is necessary since
 203         # $cb-> may access the DB on its own.
 204         my $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 205 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ?
 206 ORDER BY _rowid_ ASC LIMIT 1000
 207
 208         my $min = @$ary ? $ary->[-1]->[0] : undef;
 209         while (defined $min) {
 210                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 211
 212                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 213 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? AND _rowid_ > ?
 214 ORDER BY _rowid_ ASC LIMIT 1000
 215
 216                 $min = @$ary ? $ary->[-1]->[0] : undef;
 217         }
 218
 219         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 220 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 221 ORDER BY _rowid_ ASC LIMIT 1000
 222
 223         $min = @$ary ? $ary->[-1]->[0] : undef;
 224         while (defined $min) {
 225                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 226
 227                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 228 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 229 ORDER BY _rowid_ ASC LIMIT 1000
 230
 231                 $min = @$ary ? $ary->[-1]->[0] : undef;
 232         }
 233 }
 234
 235 sub location_stats {
 236         my ($self, $folder) = @_;
 237         my $dbh = $self->{dbh} //= dbh_new($self);
 238         my $fid;
 239         my $ret = {};
 240         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 241         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 242 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 243
 244         $ret->{'name.count'} = $row if $row;
 245         for my $op (qw(count min max)) {
 246                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 247 SELECT $op(uid) FROM blob2num WHERE fid = ?
 248
 249                 $row or last;
 250                 $ret->{"uid.$op"} = $row;
 251         }
 252         $ret;
 253 }
 254
 255 # returns a { location => [ list-of-ids-or-names ] } mapping
 256 sub locations_for {
 257         my ($self, $oidbin) = @_;
 258         my ($fid, $sth, $id, %fid2id);
 259         my $dbh = $self->{dbh} //= dbh_new($self);
 260         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 261         $sth->execute($oidbin);
 262         while (my ($fid, $uid) = $sth->fetchrow_array) {
 263                 push @{$fid2id{$fid}}, $uid;
 264         }
 265         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 266         $sth->execute($oidbin);
 267         while (my ($fid, $name) = $sth->fetchrow_array) {
 268                 push @{$fid2id{$fid}}, $name;
 269         }
 270         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 271         my $ret = {};
 272         while (my ($fid, $ids) = each %fid2id) {
 273                 $sth->execute($fid);
 274                 my ($loc) = $sth->fetchrow_array;
 275                 unless (defined $loc) {
 276                         my $oidhex = unpack('H*', $oidbin);
 277                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 278                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 279                                 } @$ids;
 280                         next;
 281                 }
 282                 $ret->{$loc} = $ids;
 283         }
 284         scalar(keys %$ret) ? $ret : undef;
 285 }
 286
 287 # returns a list of folders used for completion
 288 sub folders {
 289         my ($self, $pfx) = @_;
 290         my $dbh = $self->{dbh} //= dbh_new($self);
 291         my $sql = 'SELECT loc FROM folders';
 292         my @pfx;
 293         if (defined $pfx) {
 294                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 295                 @pfx = ($pfx, '\\');
 296                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 297                 $pfx[0] .= '%';
 298         }
 299         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 300 }
 301
 302 sub local_blob {
 303         my ($self, $oidhex, $vrfy) = @_;
 304         my $dbh = $self->{dbh} //= dbh_new($self);
 305         my $b2n = $dbh->prepare(<<'');
 306 SELECT f.loc,b.name FROM blob2name b
 307 LEFT JOIN folders f ON b.fid = f.fid
 308 WHERE b.oidbin = ?
 309
 310         $b2n->execute(pack('H*', $oidhex));
 311         while (my ($d, $n) = $b2n->fetchrow_array) {
 312                 substr($d, 0, length('maildir:')) = '';
 313                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 314                 # in "new/", despite (from what I understand of reading
 315                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 316                 # applies to files in "cur/".
 317                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 318                 for my $x (@try) {
 319                         my $f = "$d/$x/$n";
 320                         open my $fh, '<', $f or next;
 321                         # some (buggy) Maildir writers are non-atomic:
 322                         next unless -s $fh;
 323                         local $/;
 324                         my $raw = <$fh>;
 325                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 326                                 warn "$f changed $oidhex\n";
 327                                 next;
 328                         }
 329                         return \$raw;
 330                 }
 331         }
 332         undef;
 333 }
 334
 335 sub match_imap_url {
 336         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 337         $all //= [ $self->folders ];
 338         require PublicInbox::URIimap;
 339         my $want = PublicInbox::URIimap->new($url)->canonical;
 340         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 341         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 342                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 343         my @match;
 344         for my $x (@uri) {
 345                 next if $x->mailbox ne $want->mailbox;
 346                 next if $x->host ne $want->host;
 347                 next if $x->port != $want->port;
 348                 my $x_uidval = $x->uidvalidity;
 349                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 350
 351                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 352                 if (defined($x->auth) && !defined($want->auth) &&
 353                                 !defined($want->user)) {
 354                         push @match, $x;
 355                 # or maybe user was forgotten on CLI:
 356                 } elsif (defined($x->user) && !defined($want->user)) {
 357                         push @match, $x;
 358                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 359                         push @match, $x;
 360                 }
 361         }
 362         return @match if wantarray;
 363         scalar(@match) <= 1 ? $match[0] :
 364                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 365 }
 366
 367 # returns undef on failure, number on success
 368 sub group2folders {
 369         my ($self, $lei, $all, $folders) = @_;
 370         return $lei->fail(<<EOM) if @$folders;
 371 --all= not compatible with @$folders on command-line
 372 EOM
 373         my %x = map { $_ => $_ } split(/,/, $all);
 374         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 375         push(@ok, '') if $all eq '';
 376         my @no = keys %x;
 377         if (@no) {
 378                 @no = (join(',', @no));
 379                 return $lei->fail(<<EOM);
 380 --all=@no not accepted (must be `local' and/or `remote')
 381 EOM
 382         }
 383         my (%seen, @inc);
 384         my @all = $self->folders;
 385         for my $ok (@ok) {
 386                 if ($ok eq 'local') {
 387                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 388                 } elsif ($ok eq 'remote') {
 389                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 390                 } elsif ($ok ne '') {
 391                         return $lei->fail("--all=$all not understood");
 392                 } else {
 393                         @inc = @all;
 394                 }
 395                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 396         }
 397         scalar(@$folders) || $lei->fail(<<EOM);
 398 no --mail-sync folders known to lei
 399 EOM
 400 }
 401
 402 # map CLI args to folder table entries, returns undef on failure
 403 sub arg2folder {
 404         my ($self, $lei, $folders) = @_;
 405         my @all = $self->folders;
 406         my %all = map { $_ => 1 } @all;
 407         my ($err, @no);
 408         for (@$folders) {
 409                 next if $all{$_}; # ok
 410                 if (m!\A(maildir|mh):(.+)!i) {
 411                         my $type = lc $1;
 412                         my $d = "$type:".$lei->abs_path($2);
 413                         push(@no, $_) unless $all{$d};
 414                         $_ = $d;
 415                 } elsif (-d "$_/new" && -d "$_/cur") {
 416                         my $d = 'maildir:'.$lei->abs_path($_);
 417                         push(@no, $_) unless $all{$d};
 418                         $_ = $d;
 419                 } elsif (m!\Aimaps?://!i) {
 420                         my $orig = $_;
 421                         my $res = match_imap_url($self, $orig, \@all);
 422                         if (ref $res) {
 423                                 $_ = $$res;
 424                                 push(@{$err->{qerr}}, <<EOM);
 425 # using `$res' instead of `$orig'
 426 EOM
 427                         } else {
 428                                 $lei->err($res) if defined $res;
 429                                 push @no, $orig;
 430                         }
 431                 } else {
 432                         push @no, $_;
 433                 }
 434         }
 435         if (@no) {
 436                 my $no = join("\n\t", @no);
 437                 $err->{fail} = <<EOF;
 438 No sync information for: $no
 439 Run `lei ls-mail-sync' to display valid choices
 440 EOF
 441         }
 442         $err;
 443 }
 444
 445 sub forget_folders {
 446         my ($self, @folders) = @_;
 447         my $lk = $self->lock_for_scope;
 448         for my $folder (@folders) {
 449                 my $fid = delete($self->{fmap}->{$folder}) //
 450                         fid_for($self, $folder) // next;
 451                 for my $t (qw(blob2name blob2num folders)) {
 452                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 453                                         undef, $fid);
 454                 }
 455         }
 456 }
 457
 458 # only used for changing canonicalization errors
 459 sub rename_folder {
 460         my ($self, $old, $new) = @_;
 461         my $lk = $self->lock_for_scope;
 462         my $ofid = delete($self->{fmap}->{$old}) //
 463                 fid_for($self, $old) // return;
 464         eval {
 465                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 466 UPDATE folders SET loc = ? WHERE fid = ?
 467 EOM
 468         };
 469         if ($@ =~ /\bunique\b/i) {
 470                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 471                 for my $t (qw(blob2name blob2num)) {
 472                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 473 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 474 EOM
 475                 }
 476                 $self->{dbh}->do(<<EOM, undef, $ofid);
 477 DELETE FROM folders WHERE fid = ?
 478 EOM
 479         }
 480 }
 481
 482 sub imap_oidbin ($$$) {
 483         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 484         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 485         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 486 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 487 EOM
 488         $sth->execute($fid, $uid);
 489         $sth->fetchrow_array;
 490 }
 491
 492 sub name_oidbin ($$$) {
 493         my ($self, $mdir, $nm) = @_;
 494         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 495         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 496 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 497 EOM
 498         $sth->execute($fid, $nm);
 499         $sth->fetchrow_array;
 500 }
 501
 502 sub imap_oid {
 503         my ($self, $lei, $uid_uri) = @_;
 504         my $mailbox_uri = $uid_uri->clone;
 505         $mailbox_uri->uid(undef);
 506         my $folders = [ $$mailbox_uri ];
 507         if (my $err = $self->arg2folder($lei, $folders)) {
 508                 if ($err->{fail}) {
 509                         $lei->qerr("# no sync information for $mailbox_uri");
 510                         return;
 511                 }
 512                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 513         }
 514         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 515         $oidbin ? unpack('H*', $oidbin) : undef;
 516 }
 517
 518 1;